configure.ac

   1 AC_PREREQ([2.64])
   2 AC_INIT([lttng-tools],[2.9.0-pre],[jeremie.galarneau@efficios.com],[],[https://lttng.org])
   3
   4 AC_CONFIG_HEADERS([include/config.h])
   5 AC_CONFIG_AUX_DIR([config])
   6 AC_CONFIG_MACRO_DIR([m4])
   7
   8 AC_CANONICAL_TARGET
   9 AC_CANONICAL_HOST
  10
  11 AM_INIT_AUTOMAKE([foreign dist-bzip2 no-dist-gzip tar-pax])
  12 AM_MAINTAINER_MODE([enable])
  13
  14 # Enable silent rules if available (Introduced in AM 1.11)
  15 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  16
  17 AC_REQUIRE_AUX_FILE([tap-driver.sh])
  18
  19 # Checks for C compiler
  20 AC_USE_SYSTEM_EXTENSIONS
  21 AC_SYS_LARGEFILE
  22 AC_PROG_CC
  23 AC_PROG_CC_STDC
  24
  25 # Checks for programs.
  26 AC_PROG_GREP
  27 AC_PROG_LEX
  28 AC_PROG_MAKE_SET
  29 AC_PROG_SED
  30 AC_PROG_YACC
  31 AC_PATH_PROG(report_fold, fold)
  32 LT_INIT
  33
  34 # Check for objcopy, required by the base address statedump and dynamic linker tests
  35 AC_CHECK_TOOL([OBJCOPY], objcopy, no)
  36 AS_IF([test "x$OBJCOPY" = xno],
  37         [AC_MSG_WARN([Cannont find objcopy. The base address statedump and dynamic linker tests will be disabled. Install the binutils package to remediate this.])]
  38 )
  39 AM_CONDITIONAL([HAVE_OBJCOPY], [test "x$OBJCOPY" != xno])
  40
  41 # Checks for typedefs, structures, and compiler characteristics.
  42 AC_C_INLINE
  43 AC_TYPE_INT32_T
  44 AC_TYPE_INT64_T
  45 AC_TYPE_MODE_T
  46 AC_TYPE_OFF_T
  47 AC_TYPE_PID_T
  48 AC_TYPE_SIZE_T
  49 AC_TYPE_SSIZE_T
  50 AC_TYPE_UID_T
  51 AC_TYPE_UINT16_T
  52 AC_TYPE_UINT32_T
  53 AC_TYPE_UINT64_T
  54 AC_TYPE_UINT8_T
  55
  56 AX_C___ATTRIBUTE__
  57 AS_IF([test "x$ax_cv___attribute__" = "xyes"],
  58         [:],
  59         [AC_MSG_ERROR([The compiler does not support __attribute__ extensions])])
  60
  61 AX_PTHREAD(,[AC_MSG_ERROR([Could not configure pthreads support])])
  62 LIBS="$PTHREAD_LIBS $LIBS"
  63 CFLAGS="$CFLAGS $PTHREAD_CFLAGS"
  64 CC="$PTHREAD_CC"
  65
  66 AX_LIB_SOCKET_NSL
  67
  68 # Compute minor/major/patchlevel version numbers
  69 major_version=$(echo AC_PACKAGE_VERSION | $SED 's/^\([[0-9]]\)*\.[[0-9]]*\.[[0-9]]*.*$/\1/')
  70 minor_version=$(echo AC_PACKAGE_VERSION | $SED 's/^[[0-9]]*\.\([[0-9]]*\)\.[[0-9]]*.*$/\1/')
  71 patchlevel_version=$(echo AC_PACKAGE_VERSION | $SED 's/^[[0-9]]*\.[[0-9]]*\.\([[0-9]]*\).*$/\1/')
  72
  73 AC_SUBST([MAJOR_VERSION], [$major_version])
  74 AC_SUBST([MINOR_VERSION], [$minor_version])
  75 AC_SUBST([PATCHLEVEL_VERSION], [$patchlevel_version])
  76 AC_DEFINE_UNQUOTED([VERSION_MAJOR], $major_version, [LTTng-Tools major version number])
  77 AC_DEFINE_UNQUOTED([VERSION_MINOR], $minor_version, [LTTng-Tools minor version number])
  78 AC_DEFINE_UNQUOTED([VERSION_PATCHLEVEL], $patchlevel_version, [LTTng-Tools patchlevel version number])
  79
  80 version_name="Codename TBD"
  81 version_description='Description TBD'
  82 version_description_c=$(echo $version_description | $SED 's/"/\\"/g')
  83
  84 AC_DEFINE_UNQUOTED([VERSION_NAME], ["$version_name"], "")
  85 AC_DEFINE_UNQUOTED([VERSION_DESCRIPTION], ["$version_description_c"], "")
  86
  87 # libtool link_all_deplibs fixup. See http://bugs.lttng.org/issues/321.
  88 AC_ARG_ENABLE(libtool-linkdep-fixup,
  89         AS_HELP_STRING([--disable-libtool-linkdep-fixup],
  90                         [disable the libtool fixup for linking all dependent libraries (link_all_deplibs)]),
  91         libtool_fixup=$enableval,
  92         libtool_fixup=yes)
  93
  94 AS_IF([test "x$libtool_fixup" = "xyes"],
  95             [
  96             libtool_m4="$srcdir/m4/libtool.m4"
  97             libtool_flag_pattern=".*link_all_deplibs\s*,\s*\$1\s*)"
  98             AC_MSG_CHECKING([for occurence(s) of link_all_deplibs = no in $libtool_m4])
  99             libtool_flag_pattern_count=$($GREP -c "$libtool_flag_pattern\s*=\s*no" $libtool_m4)
 100             AS_IF([test $libtool_flag_pattern_count -ne 0],
 101             [
 102                   AC_MSG_RESULT([$libtool_flag_pattern_count])
 103                   AC_MSG_WARN([the detected libtool will not link all dependencies, forcing link_all_deplibs = unknown])
 104                   $SED -i "s/\($libtool_flag_pattern\)\s*=\s*no/\1=unknown/g" $libtool_m4
 105                   ],
 106                   [
 107                   AC_MSG_RESULT([none])
 108                   ])
 109             ])
 110
 111 AM_CONDITIONAL([NO_SHARED], [test x$enable_shared = xno])
 112
 113 AC_CHECK_HEADERS([ \
 114         sys/types.h unistd.h fcntl.h string.h pthread.h limits.h \
 115         signal.h stdlib.h sys/un.h sys/socket.h stdlib.h stdio.h \
 116         getopt.h sys/ipc.h sys/shm.h popt.h grp.h arpa/inet.h \
 117         netdb.h netinet/in.h paths.h stddef.h sys/file.h sys/ioctl.h \
 118         sys/mount.h sys/param.h sys/time.h
 119 ])
 120
 121 # Basic functions check
 122 AC_CHECK_FUNCS([ \
 123         atexit bzero clock_gettime dup2 fdatasync fls ftruncate \
 124         gethostbyname gethostname getpagesize localtime_r memchr memset \
 125         mkdir munmap putenv realpath rmdir socket strchr strcspn strdup \
 126         strncasecmp strndup strnlen strpbrk strrchr strstr strtol strtoul \
 127         strtoull dirfd gethostbyname2 getipnodebyname epoll_create1 \
 128 ])
 129
 130 # Check if clock_gettime, timer_create, timer_settime, and timer_delete are available in lib rt, and if so,
 131 # add -lrt to LIBS
 132 AC_CHECK_LIB([rt], [clock_gettime, timer_create, timer_settime, timer_delete])
 133
 134 # Babeltrace viewer check
 135 AC_ARG_WITH([babeltrace-bin],
 136         AS_HELP_STRING([--with-babeltrace-bin],
 137         [Location of the babeltrace viewer executable (including the filename)]),
 138         [BABELTRACE_BIN="$withval"],
 139         [BABELTRACE_BIN=''])
 140 AC_SUBST([BABELTRACE_BIN])
 141
 142 # lttv-gui
 143 AC_ARG_WITH([lttv-gui-bin],
 144         AS_HELP_STRING([--with-lttv-gui-bin],
 145    [Location of the lttv GUI viewer executable (including the filename)]),
 146    [LTTV_GUI_BIN="$withval"],
 147    [LTTV_GUI_BIN=''])
 148 AC_SUBST([LTTV_GUI_BIN])
 149
 150 AC_ARG_WITH([consumerd32-bin],
 151         AS_HELP_STRING([--with-consumerd32-bin],
 152         [Location of the 32-bit consumerd executable (including the filename)]),
 153         [CONSUMERD32_BIN="$withval"],
 154         [CONSUMERD32_BIN=''])
 155 AC_SUBST([CONSUMERD32_BIN])
 156
 157 AC_ARG_WITH([consumerd64-bin],
 158         AS_HELP_STRING([--with-consumerd64-bin],
 159         [Location of the 64-bit consumerd executable (including the filename)]),
 160         [CONSUMERD64_BIN="$withval"],
 161         [CONSUMERD64_BIN=''])
 162 AC_SUBST([CONSUMERD64_BIN])
 163
 164 AC_ARG_WITH([consumerd32-libdir],
 165         AS_HELP_STRING([--with-consumerd32-libdir],
 166         [Directory containing the 32-bit consumerd libraries]),
 167         [CONSUMERD32_LIBDIR="$withval"],
 168         [CONSUMERD32_LIBDIR=''])
 169 AC_SUBST([CONSUMERD32_LIBDIR])
 170
 171 AC_ARG_WITH([consumerd64-libdir],
 172         AS_HELP_STRING([--with-consumerd64-libdir],
 173         [Directory containing the 64-bit consumerd libraries]),
 174         [CONSUMERD64_LIBDIR="$withval"],
 175         [CONSUMERD64_LIBDIR=''])
 176 AC_SUBST([CONSUMERD64_LIBDIR])
 177
 178 AC_ARG_WITH([sessiond-bin],
 179         AS_HELP_STRING([--with-sessiond-bin],
 180         [Location of the sessiond executable (including the filename)]),
 181         [SESSIOND_BIN="$withval"],
 182         [SESSIOND_BIN=''])
 183 AC_SUBST([SESSIOND_BIN])
 184
 185 AC_ARG_WITH([lttng-system-rundir],
 186         AS_HELP_STRING([--with-lttng-system-rundir],
 187         [Location of the system directory where the system-wide lttng-sessiond runtime files are kept. The default is "/var/run/lttng".]),
 188         [LTTNG_SYSTEM_RUNDIR="$withval"],
 189         [LTTNG_SYSTEM_RUNDIR="/var/run/lttng"])
 190 AC_SUBST([LTTNG_SYSTEM_RUNDIR])
 191
 192 AC_ARG_ENABLE([test-java-agent-jul],
 193         [AS_HELP_STRING([--enable-test-java-agent-jul],[enable the LTTng UST Java agent JUL tests [default=no]])],
 194         [test_java_agent_jul=$enableval],
 195         [test_java_agent_jul=no]
 196 )
 197
 198 AC_ARG_ENABLE([test-java-agent-log4j],
 199         [AS_HELP_STRING([--enable-test-java-agent-log4j],[enable the LTTng UST Java agent Log4j tests [default=no]])],
 200         [test_java_agent_log4j=$enableval],
 201         [test_java_agent_log4j=no]
 202 )
 203
 204 AC_ARG_ENABLE([test-java-agent-all],
 205         [AS_HELP_STRING([--enable-test-java-agent-all],[enable all the LTTng UST Java agent tests [default=no]])],
 206         [test_java_agent_jul=$enableval
 207          test_java_agent_log4j=$enableval],
 208         [:]
 209 )
 210
 211 AC_DEFINE_UNQUOTED([CONFIG_CONSUMERD32_BIN], "$CONSUMERD32_BIN", [Location of the 32-bit consumerd executable.])
 212 AC_DEFINE_UNQUOTED([CONFIG_CONSUMERD64_BIN], "$CONSUMERD64_BIN", [Location of the 64-bit consumerd executable])
 213 AC_DEFINE_UNQUOTED([CONFIG_CONSUMERD32_LIBDIR], "$CONSUMERD32_LIBDIR", [Search for consumerd 32-bit libraries in this location.])
 214 AC_DEFINE_UNQUOTED([CONFIG_CONSUMERD64_LIBDIR], "$CONSUMERD64_LIBDIR", [Search for consumerd 64-bit libraries in this location.])
 215 AC_DEFINE_UNQUOTED([CONFIG_BABELTRACE_BIN], "$BABELTRACE_BIN", [Location of the babeltrace viewer executable.])
 216 AC_DEFINE_UNQUOTED([CONFIG_LTTV_GUI_BIN], "$LTTV_GUI_BIN", [Location of the lttv GUI viewer executable.])
 217 AC_DEFINE_UNQUOTED([CONFIG_SESSIOND_BIN], "$SESSIOND_BIN", [Location of the sessiond executable.])
 218 AC_DEFINE_UNQUOTED([CONFIG_LTTNG_SYSTEM_RUNDIR], ["$LTTNG_SYSTEM_RUNDIR"], [LTTng system runtime directory])
 219
 220 AC_DEFUN([_AC_DEFINE_AND_SUBST], [
 221         AC_DEFINE_UNQUOTED([CONFIG_$1], [$2], [$1])
 222         $1="$2"
 223         AC_SUBST([$1])
 224 ])
 225
 226 AC_DEFUN([_AC_DEFINE_QUOTED_AND_SUBST], [
 227         AC_DEFINE_UNQUOTED([CONFIG_$1], ["$2"], [$1])
 228         $1="$2"
 229         AC_SUBST([$1])
 230 ])
 231
 232 # Default values
 233 m4_define([_DEFAULT_CHANNEL_SUBBUF_SIZE], [4096])
 234 m4_define([_DEFAULT_CHANNEL_SUBBUF_NUM], [4])
 235 m4_define([_DEFAULT_CHANNEL_SWITCH_TIMER], [0])
 236 m4_define([_DEFAULT_CHANNEL_LIVE_TIMER], [0])
 237 m4_define([_DEFAULT_CHANNEL_READ_TIMER], [200000])
 238 _AC_DEFINE_AND_SUBST([DEFAULT_AGENT_TCP_PORT], [5345])
 239 _AC_DEFINE_AND_SUBST([DEFAULT_APP_SOCKET_RW_TIMEOUT], [5])
 240 _AC_DEFINE_AND_SUBST([DEFAULT_CHANNEL_SUBBUF_SIZE], [_DEFAULT_CHANNEL_SUBBUF_SIZE])
 241 _AC_DEFINE_AND_SUBST([DEFAULT_CHANNEL_TRACEFILE_COUNT], [0])
 242 _AC_DEFINE_AND_SUBST([DEFAULT_CHANNEL_TRACEFILE_SIZE], [0])
 243 _AC_DEFINE_AND_SUBST([DEFAULT_KERNEL_CHANNEL_LIVE_TIMER], [_DEFAULT_CHANNEL_LIVE_TIMER])
 244 _AC_DEFINE_AND_SUBST([DEFAULT_KERNEL_CHANNEL_READ_TIMER], [_DEFAULT_CHANNEL_READ_TIMER])
 245 _AC_DEFINE_AND_SUBST([DEFAULT_KERNEL_CHANNEL_SUBBUF_NUM], [_DEFAULT_CHANNEL_SUBBUF_NUM])
 246 _AC_DEFINE_AND_SUBST([DEFAULT_KERNEL_CHANNEL_SUBBUF_SIZE], [262144])
 247 _AC_DEFINE_AND_SUBST([DEFAULT_KERNEL_CHANNEL_SWITCH_TIMER], [_DEFAULT_CHANNEL_SWITCH_TIMER])
 248 _AC_DEFINE_AND_SUBST([DEFAULT_LTTNG_LIVE_TIMER], [1000000])
 249 _AC_DEFINE_AND_SUBST([DEFAULT_METADATA_CACHE_SIZE], [4096])
 250 _AC_DEFINE_AND_SUBST([DEFAULT_METADATA_READ_TIMER], [0])
 251 _AC_DEFINE_AND_SUBST([DEFAULT_METADATA_SUBBUF_NUM], [2])
 252 _AC_DEFINE_AND_SUBST([DEFAULT_METADATA_SUBBUF_SIZE], [4096])
 253 _AC_DEFINE_AND_SUBST([DEFAULT_METADATA_SWITCH_TIMER], [_DEFAULT_CHANNEL_SWITCH_TIMER])
 254 _AC_DEFINE_AND_SUBST([DEFAULT_NETWORK_CONTROL_PORT], [5342])
 255 _AC_DEFINE_AND_SUBST([DEFAULT_NETWORK_DATA_PORT], [5343])
 256 _AC_DEFINE_AND_SUBST([DEFAULT_NETWORK_VIEWER_PORT], [5344])
 257 _AC_DEFINE_AND_SUBST([DEFAULT_UST_PID_CHANNEL_LIVE_TIMER], [_DEFAULT_CHANNEL_LIVE_TIMER])
 258 _AC_DEFINE_AND_SUBST([DEFAULT_UST_PID_CHANNEL_READ_TIMER], [0])
 259 _AC_DEFINE_AND_SUBST([DEFAULT_UST_PID_CHANNEL_SUBBUF_NUM], [_DEFAULT_CHANNEL_SUBBUF_NUM])
 260 _AC_DEFINE_AND_SUBST([DEFAULT_UST_PID_CHANNEL_SUBBUF_SIZE], [_DEFAULT_CHANNEL_SUBBUF_SIZE])
 261 _AC_DEFINE_AND_SUBST([DEFAULT_UST_PID_CHANNEL_SWITCH_TIMER], [_DEFAULT_CHANNEL_SWITCH_TIMER])
 262 _AC_DEFINE_AND_SUBST([DEFAULT_UST_UID_CHANNEL_LIVE_TIMER], [_DEFAULT_CHANNEL_LIVE_TIMER])
 263 _AC_DEFINE_AND_SUBST([DEFAULT_UST_UID_CHANNEL_READ_TIMER], [0])
 264 _AC_DEFINE_AND_SUBST([DEFAULT_UST_UID_CHANNEL_SUBBUF_NUM], [_DEFAULT_CHANNEL_SUBBUF_NUM])
 265 _AC_DEFINE_AND_SUBST([DEFAULT_UST_UID_CHANNEL_SUBBUF_SIZE], [131072])
 266 _AC_DEFINE_AND_SUBST([DEFAULT_UST_UID_CHANNEL_SWITCH_TIMER], [_DEFAULT_CHANNEL_SWITCH_TIMER])
 267 _AC_DEFINE_QUOTED_AND_SUBST([DEFAULT_AGENT_BIND_ADDRESS], [localhost])
 268 _AC_DEFINE_QUOTED_AND_SUBST([DEFAULT_NETWORK_CONTROL_BIND_ADDRESS], [0.0.0.0])
 269 _AC_DEFINE_QUOTED_AND_SUBST([DEFAULT_NETWORK_DATA_BIND_ADDRESS], [0.0.0.0])
 270 _AC_DEFINE_QUOTED_AND_SUBST([DEFAULT_NETWORK_VIEWER_BIND_ADDRESS], [localhost])
 271
 272 # Command short descriptions
 273 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_ADD_CONTEXT], [Add context fields to a channel])
 274 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_CALIBRATE], [Quantify LTTng overhead])
 275 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_CREATE], [Create a tracing session])
 276 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_DESTROY], [Tear down tracing sessions])
 277 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_DISABLE_CHANNEL], [Disable tracing channels])
 278 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_DISABLE_EVENT], [Disable event rules])
 279 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_ENABLE_CHANNEL], [Create or enable tracing channels])
 280 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_ENABLE_EVENT], [Create or enable event rules])
 281 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_HELP], [Display help information about a command])
 282 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_LIST], [List tracing sessions, domains, channels, and events])
 283 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_LOAD], [Load tracing session configurations])
 284 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_METADATA], [Manage an LTTng tracing session's metadata generation])
 285 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_SAVE], [Save tracing session configurations])
 286 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_SET_SESSION], [Set current tracing session])
 287 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_SNAPSHOT], [Snapshot buffers of current tracing session])
 288 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_START], [Start tracing])
 289 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_STATUS], [Get the status of the current tracing session])
 290 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_STOP], [Stop tracing])
 291 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_TRACK], [Track specific system resources])
 292 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_UNTRACK], [Untrack specific system resources])
 293 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_VERSION], [Show version information])
 294 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_VIEW], [Start trace viewer])
 295
 296 if test "x$prefix" = "xNONE"; then
 297         prefix=$ac_default_prefix
 298 fi
 299 CONFDIR=`eval echo $sysconfdir`
 300 AC_SUBST(CONFDIR)
 301 AC_DEFINE_UNQUOTED([CONFIG_LTTNG_SYSTEM_CONFIGDIR],"$CONFDIR", [LTTng system configuration directory.])
 302
 303 AC_DEFINE_DIR([CONFIG_LTTNG_SYSTEM_DATADIR],[datadir], [LTTng system data directory.])
 304
 305 #
 306 # Check for pthread
 307 AC_CHECK_LIB([pthread], [pthread_create], [],
 308         [AC_MSG_ERROR([Cannot find libpthread. Use LDFLAGS=-Ldir to specify its location.])]
 309 )
 310
 311 # Check libpopt
 312 PKG_CHECK_MODULES([POPT], [popt],
 313         [LIBS="$LIBS $POPT_LIBS"],
 314         [
 315                 AC_MSG_WARN([pkg-config was unable to find a valid .pc for libpopt. Set PKG_CONFIG_PATH to specify the pkgconfig configuration file location])
 316                 AC_MSG_WARN([Finding libpopt without pkg-config.])
 317                 AC_CHECK_LIB([popt],
 318                         [poptGetContext],
 319                         [],
 320                         [
 321                                  AC_MSG_ERROR([Cannot find libpopt. Either set PKG_CONFIG_PATH to the configuration file location or use LDFLAGS=-Ldir to specify the library location])
 322                         ]
 323                 )
 324         ]
 325 )
 326
 327 AM_PATH_XML2(2.7.6, true, AC_MSG_ERROR(No supported version of libxml2 found.))
 328
 329 # Check for uuid in system libs
 330 AC_CHECK_FUNCS([uuid_generate],
 331 [
 332         AC_DEFINE_UNQUOTED([LTTNG_HAVE_LIBUUID], 1, [Has libuuid support.])
 333         link_with_libuuid=no
 334 ],
 335 [
 336 # First, check the pkg-config module is available, otherwise explicitly check
 337 # for libuuid, or uuid support in the C-library.
 338 PKG_CHECK_MODULES([UUID], [uuid],
 339 [
 340         LIBS="$LIBS $UUID_LIBS"
 341         AC_DEFINE_UNQUOTED([LTTNG_HAVE_LIBUUID], 1, [Has libuuid support.])
 342         link_with_libuuid=yes
 343 ],
 344 [
 345         # Check for libuuid
 346         AC_CHECK_LIB([uuid],
 347                 [uuid_generate],
 348                 [
 349                         AC_DEFINE_UNQUOTED([LTTNG_HAVE_LIBUUID], 1, [Has libuuid support.])
 350                         link_with_libuuid=yes
 351                 ],
 352                 [
 353                         # libuuid not found, check for uuid_create in libc.
 354                         AC_CHECK_LIB([c],
 355                                 [uuid_create],
 356                                 [
 357                                         AC_DEFINE_UNQUOTED([LTTNG_HAVE_LIBC_UUID], 1, [Has libc uuid support.])
 358                                         link_with_libc_uuid=yes
 359                                 ],
 360                                 [
 361                                         AC_MSG_ERROR([Cannot find libuuid uuid_generate nor libc uuid_create. Either set PKG_CONFIG_PATH to the configuration file location or use LDFLAGS=-Ldir to specify the library location])
 362                                 ]
 363                         )
 364                 ]
 365         )
 366 ])
 367 ])
 368
 369 AM_CONDITIONAL([LTTNG_BUILD_WITH_LIBUUID], [test "x$link_with_libuuid" = "xyes"])
 370 AM_CONDITIONAL([LTTNG_BUILD_WITH_LIBC_UUID], [test "x$link_with_libc_uuid" = "xyes"])
 371
 372 # URCU library version needed or newer
 373 m4_define([WRONG_LIBURCU_MSG], [Userspace RCU (liburcu) >= 0.8.0 is needed])
 374
 375 # Check liburcu needed function calls
 376 AC_CHECK_DECL([cds_list_add], [],
 377         [AC_MSG_ERROR([WRONG_LIBURCU_MSG])], [[#include <urcu/list.h>]])
 378 AC_CHECK_DECL([cds_wfcq_init], [],
 379         [AC_MSG_ERROR([WRONG_LIBURCU_MSG])], [[#include <urcu/wfcqueue.h>]])
 380 AC_CHECK_DECL([cds_wfcq_dequeue_blocking], [],
 381         [AC_MSG_ERROR([WRONG_LIBURCU_MSG])], [[#include <urcu/wfcqueue.h>]])
 382 AC_CHECK_DECL([futex_async], [],
 383         [AC_MSG_ERROR([WRONG_LIBURCU_MSG])], [[#include <urcu/futex.h>]])
 384 AC_CHECK_DECL([rcu_thread_offline], [],
 385         [AC_MSG_ERROR([WRONG_LIBURCU_MSG])], [[#include <urcu.h>]])
 386 AC_CHECK_DECL([rcu_thread_online], [],
 387         [AC_MSG_ERROR([WRONG_LIBURCU_MSG])], [[#include <urcu.h>]])
 388 AC_CHECK_DECL([caa_likely], [],
 389         [AC_MSG_ERROR([WRONG_LIBURCU_MSG])], [[#include <urcu.h>]])
 390 AC_CHECK_LIB([urcu-cds], [_cds_lfht_new], [],
 391         [AC_MSG_ERROR([WRONG_LIBURCU_MSG])])
 392
 393 #Function added in urcu 0.7.0
 394 AC_CHECK_DECL([cmm_smp_mb__before_uatomic_or], [],
 395         [AC_MSG_ERROR([WRONG_LIBURCU_MSG])], [[#include <urcu.h>]]
 396 )
 397
 398 # Check kmod library
 399 AC_ARG_WITH(kmod-prefix,
 400   AS_HELP_STRING([--with-kmod-prefix=PATH],
 401                 [Specify the installation prefix of the kmod library.
 402                 Headers must be in PATH/include; libraries in PATH/lib.]),
 403                 [
 404                         CPPFLAGS="$CPPFLAGS -I${withval}/include"
 405                         LDFLAGS="$LDFLAGS -L${withval}/lib64 -L${withval}/lib"
 406                 ])
 407
 408 AC_ARG_ENABLE(kmod,
 409         AS_HELP_STRING([--disable-kmod],[build without kmod support]),
 410         kmod_support=$enableval, kmod_support=yes)
 411
 412 AS_IF([test "x$kmod_support" = "xyes"], [
 413         AC_CHECK_LIB([kmod], [kmod_module_probe_insert_module],
 414                 [
 415                         AC_DEFINE([HAVE_KMOD], [1], [has kmod support])
 416                         LIBS="$LIBS -lkmod"
 417                         kmod_found=yes
 418                 ],
 419                 kmod_found=no
 420         )
 421 ])
 422 AM_CONDITIONAL([HAVE_KMOD], [test "x$kmod_found" = xyes])
 423
 424 AC_ARG_WITH(lttng-ust-prefix,
 425   AS_HELP_STRING([--with-lttng-ust-prefix=PATH],
 426                  [Specify the installation prefix of the lttng-ust library.
 427                   Headers must be in PATH/include; libraries in PATH/lib.]),
 428                   [
 429                     CPPFLAGS="$CPPFLAGS -I${withval}/include"
 430                     LDFLAGS="$LDFLAGS -L${withval}/lib64 -L${withval}/lib"
 431                   ])
 432
 433 # Check liblttng-ust-ctl library
 434 AC_ARG_WITH(lttng-ust,
 435         AS_HELP_STRING([--without-lttng-ust],[build without LTTng-UST (Userspace Tracing) support]),
 436         lttng_ust_support=$withval, lttng_ust_support=yes)
 437
 438 AS_IF([test "x$lttng_ust_support" = "xyes"], [
 439         AC_CHECK_LIB([lttng-ust-ctl], [ustctl_recv_channel_from_consumer],
 440                 [
 441                         AC_DEFINE([HAVE_LIBLTTNG_UST_CTL], [1], [has LTTng-UST control support])
 442                         lttng_ust_ctl_found=yes
 443                 ],
 444                 [AC_MSG_ERROR([Cannot find LTTng-UST >= 2.2.x. Use --with-lttng-ust-prefix=PREFIX to specify its location, or specify --without-lttng-ust to build lttng-tools without LTTng-UST support.])],
 445                 [-lurcu-common -lurcu-bp -lurcu-cds -lrt -ldl]
 446         )
 447 ])
 448 AM_CONDITIONAL([HAVE_LIBLTTNG_UST_CTL], [test "x$lttng_ust_ctl_found" = xyes])
 449 AC_CHECK_FUNCS([sched_getcpu sysconf sync_file_range])
 450
 451 # check for dlopen
 452 AC_CHECK_LIB([dl], [dlopen],
 453 [
 454         have_libdl=yes
 455 ],
 456 [
 457         #libdl not found, check for dlopen in libc.
 458         AC_CHECK_LIB([c], [dlopen],
 459         [
 460                 have_libc_dl=yes
 461         ],
 462         [
 463                 AC_MSG_ERROR([Cannot find dlopen in libdl nor libc. Use [LDFLAGS]=-Ldir to specify their location.])
 464         ])
 465 ])
 466 AM_CONDITIONAL([LTTNG_TOOLS_BUILD_WITH_LIBDL], [test "x$have_libdl" = "xyes"])
 467 AM_CONDITIONAL([LTTNG_TOOLS_BUILD_WITH_LIBC_DL], [test "x$have_libc_dl" = "xyes"])
 468
 469 # Check for fmemopen
 470 AC_CHECK_LIB([c], [fmemopen],
 471 [
 472         AC_DEFINE_UNQUOTED([LTTNG_HAVE_FMEMOPEN], 1, [Has fmemopen support.])
 473 ]
 474 )
 475
 476 # Check for open_memstream
 477 AC_CHECK_LIB([c], [open_memstream],
 478 [
 479         AC_DEFINE_UNQUOTED([LTTNG_HAVE_OPEN_MEMSTREAM], 1, [Has open_memstream support.])
 480 ]
 481 )
 482
 483 AC_ARG_ENABLE([git-version],
 484               [AC_HELP_STRING([--disable-git-version],
 485                               [Do not use the git version for the build])],
 486               [have_git_version=$enableval], [have_git_version=yes]
 487 )
 488
 489 AM_CONDITIONAL([LTTNG_TOOLS_BUILD_GIT_SOURCE],
 490         [test "x${have_git_version}" = "xyes"])
 491
 492 # For Python
 493 # SWIG version needed or newer:
 494 swig_version=2.0.0
 495
 496 AC_ARG_ENABLE([python-bindings],
 497               [AC_HELP_STRING([--enable-python-bindings],
 498                               [compile Python bindings])],
 499               [enable_python_binding=$enableval], [enable_python_binding=no])
 500
 501 AM_CONDITIONAL([PYTHON_BINDING], [test "x$enable_python_binding" = xyes])
 502
 503 if test "x$enable_python_binding" = xyes; then
 504   AX_PKG_SWIG($swig_version, [], [ AC_MSG_ERROR([SWIG $swig_version or newer is needed]) ])
 505   AS_IF([test x$enable_shared = xno], [ AC_MSG_ERROR([Python bindings require shared libraries.]) ])
 506   AM_PATH_PYTHON([3.0])
 507
 508   AC_ARG_VAR([PYTHON_INCLUDE], [Include flags for python, bypassing python-config])
 509   AC_ARG_VAR([PYTHON_CONFIG], [Path to python-config])
 510   AS_IF([test -z "$PYTHON_INCLUDE"], [
 511     AS_IF([test -z "$PYTHON_CONFIG"], [
 512       AC_PATH_PROGS([PYTHON_CONFIG],
 513                     [python$PYTHON_VERSION-config python-config],
 514                     [no],
 515                     [`dirname $PYTHON`])
 516       AS_IF([test "$PYTHON_CONFIG" = no], [AC_MSG_ERROR([cannot find python-config for $PYTHON. Do you have python-dev installed?])])
 517     ])
 518     AC_MSG_CHECKING([python include flags])
 519     PYTHON_INCLUDE=`$PYTHON_CONFIG --includes`
 520     AC_MSG_RESULT([$PYTHON_INCLUDE])
 521   ])
 522
 523 else
 524     AC_MSG_NOTICE([You may configure with --enable-python-bindings ]dnl
 525 [if you want Python bindings.])
 526
 527 fi
 528
 529 # Epoll check. If not present, the build will fallback on poll() API
 530 AX_HAVE_EPOLL(
 531         [AX_CONFIG_FEATURE_ENABLE(epoll)],
 532         [AX_CONFIG_FEATURE_DISABLE(epoll)]
 533 )
 534 AX_CONFIG_FEATURE(
 535         [epoll], [This platform supports epoll(7)],
 536         [HAVE_EPOLL], [This platform supports epoll(7).],
 537         [enable_epoll="yes"], [enable_epoll="no"]
 538 )
 539 AM_CONDITIONAL([COMPAT_EPOLL], [ test "$enable_epoll" = "yes" ])
 540
 541 AM_CONDITIONAL([TEST_JAVA_JUL_AGENT], [test "x$test_java_agent_jul" = "xyes"])
 542 AM_CONDITIONAL([TEST_JAVA_LOG4J_AGENT], [test "x$test_java_agent_log4j" = "xyes"])
 543
 544 if test "x$test_java_agent_jul" = "xyes" || test "x$test_java_agent_log4j" = "xyes"; then
 545         AX_JAVA_OPTIONS
 546         AX_PROG_JAVAC
 547         AX_PROG_JAVA
 548         AX_PROG_JAR
 549
 550         AX_CHECK_CLASSPATH
 551
 552         # Check for Java UST agent common class first
 553         AX_CHECK_CLASS(org.lttng.ust.agent.AbstractLttngAgent)
 554         if test "x$ac_cv_class_org_lttng_ust_agent_AbstractLttngAgent" = "xno"; then
 555                 AC_MSG_ERROR([The UST Java agent common class was not found. Please specify the location of the jar via the Java CLASSPATH e.g: export CLASSPATH="/path/to/lttng-ust-agent-common.jar"])
 556         fi
 557
 558         if test "x$test_java_agent_jul" = "xyes"; then
 559                 # Check for JUL agent class
 560                 AX_CHECK_CLASS(org.lttng.ust.agent.jul.LttngLogHandler)
 561                 if test "x$ac_cv_class_org_lttng_ust_agent_jul_LttngLogHandler" = "xno"; then
 562                         AC_MSG_ERROR([The UST Java agent JUL class was not found. Please specify the location of the jar via the Java CLASSPATH e.g: export CLASSPATH="/path/to/lttng-ust-agent-jul.jar"])
 563                 fi
 564         fi
 565
 566         if test "x$test_java_agent_log4j" = "xyes"; then
 567                 # Check for Log4j agent class
 568                 AX_CHECK_CLASS(org.lttng.ust.agent.log4j.LttngLogAppender)
 569                 if test "x$ac_cv_class_org_lttng_ust_agent_log4j_LttngLogAppender" = "xno"; then
 570                         AC_MSG_ERROR([The UST Java agent Log4j class was not found. Please specify the location of the jar via the Java CLASSPATH e.g: export CLASSPATH="/path/to/lttng-ust-agent-log4j.jar"])
 571                 fi
 572
 573                 # Check for Log4j class
 574                 AX_CHECK_CLASS(org.apache.log4j.Logger)
 575                 if test "x$ac_cv_class_org_apache_log4j_Logger" = "xno"; then
 576                         AC_MSG_ERROR([The Log4j class was not found. Please specify the location of the jar via the Java CLASSPATH e.g: export CLASSPATH="/path/to/log4j.jar"])
 577                 fi
 578         fi
 579 fi
 580
 581 # set $IN_GIT_REPO if we're in the Git repository; the `bootstrap` file
 582 # is not distributed in tarballs
 583 AS_IF([test -f "$srcdir/bootstrap"], [in_git_repo=yes], [in_git_repo=no])
 584 AM_CONDITIONAL([IN_GIT_REPO], [test "x$in_git_repo" = "xyes"])
 585
 586 # enable building man pages (user's intention)
 587 AC_ARG_ENABLE(
 588         man-pages,
 589         AS_HELP_STRING(
 590                 [--disable-man-pages],
 591                 [Do not build and install man pages (already built in a distributed tarball)]
 592         ),
 593         [man_pages_opt=$enableval],
 594         [man_pages_opt=yes]
 595 )
 596
 597 # check for asciidoc and xmlto if we enabled building the man pages
 598 have_asciidoc_xmlto=no
 599
 600 AS_IF([test "x$man_pages_opt" = "xyes"], [
 601         AC_PATH_PROG([ASCIIDOC], [asciidoc], [no])
 602         AC_PATH_PROG([XMLTO], [xmlto], [no])
 603
 604         AS_IF([test "x$ASCIIDOC" = "xno" || test "x$XMLTO" = "xno"], [
 605                 AS_IF([test "x$in_git_repo" = "xyes"], [
 606                         # this is an error because we're in the Git repo, which
 607                         # means the man pages are not already generated for us,
 608                         # thus asciidoc/xmlto are required because we were asked
 609                         # to build the man pages
 610                         AC_MSG_ERROR([
 611 Both asciidoc and xmlto are needed to build the LTTng man pages. Use
 612 --disable-man-pages to disable building the man pages, in which case
 613 they will not be installed.
 614                         ])
 615                 ], [
 616                         # only warn here: since we're in the tarball, the man
 617                         # pages should already be generated at this point, thus
 618                         # asciidoc/xmlto are not strictly required
 619                         AC_MSG_WARN([
 620 Both asciidoc and xmlto are needed to build the LTTng man pages. Note
 621 that the man pages are already built in this distribution tarball, so
 622 asciidoc and xmlto are only needed if you intend to modify their
 623 sources. Use --disable-man-pages to completely disable building
 624 and installing the man pages.
 625                         ])
 626                 ])
 627         ], [
 628                 have_asciidoc_xmlto=yes
 629         ])
 630 ])
 631
 632 # export man page build condition: build the man pages if the user
 633 # asked for it, and if the tools are available
 634 AM_CONDITIONAL([MAN_PAGES_OPT], [test "x$man_pages_opt" != "xno"])
 635 AM_CONDITIONAL([HAVE_ASCIIDOC_XMLTO], [test "x$have_asciidoc_xmlto" = "xyes"])
 636
 637 AC_DEFINE_UNQUOTED([MANPATH], ["`eval eval echo $mandir`"], [Path to man pages.])
 638
 639 # Python agent test
 640 UST_PYTHON_AGENT="lttngust"
 641
 642 AC_ARG_ENABLE(test-python2-agent,
 643         AS_HELP_STRING([--enable-test-python2-agent],
 644                 [enable tests for python2 agent. Python2 interpreter path can be overridden by setting the PYTHON2 environment variable. Default: Autodetect]
 645         ),[:],[test_python2_agent_autodetect=yes]
 646 )
 647
 648 AC_ARG_ENABLE(test-python3-agent,
 649         AS_HELP_STRING([--enable-test-python3-agent],
 650                 [enable tests for python3 agent. Python3 interpreter path can be overridden by setting the PYTHON3 environment variable. Default: Autodetect]
 651         ),[:],[test_python3_agent_autodetect=yes]
 652 )
 653
 654 AC_ARG_ENABLE(test-python-agent-all,
 655         AS_HELP_STRING([--enable-test-python-agent-all],
 656                 [enable test for all python{2/3} agent.]
 657         ),
 658 )
 659
 660 AS_IF([test ! -z "$enable_test_python_agent_all"], [
 661        unset test_python2_agent_autodetect
 662        unset test_python3_agent_autodetect
 663 ])
 664
 665 AS_IF([test "x$enable_test_python_agent_all" = "xyes"], [
 666        enable_test_python2_agent=yes
 667        enable_test_python3_agent=yes
 668 ])
 669
 670 AS_IF([test "x$enable_test_python_agent_all" = "xno"], [
 671        enable_test_python2_agent=no
 672        enable_test_python3_agent=no
 673 ])
 674
 675
 676 AS_IF([test "x$enable_test_python2_agent" = "xyes" -o "x$test_python2_agent_autodetect" = "xyes" ], [
 677         AS_IF([test -z "$PYTHON2"], [
 678                         PYTHON2=python2
 679                 ], [
 680                         AC_MSG_WARN([Using user-defined PYTHON2 ($PYTHON2) for lttng-ust python2 agent check])
 681         ])
 682
 683         AC_PATH_PROG([PYTHON2_BIN],[$PYTHON2])
 684         AS_IF([test -z "$PYTHON2_BIN"], [
 685                 AS_IF([test -z "$test_python2_agent_autodetect"],[
 686                         AC_MSG_ERROR([No python2 interpreter found. PYTHON2 can be set to override default interpreter path])
 687                 ])
 688         ], [
 689                 AC_MSG_CHECKING([for python2 lttng-ust agent])
 690                 AS_IF([$PYTHON2_BIN -c "import $UST_PYTHON_AGENT" 2>/dev/null], [
 691                         PYTHON2_AGENT=$PYTHON2_BIN
 692                         AC_MSG_RESULT([yes])
 693                         RUN_PYTHON_AGENT_TEST=yes
 694                 ], [
 695                         AC_MSG_RESULT([no])
 696                         AS_IF([test -z "$test_python2_agent_autodetect"],[
 697                                 AC_MSG_ERROR([No python2 agent found. The path to the agent can be specified by setting the PYTHONPATH environment variable.])
 698                         ])
 699                 ])
 700
 701         ])
 702
 703 ])
 704
 705 AS_IF([test "x$enable_test_python3_agent" = "xyes" -o "x$test_python3_agent_autodetect" = "xyes" ], [
 706         AS_IF([test -z "$PYTHON3"], [
 707                 PYTHON3=python3
 708         ], [
 709                 AC_MSG_WARN([Using user-defined PYTHON3 ($PYTHON3) for lttng-ust python3 agent check])
 710         ])
 711
 712         AC_PATH_PROG([PYTHON3_BIN],[$PYTHON3])
 713         AS_IF([test -z "$PYTHON3_BIN"], [
 714                 AS_IF([test -z "$test_python3_agent_autodetect"],[
 715                         AC_MSG_ERROR([No python3 interpreter found. PYTHON3 can be set to override default interpreter path])
 716                 ])
 717         ], [
 718                 AC_MSG_CHECKING([for python3 lttng-ust agent])
 719                 AS_IF([$PYTHON3_BIN -c "import $UST_PYTHON_AGENT" 2>/dev/null], [
 720                         PYTHON3_AGENT=$PYTHON3_BIN
 721                         AC_MSG_RESULT([yes])
 722                         RUN_PYTHON_AGENT_TEST=yes
 723                 ], [
 724                         AC_MSG_RESULT([no])
 725                         AS_IF([test -z "$test_python3_agent_autodetect"],[
 726                                 AC_MSG_ERROR([No python3 agent found. The path to the agent can be specified by setting the PYTHONPATH environment variable.])
 727                         ])
 728                 ])
 729
 730         ])
 731 ])
 732 AC_SUBST([RUN_PYTHON_AGENT_TEST])
 733 AC_SUBST([PYTHON2_AGENT])
 734 AC_SUBST([PYTHON3_AGENT])
 735
 736 # Arguments for binaries build exclusion
 737 AC_ARG_ENABLE([bin-lttng], AS_HELP_STRING([--disable-bin-lttng],[Disable the build of lttng binaries]))
 738 AC_ARG_ENABLE([bin-lttng-consumerd], AS_HELP_STRING([--disable-bin-lttng-consumerd],
 739               [Disable the build of lttng-consumerd binaries]))
 740 AC_ARG_ENABLE([bin-lttng-crash], AS_HELP_STRING([--disable-bin-lttng-crash],[Disable the build of lttng-crash binaries]))
 741 AC_ARG_ENABLE([bin-lttng-relayd], AS_HELP_STRING([--disable-bin-lttng-relayd],
 742               [Disable the build of lttng-relayd binaries]))
 743 AC_ARG_ENABLE([bin-lttng-sessiond], AS_HELP_STRING([--disable-bin-lttng-sessiond],
 744               [Disable the build of lttng-sessiond binaries]))
 745 AC_ARG_ENABLE([extras], AS_HELP_STRING([--disable-extras],
 746               [Disable the build of the extra components]))
 747
 748
 749 # Always build libconfig since it a dependency of libcommon
 750 build_lib_config=yes
 751
 752 build_lib_compat=no
 753 build_lib_consumer=no
 754 build_lib_hashtable=no
 755 build_lib_health=no
 756 build_lib_index=no
 757 build_lib_kernel_consumer=no
 758 build_lib_kernel_ctl=no
 759 build_lib_lttng_ctl=no
 760 build_lib_relayd=no
 761 build_lib_sessiond_comm=no
 762 build_lib_testpoint=no
 763 build_lib_ust_consumer=no
 764
 765 # There is an overlap for enabled dependencies, but this makes everything
 766 # simpler. libcommon and libconfig are always compiled so they are not repeated
 767 # here.
 768
 769 # Enable binary dependencies.
 770 AS_IF([test x$enable_bin_lttng != xno],
 771       [
 772        build_lib_lttng_ctl=yes
 773       ]
 774 )
 775
 776 AS_IF([test x$enable_bin_lttng_consumerd != xno],
 777       [
 778        build_lib_consumer=yes
 779        build_lib_sessiond_comm=yes
 780        build_lib_index=yes
 781        build_lib_health=yes
 782        build_lib_testpoint=yes
 783       ]
 784 )
 785
 786 AS_IF([test x$enable_bin_lttng_crash != xno],
 787       # Do nothing since libconfig and libcommon are built by default.
 788       []
 789 )
 790
 791 AS_IF([test x$enable_bin_lttng_relayd != xno],
 792       [
 793        build_lib_lttng_ctl=yes
 794        build_lib_sessiond_comm=yes
 795        build_lib_hashtable=yes
 796        build_lib_compat=yes
 797        build_lib_index=yes
 798        build_lib_health=yes
 799        build_lib_testpoint=yes
 800       ]
 801 )
 802 AS_IF([test x$enable_bin_lttng_sessiond != xno],
 803       [
 804        build_lib_lttng_ctl=yes
 805        build_lib_sessiond_comm=yes
 806        build_lib_kernel_ctl=yes
 807        build_lib_hashtable=yes
 808        build_lib_compat=yes
 809        build_lib_relayd=yes
 810        build_lib_testpoint=yes
 811        build_lib_health=yes
 812        build_lib_health=yes
 813       ]
 814 )
 815
 816 # Libraries dependencies enabling
 817 AS_IF([test x$build_lib_lttng_ctl = xyes],
 818       [
 819        build_lib_sessiond_comm=yes
 820        build_lib_hashtable=yes
 821       ]
 822 )
 823
 824 AS_IF([test x$build_lib_consumer = xyes],
 825       [
 826        build_lib_sessiond_comm=yes
 827        build_lib_kernel_consumer=yes
 828        build_lib_hashtable=yes
 829        build_lib_compat=yes
 830        build_lib_relayd=yes
 831        AS_IF([test x$lttng_ust_ctl_found = xyes],[build_lib_ust_consumer=yes])
 832       ]
 833 )
 834
 835 AS_IF([test x$build_lib_kernel_consumer = xyes],
 836       [
 837        build_lib_kernel_ctl=yes
 838        build_lib_relayd=yes
 839       ]
 840 )
 841
 842 AS_IF([test x$build_lib_relayd = xyes],
 843       [
 844        build_lib_sessiond_comm=yes
 845       ]
 846 )
 847
 848
 849 # Export binaries build conditions.
 850 AM_CONDITIONAL([BUILD_BIN_LTTNG], [test x$enable_bin_lttng != xno])
 851 AM_CONDITIONAL([BUILD_BIN_LTTNG_CONSUMERD], [test x$enable_bin_lttng_consumerd != xno])
 852 AM_CONDITIONAL([BUILD_BIN_LTTNG_CRASH], [test x$enable_bin_lttng_crash != xno])
 853 AM_CONDITIONAL([BUILD_BIN_LTTNG_RELAYD], [test x$enable_bin_lttng_relayd != xno])
 854 AM_CONDITIONAL([BUILD_BIN_LTTNG_SESSIOND], [test x$enable_bin_lttng_sessiond != xno])
 855
 856 # Export the tests and extras build conditions.
 857 AS_IF([\
 858 test "x$enable_bin_lttng" != "xno" && \
 859 test "x$enable_bin_lttng_consumerd" != "xno" && \
 860 test "x$enable_bin_lttng_crash" != "xno" && \
 861 test "x$enable_bin_lttng_relayd" != "xno" && \
 862 test "x$enable_bin_lttng_sessiond" != "xno"],
 863 [build_tests=yes],
 864 [build_tests=no]
 865 )
 866
 867 AM_CONDITIONAL([BUILD_TESTS], [test x$build_tests = xyes])
 868 AM_CONDITIONAL([BUILD_EXTRAS], [test x$enable_extras != xno])
 869
 870 # Export libraries build conditions.
 871 AM_CONDITIONAL([BUILD_LIB_COMPAT], [test x$build_lib_compat = xyes])
 872 AM_CONDITIONAL([BUILD_LIB_CONFIG], [test x$build_lib_config = xyes])
 873 AM_CONDITIONAL([BUILD_LIB_CONSUMER], [test x$build_lib_consumer = xyes])
 874 AM_CONDITIONAL([BUILD_LIB_HASHTABLE], [test x$build_lib_hashtable = xyes])
 875 AM_CONDITIONAL([BUILD_LIB_HEALTH], [test x$build_lib_health = xyes])
 876 AM_CONDITIONAL([BUILD_LIB_INDEX], [test x$build_lib_index = xyes])
 877 AM_CONDITIONAL([BUILD_LIB_KERNEL_CONSUMER], [test x$build_lib_kernel_consumer = xyes])
 878 AM_CONDITIONAL([BUILD_LIB_KERNEL_CTL], [test x$build_lib_kernel_ctl = xyes])
 879 AM_CONDITIONAL([BUILD_LIB_LTTNG_CTL], [test x$build_lib_lttng_ctl = xyes])
 880 AM_CONDITIONAL([BUILD_LIB_RELAYD], [test x$build_lib_relayd = xyes])
 881 AM_CONDITIONAL([BUILD_LIB_SESSIOND_COMM], [test x$build_lib_sessiond_comm = xyes])
 882 AM_CONDITIONAL([BUILD_LIB_TESTPOINT], [test x$build_lib_testpoint = xyes])
 883 AM_CONDITIONAL([BUILD_LIB_UST_CONSUMER], [test x$build_lib_ust_consumer = xyes])
 884
 885 # check for pgrep
 886 AC_PATH_PROG([PGREP], [pgrep], [no])
 887 AM_CONDITIONAL([HAS_PGREP], [test "x$PGREP" != "xno"])
 888
 889 # check for bison
 890 have_bison=yes
 891
 892 AS_IF([test "x$(basename "$YACC")" != "xbison -y"], [have_bison=no])
 893 AC_PATH_PROG([BISON], [bison])
 894 AX_PROG_BISON_VERSION([2.4], [], [have_bison=no])
 895
 896 AS_IF([test "x$have_bison" = "xno"], [
 897         AS_IF([test "x$in_git_repo" = "xyes"], [
 898                 AC_MSG_ERROR([Bison >= 2.4 is required when building from the Git repository.])
 899         ], [
 900                 AC_MSG_WARN([
 901 Missing Bison >= 2.4. Note that the parser files are already built in
 902 this distribution tarball, so Bison is only needed if you intend to
 903 modify their sources.
 904                 ])
 905         ])
 906 ])
 907
 908 # export bison condition
 909 AM_CONDITIONAL([HAVE_BISON], [test "x$have_bison" = "xyes"])
 910
 911 # check for flex
 912 have_flex=yes
 913
 914 AS_IF([test "x$LEX" != "xflex"], [have_flex=no])
 915 AC_PATH_PROG([FLEX], [flex])
 916 AX_PROG_FLEX_VERSION([2.5.35], [], [have_flex=no])
 917
 918 AS_IF([test "x$have_flex" = "xno"], [
 919         AS_IF([test "x$in_git_repo" = "xyes"], [
 920                 AC_MSG_ERROR([Flex >= 2.5.35 is required when building from the Git repository.])
 921         ], [
 922                 AC_MSG_WARN([
 923 Missing Flex >= 2.5.35. Note that the lexer files are already built in
 924 this distribution tarball, so Flex is only needed if you intend to
 925 modify their sources.
 926                 ])
 927         ])
 928 ])
 929
 930 # export flex condition
 931 AM_CONDITIONAL([HAVE_FLEX], [test "x$have_flex" = "xyes"])
 932
 933 CFLAGS="-Wall $CFLAGS -g -fno-strict-aliasing"
 934
 935 DEFAULT_INCLUDES="-I\$(top_srcdir) -I\$(top_builddir) -I\$(top_builddir)/src -I\$(top_builddir)/include -include config.h"
 936
 937 lttngincludedir="${includedir}/lttng"
 938
 939 AC_SUBST(lttngincludedir)
 940 AC_SUBST(DEFAULT_INCLUDES)
 941
 942 lttnglibexecdir="${libdir}/lttng/libexec"
 943 AC_SUBST(lttnglibexecdir)
 944
 945 AC_CONFIG_FILES([
 946         Makefile
 947         doc/Makefile
 948         doc/man/Makefile
 949         doc/man/asciidoc-attrs.conf
 950         include/Makefile
 951         extras/Makefile
 952         extras/bindings/Makefile
 953         extras/bindings/swig/Makefile
 954         extras/bindings/swig/python/Makefile
 955         extras/core-handler/Makefile
 956         src/Makefile
 957         src/common/Makefile
 958         src/common/kernel-ctl/Makefile
 959         src/common/kernel-consumer/Makefile
 960         src/common/consumer/Makefile
 961         src/common/ust-consumer/Makefile
 962         src/common/hashtable/Makefile
 963         src/common/sessiond-comm/Makefile
 964         src/common/compat/Makefile
 965         src/common/relayd/Makefile
 966         src/common/testpoint/Makefile
 967         src/common/index/Makefile
 968         src/common/health/Makefile
 969         src/common/config/Makefile
 970         src/lib/Makefile
 971         src/lib/lttng-ctl/Makefile
 972         src/lib/lttng-ctl/filter/Makefile
 973         src/lib/lttng-ctl/lttng-ctl.pc
 974         src/bin/Makefile
 975         src/bin/lttng-consumerd/Makefile
 976         src/bin/lttng-sessiond/Makefile
 977         src/bin/lttng-relayd/Makefile
 978         src/bin/lttng/Makefile
 979         src/bin/lttng-crash/Makefile
 980         tests/Makefile
 981         tests/destructive/Makefile
 982         tests/regression/Makefile
 983         tests/regression/kernel/Makefile
 984         tests/regression/tools/Makefile
 985         tests/regression/tools/streaming/Makefile
 986         tests/regression/tools/filtering/Makefile
 987         tests/regression/tools/health/Makefile
 988         tests/regression/tools/tracefile-limits/Makefile
 989         tests/regression/tools/snapshots/Makefile
 990         tests/regression/tools/live/Makefile
 991         tests/regression/tools/exclusion/Makefile
 992         tests/regression/tools/save-load/Makefile
 993         tests/regression/tools/mi/Makefile
 994         tests/regression/tools/wildcard/Makefile
 995         tests/regression/tools/crash/Makefile
 996         tests/regression/tools/regen-metadata/Makefile
 997         tests/regression/tools/regen-statedump/Makefile
 998         tests/regression/ust/Makefile
 999         tests/regression/ust/nprocesses/Makefile
1000         tests/regression/ust/high-throughput/Makefile
1001         tests/regression/ust/low-throughput/Makefile
1002         tests/regression/ust/before-after/Makefile
1003         tests/regression/ust/buffers-pid/Makefile
1004         tests/regression/ust/periodical-metadata-flush/Makefile
1005         tests/regression/ust/multi-session/Makefile
1006         tests/regression/ust/overlap/Makefile
1007         tests/regression/ust/overlap/demo/Makefile
1008         tests/regression/ust/linking/Makefile
1009         tests/regression/ust/daemon/Makefile
1010         tests/regression/ust/exit-fast/Makefile
1011         tests/regression/ust/fork/Makefile
1012         tests/regression/ust/libc-wrapper/Makefile
1013         tests/regression/ust/baddr-statedump/Makefile
1014         tests/regression/ust/ust-dl/Makefile
1015         tests/regression/ust/java-jul/Makefile
1016         tests/regression/ust/java-log4j/Makefile
1017         tests/regression/ust/python-logging/Makefile
1018         tests/regression/ust/getcpu-override/Makefile
1019         tests/regression/ust/clock-override/Makefile
1020         tests/regression/ust/type-declarations/Makefile
1021         tests/regression/ust/rotation-destroy-flush/Makefile
1022         tests/stress/Makefile
1023         tests/unit/Makefile
1024         tests/unit/ini_config/Makefile
1025         tests/utils/Makefile
1026         tests/utils/tap/Makefile
1027         tests/utils/testapp/Makefile
1028         tests/utils/testapp/gen-ust-events/Makefile
1029         tests/utils/testapp/gen-ust-nevents/Makefile
1030         tests/utils/testapp/gen-ust-tracef/Makefile
1031 ])
1032
1033 # Inject variable into python test script.
1034 AC_CONFIG_FILES([tests/regression/ust/python-logging/test_python_logging],[chmod +x tests/regression/ust/python-logging/test_python_logging])
1035
1036 AC_OUTPUT
1037
1038 #
1039 # Mini-report on what will be built.
1040 #
1041
1042 PPRINT_INIT
1043 PPRINT_SET_INDENT(1)
1044 PPRINT_SET_TS(38)
1045
1046 AS_ECHO
1047 AS_ECHO("${PPRINT_COLOR_BLDBLU}LTTng-tools $PACKAGE_VERSION \"$version_name\"$PPRINT_COLOR_RST")
1048 AS_ECHO
1049
1050 AS_IF([test -n "$report_fold"], [
1051         AS_ECHO("`AS_ECHO("$version_description") | $report_fold -s`")
1052 ], [
1053         AS_ECHO("$version_description")
1054 ])
1055
1056 AS_ECHO
1057 PPRINT_SUBTITLE([Features])
1058
1059 # Target architecture we're building for.
1060 target_arch=$host_cpu
1061 [
1062 for f in $CFLAGS; do
1063         if test $f = "-m32"; then
1064                         target_arch="32-bit"
1065         elif test $f = "-m64"; then
1066                         target_arch="64-bit"
1067         fi
1068 done
1069 ]
1070 PPRINT_PROP_STRING([Target architecture], $target_arch)
1071
1072 # kmod enabled/disabled
1073 test "x$kmod_found" = "xyes" && value=1 || value=0
1074 PPRINT_PROP_BOOL([libkmod support], $value)
1075
1076 # LTTng-UST enabled/disabled
1077 test "x$lttng_ust_support" = "xyes" && value=1 || value=0
1078 PPRINT_PROP_BOOL([LTTng-UST support], $value)
1079
1080 AS_ECHO
1081 PPRINT_SUBTITLE([Binaries])
1082
1083 # List binaries to be built
1084 test x$enable_bin_lttng != xno && value=1 || value=0
1085 PPRINT_PROP_BOOL([lttng], $value)
1086
1087 test x$enable_bin_lttng_consumerd != xno && value=1 || value=0
1088 PPRINT_PROP_BOOL([lttng-consumerd], $value)
1089
1090 test x$enable_bin_lttng_crash != xno && value=1 || value=0
1091 PPRINT_PROP_BOOL([lttng-crash], $value)
1092
1093 test x$enable_bin_lttng_relayd != xno && value=1 || value=0
1094 PPRINT_PROP_BOOL([lttng-relayd], $value)
1095
1096 test x$enable_bin_lttng_sessiond != xno && value=1 || value=0
1097 PPRINT_PROP_BOOL([lttng-sessiond], $value)
1098
1099 # Extras
1100 test x$enable_extras != xno && value=1 || value=0
1101 AS_ECHO
1102 PPRINT_SET_INDENT(0)
1103 PPRINT_PROP_BOOL([Extras], $value, $PPRINT_COLOR_SUBTITLE)
1104 PPRINT_SET_INDENT(1)
1105
1106 AS_ECHO
1107 PPRINT_SUBTITLE([Tests])
1108
1109 # Print clear message that tests won't be built
1110 AS_IF([test "x$build_tests" = "xno"],[
1111         PPRINT_WARN([Tests won't be built since some binaries were disabled])
1112 ])
1113
1114 # LTTng UST Java agent JUL tests enabled/disabled
1115 test "x$test_java_agent_jul" = "xyes" && value=1 || value=0
1116 PPRINT_PROP_BOOL([LTTng-UST Java agent JUL tests], $value)
1117
1118 # LTTng UST Java agent Log4j tests enabled/disabled
1119 test "x$test_java_agent_log4j" = "xyes" && value=1 || value=0
1120 PPRINT_PROP_BOOL([LTTng-UST Java agent Log4j tests], $value)
1121
1122 test ! -z "$PYTHON2_AGENT" && value=1 || value=0
1123 PPRINT_PROP_BOOL([LTTng-UST Python2 agent tests], $value)
1124
1125 test ! -z "$PYTHON3_AGENT" && value=1 || value=0
1126 PPRINT_PROP_BOOL([LTTng-UST Python3 agent tests], $value)
1127
1128 #Python binding enabled/disabled
1129 test "x$enable_python_binding" = xyes && value=1 || value=0
1130 AS_ECHO
1131 PPRINT_SET_INDENT(0)
1132 PPRINT_PROP_BOOL([Python binding], $value, $PPRINT_COLOR_SUBTITLE)
1133
1134 # man pages build enabled/disabled
1135 m4_pushdef([build_man_pages_msg], [Build and install man pages])
1136
1137 AS_IF([test "x$man_pages_opt" != "xno"], [
1138         AS_IF([test "x$in_git_repo" = "xyes"], [
1139                 PPRINT_PROP_BOOL([build_man_pages_msg], 1, $PPRINT_COLOR_SUBTITLE)
1140         ], [
1141                 AS_IF([test "x$have_asciidoc_xmlto" = "xyes"], [
1142                         PPRINT_PROP_BOOL([build_man_pages_msg], 1, $PPRINT_COLOR_SUBTITLE)
1143                 ], [
1144                         PPRINT_PROP_STRING([build_man_pages_msg],
1145                                 [${PPRINT_COLOR_BLDGRN}yes (already built)],
1146                                 $PPRINT_COLOR_SUBTITLE)
1147                 ])
1148         ])
1149 ], [
1150         PPRINT_PROP_BOOL([build_man_pages_msg], 0, $PPRINT_COLOR_SUBTITLE)
1151 ])
1152
1153 m4_popdef([build_man_pages_msg])
1154
1155 PPRINT_SET_INDENT(1)
1156
1157 report_bindir="`eval eval echo $bindir`"
1158 report_libdir="`eval eval echo $libdir`"
1159
1160 # Print the bindir and libdir this `make install' will install into.
1161 AS_ECHO
1162 PPRINT_SUBTITLE([Install directories])
1163 PPRINT_PROP_STRING([Binaries], [$report_bindir])
1164 PPRINT_PROP_STRING([Libraries], [$report_libdir])
1165
1166 AS_ECHO
1167 PPRINT_SUBTITLE([Search directories])
1168
1169 # If we build the sessiond, print the paths it will use
1170 AS_IF([test "$SESSIOND_BIN" = ""],[
1171         path="$report_bindir/lttng-sessiond"
1172 ],[
1173         path="$SESSIOND_BIN"
1174 ])
1175 PPRINT_PROP_STRING([lttng-sessiond executable], [$path])
1176
1177 AS_IF([test "$CONSUMERD32_BIN" = ""],[
1178         path="`eval eval echo $lttnglibexecdir`/lttng-consumerd"
1179 ],[
1180         path="$CONSUMERD32_BIN"
1181 ])
1182 PPRINT_PROP_STRING([32-bit lttng-consumerd executable], [$path])
1183
1184 AS_IF([test "$CONSUMERD32_LIBDIR" = ""],[
1185         path="`eval eval echo $libdir`"
1186 ],[
1187         path="$CONSUMERD32_LIBDIR"
1188 ])
1189 PPRINT_PROP_STRING([32-bit consumer libraries], [$path])
1190
1191 AS_IF([test "$CONSUMERD64_BIN" = ""],[
1192         path="`eval eval echo $lttnglibexecdir`/lttng-consumerd"
1193 ],[
1194         path="$CONSUMERD64_BIN"
1195 ])
1196 PPRINT_PROP_STRING([64-bit lttng-consumerd executable], [$path])
1197
1198 AS_IF([test "$CONSUMERD64_LIBDIR" = ""],[
1199         path="`eval eval echo $libdir`"
1200 ],[
1201         path="$CONSUMERD64_LIBDIR"
1202 ])
1203 PPRINT_PROP_STRING([64-bit consumer libraries], [$path])