Test: Add the new log4j agent
[lttng-tools.git] / configure.ac
1 AC_INIT([lttng-tools],[2.5.0-rc2],[dgoulet@efficios.com],[],[http://lttng.org])
2 AC_CONFIG_AUX_DIR([config])
3 AC_CANONICAL_TARGET
4 AC_CANONICAL_HOST
5 AC_CONFIG_MACRO_DIR([config])
6 AM_INIT_AUTOMAKE([foreign dist-bzip2 no-dist-gzip])
7 AM_MAINTAINER_MODE([enable])
8 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
9
10 # Compute minor/major/patchlevel version numbers
11 AC_PROG_SED
12 major_version=$(echo AC_PACKAGE_VERSION | sed 's/^\([[0-9]]\)*\.[[0-9]]*\.[[0-9]]*.*$/\1/')
13 minor_version=$(echo AC_PACKAGE_VERSION | sed 's/^[[0-9]]*\.\([[0-9]]*\)\.[[0-9]]*.*$/\1/')
14 patchlevel_version=$(echo AC_PACKAGE_VERSION | sed 's/^[[0-9]]*\.[[0-9]]*\.\([[0-9]]*\).*$/\1/')
15 AC_SUBST([MAJOR_VERSION], [$major_version])
16 AC_SUBST([MINOR_VERSION], [$minor_version])
17 AC_SUBST([PATCHLEVEL_VERSION], [$patchlevel_version])
18 AC_DEFINE_UNQUOTED([VERSION_MAJOR], $major_version, [LTTng-Tools major version number])
19 AC_DEFINE_UNQUOTED([VERSION_MINOR], $minor_version, [LTTng-Tools minor version number])
20 AC_DEFINE_UNQUOTED([VERSION_PATCHLEVEL], $patchlevel_version, [LTTng-Tools patchlevel version number])
21
22 version_name="Fumisterie"
23 version_description="The Fumisterie is a beer whose style is at the confluence of English and German ales. On the palate, it is full-bodied, malty and slightly caramelized. The organic hemp seeds incorporated during the brewing gives it a unique and original taste. The hop flavour comes through delicately in the after taste."
24
25 AC_DEFINE_UNQUOTED([VERSION_NAME], ["$version_name"], "")
26 AC_DEFINE_UNQUOTED([VERSION_DESCRIPTION], ["$version_description"], "")
27
28 AC_CONFIG_HEADERS([include/config.h])
29
30 AC_PROG_GREP
31 # libtool link_all_deplibs fixup. See http://bugs.lttng.org/issues/321.
32 AC_ARG_ENABLE(libtool-linkdep-fixup,
33 AS_HELP_STRING([--disable-libtool-linkdep-fixup],
34 [disable the libtool fixup for linking all dependent libraries (link_all_deplibs)]),
35 libtool_fixup=$enableval,
36 libtool_fixup=yes)
37
38 AS_IF([test "x$libtool_fixup" = "xyes"],
39 [
40 libtool_m4="$srcdir/config/libtool.m4"
41 libtool_flag_pattern=".*link_all_deplibs\s*,\s*\$1\s*)"
42 AC_MSG_CHECKING([for occurence(s) of link_all_deplibs = no in $libtool_m4])
43 libtool_flag_pattern_count=$(grep -c "$libtool_flag_pattern\s*=\s*no" $libtool_m4)
44 AS_IF([test $libtool_flag_pattern_count -ne 0],
45 [
46 AC_MSG_RESULT([$libtool_flag_pattern_count])
47 AC_MSG_WARN([the detected libtool will not link all dependencies, forcing link_all_deplibs = unknown])
48 sed -i "s/\($libtool_flag_pattern\)\s*=\s*no/\1=unknown/g" $libtool_m4
49 ],
50 [
51 AC_MSG_RESULT([none])
52 ])
53 ])
54
55 AM_CONDITIONAL([NO_SHARED], [test x$enable_shared = xno])
56
57 AC_CHECK_HEADERS([ \
58 sys/types.h unistd.h fcntl.h string.h pthread.h limits.h \
59 signal.h stdlib.h sys/un.h sys/socket.h stdlib.h stdio.h \
60 getopt.h sys/ipc.h sys/shm.h popt.h grp.h \
61 ])
62
63 # Babeltrace viewer check
64 AC_ARG_WITH([babeltrace-bin],
65 AS_HELP_STRING([--with-babeltrace-bin],
66 [Location of the babeltrace viewer executable (including the filename)]),
67 [BABELTRACE_BIN="$withval"],
68 [BABELTRACE_BIN=''])
69 AC_SUBST([BABELTRACE_BIN])
70
71 # lttv-gui
72 AC_ARG_WITH([lttv-gui-bin],
73 AS_HELP_STRING([--with-lttv-gui-bin],
74 [Location of the lttv GUI viewer executable (including the filename)]),
75 [LTTV_GUI_BIN="$withval"],
76 [LTTV_GUI_BIN=''])
77 AC_SUBST([LTTV_GUI_BIN])
78
79 AC_ARG_WITH([consumerd32-bin],
80 AS_HELP_STRING([--with-consumerd32-bin],
81 [Location of the 32-bit consumerd executable (including the filename)]),
82 [CONSUMERD32_BIN="$withval"],
83 [CONSUMERD32_BIN=''])
84 AC_SUBST([CONSUMERD32_BIN])
85
86 AC_ARG_WITH([consumerd64-bin],
87 AS_HELP_STRING([--with-consumerd64-bin],
88 [Location of the 64-bit consumerd executable (including the filename)]),
89 [CONSUMERD64_BIN="$withval"],
90 [CONSUMERD64_BIN=''])
91 AC_SUBST([CONSUMERD64_BIN])
92
93 AC_ARG_WITH([consumerd32-libdir],
94 AS_HELP_STRING([--with-consumerd32-libdir],
95 [Directory containing the 32-bit consumerd libraries]),
96 [CONSUMERD32_LIBDIR="$withval"],
97 [CONSUMERD32_LIBDIR=''])
98 AC_SUBST([CONSUMERD32_LIBDIR])
99
100 AC_ARG_WITH([consumerd64-libdir],
101 AS_HELP_STRING([--with-consumerd64-libdir],
102 [Directory containing the 64-bit consumerd libraries]),
103 [CONSUMERD64_LIBDIR="$withval"],
104 [CONSUMERD64_LIBDIR=''])
105 AC_SUBST([CONSUMERD64_LIBDIR])
106
107 AC_ARG_WITH([sessiond-bin],
108 AS_HELP_STRING([--with-sessiond-bin],
109 [Location of the sessiond executable (including the filename)]),
110 [SESSIOND_BIN="$withval"],
111 [SESSIOND_BIN=''])
112 AC_SUBST([SESSIOND_BIN])
113
114 AC_ARG_WITH([lttng-system-rundir],
115 AS_HELP_STRING([--with-lttng-system-rundir],
116 [Location of the system directory where the system-wide lttng-sessiond runtime files are kept. The default is "/var/run/lttng".]),
117 [LTTNG_SYSTEM_RUNDIR="$withval"],
118 [LTTNG_SYSTEM_RUNDIR="/var/run/lttng"])
119 AC_SUBST([LTTNG_SYSTEM_RUNDIR])
120
121 AC_DEFINE_UNQUOTED([CONFIG_CONSUMERD32_BIN], "$CONSUMERD32_BIN", [Location of the 32-bit consumerd executable.])
122 AC_DEFINE_UNQUOTED([CONFIG_CONSUMERD64_BIN], "$CONSUMERD64_BIN", [Location of the 64-bit consumerd executable])
123 AC_DEFINE_UNQUOTED([CONFIG_CONSUMERD32_LIBDIR], "$CONSUMERD32_LIBDIR", [Search for consumerd 32-bit libraries in this location.])
124 AC_DEFINE_UNQUOTED([CONFIG_CONSUMERD64_LIBDIR], "$CONSUMERD64_LIBDIR", [Search for consumerd 64-bit libraries in this location.])
125 AC_DEFINE_UNQUOTED([CONFIG_BABELTRACE_BIN], "$BABELTRACE_BIN", [Location of the babeltrace viewer executable.])
126 AC_DEFINE_UNQUOTED([CONFIG_LTTV_GUI_BIN], "$LTTV_GUI_BIN", [Location of the lttv GUI viewer executable.])
127 AC_DEFINE_UNQUOTED([CONFIG_SESSIOND_BIN], "$SESSIOND_BIN", [Location of the sessiond executable.])
128 AC_DEFINE_UNQUOTED([CONFIG_LTTNG_SYSTEM_RUNDIR], ["$LTTNG_SYSTEM_RUNDIR"], [LTTng system runtime directory])
129
130 if test "x$prefix" = "xNONE"; then
131 prefix=$ac_default_prefix
132 fi
133 CONFDIR=`eval echo $sysconfdir`
134 AC_SUBST(CONFDIR)
135 AC_DEFINE_UNQUOTED([CONFIG_LTTNG_SYSTEM_CONFIGDIR],"$CONFDIR", [LTTng system configuration directory.])
136
137 AC_DEFINE_DIR([CONFIG_LTTNG_SYSTEM_DATADIR],[datadir], [LTTng system data directory.])
138
139 #
140 # Check for pthread
141 AC_CHECK_LIB([pthread], [pthread_create], [],
142 [AC_MSG_ERROR([Cannot find libpthread. Use [LDFLAGS]=-Ldir to specify its location.])]
143 )
144
145 # Check libpopt
146 AC_CHECK_LIB([popt], [poptGetContext], [],
147 [AC_MSG_ERROR([Cannot find libpopt. Use [LDFLAGS]=-Ldir to specify its location.])]
148 )
149
150 AM_PATH_XML2(2.7.6, true, AC_MSG_ERROR(No supported version of libxml2 found.))
151
152 # Check for libuuid
153 AC_CHECK_LIB([uuid], [uuid_generate],
154 [
155 AC_DEFINE_UNQUOTED([LTTNG_HAVE_LIBUUID], 1, [Has libuuid support.])
156 have_libuuid=yes
157 ],
158 [
159 # libuuid not found, check for uuid_create in libc.
160 AC_CHECK_LIB([c], [uuid_create],
161 [
162 AC_DEFINE_UNQUOTED([LTTNG_HAVE_LIBC_UUID], 1, [Has libc uuid support.])
163 have_libc_uuid=yes
164 ],
165 [
166 AC_MSG_ERROR([Cannot find libuuid uuid_generate nor libc uuid_create. Use [LDFLAGS]=-Ldir to specify their location.])
167 ])
168 ]
169 )
170 AM_CONDITIONAL([LTTNG_BUILD_WITH_LIBUUID], [test "x$have_libuuid" = "xyes"])
171 AM_CONDITIONAL([LTTNG_BUILD_WITH_LIBC_UUID], [test "x$have_libc_uuid" = "xyes"])
172
173 # URCU library version needed or newer
174 liburcu_version=">= 0.8.0"
175
176 # Check liburcu needed function calls
177 AC_CHECK_DECL([cds_list_add], [],
178 [AC_MSG_ERROR([liburcu $liburcu_version or newer is needed])], [[#include <urcu/list.h>]]
179 )
180 AC_CHECK_DECL([cds_wfcq_init], [],
181 [AC_MSG_ERROR([liburcu $liburcu_version or newer is needed])], [[#include <urcu/wfcqueue.h>]]
182 )
183 AC_CHECK_DECL([cds_wfcq_dequeue_blocking], [],
184 [AC_MSG_ERROR([liburcu $liburcu_version or newer is needed])], [[#include <urcu/wfcqueue.h>]]
185 )
186 AC_CHECK_DECL([futex_async], [],
187 [AC_MSG_ERROR([liburcu $liburcu_version or newer is needed])], [[#include <urcu/futex.h>]]
188 )
189 AC_CHECK_DECL([rcu_thread_offline], [],
190 [AC_MSG_ERROR([liburcu $liburcu_version or newer is needed])], [[#include <urcu.h>]]
191 )
192 AC_CHECK_DECL([rcu_thread_online], [],
193 [AC_MSG_ERROR([liburcu $liburcu_version or newer is needed])], [[#include <urcu.h>]]
194 )
195 AC_CHECK_DECL([caa_likely], [],
196 [AC_MSG_ERROR([liburcu $liburcu_version or newer is needed])], [[#include <urcu.h>]]
197 )
198 #Function added in urcu 0.7.0
199 AC_CHECK_DECL([cmm_smp_mb__before_uatomic_or], [],
200 [AC_MSG_ERROR([liburcu $liburcu_version or newer is needed])], [[#include <urcu.h>]]
201 )
202
203 # Check kmod library
204 AC_ARG_WITH(kmod-prefix,
205 AS_HELP_STRING([--with-kmod-prefix=PATH],
206 [Specify the installation prefix of the kmod library.
207 Headers must be in PATH/include; libraries in PATH/lib.]),
208 [
209 CPPFLAGS="$CPPFLAGS -I${withval}/include"
210 LDFLAGS="$LDFLAGS -L${withval}/lib64 -L${withval}/lib"
211 ])
212
213 AC_ARG_ENABLE(kmod,
214 AS_HELP_STRING([--disable-kmod],[build without kmod support]),
215 kmod_support=zz$enableval, kmod_support=yes)
216
217 AS_IF([test "x$kmod_support" = "xyes"], [
218 AC_CHECK_LIB([kmod], [kmod_module_probe_insert_module],
219 [
220 AC_DEFINE([HAVE_KMOD], [1], [has kmod support])
221 LIBS="$LIBS -lkmod"
222 kmod_found=yes
223 ],
224 kmod_found=no
225 )
226 ])
227 AM_CONDITIONAL([HAVE_KMOD], [test "x$kmod_found" = xyes])
228
229 AC_ARG_WITH(lttng-ust-prefix,
230 AS_HELP_STRING([--with-lttng-ust-prefix=PATH],
231 [Specify the installation prefix of the lttng-ust library.
232 Headers must be in PATH/include; libraries in PATH/lib.]),
233 [
234 CPPFLAGS="$CPPFLAGS -I${withval}/include"
235 LDFLAGS="$LDFLAGS -L${withval}/lib64 -L${withval}/lib"
236 ])
237
238 # Check liblttng-ust-ctl library
239 AC_ARG_ENABLE(lttng-ust,
240 AS_HELP_STRING([--disable-lttng-ust],[build without LTTng-UST (Userspace Tracing) support]),
241 lttng_ust_support=$enableval, lttng_ust_support=yes)
242
243 AS_IF([test "x$lttng_ust_support" = "xyes"], [
244 AC_CHECK_LIB([lttng-ust-ctl], [ustctl_recv_channel_from_consumer],
245 [
246 AC_DEFINE([HAVE_LIBLTTNG_UST_CTL], [1], [has LTTng-UST control support])
247 lttng_ust_ctl_found=yes
248 ],
249 [AC_MSG_ERROR([Cannot find LTTng-UST >= 2.2.x. Use --with-lttng-ust-prefix=PREFIX to specify its location, or specify --disable-lttng-ust to build lttng-tools without LTTng-UST support.])],
250 [-lurcu-common -lurcu-bp -lurcu-cds -lrt]
251 )
252 ])
253 AM_CONDITIONAL([HAVE_LIBLTTNG_UST_CTL], [test "x$lttng_ust_ctl_found" = xyes])
254 AC_CHECK_FUNCS([sched_getcpu sysconf sync_file_range])
255
256 # check for dlopen
257 AC_CHECK_LIB([dl], [dlopen],
258 [
259 have_libdl=yes
260 ],
261 [
262 #libdl not found, check for dlopen in libc.
263 AC_CHECK_LIB([c], [dlopen],
264 [
265 have_libc_dl=yes
266 ],
267 [
268 AC_MSG_ERROR([Cannot find dlopen in libdl nor libc. Use [LDFLAGS]=-Ldir to specify their location.])
269 ])
270 ])
271 AM_CONDITIONAL([LTTNG_TOOLS_BUILD_WITH_LIBDL], [test "x$have_libdl" = "xyes"])
272 AM_CONDITIONAL([LTTNG_TOOLS_BUILD_WITH_LIBC_DL], [test "x$have_libc_dl" = "xyes"])
273
274 # Check for fmemopen
275 AC_CHECK_LIB([c], [fmemopen],
276 [
277 AC_DEFINE_UNQUOTED([LTTNG_HAVE_FMEMOPEN], 1, [Has fmemopen support.])
278 ]
279 )
280
281 # Check for open_memstream
282 AC_CHECK_LIB([c], [open_memstream],
283 [
284 AC_DEFINE_UNQUOTED([LTTNG_HAVE_OPEN_MEMSTREAM], 1, [Has open_memstream support.])
285 ]
286 )
287
288 AC_ARG_ENABLE([git-version],
289 [AC_HELP_STRING([--disable-git-version],
290 [Do not use the git version for the build])],
291 [have_git_version=$enableval], [have_git_version=yes]
292 )
293
294 AM_CONDITIONAL([LTTNG_TOOLS_BUILD_GIT_SOURCE],
295 [test "x${have_git_version}" = "xyes"])
296
297 # For Python
298 # SWIG version needed or newer:
299 swig_version=2.0.0
300
301 AC_ARG_ENABLE([python-bindings],
302 [AC_HELP_STRING([--enable-python-bindings],
303 [compile Python bindings])],
304 [enable_python=yes], [enable_python=no])
305
306 AM_CONDITIONAL([USE_PYTHON], [test "x${enable_python:-yes}" = xyes])
307
308 if test "x${enable_python:-yes}" = xyes; then
309 AX_PKG_SWIG($swig_version, [], [ AC_MSG_ERROR([SWIG $swig_version or newer is needed]) ])
310 AM_PATH_PYTHON
311
312 AC_ARG_VAR([PYTHON_INCLUDE], [Include flags for python, bypassing python-config])
313 AC_ARG_VAR([PYTHON_CONFIG], [Path to python-config])
314 AS_IF([test -z "$PYTHON_INCLUDE"], [
315 AS_IF([test -z "$PYTHON_CONFIG"], [
316 AC_PATH_PROGS([PYTHON_CONFIG],
317 [python$PYTHON_VERSION-config python-config],
318 [no],
319 [`dirname $PYTHON`])
320 AS_IF([test "$PYTHON_CONFIG" = no], [AC_MSG_ERROR([cannot find python-config for $PYTHON. Do you have python-dev installed?])])
321 ])
322 AC_MSG_CHECKING([python include flags])
323 PYTHON_INCLUDE=`$PYTHON_CONFIG --includes`
324 AC_MSG_RESULT([$PYTHON_INCLUDE])
325 ])
326
327 else
328 AC_MSG_NOTICE([You may configure with --enable-python-bindings ]dnl
329 [if you want Python bindings.])
330
331 fi
332
333 # Epoll check. If not present, the build will fallback on poll() API
334 AX_HAVE_EPOLL(
335 [AX_CONFIG_FEATURE_ENABLE(epoll)],
336 [AX_CONFIG_FEATURE_DISABLE(epoll)]
337 )
338 AX_CONFIG_FEATURE(
339 [epoll], [This platform supports epoll(7)],
340 [HAVE_EPOLL], [This platform supports epoll(7).],
341 [enable_epoll="yes"], [enable_epoll="no"]
342 )
343 AM_CONDITIONAL([COMPAT_EPOLL], [ test "$enable_epoll" = "yes" ])
344
345 # Set compile flags to java include files if given. This is only used to
346 # compile java agent tests.
347 AC_ARG_WITH([java-jdk],
348 [AS_HELP_STRING([--with-java-jdk=DIR],[use the Java JDK in DIR. Ex : $JAVA_HOME.])],
349 [JAVA_JDK=$withval],
350 [JAVA_JDK=""]
351 )
352 AM_CONDITIONAL([HAVE_JAVA_JDK], [test $JAVA_JDK], [Java JDK path])
353 AC_SUBST([JAVA_JDK])
354
355 AS_IF([test $JAVA_JDK],[
356 AS_IF([test -d $JAVA_JDK],
357 [
358 AC_MSG_RESULT([using Java includes in $JAVA_SDK])
359 SUBDIRS=`find $JAVA_JDK/include -type d`
360 CPPFLAGS+=" "
361 CPPFLAGS+=`for x in $SUBDIRS; do echo -n "-I$x "; done`
362 CPPFLAGS+=" "
363 ],[AC_MSG_ERROR(Unable to find Java include files in $JAVA_JDK)]
364 )
365 ])
366
367 # Check for the UST agent jar file in the system. Hardcoded path is added here
368 # since we have *no* idea where this could be installed. Note that this is only
369 # used for agent testing.
370 AC_MSG_CHECKING(Java UST agent jar file)
371 java_agent_jar_path="${prefix}/share/java/liblttng-ust-agent.jar"
372 if test -f $java_agent_jar_path; then
373 build_java_agent=yes
374 AC_MSG_RESULT(found)
375 else
376 build_java_agent=no
377 AC_MSG_RESULT(not found)
378 fi
379 AM_CONDITIONAL([BUILD_JAVA_AGENT], [test "x$build_java_agent" = "xyes"])
380 AC_SUBST([java_agent_jar_path])
381
382 # Check for log4j support on the system to know if we can build or not the
383 # log4j tests.
384 if test "x$build_java_agent" = "xyes"; then
385 AC_MSG_CHECKING(Java agent support for log4j)
386 AX_JAVA_OPTIONS
387 AX_PROG_JAR
388 AX_PROG_JAVA
389 AX_PROG_JAVAC
390
391 # By default, use a commonly used classpath on the system to ease things up
392 # for the Java testing in this directory.
393 LOG4J_CLASSPATH="$java_agent_jar_path:$CLASSPATH:.:/usr/share/java/*"
394 JAVAFLAGS="-cp $LOG4J_CLASSPATH"
395 JAVACFLAGS="$JAVAFLAGS"
396 AX_CHECK_CLASS(org.apache.log4j.Logger)
397
398 if test "x$ac_cv_class_org_apache_log4j_Logger" = "xno"; then
399 build_java_log4j_agent=no
400 else
401 build_java_log4j_agent=yes
402 fi
403 fi
404 AM_CONDITIONAL([BUILD_JAVA_LOG4J_AGENT], [test "x$build_java_log4j_agent" = "xyes"])
405
406 AC_SYS_LARGEFILE
407 AC_PROG_CC
408 LT_INIT
409 AC_PROG_YACC
410 AC_PROG_LEX
411
412 if test ! -f "$srcdir/src/lib/lttng-ctl/filter/filter-parser.h"; then
413 if test x"$YACC" != "xbison -y"; then
414 AC_MSG_ERROR([[bison not found and is required when building from git.
415 Please install bison]])
416 fi
417 fi
418
419 if test ! -f "$srcdir/src/lib/lttng-ctl/filter/filter-lexer.c"; then
420 if test x"$LEX" != "xflex"; then
421 AC_MSG_ERROR([[flex not found and is required when building from git.
422 Please install flex]])
423 fi
424 fi
425
426 CFLAGS="-Wall $CFLAGS -g -fno-strict-aliasing"
427
428 DEFAULT_INCLUDES="-I\$(top_srcdir) -I\$(top_builddir) -I\$(top_builddir)/src -I\$(top_builddir)/include -include config.h"
429
430 lttngincludedir="${includedir}/lttng"
431
432 AC_SUBST(lttngincludedir)
433 AC_SUBST(DEFAULT_INCLUDES)
434
435 lttnglibexecdir="${libdir}/lttng/libexec"
436 AC_SUBST(lttnglibexecdir)
437
438 AC_CONFIG_FILES([
439 Makefile
440 doc/Makefile
441 doc/man/Makefile
442 include/Makefile
443 extras/Makefile
444 extras/bindings/Makefile
445 extras/bindings/swig/Makefile
446 extras/bindings/swig/python/Makefile
447 extras/core-handler/Makefile
448 src/Makefile
449 src/common/Makefile
450 src/common/kernel-ctl/Makefile
451 src/common/kernel-consumer/Makefile
452 src/common/ust-consumer/Makefile
453 src/common/hashtable/Makefile
454 src/common/sessiond-comm/Makefile
455 src/common/compat/Makefile
456 src/common/relayd/Makefile
457 src/common/testpoint/Makefile
458 src/common/index/Makefile
459 src/common/health/Makefile
460 src/common/config/Makefile
461 src/lib/Makefile
462 src/lib/lttng-ctl/Makefile
463 src/lib/lttng-ctl/filter/Makefile
464 src/lib/lttng-ctl/lttng-ctl.pc
465 src/bin/Makefile
466 src/bin/lttng-consumerd/Makefile
467 src/bin/lttng-sessiond/Makefile
468 src/bin/lttng-relayd/Makefile
469 src/bin/lttng/Makefile
470 tests/Makefile
471 tests/regression/Makefile
472 tests/regression/kernel/Makefile
473 tests/regression/tools/Makefile
474 tests/regression/tools/streaming/Makefile
475 tests/regression/tools/filtering/Makefile
476 tests/regression/tools/health/Makefile
477 tests/regression/tools/tracefile-limits/Makefile
478 tests/regression/tools/snapshots/Makefile
479 tests/regression/tools/live/Makefile
480 tests/regression/tools/exclusion/Makefile
481 tests/regression/tools/save-load/Makefile
482 tests/regression/tools/mi/Makefile
483 tests/regression/ust/Makefile
484 tests/regression/ust/nprocesses/Makefile
485 tests/regression/ust/high-throughput/Makefile
486 tests/regression/ust/low-throughput/Makefile
487 tests/regression/ust/before-after/Makefile
488 tests/regression/ust/buffers-pid/Makefile
489 tests/regression/ust/periodical-metadata-flush/Makefile
490 tests/regression/ust/multi-session/Makefile
491 tests/regression/ust/overlap/Makefile
492 tests/regression/ust/overlap/demo/Makefile
493 tests/regression/ust/linking/Makefile
494 tests/regression/ust/daemon/Makefile
495 tests/regression/ust/exit-fast/Makefile
496 tests/regression/ust/fork/Makefile
497 tests/regression/ust/libc-wrapper/Makefile
498 tests/regression/ust/java-jul/Makefile
499 tests/regression/ust/java-log4j/Makefile
500 tests/stress/Makefile
501 tests/unit/Makefile
502 tests/unit/ini_config/Makefile
503 tests/utils/Makefile
504 tests/utils/tap/Makefile
505 tests/utils/testapp/Makefile
506 tests/utils/testapp/gen-ust-events/Makefile
507 tests/utils/testapp/gen-ust-nevents/Makefile
508 tests/utils/testapp/gen-ust-tracef/Makefile
509 ])
510
511 AC_OUTPUT
512
513 #
514 # Mini-report on what will be built
515 #
516 AS_ECHO()
517
518 AS_ECHO("Version name: $version_name")
519 AS_ECHO("$version_description")
520
521 AS_ECHO()
522
523 # Target architecture we're building for
524 target_arch=$host_cpu
525 [
526 for f in $CFLAGS; do
527 if test $f = "-m32"; then
528 target_arch="32-bit"
529 elif test $f = "-m64"; then
530 target_arch="64-bit"
531 fi
532 done
533 ]
534 AS_ECHO_N("Target architecture: ")
535 AS_ECHO($target_arch)
536
537 # kmod enabled/disabled
538 AS_ECHO_N("libkmod support: ")
539 AS_IF([test "x$kmod_found" = "xyes"],[
540 AS_ECHO("Enabled")
541 ],[
542 AS_ECHO("Disabled")
543 ])
544
545 # LTTng-UST enabled/disabled
546 AS_ECHO_N("Lttng-UST support: ")
547 AS_IF([test "x$lttng_ust_support" = "xyes"],[
548 AS_ECHO("Enabled")
549 ],[
550 AS_ECHO("Disabled")
551 ])
552
553 #Python binding enabled/disabled
554 AS_ECHO_N("Python binding: ")
555 AS_IF([test "x${enable_python:-yes}" = xyes], [
556 AS_ECHO("Enabled")
557 ],[
558 AS_ECHO("Disabled")
559 ])
560
561 # Do we build only the consumerd, or everything
562 AS_IF([test "x$consumerd_only" = "xyes"],[
563 AS_ECHO("Only the consumerd daemon will be built.")
564 ],[
565 AS_ECHO("All binaries will be built.")
566 ])
567
568 # Print the bindir and libdir this `make install' will install into.
569 AS_ECHO()
570 AS_ECHO_N("Binaries will be installed in: ")
571 AS_ECHO("`eval eval echo $bindir`")
572 AS_ECHO_N("Libraries will be installed in: ")
573 AS_ECHO("`eval eval echo $libdir`")
574
575 # If we build the sessiond, print the paths it will use
576 AS_IF([test "x$consumerd_only" = "xno"],[
577 AS_ECHO()
578 AS_ECHO_N("The lttng command will look for the lttng-sessiond executable at: ")
579 AS_IF([test "$SESSIOND_BIN" = ""],[
580 AS_ECHO_N("`eval eval echo $bindir`")
581 AS_ECHO("/lttng-sessiond")
582 ],[
583 AS_ECHO("$SESSIOND_BIN")
584 ])
585
586 AS_ECHO()
587 AS_ECHO("The sessiond daemon will look in the following directories: ")
588 AS_ECHO_N("32-bit consumerd executable at: ")
589 AS_IF([test "$CONSUMERD32_BIN" = ""],[
590 AS_ECHO_N("`eval eval echo $lttnglibexecdir`")
591 AS_ECHO("/lttng-consumerd")
592 ],[
593 AS_ECHO("$CONSUMERD32_BIN")
594 ])
595
596 AS_ECHO_N("32-bit consumer libraries in: ")
597 AS_IF([test "$CONSUMERD32_LIBDIR" = ""],[
598 AS_ECHO("`eval eval echo $libdir`")
599 ],[
600 AS_ECHO("$CONSUMERD32_LIBDIR")
601 ])
602
603 AS_ECHO_N("64-bit consumerd executable at: ")
604 AS_IF([test "$CONSUMERD64_BIN" = ""],[
605 AS_ECHO_N("`eval eval echo $lttnglibexecdir`")
606 AS_ECHO("/lttng-consumerd")
607 ],[
608 AS_ECHO("$CONSUMERD64_BIN")
609 ])
610
611 AS_ECHO_N("64-bit consumer libraries in: ")
612 AS_IF([test "$CONSUMERD64_LIBDIR" = ""],[
613 AS_ECHO("`eval eval echo $libdir`")
614 ],[
615 AS_ECHO("$CONSUMERD64_LIBDIR")
616 ])
617 ])
618
619 AS_ECHO()
620
This page took 0.064717 seconds and 4 git commands to generate.