9239e3b0b0f8afcc34d080917fab4333ad6ed99b
[lttng-tools.git] / configure.ac
1 AC_PREREQ([2.64])
2 AC_INIT([lttng-tools],[2.10.0-pre],[jeremie.galarneau@efficios.com],[],[https://lttng.org])
3
4 AC_CONFIG_HEADERS([include/config.h])
5 AC_CONFIG_AUX_DIR([config])
6 AC_CONFIG_MACRO_DIR([m4])
7
8 AC_CANONICAL_TARGET
9 AC_CANONICAL_HOST
10
11 AM_INIT_AUTOMAKE([foreign dist-bzip2 no-dist-gzip tar-pax])
12 AM_MAINTAINER_MODE([enable])
13
14 # Enable silent rules if available (Introduced in AM 1.11)
15 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
16
17 AC_REQUIRE_AUX_FILE([tap-driver.sh])
18
19 # Checks for C compiler
20 AC_USE_SYSTEM_EXTENSIONS
21 AC_SYS_LARGEFILE
22 AC_PROG_CC
23 AC_PROG_CC_STDC
24
25 # Checks for programs.
26 AC_PROG_GREP
27 AC_PROG_LEX
28 AC_PROG_MAKE_SET
29 AC_PROG_SED
30 AC_PROG_YACC
31 AC_PATH_PROG(report_fold, fold)
32 LT_INIT
33
34 # Check for objcopy, required by the base address statedump and dynamic linker tests
35 AC_CHECK_TOOL([OBJCOPY], objcopy, no)
36 AS_IF([test "x$OBJCOPY" = xno],
37 [AC_MSG_WARN([Cannont find objcopy. The base address statedump and dynamic linker tests will be disabled. Install the binutils package to remediate this.])]
38 )
39 AM_CONDITIONAL([HAVE_OBJCOPY], [test "x$OBJCOPY" != xno])
40
41 # Checks for typedefs, structures, and compiler characteristics.
42 AC_C_INLINE
43 AC_TYPE_INT32_T
44 AC_TYPE_INT64_T
45 AC_TYPE_MODE_T
46 AC_TYPE_OFF_T
47 AC_TYPE_PID_T
48 AC_TYPE_SIZE_T
49 AC_TYPE_SSIZE_T
50 AC_TYPE_UID_T
51 AC_TYPE_UINT16_T
52 AC_TYPE_UINT32_T
53 AC_TYPE_UINT64_T
54 AC_TYPE_UINT8_T
55
56 AX_C___ATTRIBUTE__
57 AS_IF([test "x$ax_cv___attribute__" = "xyes"],
58 [:],
59 [AC_MSG_ERROR([The compiler does not support __attribute__ extensions])])
60
61 AX_PTHREAD(,[AC_MSG_ERROR([Could not configure pthreads support])])
62 LIBS="$PTHREAD_LIBS $LIBS"
63 CFLAGS="$CFLAGS $PTHREAD_CFLAGS"
64 CC="$PTHREAD_CC"
65
66 AX_LIB_SOCKET_NSL
67
68 LT_NO_UNDEFINED=""
69 AS_CASE([$host_os],
70 [cygwin*],
71 [
72 LT_NO_UNDEFINED="-no-undefined"
73 ]
74 )
75
76 AC_SUBST(LT_NO_UNDEFINED)
77
78 # Compute minor/major/patchlevel version numbers
79 major_version=$(echo AC_PACKAGE_VERSION | $SED 's/^\([[0-9]]\)*\.[[0-9]]*\.[[0-9]]*.*$/\1/')
80 minor_version=$(echo AC_PACKAGE_VERSION | $SED 's/^[[0-9]]*\.\([[0-9]]*\)\.[[0-9]]*.*$/\1/')
81 patchlevel_version=$(echo AC_PACKAGE_VERSION | $SED 's/^[[0-9]]*\.[[0-9]]*\.\([[0-9]]*\).*$/\1/')
82
83 AC_SUBST([MAJOR_VERSION], [$major_version])
84 AC_SUBST([MINOR_VERSION], [$minor_version])
85 AC_SUBST([PATCHLEVEL_VERSION], [$patchlevel_version])
86 AC_DEFINE_UNQUOTED([VERSION_MAJOR], $major_version, [LTTng-Tools major version number])
87 AC_DEFINE_UNQUOTED([VERSION_MINOR], $minor_version, [LTTng-Tools minor version number])
88 AC_DEFINE_UNQUOTED([VERSION_PATCHLEVEL], $patchlevel_version, [LTTng-Tools patchlevel version number])
89
90 version_name="KeKriek"
91 version_description='From Brasserie Dunham, a sour mashed golden wheat ale fermented with local sour cherries from Tougas orchards. Fresh sweet cherry notes with some tartness, lively carbonation with a dry finish.'
92 version_description_c=$(echo $version_description | $SED 's/"/\\"/g')
93
94 AC_DEFINE_UNQUOTED([VERSION_NAME], ["$version_name"], "")
95 AC_DEFINE_UNQUOTED([VERSION_DESCRIPTION], ["$version_description_c"], "")
96
97 # libtool link_all_deplibs fixup. See http://bugs.lttng.org/issues/321.
98 AC_ARG_ENABLE(libtool-linkdep-fixup,
99 AS_HELP_STRING([--disable-libtool-linkdep-fixup],
100 [disable the libtool fixup for linking all dependent libraries (link_all_deplibs)]),
101 libtool_fixup=$enableval,
102 libtool_fixup=yes)
103
104 AS_IF([test "x$libtool_fixup" = "xyes"],
105 [
106 libtool_m4="$srcdir/m4/libtool.m4"
107 libtool_flag_pattern=".*link_all_deplibs\s*,\s*\$1\s*)"
108 AC_MSG_CHECKING([for occurence(s) of link_all_deplibs = no in $libtool_m4])
109 libtool_flag_pattern_count=$($GREP -c "$libtool_flag_pattern\s*=\s*no" $libtool_m4)
110 AS_IF([test $libtool_flag_pattern_count -ne 0],
111 [
112 AC_MSG_RESULT([$libtool_flag_pattern_count])
113 AC_MSG_WARN([the detected libtool will not link all dependencies, forcing link_all_deplibs = unknown])
114 $SED -i "s/\($libtool_flag_pattern\)\s*=\s*no/\1=unknown/g" $libtool_m4
115 ],
116 [
117 AC_MSG_RESULT([none])
118 ])
119 ])
120
121 AM_CONDITIONAL([NO_SHARED], [test x$enable_shared = xno])
122
123 AC_CHECK_HEADERS([ \
124 sys/types.h unistd.h fcntl.h string.h pthread.h limits.h \
125 signal.h stdlib.h sys/un.h sys/socket.h stdlib.h stdio.h \
126 getopt.h sys/ipc.h sys/shm.h popt.h grp.h arpa/inet.h \
127 netdb.h netinet/in.h paths.h stddef.h sys/file.h sys/ioctl.h \
128 sys/mount.h sys/param.h sys/time.h
129 ])
130
131 # Basic functions check
132 AC_CHECK_FUNCS([ \
133 atexit bzero clock_gettime dup2 fdatasync fls ftruncate \
134 gethostbyname gethostname getpagesize localtime_r memchr memset \
135 mkdir munmap putenv realpath rmdir socket strchr strcspn strdup \
136 strncasecmp strndup strnlen strpbrk strrchr strstr strtol strtoul \
137 strtoull dirfd gethostbyname2 getipnodebyname epoll_create1 \
138 ])
139
140 # Check if clock_gettime, timer_create, timer_settime, and timer_delete are available in lib rt, and if so,
141 # add -lrt to LIBS
142 AC_CHECK_LIB([rt], [clock_gettime, timer_create, timer_settime, timer_delete])
143
144 # Babeltrace viewer check
145 AC_ARG_WITH([babeltrace-bin],
146 AS_HELP_STRING([--with-babeltrace-bin],
147 [Location of the babeltrace viewer executable (including the filename)]),
148 [BABELTRACE_BIN="$withval"],
149 [BABELTRACE_BIN=''])
150 AC_SUBST([BABELTRACE_BIN])
151
152 # lttv-gui
153 AC_ARG_WITH([lttv-gui-bin],
154 AS_HELP_STRING([--with-lttv-gui-bin],
155 [Location of the lttv GUI viewer executable (including the filename)]),
156 [LTTV_GUI_BIN="$withval"],
157 [LTTV_GUI_BIN=''])
158 AC_SUBST([LTTV_GUI_BIN])
159
160 AC_ARG_WITH([consumerd32-bin],
161 AS_HELP_STRING([--with-consumerd32-bin],
162 [Location of the 32-bit consumerd executable (including the filename)]),
163 [CONSUMERD32_BIN="$withval"],
164 [CONSUMERD32_BIN=''])
165 AC_SUBST([CONSUMERD32_BIN])
166
167 AC_ARG_WITH([consumerd64-bin],
168 AS_HELP_STRING([--with-consumerd64-bin],
169 [Location of the 64-bit consumerd executable (including the filename)]),
170 [CONSUMERD64_BIN="$withval"],
171 [CONSUMERD64_BIN=''])
172 AC_SUBST([CONSUMERD64_BIN])
173
174 AC_ARG_WITH([consumerd32-libdir],
175 AS_HELP_STRING([--with-consumerd32-libdir],
176 [Directory containing the 32-bit consumerd libraries]),
177 [CONSUMERD32_LIBDIR="$withval"],
178 [CONSUMERD32_LIBDIR=''])
179 AC_SUBST([CONSUMERD32_LIBDIR])
180
181 AC_ARG_WITH([consumerd64-libdir],
182 AS_HELP_STRING([--with-consumerd64-libdir],
183 [Directory containing the 64-bit consumerd libraries]),
184 [CONSUMERD64_LIBDIR="$withval"],
185 [CONSUMERD64_LIBDIR=''])
186 AC_SUBST([CONSUMERD64_LIBDIR])
187
188 AC_ARG_WITH([sessiond-bin],
189 AS_HELP_STRING([--with-sessiond-bin],
190 [Location of the sessiond executable (including the filename)]),
191 [SESSIOND_BIN="$withval"],
192 [SESSIOND_BIN=''])
193 AC_SUBST([SESSIOND_BIN])
194
195 AC_ARG_WITH([lttng-system-rundir],
196 AS_HELP_STRING([--with-lttng-system-rundir],
197 [Location of the system directory where the system-wide lttng-sessiond runtime files are kept. The default is "/var/run/lttng".]),
198 [LTTNG_SYSTEM_RUNDIR="$withval"],
199 [LTTNG_SYSTEM_RUNDIR="/var/run/lttng"])
200 AC_SUBST([LTTNG_SYSTEM_RUNDIR])
201
202 AC_ARG_ENABLE([test-java-agent-jul],
203 [AS_HELP_STRING([--enable-test-java-agent-jul],[enable the LTTng UST Java agent JUL tests [default=no]])],
204 [test_java_agent_jul=$enableval],
205 [test_java_agent_jul=no]
206 )
207
208 AC_ARG_ENABLE([test-java-agent-log4j],
209 [AS_HELP_STRING([--enable-test-java-agent-log4j],[enable the LTTng UST Java agent Log4j tests [default=no]])],
210 [test_java_agent_log4j=$enableval],
211 [test_java_agent_log4j=no]
212 )
213
214 AC_ARG_ENABLE([test-java-agent-all],
215 [AS_HELP_STRING([--enable-test-java-agent-all],[enable all the LTTng UST Java agent tests [default=no]])],
216 [test_java_agent_jul=$enableval
217 test_java_agent_log4j=$enableval],
218 [:]
219 )
220
221 AC_DEFINE_UNQUOTED([CONFIG_CONSUMERD32_BIN], "$CONSUMERD32_BIN", [Location of the 32-bit consumerd executable.])
222 AC_DEFINE_UNQUOTED([CONFIG_CONSUMERD64_BIN], "$CONSUMERD64_BIN", [Location of the 64-bit consumerd executable])
223 AC_DEFINE_UNQUOTED([CONFIG_CONSUMERD32_LIBDIR], "$CONSUMERD32_LIBDIR", [Search for consumerd 32-bit libraries in this location.])
224 AC_DEFINE_UNQUOTED([CONFIG_CONSUMERD64_LIBDIR], "$CONSUMERD64_LIBDIR", [Search for consumerd 64-bit libraries in this location.])
225 AC_DEFINE_UNQUOTED([CONFIG_BABELTRACE_BIN], "$BABELTRACE_BIN", [Location of the babeltrace viewer executable.])
226 AC_DEFINE_UNQUOTED([CONFIG_LTTV_GUI_BIN], "$LTTV_GUI_BIN", [Location of the lttv GUI viewer executable.])
227 AC_DEFINE_UNQUOTED([CONFIG_SESSIOND_BIN], "$SESSIOND_BIN", [Location of the sessiond executable.])
228 AC_DEFINE_UNQUOTED([CONFIG_LTTNG_SYSTEM_RUNDIR], ["$LTTNG_SYSTEM_RUNDIR"], [LTTng system runtime directory])
229
230 AC_DEFUN([_AC_DEFINE_AND_SUBST], [
231 AC_DEFINE_UNQUOTED([CONFIG_$1], [$2], [$1])
232 $1="$2"
233 AC_SUBST([$1])
234 ])
235
236 AC_DEFUN([_AC_DEFINE_QUOTED_AND_SUBST], [
237 AC_DEFINE_UNQUOTED([CONFIG_$1], ["$2"], [$1])
238 $1="$2"
239 AC_SUBST([$1])
240 ])
241
242 # Default values
243 m4_define([_DEFAULT_CHANNEL_SUBBUF_SIZE], [16384])
244 m4_define([_DEFAULT_CHANNEL_SUBBUF_NUM], [4])
245 m4_define([_DEFAULT_CHANNEL_SWITCH_TIMER], [0])
246 m4_define([_DEFAULT_CHANNEL_LIVE_TIMER], [0])
247 m4_define([_DEFAULT_CHANNEL_READ_TIMER], [200000])
248 m4_define([_DEFAULT_CHANNEL_MONITOR_TIMER], [1000000])
249 _AC_DEFINE_AND_SUBST([DEFAULT_AGENT_TCP_PORT], [5345])
250 _AC_DEFINE_AND_SUBST([DEFAULT_APP_SOCKET_RW_TIMEOUT], [5])
251 _AC_DEFINE_AND_SUBST([DEFAULT_CHANNEL_SUBBUF_SIZE], [_DEFAULT_CHANNEL_SUBBUF_SIZE])
252 _AC_DEFINE_AND_SUBST([DEFAULT_CHANNEL_TRACEFILE_COUNT], [0])
253 _AC_DEFINE_AND_SUBST([DEFAULT_CHANNEL_TRACEFILE_SIZE], [0])
254 _AC_DEFINE_AND_SUBST([DEFAULT_KERNEL_CHANNEL_LIVE_TIMER], [_DEFAULT_CHANNEL_LIVE_TIMER])
255 _AC_DEFINE_AND_SUBST([DEFAULT_KERNEL_CHANNEL_READ_TIMER], [_DEFAULT_CHANNEL_READ_TIMER])
256 _AC_DEFINE_AND_SUBST([DEFAULT_KERNEL_CHANNEL_SUBBUF_NUM], [_DEFAULT_CHANNEL_SUBBUF_NUM])
257 _AC_DEFINE_AND_SUBST([DEFAULT_KERNEL_CHANNEL_SUBBUF_SIZE], [1048576])
258 _AC_DEFINE_AND_SUBST([DEFAULT_KERNEL_CHANNEL_SWITCH_TIMER], [_DEFAULT_CHANNEL_SWITCH_TIMER])
259 _AC_DEFINE_AND_SUBST([DEFAULT_KERNEL_CHANNEL_MONITOR_TIMER], [_DEFAULT_CHANNEL_MONITOR_TIMER])
260 _AC_DEFINE_AND_SUBST([DEFAULT_LTTNG_LIVE_TIMER], [1000000])
261 _AC_DEFINE_AND_SUBST([DEFAULT_METADATA_CACHE_SIZE], [4096])
262 _AC_DEFINE_AND_SUBST([DEFAULT_METADATA_READ_TIMER], [0])
263 _AC_DEFINE_AND_SUBST([DEFAULT_METADATA_SUBBUF_NUM], [2])
264 _AC_DEFINE_AND_SUBST([DEFAULT_METADATA_SUBBUF_SIZE], [4096])
265 _AC_DEFINE_AND_SUBST([DEFAULT_METADATA_SWITCH_TIMER], [_DEFAULT_CHANNEL_SWITCH_TIMER])
266 _AC_DEFINE_AND_SUBST([DEFAULT_NETWORK_CONTROL_PORT], [5342])
267 _AC_DEFINE_AND_SUBST([DEFAULT_NETWORK_DATA_PORT], [5343])
268 _AC_DEFINE_AND_SUBST([DEFAULT_NETWORK_VIEWER_PORT], [5344])
269 _AC_DEFINE_AND_SUBST([DEFAULT_UST_PID_CHANNEL_LIVE_TIMER], [_DEFAULT_CHANNEL_LIVE_TIMER])
270 _AC_DEFINE_AND_SUBST([DEFAULT_UST_PID_CHANNEL_READ_TIMER], [0])
271 _AC_DEFINE_AND_SUBST([DEFAULT_UST_PID_CHANNEL_SUBBUF_NUM], [_DEFAULT_CHANNEL_SUBBUF_NUM])
272 _AC_DEFINE_AND_SUBST([DEFAULT_UST_PID_CHANNEL_SUBBUF_SIZE], [_DEFAULT_CHANNEL_SUBBUF_SIZE])
273 _AC_DEFINE_AND_SUBST([DEFAULT_UST_PID_CHANNEL_SWITCH_TIMER], [_DEFAULT_CHANNEL_SWITCH_TIMER])
274 _AC_DEFINE_AND_SUBST([DEFAULT_UST_PID_CHANNEL_MONITOR_TIMER], [_DEFAULT_CHANNEL_MONITOR_TIMER])
275 _AC_DEFINE_AND_SUBST([DEFAULT_UST_UID_CHANNEL_LIVE_TIMER], [_DEFAULT_CHANNEL_LIVE_TIMER])
276 _AC_DEFINE_AND_SUBST([DEFAULT_UST_UID_CHANNEL_READ_TIMER], [0])
277 _AC_DEFINE_AND_SUBST([DEFAULT_UST_UID_CHANNEL_SUBBUF_NUM], [_DEFAULT_CHANNEL_SUBBUF_NUM])
278 _AC_DEFINE_AND_SUBST([DEFAULT_UST_UID_CHANNEL_SUBBUF_SIZE], [524288])
279 _AC_DEFINE_AND_SUBST([DEFAULT_UST_UID_CHANNEL_SWITCH_TIMER], [_DEFAULT_CHANNEL_SWITCH_TIMER])
280 _AC_DEFINE_AND_SUBST([DEFAULT_UST_UID_CHANNEL_MONITOR_TIMER], [_DEFAULT_CHANNEL_MONITOR_TIMER])
281 _AC_DEFINE_QUOTED_AND_SUBST([DEFAULT_AGENT_BIND_ADDRESS], [localhost])
282 _AC_DEFINE_QUOTED_AND_SUBST([DEFAULT_NETWORK_CONTROL_BIND_ADDRESS], [0.0.0.0])
283 _AC_DEFINE_QUOTED_AND_SUBST([DEFAULT_NETWORK_DATA_BIND_ADDRESS], [0.0.0.0])
284 _AC_DEFINE_QUOTED_AND_SUBST([DEFAULT_NETWORK_VIEWER_BIND_ADDRESS], [localhost])
285
286 # Command short descriptions
287 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_ADD_CONTEXT], [Add context fields to a channel])
288 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_CREATE], [Create a tracing session])
289 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_DESTROY], [Tear down tracing sessions])
290 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_DISABLE_CHANNEL], [Disable tracing channels])
291 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_DISABLE_EVENT], [Disable event rules])
292 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_ENABLE_CHANNEL], [Create or enable tracing channels])
293 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_ENABLE_EVENT], [Create or enable event rules])
294 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_HELP], [Display help information about a command])
295 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_LIST], [List tracing sessions, domains, channels, and events])
296 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_LOAD], [Load tracing session configurations])
297 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_REGENERATE], [Manage an LTTng tracing session's data regeneration])
298 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_SAVE], [Save tracing session configurations])
299 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_SET_SESSION], [Set current tracing session])
300 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_SNAPSHOT], [Snapshot buffers of current tracing session])
301 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_START], [Start tracing])
302 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_STATUS], [Get the status of the current tracing session])
303 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_STOP], [Stop tracing])
304 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_TRACK], [Track specific system resources])
305 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_UNTRACK], [Untrack specific system resources])
306 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_VERSION], [Show version information])
307 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_VIEW], [Start trace viewer])
308
309 if test "x$prefix" = "xNONE"; then
310 prefix=$ac_default_prefix
311 fi
312 CONFDIR=`eval echo $sysconfdir`
313 AC_SUBST(CONFDIR)
314 AC_DEFINE_UNQUOTED([CONFIG_LTTNG_SYSTEM_CONFIGDIR],"$CONFDIR", [LTTng system configuration directory.])
315
316 AC_DEFINE_DIR([CONFIG_LTTNG_SYSTEM_DATADIR],[datadir], [LTTng system data directory.])
317
318 #
319 # Check for pthread
320 AC_CHECK_LIB([pthread], [pthread_create], [],
321 [AC_MSG_ERROR([Cannot find libpthread. Use LDFLAGS=-Ldir to specify its location.])]
322 )
323
324 # Check libpopt
325 PKG_CHECK_MODULES([POPT], [popt],
326 [LIBS="$LIBS $POPT_LIBS"],
327 [
328 AC_MSG_WARN([pkg-config was unable to find a valid .pc for libpopt. Set PKG_CONFIG_PATH to specify the pkgconfig configuration file location])
329 AC_MSG_WARN([Finding libpopt without pkg-config.])
330 AC_CHECK_LIB([popt],
331 [poptGetContext],
332 [],
333 [
334 AC_MSG_ERROR([Cannot find libpopt. Either set PKG_CONFIG_PATH to the configuration file location or use LDFLAGS=-Ldir to specify the library location])
335 ]
336 )
337 ]
338 )
339
340 PKG_CHECK_MODULES([libxml2], [libxml-2.0 >= 2.7.6])
341
342 # Check for uuid in system libs
343 AC_CHECK_FUNCS([uuid_generate],
344 [
345 AC_DEFINE_UNQUOTED([LTTNG_HAVE_LIBUUID], 1, [Has libuuid support.])
346 link_with_libuuid=no
347 ],
348 [
349 # First, check the pkg-config module is available, otherwise explicitly check
350 # for libuuid, or uuid support in the C-library.
351 PKG_CHECK_MODULES([UUID], [uuid],
352 [
353 LIBS="$LIBS $UUID_LIBS"
354 AC_DEFINE_UNQUOTED([LTTNG_HAVE_LIBUUID], 1, [Has libuuid support.])
355 link_with_libuuid=yes
356 ],
357 [
358 # Check for libuuid
359 AC_CHECK_LIB([uuid],
360 [uuid_generate],
361 [
362 AC_DEFINE_UNQUOTED([LTTNG_HAVE_LIBUUID], 1, [Has libuuid support.])
363 link_with_libuuid=yes
364 ],
365 [
366 # libuuid not found, check for uuid_create in libc.
367 AC_CHECK_LIB([c],
368 [uuid_create],
369 [
370 AC_DEFINE_UNQUOTED([LTTNG_HAVE_LIBC_UUID], 1, [Has libc uuid support.])
371 link_with_libc_uuid=yes
372 ],
373 [
374 AC_MSG_ERROR([Cannot find libuuid uuid_generate nor libc uuid_create. Either set PKG_CONFIG_PATH to the configuration file location or use LDFLAGS=-Ldir to specify the library location])
375 ]
376 )
377 ]
378 )
379 ])
380 ])
381
382 AM_CONDITIONAL([LTTNG_BUILD_WITH_LIBUUID], [test "x$link_with_libuuid" = "xyes"])
383 AM_CONDITIONAL([LTTNG_BUILD_WITH_LIBC_UUID], [test "x$link_with_libc_uuid" = "xyes"])
384
385 AC_CHECK_FUNC([clock_gettime], [AC_DEFINE_UNQUOTED([LTTNG_HAVE_CLOCK_GETTIME], 1, [Has clock_gettime() support.])])
386
387 # URCU library version needed or newer
388 m4_define([WRONG_LIBURCU_MSG], [Userspace RCU (liburcu) >= 0.9.0 is needed])
389
390 # Check liburcu needed function calls
391 AC_CHECK_DECL([cds_list_add], [],
392 [AC_MSG_ERROR([WRONG_LIBURCU_MSG])], [[#include <urcu/list.h>]])
393 AC_CHECK_DECL([cds_wfcq_init], [],
394 [AC_MSG_ERROR([WRONG_LIBURCU_MSG])], [[#include <urcu/wfcqueue.h>]])
395 AC_CHECK_DECL([cds_wfcq_dequeue_blocking], [],
396 [AC_MSG_ERROR([WRONG_LIBURCU_MSG])], [[#include <urcu/wfcqueue.h>]])
397 AC_CHECK_DECL([futex_async], [],
398 [AC_MSG_ERROR([WRONG_LIBURCU_MSG])], [[#include <urcu/futex.h>]])
399 AC_CHECK_DECL([rcu_thread_offline], [],
400 [AC_MSG_ERROR([WRONG_LIBURCU_MSG])], [[#include <urcu.h>]])
401 AC_CHECK_DECL([rcu_thread_online], [],
402 [AC_MSG_ERROR([WRONG_LIBURCU_MSG])], [[#include <urcu.h>]])
403 AC_CHECK_DECL([caa_likely], [],
404 [AC_MSG_ERROR([WRONG_LIBURCU_MSG])], [[#include <urcu.h>]])
405 AC_CHECK_LIB([urcu-cds], [_cds_lfht_new], [],
406 [AC_MSG_ERROR([WRONG_LIBURCU_MSG])])
407
408 #Function added in urcu 0.7.0
409 AC_CHECK_DECL([cmm_smp_mb__before_uatomic_or], [],
410 [AC_MSG_ERROR([WRONG_LIBURCU_MSG])], [[#include <urcu.h>]]
411 )
412
413 #Function added in urcu 0.9.0
414 AC_CHECK_DECL([urcu_ref_get_unless_zero], [],
415 [AC_MSG_ERROR([WRONG_LIBURCU_MSG])], [[#include <urcu/ref.h>]]
416 )
417
418 # Check kmod library
419 AC_ARG_WITH(kmod-prefix,
420 AS_HELP_STRING([--with-kmod-prefix=PATH],
421 [Specify the installation prefix of the kmod library.
422 Headers must be in PATH/include; libraries in PATH/lib.]),
423 [
424 CPPFLAGS="$CPPFLAGS -I${withval}/include"
425 LDFLAGS="$LDFLAGS -L${withval}/lib64 -L${withval}/lib"
426 ])
427
428 AC_ARG_ENABLE(kmod,
429 AS_HELP_STRING([--disable-kmod],[build without kmod support]),
430 kmod_support=$enableval, kmod_support=yes)
431
432 AS_IF([test "x$kmod_support" = "xyes"], [
433 AC_CHECK_LIB([kmod], [kmod_module_probe_insert_module],
434 [
435 AC_DEFINE([HAVE_KMOD], [1], [has kmod support])
436 LIBS="$LIBS -lkmod"
437 kmod_found=yes
438 ],
439 kmod_found=no
440 )
441 ])
442 AM_CONDITIONAL([HAVE_KMOD], [test "x$kmod_found" = xyes])
443
444 AC_ARG_WITH(lttng-ust-prefix,
445 AS_HELP_STRING([--with-lttng-ust-prefix=PATH],
446 [Specify the installation prefix of the lttng-ust library.
447 Headers must be in PATH/include; libraries in PATH/lib.]),
448 [
449 CPPFLAGS="$CPPFLAGS -I${withval}/include"
450 LDFLAGS="$LDFLAGS -L${withval}/lib64 -L${withval}/lib"
451 ])
452
453 # Check liblttng-ust-ctl library
454 AC_ARG_WITH(lttng-ust,
455 AS_HELP_STRING([--without-lttng-ust],[build without LTTng-UST (Userspace Tracing) support]),
456 lttng_ust_support=$withval, lttng_ust_support=yes)
457
458 AS_IF([test "x$lttng_ust_support" = "xyes"], [
459 AC_CHECK_LIB([lttng-ust-ctl], [ustctl_recv_channel_from_consumer],
460 [
461 AC_DEFINE([HAVE_LIBLTTNG_UST_CTL], [1], [has LTTng-UST control support])
462 lttng_ust_ctl_found=yes
463 ],
464 [AC_MSG_ERROR([Cannot find LTTng-UST >= 2.2.x. Use --with-lttng-ust-prefix=PREFIX to specify its location, or specify --without-lttng-ust to build lttng-tools without LTTng-UST support.])],
465 [-lurcu-common -lurcu-bp -lurcu-cds -lrt -ldl]
466 )
467 ])
468 AM_CONDITIONAL([HAVE_LIBLTTNG_UST_CTL], [test "x$lttng_ust_ctl_found" = xyes])
469 AC_CHECK_FUNCS([sched_getcpu sysconf sync_file_range])
470
471 # check for dlopen
472 AC_CHECK_LIB([dl], [dlopen],
473 [
474 have_libdl=yes
475 ],
476 [
477 #libdl not found, check for dlopen in libc.
478 AC_CHECK_LIB([c], [dlopen],
479 [
480 have_libc_dl=yes
481 ],
482 [
483 AC_MSG_ERROR([Cannot find dlopen in libdl nor libc. Use [LDFLAGS]=-Ldir to specify their location.])
484 ])
485 ])
486 AM_CONDITIONAL([LTTNG_TOOLS_BUILD_WITH_LIBDL], [test "x$have_libdl" = "xyes"])
487 AM_CONDITIONAL([LTTNG_TOOLS_BUILD_WITH_LIBC_DL], [test "x$have_libc_dl" = "xyes"])
488
489 # Check for fmemopen
490 AC_CHECK_LIB([c], [fmemopen],
491 [
492 AC_DEFINE_UNQUOTED([LTTNG_HAVE_FMEMOPEN], 1, [Has fmemopen support.])
493 ]
494 )
495
496 # Check for open_memstream
497 AC_CHECK_LIB([c], [open_memstream],
498 [
499 AC_DEFINE_UNQUOTED([LTTNG_HAVE_OPEN_MEMSTREAM], 1, [Has open_memstream support.])
500 ]
501 )
502
503 # check for libpfm
504 AC_CHECK_LIB([pfm], [pfm_initialize],
505 [
506 have_libpfm=yes
507 ])
508 AM_CONDITIONAL([LTTNG_TOOLS_BUILD_WITH_LIBPFM], [test "x$have_libpfm" = "xyes"])
509
510 AC_ARG_ENABLE([git-version],
511 [AC_HELP_STRING([--disable-git-version],
512 [Do not use the git version for the build])],
513 [have_git_version=$enableval], [have_git_version=yes]
514 )
515
516 AM_CONDITIONAL([LTTNG_TOOLS_BUILD_GIT_SOURCE],
517 [test "x${have_git_version}" = "xyes"])
518
519 # For Python
520 # SWIG version needed or newer:
521 swig_version=2.0.0
522
523 AC_ARG_ENABLE([python-bindings],
524 [AC_HELP_STRING([--enable-python-bindings],
525 [compile Python bindings])],
526 [enable_python_binding=$enableval], [enable_python_binding=no])
527
528 AM_CONDITIONAL([PYTHON_BINDING], [test "x$enable_python_binding" = xyes])
529
530 if test "x$enable_python_binding" = xyes; then
531 AX_PKG_SWIG($swig_version, [], [ AC_MSG_ERROR([SWIG $swig_version or newer is needed]) ])
532 AS_IF([test x$enable_shared = xno], [ AC_MSG_ERROR([Python bindings require shared libraries.]) ])
533 AM_PATH_PYTHON([3.0])
534
535 AC_ARG_VAR([PYTHON_INCLUDE], [Include flags for python, bypassing python-config])
536 AC_ARG_VAR([PYTHON_CONFIG], [Path to python-config])
537 AS_IF([test -z "$PYTHON_INCLUDE"], [
538 AS_IF([test -z "$PYTHON_CONFIG"], [
539 AC_PATH_PROGS([PYTHON_CONFIG],
540 [python$PYTHON_VERSION-config python-config],
541 [no],
542 [`dirname $PYTHON`])
543 AS_IF([test "$PYTHON_CONFIG" = no], [AC_MSG_ERROR([cannot find python-config for $PYTHON. Do you have python-dev installed?])])
544 ])
545 AC_MSG_CHECKING([python include flags])
546 PYTHON_INCLUDE=`$PYTHON_CONFIG --includes`
547 AC_MSG_RESULT([$PYTHON_INCLUDE])
548 ])
549
550 else
551 AC_MSG_NOTICE([You may configure with --enable-python-bindings ]dnl
552 [if you want Python bindings.])
553
554 fi
555
556 # Epoll check. If not present, the build will fallback on poll() API
557 AX_HAVE_EPOLL(
558 [AX_CONFIG_FEATURE_ENABLE(epoll)],
559 [AX_CONFIG_FEATURE_DISABLE(epoll)]
560 )
561 AX_CONFIG_FEATURE(
562 [epoll], [This platform supports epoll(7)],
563 [HAVE_EPOLL], [This platform supports epoll(7).],
564 [enable_epoll="yes"], [enable_epoll="no"]
565 )
566 AM_CONDITIONAL([COMPAT_EPOLL], [ test "$enable_epoll" = "yes" ])
567
568 AM_CONDITIONAL([TEST_JAVA_JUL_AGENT], [test "x$test_java_agent_jul" = "xyes"])
569 AM_CONDITIONAL([TEST_JAVA_LOG4J_AGENT], [test "x$test_java_agent_log4j" = "xyes"])
570
571 if test "x$test_java_agent_jul" = "xyes" || test "x$test_java_agent_log4j" = "xyes"; then
572 AX_JAVA_OPTIONS
573 AX_PROG_JAVAC
574 AX_PROG_JAVA
575 AX_PROG_JAR
576
577 AX_CHECK_CLASSPATH
578
579 # Check for Java UST agent common class first
580 AX_CHECK_CLASS(org.lttng.ust.agent.AbstractLttngAgent)
581 if test "x$ac_cv_class_org_lttng_ust_agent_AbstractLttngAgent" = "xno"; then
582 AC_MSG_ERROR([The UST Java agent common class was not found. Please specify the location of the jar via the Java CLASSPATH e.g: export CLASSPATH="/path/to/lttng-ust-agent-common.jar"])
583 fi
584
585 if test "x$test_java_agent_jul" = "xyes"; then
586 # Check for JUL agent class
587 AX_CHECK_CLASS(org.lttng.ust.agent.jul.LttngLogHandler)
588 if test "x$ac_cv_class_org_lttng_ust_agent_jul_LttngLogHandler" = "xno"; then
589 AC_MSG_ERROR([The UST Java agent JUL class was not found. Please specify the location of the jar via the Java CLASSPATH e.g: export CLASSPATH="/path/to/lttng-ust-agent-jul.jar"])
590 fi
591 fi
592
593 if test "x$test_java_agent_log4j" = "xyes"; then
594 # Check for Log4j agent class
595 AX_CHECK_CLASS(org.lttng.ust.agent.log4j.LttngLogAppender)
596 if test "x$ac_cv_class_org_lttng_ust_agent_log4j_LttngLogAppender" = "xno"; then
597 AC_MSG_ERROR([The UST Java agent Log4j class was not found. Please specify the location of the jar via the Java CLASSPATH e.g: export CLASSPATH="/path/to/lttng-ust-agent-log4j.jar"])
598 fi
599
600 # Check for Log4j class
601 AX_CHECK_CLASS(org.apache.log4j.Logger)
602 if test "x$ac_cv_class_org_apache_log4j_Logger" = "xno"; then
603 AC_MSG_ERROR([The Log4j class was not found. Please specify the location of the jar via the Java CLASSPATH e.g: export CLASSPATH="/path/to/log4j.jar"])
604 fi
605 fi
606 fi
607
608 # set $IN_GIT_REPO if we're in the Git repository; the `bootstrap` file
609 # is not distributed in tarballs
610 AS_IF([test -f "$srcdir/bootstrap"], [in_git_repo=yes], [in_git_repo=no])
611 AM_CONDITIONAL([IN_GIT_REPO], [test "x$in_git_repo" = "xyes"])
612
613 # enable building man pages (user's intention)
614 AC_ARG_ENABLE(
615 man-pages,
616 AS_HELP_STRING(
617 [--disable-man-pages],
618 [Do not build and install man pages (already built in a distributed tarball)]
619 ),
620 [man_pages_opt=$enableval],
621 [man_pages_opt=yes]
622 )
623
624 # check for asciidoc and xmlto if we enabled building the man pages
625 have_asciidoc_xmlto=no
626 warn_prebuilt_man_pages=no
627
628 AS_IF([test "x$man_pages_opt" = "xyes"], [
629 AC_PATH_PROG([ASCIIDOC], [asciidoc], [no])
630 AC_PATH_PROG([XMLTO], [xmlto], [no])
631
632 AS_IF([test "x$ASCIIDOC" = "xno" || test "x$XMLTO" = "xno"], [
633 AS_IF([test "x$in_git_repo" = "xyes"], [
634 # this is an error because we're in the Git repo, which
635 # means the man pages are not already generated for us,
636 # thus asciidoc/xmlto are required because we were asked
637 # to build the man pages
638 AC_MSG_ERROR([
639 You need asciidoc and xmlto to build the LTTng-tools man pages. Use
640 --disable-man-pages to disable building the man pages, in which case
641 they will not be installed.
642 ])
643 ], [
644 # only warn here: since we're in the tarball, the man
645 # pages should already be generated at this point, thus
646 # asciidoc/xmlto are not strictly required
647 warn_prebuilt_man_pages=yes
648 ])
649 ], [
650 have_asciidoc_xmlto=yes
651 ])
652 ])
653
654 # export man page build condition: build the man pages if the user
655 # asked for it, and if the tools are available
656 AM_CONDITIONAL([MAN_PAGES_OPT], [test "x$man_pages_opt" != "xno"])
657 AM_CONDITIONAL([HAVE_ASCIIDOC_XMLTO], [test "x$have_asciidoc_xmlto" = "xyes"])
658
659 AC_DEFINE_UNQUOTED([MANPATH], ["`eval eval echo $mandir`"], [Path to man pages.])
660
661 # embedded --help message
662 AC_ARG_ENABLE(
663 [embedded-help],
664 AS_HELP_STRING(
665 [--enable-embedded-help],
666 [Embed the --help messages in the executable files]
667 ),
668 [embedded_help=$enableval],
669 [embedded_help=no]
670 )
671 AS_IF([test "x$embedded_help" = "xyes"], [
672 AS_IF([test "x$man_pages_opt" = "xno"], [
673 AC_MSG_ERROR([You need the --enable-man-pages option with the --enable-embedded-help option.])
674 ])
675 AC_PATH_PROG([man_prog_path], [man], [no])
676 AS_IF([test "x$man_prog_path" = "xno"], [
677 AC_MSG_ERROR([You need man with the --enable-embedded-help option.])
678 ])
679 AC_DEFINE_UNQUOTED([LTTNG_EMBED_HELP], 1, [Embed --help messages.])
680 AC_SUBST([MANPROG], [$man_prog_path])
681 ])
682 AM_CONDITIONAL([EMBED_HELP], [test "x$embedded_help" != "xno"])
683
684 # Python agent test
685 UST_PYTHON_AGENT="lttngust"
686
687 AC_ARG_ENABLE(test-python2-agent,
688 AS_HELP_STRING([--enable-test-python2-agent],
689 [enable tests for python2 agent. Python2 interpreter path can be overridden by setting the PYTHON2 environment variable. Default: Autodetect]
690 ),[:],[test_python2_agent_autodetect=yes]
691 )
692
693 AC_ARG_ENABLE(test-python3-agent,
694 AS_HELP_STRING([--enable-test-python3-agent],
695 [enable tests for python3 agent. Python3 interpreter path can be overridden by setting the PYTHON3 environment variable. Default: Autodetect]
696 ),[:],[test_python3_agent_autodetect=yes]
697 )
698
699 AC_ARG_ENABLE(test-python-agent-all,
700 AS_HELP_STRING([--enable-test-python-agent-all],
701 [enable test for all python{2/3} agent.]
702 ),
703 )
704
705 AS_IF([test ! -z "$enable_test_python_agent_all"], [
706 unset test_python2_agent_autodetect
707 unset test_python3_agent_autodetect
708 ])
709
710 AS_IF([test "x$enable_test_python_agent_all" = "xyes"], [
711 enable_test_python2_agent=yes
712 enable_test_python3_agent=yes
713 ])
714
715 AS_IF([test "x$enable_test_python_agent_all" = "xno"], [
716 enable_test_python2_agent=no
717 enable_test_python3_agent=no
718 ])
719
720
721 AS_IF([test "x$enable_test_python2_agent" = "xyes" -o "x$test_python2_agent_autodetect" = "xyes" ], [
722 AS_IF([test -z "$PYTHON2"], [
723 PYTHON2=python2
724 ], [
725 AC_MSG_WARN([Using user-defined PYTHON2 ($PYTHON2) for lttng-ust python2 agent check])
726 ])
727
728 AC_PATH_PROG([PYTHON2_BIN],[$PYTHON2])
729 AS_IF([test -z "$PYTHON2_BIN"], [
730 AS_IF([test -z "$test_python2_agent_autodetect"],[
731 AC_MSG_ERROR([No python2 interpreter found. PYTHON2 can be set to override default interpreter path])
732 ])
733 ], [
734 AC_MSG_CHECKING([for python2 lttng-ust agent])
735 AS_IF([$PYTHON2_BIN -c "import $UST_PYTHON_AGENT" 2>/dev/null], [
736 PYTHON2_AGENT=$PYTHON2_BIN
737 AC_MSG_RESULT([yes])
738 RUN_PYTHON_AGENT_TEST=yes
739 ], [
740 AC_MSG_RESULT([no])
741 AS_IF([test -z "$test_python2_agent_autodetect"],[
742 AC_MSG_ERROR([No python2 agent found. The path to the agent can be specified by setting the PYTHONPATH environment variable.])
743 ])
744 ])
745
746 ])
747
748 ])
749
750 AS_IF([test "x$enable_test_python3_agent" = "xyes" -o "x$test_python3_agent_autodetect" = "xyes" ], [
751 AS_IF([test -z "$PYTHON3"], [
752 PYTHON3=python3
753 ], [
754 AC_MSG_WARN([Using user-defined PYTHON3 ($PYTHON3) for lttng-ust python3 agent check])
755 ])
756
757 AC_PATH_PROG([PYTHON3_BIN],[$PYTHON3])
758 AS_IF([test -z "$PYTHON3_BIN"], [
759 AS_IF([test -z "$test_python3_agent_autodetect"],[
760 AC_MSG_ERROR([No python3 interpreter found. PYTHON3 can be set to override default interpreter path])
761 ])
762 ], [
763 AC_MSG_CHECKING([for python3 lttng-ust agent])
764 AS_IF([$PYTHON3_BIN -c "import $UST_PYTHON_AGENT" 2>/dev/null], [
765 PYTHON3_AGENT=$PYTHON3_BIN
766 AC_MSG_RESULT([yes])
767 RUN_PYTHON_AGENT_TEST=yes
768 ], [
769 AC_MSG_RESULT([no])
770 AS_IF([test -z "$test_python3_agent_autodetect"],[
771 AC_MSG_ERROR([No python3 agent found. The path to the agent can be specified by setting the PYTHONPATH environment variable.])
772 ])
773 ])
774
775 ])
776 ])
777 AC_SUBST([RUN_PYTHON_AGENT_TEST])
778 AC_SUBST([PYTHON2_AGENT])
779 AC_SUBST([PYTHON3_AGENT])
780
781 # Arguments for binaries build exclusion
782 AC_ARG_ENABLE([bin-lttng], AS_HELP_STRING([--disable-bin-lttng],[Disable the build of lttng binaries]))
783 AC_ARG_ENABLE([bin-lttng-consumerd], AS_HELP_STRING([--disable-bin-lttng-consumerd],
784 [Disable the build of lttng-consumerd binaries]))
785 AC_ARG_ENABLE([bin-lttng-crash], AS_HELP_STRING([--disable-bin-lttng-crash],[Disable the build of lttng-crash binaries]))
786 AC_ARG_ENABLE([bin-lttng-relayd], AS_HELP_STRING([--disable-bin-lttng-relayd],
787 [Disable the build of lttng-relayd binaries]))
788 AC_ARG_ENABLE([bin-lttng-sessiond], AS_HELP_STRING([--disable-bin-lttng-sessiond],
789 [Disable the build of lttng-sessiond binaries]))
790 AC_ARG_ENABLE([extras], AS_HELP_STRING([--disable-extras],
791 [Disable the build of the extra components]))
792
793
794 # Always build libconfig since it a dependency of libcommon
795 build_lib_config=yes
796
797 build_lib_compat=no
798 build_lib_consumer=no
799 build_lib_hashtable=no
800 build_lib_health=no
801 build_lib_index=no
802 build_lib_kernel_consumer=no
803 build_lib_kernel_ctl=no
804 build_lib_lttng_ctl=no
805 build_lib_relayd=no
806 build_lib_sessiond_comm=no
807 build_lib_testpoint=no
808 build_lib_ust_consumer=no
809
810 # There is an overlap for enabled dependencies, but this makes everything
811 # simpler. libcommon and libconfig are always compiled so they are not repeated
812 # here.
813
814 # Enable binary dependencies.
815 AS_IF([test x$enable_bin_lttng != xno],
816 [
817 build_lib_lttng_ctl=yes
818 ]
819 )
820
821 AS_IF([test x$enable_bin_lttng_consumerd != xno],
822 [
823 build_lib_consumer=yes
824 build_lib_sessiond_comm=yes
825 build_lib_index=yes
826 build_lib_health=yes
827 build_lib_testpoint=yes
828 ]
829 )
830
831 AS_IF([test x$enable_bin_lttng_crash != xno],
832 # Do nothing since libconfig and libcommon are built by default.
833 []
834 )
835
836 AS_IF([test x$enable_bin_lttng_relayd != xno],
837 [
838 build_lib_lttng_ctl=yes
839 build_lib_sessiond_comm=yes
840 build_lib_hashtable=yes
841 build_lib_compat=yes
842 build_lib_index=yes
843 build_lib_health=yes
844 build_lib_testpoint=yes
845 ]
846 )
847 AS_IF([test x$enable_bin_lttng_sessiond != xno],
848 [
849 build_lib_lttng_ctl=yes
850 build_lib_sessiond_comm=yes
851 build_lib_kernel_ctl=yes
852 build_lib_hashtable=yes
853 build_lib_compat=yes
854 build_lib_relayd=yes
855 build_lib_testpoint=yes
856 build_lib_health=yes
857 build_lib_health=yes
858 ]
859 )
860
861 # Libraries dependencies enabling
862 AS_IF([test x$build_lib_lttng_ctl = xyes],
863 [
864 build_lib_sessiond_comm=yes
865 build_lib_hashtable=yes
866 ]
867 )
868
869 AS_IF([test x$build_lib_consumer = xyes],
870 [
871 build_lib_sessiond_comm=yes
872 build_lib_kernel_consumer=yes
873 build_lib_hashtable=yes
874 build_lib_compat=yes
875 build_lib_relayd=yes
876 AS_IF([test x$lttng_ust_ctl_found = xyes],[build_lib_ust_consumer=yes])
877 ]
878 )
879
880 AS_IF([test x$build_lib_kernel_consumer = xyes],
881 [
882 build_lib_kernel_ctl=yes
883 build_lib_relayd=yes
884 ]
885 )
886
887 AS_IF([test x$build_lib_relayd = xyes],
888 [
889 build_lib_sessiond_comm=yes
890 ]
891 )
892
893
894 # Export binaries build conditions.
895 AM_CONDITIONAL([BUILD_BIN_LTTNG], [test x$enable_bin_lttng != xno])
896 AM_CONDITIONAL([BUILD_BIN_LTTNG_CONSUMERD], [test x$enable_bin_lttng_consumerd != xno])
897 AM_CONDITIONAL([BUILD_BIN_LTTNG_CRASH], [test x$enable_bin_lttng_crash != xno])
898 AM_CONDITIONAL([BUILD_BIN_LTTNG_RELAYD], [test x$enable_bin_lttng_relayd != xno])
899 AM_CONDITIONAL([BUILD_BIN_LTTNG_SESSIOND], [test x$enable_bin_lttng_sessiond != xno])
900
901 # Export the tests and extras build conditions.
902 AS_IF([\
903 test "x$enable_bin_lttng" != "xno" && \
904 test "x$enable_bin_lttng_consumerd" != "xno" && \
905 test "x$enable_bin_lttng_crash" != "xno" && \
906 test "x$enable_bin_lttng_relayd" != "xno" && \
907 test "x$enable_bin_lttng_sessiond" != "xno"],
908 [build_tests=yes],
909 [build_tests=no]
910 )
911
912 AM_CONDITIONAL([BUILD_TESTS], [test x$build_tests = xyes])
913 AM_CONDITIONAL([BUILD_EXTRAS], [test x$enable_extras != xno])
914
915 # Export libraries build conditions.
916 AM_CONDITIONAL([BUILD_LIB_COMPAT], [test x$build_lib_compat = xyes])
917 AM_CONDITIONAL([BUILD_LIB_CONFIG], [test x$build_lib_config = xyes])
918 AM_CONDITIONAL([BUILD_LIB_CONSUMER], [test x$build_lib_consumer = xyes])
919 AM_CONDITIONAL([BUILD_LIB_HASHTABLE], [test x$build_lib_hashtable = xyes])
920 AM_CONDITIONAL([BUILD_LIB_HEALTH], [test x$build_lib_health = xyes])
921 AM_CONDITIONAL([BUILD_LIB_INDEX], [test x$build_lib_index = xyes])
922 AM_CONDITIONAL([BUILD_LIB_KERNEL_CONSUMER], [test x$build_lib_kernel_consumer = xyes])
923 AM_CONDITIONAL([BUILD_LIB_KERNEL_CTL], [test x$build_lib_kernel_ctl = xyes])
924 AM_CONDITIONAL([BUILD_LIB_LTTNG_CTL], [test x$build_lib_lttng_ctl = xyes])
925 AM_CONDITIONAL([BUILD_LIB_RELAYD], [test x$build_lib_relayd = xyes])
926 AM_CONDITIONAL([BUILD_LIB_SESSIOND_COMM], [test x$build_lib_sessiond_comm = xyes])
927 AM_CONDITIONAL([BUILD_LIB_TESTPOINT], [test x$build_lib_testpoint = xyes])
928 AM_CONDITIONAL([BUILD_LIB_UST_CONSUMER], [test x$build_lib_ust_consumer = xyes])
929
930 # check for pgrep
931 AC_PATH_PROG([PGREP], [pgrep], [no])
932 AM_CONDITIONAL([HAS_PGREP], [test "x$PGREP" != "xno"])
933
934 # check for bison
935 have_bison=yes
936
937 AS_IF([test "x$(basename "$YACC")" != "xbison -y"], [have_bison=no])
938 AC_PATH_PROG([BISON], [bison])
939 AX_PROG_BISON_VERSION([2.4], [], [have_bison=no])
940
941 AS_IF([test "x$have_bison" = "xno"], [
942 AS_IF([test "x$in_git_repo" = "xyes"], [
943 AC_MSG_ERROR([Bison >= 2.4 is required when building from the Git repository.])
944 ], [
945 AC_MSG_WARN([
946 Missing Bison >= 2.4. Note that the parser files are already built in
947 this distribution tarball, so Bison is only needed if you intend to
948 modify their sources.
949 ])
950 ])
951 ])
952
953 # export bison condition
954 AM_CONDITIONAL([HAVE_BISON], [test "x$have_bison" = "xyes"])
955
956 # check for flex
957 have_flex=yes
958
959 AS_IF([test "x$LEX" != "xflex"], [have_flex=no])
960 AC_PATH_PROG([FLEX], [flex])
961 AX_PROG_FLEX_VERSION([2.5.35], [], [have_flex=no])
962
963 AS_IF([test "x$have_flex" = "xno"], [
964 AS_IF([test "x$in_git_repo" = "xyes"], [
965 AC_MSG_ERROR([Flex >= 2.5.35 is required when building from the Git repository.])
966 ], [
967 AC_MSG_WARN([
968 Missing Flex >= 2.5.35. Note that the lexer files are already built in
969 this distribution tarball, so Flex is only needed if you intend to
970 modify their sources.
971 ])
972 ])
973 ])
974
975 # export flex condition
976 AM_CONDITIONAL([HAVE_FLEX], [test "x$have_flex" = "xyes"])
977
978 CFLAGS="-Wall $CFLAGS -g -fno-strict-aliasing"
979
980 DEFAULT_INCLUDES="-I\$(top_srcdir) -I\$(top_builddir) -I\$(top_builddir)/src -I\$(top_builddir)/include -include config.h"
981
982 lttngincludedir="${includedir}/lttng"
983 AC_SUBST(lttngincludedir)
984
985 lttngactionincludedir="${includedir}/lttng/action"
986 AC_SUBST(lttngactionincludedir)
987
988 lttngconditionincludedir="${includedir}/lttng/condition"
989 AC_SUBST(lttngconditionincludedir)
990
991 lttngnotificationincludedir="${includedir}/lttng/notification"
992 AC_SUBST(lttngnotificationincludedir)
993
994 lttngtriggerincludedir="${includedir}/lttng/trigger"
995 AC_SUBST(lttngtriggerincludedir)
996
997 AC_SUBST(DEFAULT_INCLUDES)
998
999 lttnglibexecdir="${libdir}/lttng/libexec"
1000 AC_SUBST(lttnglibexecdir)
1001
1002 AC_CONFIG_FILES([
1003 Makefile
1004 doc/Makefile
1005 doc/man/Makefile
1006 doc/man/asciidoc-attrs.conf
1007 include/Makefile
1008 extras/Makefile
1009 extras/bindings/Makefile
1010 extras/bindings/swig/Makefile
1011 extras/bindings/swig/python/Makefile
1012 extras/core-handler/Makefile
1013 src/Makefile
1014 src/common/Makefile
1015 src/common/kernel-ctl/Makefile
1016 src/common/kernel-consumer/Makefile
1017 src/common/consumer/Makefile
1018 src/common/ust-consumer/Makefile
1019 src/common/hashtable/Makefile
1020 src/common/sessiond-comm/Makefile
1021 src/common/compat/Makefile
1022 src/common/relayd/Makefile
1023 src/common/testpoint/Makefile
1024 src/common/index/Makefile
1025 src/common/health/Makefile
1026 src/common/config/Makefile
1027 src/common/string-utils/Makefile
1028 src/lib/Makefile
1029 src/lib/lttng-ctl/Makefile
1030 src/lib/lttng-ctl/filter/Makefile
1031 src/lib/lttng-ctl/lttng-ctl.pc
1032 src/bin/Makefile
1033 src/bin/lttng-consumerd/Makefile
1034 src/bin/lttng-sessiond/Makefile
1035 src/bin/lttng-relayd/Makefile
1036 src/bin/lttng/Makefile
1037 src/bin/lttng-crash/Makefile
1038 tests/Makefile
1039 tests/destructive/Makefile
1040 tests/regression/Makefile
1041 tests/regression/kernel/Makefile
1042 tests/regression/tools/Makefile
1043 tests/regression/tools/streaming/Makefile
1044 tests/regression/tools/filtering/Makefile
1045 tests/regression/tools/health/Makefile
1046 tests/regression/tools/tracefile-limits/Makefile
1047 tests/regression/tools/snapshots/Makefile
1048 tests/regression/tools/live/Makefile
1049 tests/regression/tools/exclusion/Makefile
1050 tests/regression/tools/save-load/Makefile
1051 tests/regression/tools/save-load/configuration/Makefile
1052 tests/regression/tools/mi/Makefile
1053 tests/regression/tools/wildcard/Makefile
1054 tests/regression/tools/crash/Makefile
1055 tests/regression/tools/regen-metadata/Makefile
1056 tests/regression/tools/regen-statedump/Makefile
1057 tests/regression/ust/Makefile
1058 tests/regression/ust/nprocesses/Makefile
1059 tests/regression/ust/high-throughput/Makefile
1060 tests/regression/ust/low-throughput/Makefile
1061 tests/regression/ust/before-after/Makefile
1062 tests/regression/ust/buffers-pid/Makefile
1063 tests/regression/ust/periodical-metadata-flush/Makefile
1064 tests/regression/ust/multi-session/Makefile
1065 tests/regression/ust/overlap/Makefile
1066 tests/regression/ust/overlap/demo/Makefile
1067 tests/regression/ust/linking/Makefile
1068 tests/regression/ust/daemon/Makefile
1069 tests/regression/ust/exit-fast/Makefile
1070 tests/regression/ust/fork/Makefile
1071 tests/regression/ust/libc-wrapper/Makefile
1072 tests/regression/ust/baddr-statedump/Makefile
1073 tests/regression/ust/ust-dl/Makefile
1074 tests/regression/ust/java-jul/Makefile
1075 tests/regression/ust/java-log4j/Makefile
1076 tests/regression/ust/python-logging/Makefile
1077 tests/regression/ust/getcpu-override/Makefile
1078 tests/regression/ust/clock-override/Makefile
1079 tests/regression/ust/type-declarations/Makefile
1080 tests/regression/ust/rotation-destroy-flush/Makefile
1081 tests/regression/ust/blocking/Makefile
1082 tests/stress/Makefile
1083 tests/unit/Makefile
1084 tests/unit/ini_config/Makefile
1085 tests/perf/Makefile
1086 tests/utils/Makefile
1087 tests/utils/tap/Makefile
1088 tests/utils/testapp/Makefile
1089 tests/utils/testapp/gen-ust-events/Makefile
1090 tests/utils/testapp/gen-ust-nevents/Makefile
1091 tests/utils/testapp/gen-ust-nevents-str/Makefile
1092 tests/utils/testapp/gen-ust-tracef/Makefile
1093 ])
1094
1095 # Inject variable into python test script.
1096 AC_CONFIG_FILES([tests/regression/ust/python-logging/test_python_logging],[chmod +x tests/regression/ust/python-logging/test_python_logging])
1097 # Inject LTTNG_TOOLS_BUILD_WITH_LIBPFM variable in test script.
1098 AC_CONFIG_FILES([tests/perf/test_perf_raw],[chmod +x tests/perf/test_perf_raw])
1099
1100 AC_OUTPUT
1101
1102 #
1103 # Mini-report on what will be built.
1104 #
1105
1106 PPRINT_INIT
1107 PPRINT_SET_INDENT(1)
1108 PPRINT_SET_TS(38)
1109
1110 AS_ECHO
1111 AS_ECHO("${PPRINT_COLOR_BLDBLU}LTTng-tools $PACKAGE_VERSION \"$version_name\"$PPRINT_COLOR_RST")
1112 AS_ECHO
1113
1114 AS_IF([test -n "$report_fold"], [
1115 AS_ECHO("`AS_ECHO("$version_description") | $report_fold -s`")
1116 ], [
1117 AS_ECHO("$version_description")
1118 ])
1119
1120 AS_ECHO
1121 PPRINT_SUBTITLE([Features])
1122
1123 # Target architecture we're building for.
1124 target_arch=$host_cpu
1125 [
1126 for f in $CFLAGS; do
1127 if test $f = "-m32"; then
1128 target_arch="32-bit"
1129 elif test $f = "-m64"; then
1130 target_arch="64-bit"
1131 fi
1132 done
1133 ]
1134 PPRINT_PROP_STRING([Target architecture], $target_arch)
1135
1136 # kmod enabled/disabled
1137 test "x$kmod_found" = "xyes" && value=1 || value=0
1138 PPRINT_PROP_BOOL([libkmod support], $value)
1139
1140 # LTTng-UST enabled/disabled
1141 test "x$lttng_ust_support" = "xyes" && value=1 || value=0
1142 PPRINT_PROP_BOOL([LTTng-UST support], $value)
1143
1144 AS_ECHO
1145 PPRINT_SUBTITLE([Binaries])
1146
1147 # List binaries to be built
1148 test x$enable_bin_lttng != xno && value=1 || value=0
1149 PPRINT_PROP_BOOL([lttng], $value)
1150
1151 test x$enable_bin_lttng_consumerd != xno && value=1 || value=0
1152 PPRINT_PROP_BOOL([lttng-consumerd], $value)
1153
1154 test x$enable_bin_lttng_crash != xno && value=1 || value=0
1155 PPRINT_PROP_BOOL([lttng-crash], $value)
1156
1157 test x$enable_bin_lttng_relayd != xno && value=1 || value=0
1158 PPRINT_PROP_BOOL([lttng-relayd], $value)
1159
1160 test x$enable_bin_lttng_sessiond != xno && value=1 || value=0
1161 PPRINT_PROP_BOOL([lttng-sessiond], $value)
1162
1163 # Extras
1164 test x$enable_extras != xno && value=1 || value=0
1165 AS_ECHO
1166 PPRINT_SET_INDENT(0)
1167 PPRINT_PROP_BOOL([Extras], $value, $PPRINT_COLOR_SUBTITLE)
1168 PPRINT_SET_INDENT(1)
1169
1170 AS_ECHO
1171 PPRINT_SUBTITLE([Tests])
1172
1173 # Print clear message that tests won't be built
1174 AS_IF([test "x$build_tests" = "xno"],[
1175 PPRINT_WARN([Tests won't be built since some binaries were disabled])
1176 ])
1177
1178 # LTTng UST Java agent JUL tests enabled/disabled
1179 test "x$test_java_agent_jul" = "xyes" && value=1 || value=0
1180 PPRINT_PROP_BOOL([LTTng-UST Java agent JUL tests], $value)
1181
1182 # LTTng UST Java agent Log4j tests enabled/disabled
1183 test "x$test_java_agent_log4j" = "xyes" && value=1 || value=0
1184 PPRINT_PROP_BOOL([LTTng-UST Java agent Log4j tests], $value)
1185
1186 test ! -z "$PYTHON2_AGENT" && value=1 || value=0
1187 PPRINT_PROP_BOOL([LTTng-UST Python2 agent tests], $value)
1188
1189 test ! -z "$PYTHON3_AGENT" && value=1 || value=0
1190 PPRINT_PROP_BOOL([LTTng-UST Python3 agent tests], $value)
1191
1192 #Python binding enabled/disabled
1193 test "x$enable_python_binding" = xyes && value=1 || value=0
1194 AS_ECHO
1195 PPRINT_SET_INDENT(0)
1196 PPRINT_PROP_BOOL([Python binding], $value, $PPRINT_COLOR_SUBTITLE)
1197
1198 # man pages build enabled/disabled
1199 m4_pushdef([build_man_pages_msg], [Build and install man pages])
1200
1201 AS_IF([test "x$man_pages_opt" != "xno"], [
1202 AS_IF([test "x$in_git_repo" = "xyes"], [
1203 PPRINT_PROP_BOOL([build_man_pages_msg], 1, $PPRINT_COLOR_SUBTITLE)
1204 ], [
1205 AS_IF([test "x$have_asciidoc_xmlto" = "xyes"], [
1206 PPRINT_PROP_BOOL([build_man_pages_msg], 1, $PPRINT_COLOR_SUBTITLE)
1207 ], [
1208 PPRINT_PROP_STRING([build_man_pages_msg],
1209 [${PPRINT_COLOR_BLDGRN}yes (already built)],
1210 $PPRINT_COLOR_SUBTITLE)
1211 ])
1212 ])
1213 ], [
1214 PPRINT_PROP_BOOL([build_man_pages_msg], 0, $PPRINT_COLOR_SUBTITLE)
1215 ])
1216
1217 m4_popdef([build_man_pages_msg])
1218
1219 test "x$embedded_help" = xyes && value=1 || value=0
1220 PPRINT_PROP_BOOL([Embed --help messages], $value, $PPRINT_COLOR_SUBTITLE)
1221
1222 PPRINT_SET_INDENT(1)
1223
1224 report_bindir="`eval eval echo $bindir`"
1225 report_libdir="`eval eval echo $libdir`"
1226
1227 # Print the bindir and libdir this `make install' will install into.
1228 AS_ECHO
1229 PPRINT_SUBTITLE([Install directories])
1230 PPRINT_PROP_STRING([Binaries], [$report_bindir])
1231 PPRINT_PROP_STRING([Libraries], [$report_libdir])
1232
1233 AS_ECHO
1234 PPRINT_SUBTITLE([Search directories])
1235
1236 # If we build the sessiond, print the paths it will use
1237 AS_IF([test "$SESSIOND_BIN" = ""],[
1238 path="$report_bindir/lttng-sessiond"
1239 ],[
1240 path="$SESSIOND_BIN"
1241 ])
1242 PPRINT_PROP_STRING([lttng-sessiond executable], [$path])
1243
1244 AS_IF([test "$CONSUMERD32_BIN" = ""],[
1245 path="`eval eval echo $lttnglibexecdir`/lttng-consumerd"
1246 ],[
1247 path="$CONSUMERD32_BIN"
1248 ])
1249 PPRINT_PROP_STRING([32-bit lttng-consumerd executable], [$path])
1250
1251 AS_IF([test "$CONSUMERD32_LIBDIR" = ""],[
1252 path="`eval eval echo $libdir`"
1253 ],[
1254 path="$CONSUMERD32_LIBDIR"
1255 ])
1256 PPRINT_PROP_STRING([32-bit consumer libraries], [$path])
1257
1258 AS_IF([test "$CONSUMERD64_BIN" = ""],[
1259 path="`eval eval echo $lttnglibexecdir`/lttng-consumerd"
1260 ],[
1261 path="$CONSUMERD64_BIN"
1262 ])
1263 PPRINT_PROP_STRING([64-bit lttng-consumerd executable], [$path])
1264
1265 AS_IF([test "$CONSUMERD64_LIBDIR" = ""],[
1266 path="`eval eval echo $libdir`"
1267 ],[
1268 path="$CONSUMERD64_LIBDIR"
1269 ])
1270 PPRINT_PROP_STRING([64-bit consumer libraries], [$path])
1271 PPRINT_SET_INDENT(0)
1272
1273 AS_IF([test "x$warn_prebuilt_man_pages" = "xyes" ], [
1274 AS_ECHO
1275 PPRINT_WARN([You need asciidoc and xmlto to build the LTTng-tools man pages.
1276
1277 Note that the man pages are already built in this distribution tarball,
1278 therefore asciidoc and xmlto are only needed if you intend to modify
1279 their sources.
1280
1281 Also note that the installed man pages will contain the project's
1282 default command-line option and environment variable values.
1283
1284 Use --disable-man-pages to completely disable building and installing
1285 the man pages.])
1286 ])
This page took 0.051811 seconds and 3 git commands to generate.