configure.ac

   1 AC_PREREQ([2.64])
   2 AC_INIT([lttng-tools],[2.11.0-pre],[jeremie.galarneau@efficios.com],[],[https://lttng.org])
   3
   4 AC_CONFIG_HEADERS([include/config.h])
   5 AC_CONFIG_AUX_DIR([config])
   6 AC_CONFIG_MACRO_DIR([m4])
   7
   8 AC_CANONICAL_TARGET
   9 AC_CANONICAL_HOST
  10
  11 AM_INIT_AUTOMAKE([foreign dist-bzip2 no-dist-gzip tar-pax nostdinc])
  12 AM_MAINTAINER_MODE([enable])
  13
  14 # Enable silent rules if available (Introduced in AM 1.11)
  15 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  16
  17 AC_REQUIRE_AUX_FILE([tap-driver.sh])
  18
  19 # Checks for C compiler
  20 AC_USE_SYSTEM_EXTENSIONS
  21 AC_SYS_LARGEFILE
  22 AC_PROG_CC
  23 AC_PROG_CC_STDC
  24
  25 # Checks for programs.
  26 AC_PROG_GREP
  27 AC_PROG_MAKE_SET
  28 AC_PROG_SED
  29 AC_PATH_PROG([report_fold], [fold])
  30 LT_INIT
  31
  32 # Check for objcopy, required by the base address statedump and dynamic linker tests
  33 AC_CHECK_TOOL([OBJCOPY], [objcopy], [no])
  34 AS_IF([test "x$OBJCOPY" = "xno"],
  35         [AC_MSG_WARN([Cannot find objcopy. The base address statedump and dynamic linker tests will be disabled. Install the binutils package to remediate this.])]
  36 )
  37 AM_CONDITIONAL([HAVE_OBJCOPY], [test "x$OBJCOPY" != xno])
  38
  39 # check for pgrep
  40 AC_PATH_PROG([PGREP], [pgrep], [no])
  41 AM_CONDITIONAL([HAVE_PGREP], [test "x$PGREP" != "xno"])
  42
  43 # check for bison
  44 AC_PROG_YACC
  45 BISON=$YACC
  46 AX_PROG_BISON_VERSION([2.4], [have_bison=yes])
  47
  48 AS_IF([test "x$have_bison" != "xyes"], [
  49   AS_IF([test "x$in_git_repo" = "xyes"], [
  50     AC_MSG_FAILURE([
  51 Bison >= 2.4 is required when building from the Git repository. You can
  52 set the YACC variable to override automatic detection.
  53     ])
  54   ], [
  55     AC_MSG_WARN([
  56 Missing Bison >= 2.4. Note that the parser files are already built in
  57 this distribution tarball, so Bison is only needed if you intend to
  58 modify their sources. You can set the YACC variable to override automatic
  59 detection.
  60     ])
  61   ])
  62 ])
  63 AM_CONDITIONAL([HAVE_BISON], [test "x$have_bison" = "xyes"])
  64
  65 # check for flex
  66 AC_PROG_LEX
  67 FLEX=$LEX
  68 AX_PROG_FLEX_VERSION([2.5.35], [have_flex=yes])
  69
  70 AS_IF([test "x$have_flex" != "xyes"], [
  71   AS_IF([test "x$in_git_repo" = "xyes"], [
  72     AC_MSG_FAILURE([
  73 Flex >= 2.5.35 is required when building from the Git repository. You can
  74 set the LEX variable to override automatic detection.
  75     ])
  76   ], [
  77     AC_MSG_WARN([
  78 Missing Flex >= 2.5.35. Note that the lexer files are already built in
  79 this distribution tarball, so Flex is only needed if you intend to
  80 modify their sources. You can set the LEX variable to override automatic
  81 detection.
  82     ])
  83   ])
  84 ])
  85 AM_CONDITIONAL([HAVE_FLEX], [test "x$have_flex" = "xyes"])
  86
  87
  88 # Checks for typedefs, structures, and compiler characteristics.
  89 AC_C_INLINE
  90 AC_TYPE_INT32_T
  91 AC_TYPE_INT64_T
  92 AC_TYPE_MODE_T
  93 AC_TYPE_OFF_T
  94 AC_TYPE_PID_T
  95 AC_TYPE_SIZE_T
  96 AC_TYPE_SSIZE_T
  97 AC_TYPE_UID_T
  98 AC_TYPE_UINT16_T
  99 AC_TYPE_UINT32_T
 100 AC_TYPE_UINT64_T
 101 AC_TYPE_UINT8_T
 102
 103 AX_C___ATTRIBUTE__
 104 AS_IF([test "x$ax_cv___attribute__" = "xyes"],
 105         [:],
 106         [AC_MSG_ERROR([The compiler does not support __attribute__ extensions])])
 107
 108 AX_PTHREAD(,[AC_MSG_ERROR([Could not configure pthreads support])])
 109
 110 AX_LIB_SOCKET_NSL
 111
 112 LT_NO_UNDEFINED=""
 113 AS_CASE([$host_os],
 114   [cygwin*],
 115     [
 116       LT_NO_UNDEFINED="-no-undefined"
 117     ],
 118   [cygwin*|darwin*|mingw*|solaris*],
 119     [
 120       # On platforms where we only support the relayd, disable the other binaries by default
 121       AS_IF([test "x$enable_bin_lttng" = "x" ], [enable_bin_lttng=no])
 122       AS_IF([test "x$enable_bin_lttng_consumerd" = "x" ], [enable_bin_lttng_consumerd=no])
 123       AS_IF([test "x$enable_bin_lttng_crash" = "x" ], [enable_bin_lttng_crash=no])
 124       AS_IF([test "x$enable_bin_lttng_sessiond" = "x" ], [enable_bin_lttng_sessiond=no])
 125       AS_IF([test "x$enable_extras" = "x" ], [enable_extras=no])
 126       AS_IF([test "x$with_lttng_ust" = "x" ], [with_lttng_ust=no])
 127     ]
 128 )
 129
 130 AC_SUBST(LT_NO_UNDEFINED)
 131
 132 # Compute minor/major/patchlevel version numbers
 133 major_version=$(echo AC_PACKAGE_VERSION | $SED 's/^\([[0-9]]\)*\.[[0-9]]*\.[[0-9]]*.*$/\1/')
 134 minor_version=$(echo AC_PACKAGE_VERSION | $SED 's/^[[0-9]]*\.\([[0-9]]*\)\.[[0-9]]*.*$/\1/')
 135 patchlevel_version=$(echo AC_PACKAGE_VERSION | $SED 's/^[[0-9]]*\.[[0-9]]*\.\([[0-9]]*\).*$/\1/')
 136
 137 AC_SUBST([MAJOR_VERSION], [$major_version])
 138 AC_SUBST([MINOR_VERSION], [$minor_version])
 139 AC_SUBST([PATCHLEVEL_VERSION], [$patchlevel_version])
 140 AC_DEFINE_UNQUOTED([VERSION_MAJOR], $major_version, [LTTng-Tools major version number])
 141 AC_DEFINE_UNQUOTED([VERSION_MINOR], $minor_version, [LTTng-Tools minor version number])
 142 AC_DEFINE_UNQUOTED([VERSION_PATCHLEVEL], $patchlevel_version, [LTTng-Tools patchlevel version number])
 143
 144 version_name="Codename TBD"
 145 version_description='Description TBD'
 146 version_description_c=$(echo $version_description | $SED 's/"/\\"/g')
 147
 148 AC_DEFINE_UNQUOTED([VERSION_NAME], ["$version_name"], "")
 149 AC_DEFINE_UNQUOTED([VERSION_DESCRIPTION], ["$version_description_c"], "")
 150
 151 # libtool link_all_deplibs fixup. See http://bugs.lttng.org/issues/321.
 152 AC_ARG_ENABLE(libtool-linkdep-fixup,
 153         AS_HELP_STRING([--disable-libtool-linkdep-fixup],
 154                         [disable the libtool fixup for linking all dependent libraries (link_all_deplibs)]),
 155         libtool_fixup=$enableval,
 156         libtool_fixup=yes)
 157
 158 AS_IF([test "x$libtool_fixup" = "xyes"],
 159             [
 160             libtool_m4="$srcdir/m4/libtool.m4"
 161             libtool_flag_pattern=".*link_all_deplibs\s*,\s*\$1\s*)"
 162             AC_MSG_CHECKING([for occurence(s) of link_all_deplibs = no in $libtool_m4])
 163             libtool_flag_pattern_count=$($GREP -c "$libtool_flag_pattern\s*=\s*no" $libtool_m4)
 164             AS_IF([test $libtool_flag_pattern_count -ne 0],
 165             [
 166                   AC_MSG_RESULT([$libtool_flag_pattern_count])
 167                   AC_MSG_WARN([the detected libtool will not link all dependencies, forcing link_all_deplibs = unknown])
 168                   $SED -i "s/\($libtool_flag_pattern\)\s*=\s*no/\1=unknown/g" $libtool_m4
 169                   ],
 170                   [
 171                   AC_MSG_RESULT([none])
 172                   ])
 173             ])
 174
 175 AM_CONDITIONAL([NO_SHARED], [test x$enable_shared = xno])
 176
 177 AC_CHECK_HEADERS([ \
 178         sys/types.h unistd.h fcntl.h string.h pthread.h limits.h \
 179         signal.h stdlib.h sys/un.h sys/socket.h stdlib.h stdio.h \
 180         getopt.h sys/ipc.h sys/shm.h popt.h grp.h arpa/inet.h \
 181         netdb.h netinet/in.h paths.h stddef.h sys/file.h sys/ioctl.h \
 182         sys/mount.h sys/param.h sys/time.h
 183 ])
 184
 185 # Basic functions check
 186 AC_CHECK_FUNCS([ \
 187         atexit bzero clock_gettime dup2 fdatasync fls ftruncate \
 188         gethostbyname gethostname getpagesize localtime_r memchr memset \
 189         mkdir munmap putenv realpath rmdir socket strchr strcspn strdup \
 190         strncasecmp strndup strnlen strpbrk strrchr strstr strtol strtoul \
 191         strtoull dirfd gethostbyname2 getipnodebyname epoll_create1 \
 192         sched_getcpu sysconf sync_file_range
 193 ])
 194
 195 # Check if clock_gettime, timer_create, timer_settime, and timer_delete are available in lib rt, and if so,
 196 # add -lrt to LIBS
 197 AC_CHECK_LIB([rt], [clock_gettime, timer_create, timer_settime, timer_delete])
 198
 199 # Checks for dl.
 200 AC_CHECK_LIB([dl], [dlopen], [
 201         have_libdl=yes
 202         libdl_name=dl
 203 ], [
 204         # libdl not found, check for dlopen in libc.
 205         AC_CHECK_LIB([c], [dlopen], [
 206                 have_libc_dl=yes
 207                 libdl_name=c
 208         ], [
 209                 AC_MSG_ERROR([Cannot find dlopen in libdl nor libc. Use [LDFLAGS]=-Ldir to specify their location.])
 210         ])
 211 ])
 212
 213 # Check if libdl has dlmopen support.
 214 AH_TEMPLATE([HAVE_DLMOPEN], ["Define to 1 if dlmopen is available."])
 215 AC_CHECK_LIB([$libdl_name], [dlmopen], [
 216         AC_DEFINE([HAVE_DLMOPEN], [1])
 217         HAVE_DLMOPEN=1
 218 ], [
 219         HAVE_DLMOPEN=0
 220 ])
 221 AC_SUBST(HAVE_DLMOPEN)
 222
 223 # Babeltrace viewer check
 224 AC_ARG_WITH([babeltrace-bin],
 225         AS_HELP_STRING([--with-babeltrace-bin],
 226         [Location of the babeltrace viewer executable (including the filename)]),
 227         [BABELTRACE_BIN="$withval"],
 228         [BABELTRACE_BIN=''])
 229 AC_SUBST([BABELTRACE_BIN])
 230
 231 # lttv-gui
 232 AC_ARG_WITH([lttv-gui-bin],
 233         AS_HELP_STRING([--with-lttv-gui-bin],
 234    [Location of the lttv GUI viewer executable (including the filename)]),
 235    [LTTV_GUI_BIN="$withval"],
 236    [LTTV_GUI_BIN=''])
 237 AC_SUBST([LTTV_GUI_BIN])
 238
 239 AC_ARG_WITH([consumerd32-bin],
 240         AS_HELP_STRING([--with-consumerd32-bin],
 241         [Location of the 32-bit consumerd executable (including the filename)]),
 242         [CONSUMERD32_BIN="$withval"],
 243         [CONSUMERD32_BIN=''])
 244 AC_SUBST([CONSUMERD32_BIN])
 245
 246 AC_ARG_WITH([consumerd64-bin],
 247         AS_HELP_STRING([--with-consumerd64-bin],
 248         [Location of the 64-bit consumerd executable (including the filename)]),
 249         [CONSUMERD64_BIN="$withval"],
 250         [CONSUMERD64_BIN=''])
 251 AC_SUBST([CONSUMERD64_BIN])
 252
 253 AC_ARG_WITH([consumerd32-libdir],
 254         AS_HELP_STRING([--with-consumerd32-libdir],
 255         [Directory containing the 32-bit consumerd libraries]),
 256         [CONSUMERD32_LIBDIR="$withval"],
 257         [CONSUMERD32_LIBDIR=''])
 258 AC_SUBST([CONSUMERD32_LIBDIR])
 259
 260 AC_ARG_WITH([consumerd64-libdir],
 261         AS_HELP_STRING([--with-consumerd64-libdir],
 262         [Directory containing the 64-bit consumerd libraries]),
 263         [CONSUMERD64_LIBDIR="$withval"],
 264         [CONSUMERD64_LIBDIR=''])
 265 AC_SUBST([CONSUMERD64_LIBDIR])
 266
 267 AC_ARG_WITH([sessiond-bin],
 268         AS_HELP_STRING([--with-sessiond-bin],
 269         [Location of the sessiond executable (including the filename)]),
 270         [SESSIOND_BIN="$withval"],
 271         [SESSIOND_BIN=''])
 272 AC_SUBST([SESSIOND_BIN])
 273
 274 AC_ARG_WITH([lttng-system-rundir],
 275         AS_HELP_STRING([--with-lttng-system-rundir],
 276         [Location of the system directory where the system-wide lttng-sessiond runtime files are kept. The default is "/var/run/lttng".]),
 277         [LTTNG_SYSTEM_RUNDIR="$withval"],
 278         [LTTNG_SYSTEM_RUNDIR="/var/run/lttng"])
 279 AC_SUBST([LTTNG_SYSTEM_RUNDIR])
 280
 281 AC_ARG_ENABLE([test-java-agent-jul],
 282         [AS_HELP_STRING([--enable-test-java-agent-jul],[enable the LTTng UST Java agent JUL tests [default=no]])],
 283         [test_java_agent_jul=$enableval],
 284         [test_java_agent_jul=no]
 285 )
 286
 287 AC_ARG_ENABLE([test-java-agent-log4j],
 288         [AS_HELP_STRING([--enable-test-java-agent-log4j],[enable the LTTng UST Java agent Log4j tests [default=no]])],
 289         [test_java_agent_log4j=$enableval],
 290         [test_java_agent_log4j=no]
 291 )
 292
 293 AC_ARG_ENABLE([test-java-agent-all],
 294         [AS_HELP_STRING([--enable-test-java-agent-all],[enable all the LTTng UST Java agent tests [default=no]])],
 295         [test_java_agent_jul=$enableval
 296          test_java_agent_log4j=$enableval],
 297         [:]
 298 )
 299
 300 AC_DEFINE_UNQUOTED([CONFIG_CONSUMERD32_BIN], "$CONSUMERD32_BIN", [Location of the 32-bit consumerd executable.])
 301 AC_DEFINE_UNQUOTED([CONFIG_CONSUMERD64_BIN], "$CONSUMERD64_BIN", [Location of the 64-bit consumerd executable])
 302 AC_DEFINE_UNQUOTED([CONFIG_CONSUMERD32_LIBDIR], "$CONSUMERD32_LIBDIR", [Search for consumerd 32-bit libraries in this location.])
 303 AC_DEFINE_UNQUOTED([CONFIG_CONSUMERD64_LIBDIR], "$CONSUMERD64_LIBDIR", [Search for consumerd 64-bit libraries in this location.])
 304 AC_DEFINE_UNQUOTED([CONFIG_BABELTRACE_BIN], "$BABELTRACE_BIN", [Location of the babeltrace viewer executable.])
 305 AC_DEFINE_UNQUOTED([CONFIG_LTTV_GUI_BIN], "$LTTV_GUI_BIN", [Location of the lttv GUI viewer executable.])
 306 AC_DEFINE_UNQUOTED([CONFIG_SESSIOND_BIN], "$SESSIOND_BIN", [Location of the sessiond executable.])
 307 AC_DEFINE_UNQUOTED([CONFIG_LTTNG_SYSTEM_RUNDIR], ["$LTTNG_SYSTEM_RUNDIR"], [LTTng system runtime directory])
 308
 309 AC_DEFUN([_AC_DEFINE_AND_SUBST], [
 310         AC_DEFINE_UNQUOTED([CONFIG_$1], [$2], [$1])
 311         $1="$2"
 312         AC_SUBST([$1])
 313 ])
 314
 315 AC_DEFUN([_AC_DEFINE_QUOTED_AND_SUBST], [
 316         AC_DEFINE_UNQUOTED([CONFIG_$1], ["$2"], [$1])
 317         $1="$2"
 318         AC_SUBST([$1])
 319 ])
 320
 321 # Default values
 322 m4_define([_DEFAULT_CHANNEL_SUBBUF_SIZE], [16384])
 323 m4_define([_DEFAULT_CHANNEL_SUBBUF_NUM], [4])
 324 m4_define([_DEFAULT_CHANNEL_SWITCH_TIMER], [0])
 325 m4_define([_DEFAULT_CHANNEL_LIVE_TIMER], [0])
 326 m4_define([_DEFAULT_CHANNEL_READ_TIMER], [200000])
 327 m4_define([_DEFAULT_CHANNEL_MONITOR_TIMER], [1000000])
 328 m4_define([_DEFAULT_CHANNEL_BLOCKING_TIMEOUT], [0])
 329 _AC_DEFINE_AND_SUBST([DEFAULT_AGENT_TCP_PORT_RANGE_BEGIN], [5345])
 330 _AC_DEFINE_AND_SUBST([DEFAULT_AGENT_TCP_PORT_RANGE_END], [5354])
 331 _AC_DEFINE_AND_SUBST([DEFAULT_APP_SOCKET_RW_TIMEOUT], [5])
 332 _AC_DEFINE_AND_SUBST([DEFAULT_CHANNEL_SUBBUF_SIZE], [_DEFAULT_CHANNEL_SUBBUF_SIZE])
 333 _AC_DEFINE_AND_SUBST([DEFAULT_CHANNEL_TRACEFILE_COUNT], [0])
 334 _AC_DEFINE_AND_SUBST([DEFAULT_CHANNEL_TRACEFILE_SIZE], [0])
 335 _AC_DEFINE_AND_SUBST([DEFAULT_KERNEL_CHANNEL_LIVE_TIMER], [_DEFAULT_CHANNEL_LIVE_TIMER])
 336 _AC_DEFINE_AND_SUBST([DEFAULT_KERNEL_CHANNEL_READ_TIMER], [_DEFAULT_CHANNEL_READ_TIMER])
 337 _AC_DEFINE_AND_SUBST([DEFAULT_KERNEL_CHANNEL_SUBBUF_NUM], [_DEFAULT_CHANNEL_SUBBUF_NUM])
 338 _AC_DEFINE_AND_SUBST([DEFAULT_KERNEL_CHANNEL_SUBBUF_SIZE], [1048576])
 339 _AC_DEFINE_AND_SUBST([DEFAULT_KERNEL_CHANNEL_SWITCH_TIMER], [_DEFAULT_CHANNEL_SWITCH_TIMER])
 340 _AC_DEFINE_AND_SUBST([DEFAULT_KERNEL_CHANNEL_MONITOR_TIMER], [_DEFAULT_CHANNEL_MONITOR_TIMER])
 341 _AC_DEFINE_AND_SUBST([DEFAULT_KERNEL_CHANNEL_BLOCKING_TIMEOUT], [_DEFAULT_CHANNEL_BLOCKING_TIMEOUT])
 342 _AC_DEFINE_AND_SUBST([DEFAULT_LTTNG_LIVE_TIMER], [1000000])
 343 _AC_DEFINE_AND_SUBST([DEFAULT_METADATA_CACHE_SIZE], [4096])
 344 _AC_DEFINE_AND_SUBST([DEFAULT_METADATA_READ_TIMER], [0])
 345 _AC_DEFINE_AND_SUBST([DEFAULT_METADATA_SUBBUF_NUM], [2])
 346 _AC_DEFINE_AND_SUBST([DEFAULT_METADATA_SUBBUF_SIZE], [4096])
 347 _AC_DEFINE_AND_SUBST([DEFAULT_METADATA_SWITCH_TIMER], [_DEFAULT_CHANNEL_SWITCH_TIMER])
 348 _AC_DEFINE_AND_SUBST([DEFAULT_NETWORK_CONTROL_PORT], [5342])
 349 _AC_DEFINE_AND_SUBST([DEFAULT_NETWORK_DATA_PORT], [5343])
 350 _AC_DEFINE_AND_SUBST([DEFAULT_NETWORK_VIEWER_PORT], [5344])
 351 _AC_DEFINE_AND_SUBST([DEFAULT_UST_PID_CHANNEL_LIVE_TIMER], [_DEFAULT_CHANNEL_LIVE_TIMER])
 352 _AC_DEFINE_AND_SUBST([DEFAULT_UST_PID_CHANNEL_READ_TIMER], [0])
 353 _AC_DEFINE_AND_SUBST([DEFAULT_UST_PID_CHANNEL_BLOCKING_TIMEOUT], [0])
 354 _AC_DEFINE_AND_SUBST([DEFAULT_UST_PID_CHANNEL_SUBBUF_NUM], [_DEFAULT_CHANNEL_SUBBUF_NUM])
 355 _AC_DEFINE_AND_SUBST([DEFAULT_UST_PID_CHANNEL_SUBBUF_SIZE], [_DEFAULT_CHANNEL_SUBBUF_SIZE])
 356 _AC_DEFINE_AND_SUBST([DEFAULT_UST_PID_CHANNEL_SWITCH_TIMER], [_DEFAULT_CHANNEL_SWITCH_TIMER])
 357 _AC_DEFINE_AND_SUBST([DEFAULT_UST_PID_CHANNEL_MONITOR_TIMER], [_DEFAULT_CHANNEL_MONITOR_TIMER])
 358 _AC_DEFINE_AND_SUBST([DEFAULT_UST_UID_CHANNEL_LIVE_TIMER], [_DEFAULT_CHANNEL_LIVE_TIMER])
 359 _AC_DEFINE_AND_SUBST([DEFAULT_UST_UID_CHANNEL_READ_TIMER], [0])
 360 _AC_DEFINE_AND_SUBST([DEFAULT_UST_UID_CHANNEL_BLOCKING_TIMEOUT], [0])
 361 _AC_DEFINE_AND_SUBST([DEFAULT_UST_UID_CHANNEL_SUBBUF_NUM], [_DEFAULT_CHANNEL_SUBBUF_NUM])
 362 _AC_DEFINE_AND_SUBST([DEFAULT_UST_UID_CHANNEL_SUBBUF_SIZE], [524288])
 363 _AC_DEFINE_AND_SUBST([DEFAULT_UST_UID_CHANNEL_SWITCH_TIMER], [_DEFAULT_CHANNEL_SWITCH_TIMER])
 364 _AC_DEFINE_AND_SUBST([DEFAULT_UST_UID_CHANNEL_MONITOR_TIMER], [_DEFAULT_CHANNEL_MONITOR_TIMER])
 365 _AC_DEFINE_QUOTED_AND_SUBST([DEFAULT_AGENT_BIND_ADDRESS], [localhost])
 366 _AC_DEFINE_QUOTED_AND_SUBST([DEFAULT_NETWORK_CONTROL_BIND_ADDRESS], [0.0.0.0])
 367 _AC_DEFINE_QUOTED_AND_SUBST([DEFAULT_NETWORK_DATA_BIND_ADDRESS], [0.0.0.0])
 368 _AC_DEFINE_QUOTED_AND_SUBST([DEFAULT_NETWORK_VIEWER_BIND_ADDRESS], [localhost])
 369 _AC_DEFINE_AND_SUBST([DEFAULT_ROTATE_PENDING_RELAY_TIMER], [200000])
 370
 371 # Command short descriptions
 372 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_ADD_CONTEXT], [Add context fields to a channel])
 373 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_CREATE], [Create a tracing session])
 374 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_DESTROY], [Tear down tracing sessions])
 375 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_DISABLE_CHANNEL], [Disable tracing channels])
 376 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_DISABLE_EVENT], [Disable event rules])
 377 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_DISABLE_ROTATION], [Unset an automatic rotation schedule])
 378 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_ENABLE_CHANNEL], [Create or enable tracing channels])
 379 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_ENABLE_EVENT], [Create or enable event rules])
 380 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_ENABLE_ROTATION], [Set an automatic rotation schedule])
 381 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_HELP], [Display help information about a command])
 382 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_LIST], [List tracing sessions, domains, channels, and events])
 383 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_LOAD], [Load tracing session configurations])
 384 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_REGENERATE], [Manage an LTTng tracing session's data regeneration])
 385 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_ROTATE], [Archive a tracing session's current trace chunk])
 386 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_SAVE], [Save tracing session configurations])
 387 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_SET_SESSION], [Set current tracing session])
 388 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_SNAPSHOT], [Snapshot buffers of current tracing session])
 389 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_START], [Start tracing])
 390 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_STATUS], [Get the status of the current tracing session])
 391 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_STOP], [Stop tracing])
 392 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_TRACK], [Track specific system resources])
 393 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_UNTRACK], [Untrack specific system resources])
 394 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_VERSION], [Show version information])
 395 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_VIEW], [Start trace viewer])
 396
 397 if test "x$prefix" = "xNONE"; then
 398         prefix=$ac_default_prefix
 399 fi
 400 CONFDIR=`eval echo $sysconfdir`
 401 AC_SUBST(CONFDIR)
 402 AC_DEFINE_UNQUOTED([CONFIG_LTTNG_SYSTEM_CONFIGDIR],"$CONFDIR", [LTTng system configuration directory.])
 403
 404 AC_DEFINE_DIR([CONFIG_LTTNG_SYSTEM_DATADIR],[datadir], [LTTng system data directory.])
 405
 406 # Check libpopt
 407 PKG_CHECK_MODULES([POPT], [popt],
 408   [
 409     dnl PKG_CHECK_MODULES defines POPT_LIBS
 410   ],
 411   [
 412     AC_MSG_WARN([pkg-config was unable to find a valid .pc for libpopt. Set PKG_CONFIG_PATH to specify the pkgconfig configuration file location])
 413     AC_MSG_WARN([Finding libpopt without pkg-config.])
 414     AC_CHECK_LIB([popt],
 415       [poptGetContext],
 416       [POPT_LIBS="-lpopt"],
 417       [
 418         AC_MSG_FAILURE([Cannot find libpopt. Either set PKG_CONFIG_PATH to the configuration file location or use LDFLAGS=-Ldir to specify the library location])
 419       ]
 420     )
 421   ]
 422 )
 423 AC_SUBST(POPT_LIBS)
 424
 425 PKG_CHECK_MODULES([libxml2], [libxml-2.0 >= 2.7.6])
 426
 427 # First, check for uuid in system libs
 428 AH_TEMPLATE([LTTNG_HAVE_LIBUUID], [Define if you have libuuid support])
 429 AC_CHECK_FUNCS([uuid_generate],
 430   [
 431     AC_DEFINE([LTTNG_HAVE_LIBUUID], [1])
 432     UUID_LIBS=""
 433   ],
 434   [
 435     # Then, check if the pkg-config module is available, otherwise explicitly check
 436     # for libuuid, or uuid support in the C-library.
 437     PKG_CHECK_MODULES([UUID], [uuid],
 438       [
 439         AC_DEFINE([LTTNG_HAVE_LIBUUID], [1])
 440         dnl PKG_CHECK_MODULES defines UUID_LIBS
 441       ],
 442       [
 443         AC_MSG_WARN([pkg-config was unable to find a valid .pc for libuuid. Set PKG_CONFIG_PATH to specify the pkgconfig configuration file location])
 444         AC_MSG_WARN([Finding libuuid without pkg-config.])
 445         AC_CHECK_LIB([uuid], [uuid_generate],
 446           [
 447             AC_DEFINE([LTTNG_HAVE_LIBUUID], [1])
 448             UUID_LIBS="-luuid"
 449           ],
 450           [
 451             # libuuid not found, check for uuid_create in libc.
 452             AC_CHECK_LIB([c], [uuid_create],
 453               [
 454                 AC_DEFINE([LTTNG_HAVE_LIBUUID], [1])
 455                 UUID_LIBS="-lc"
 456               ],
 457               [
 458                 AC_MSG_FAILURE([Cannot find libuuid uuid_generate nor libc uuid_create. Either set PKG_CONFIG_PATH to the configuration file location or use LDFLAGS=-Ldir to specify the library location])
 459               ]
 460             )
 461           ]
 462         )
 463       ]
 464     )
 465   ]
 466 )
 467 AC_SUBST(UUID_LIBS)
 468
 469 AC_CHECK_FUNC([clock_gettime], [AC_DEFINE_UNQUOTED([LTTNG_HAVE_CLOCK_GETTIME], 1, [Has clock_gettime() support.])])
 470
 471 # URCU library version needed or newer
 472 m4_define([WRONG_LIBURCU_MSG], [Userspace RCU (liburcu) >= 0.9.0 is needed])
 473
 474 # Check liburcu needed function calls
 475 AC_CHECK_DECL([cds_list_add], [],
 476         [AC_MSG_ERROR([WRONG_LIBURCU_MSG])], [[#include <urcu/list.h>]])
 477 AC_CHECK_DECL([cds_wfcq_init], [],
 478         [AC_MSG_ERROR([WRONG_LIBURCU_MSG])], [[#include <urcu/wfcqueue.h>]])
 479 AC_CHECK_DECL([cds_wfcq_dequeue_blocking], [],
 480         [AC_MSG_ERROR([WRONG_LIBURCU_MSG])], [[#include <urcu/wfcqueue.h>]])
 481 AC_CHECK_DECL([futex_async], [],
 482         [AC_MSG_ERROR([WRONG_LIBURCU_MSG])], [[#include <urcu/futex.h>]])
 483 AC_CHECK_DECL([rcu_thread_offline], [],
 484         [AC_MSG_ERROR([WRONG_LIBURCU_MSG])], [[#include <urcu.h>]])
 485 AC_CHECK_DECL([rcu_thread_online], [],
 486         [AC_MSG_ERROR([WRONG_LIBURCU_MSG])], [[#include <urcu.h>]])
 487 AC_CHECK_DECL([caa_likely], [],
 488         [AC_MSG_ERROR([WRONG_LIBURCU_MSG])], [[#include <urcu.h>]])
 489 AC_CHECK_LIB([urcu-cds], [_cds_lfht_new], [],
 490         [AC_MSG_ERROR([WRONG_LIBURCU_MSG])])
 491
 492 #Function added in urcu 0.7.0
 493 AC_CHECK_DECL([cmm_smp_mb__before_uatomic_or], [],
 494         [AC_MSG_ERROR([WRONG_LIBURCU_MSG])], [[#include <urcu.h>]]
 495 )
 496
 497 #Function added in urcu 0.9.0
 498 AC_CHECK_DECL([urcu_ref_get_unless_zero], [],
 499         [AC_MSG_ERROR([WRONG_LIBURCU_MSG])], [[#include <urcu/ref.h>]]
 500 )
 501
 502 # Check for libkmod, it will be auto-neabled if found but won't fail if it's not,
 503 # it can be explicitly disabled with --without-kmod
 504 AH_TEMPLATE([HAVE_KMOD], [Define if you have kmod support])
 505 AC_ARG_WITH([kmod],
 506   [AS_HELP_STRING([--with-kmod], [build with lkmod support @<:@default=check@:>@])],
 507   [],
 508   [with_kmod=check]
 509 )
 510
 511 AS_IF([test "x$with_kmod" != "xno"],
 512   [
 513     AC_CHECK_LIB([kmod], [kmod_module_probe_insert_module],
 514       [
 515         AC_DEFINE([HAVE_KMOD], [1])
 516         KMOD_LIBS="-lkmod"
 517       ],
 518       [
 519         if test "x$with_kmod" != xcheck; then
 520           AC_MSG_FAILURE([Cannot find libkmod. Use [LDFLAGS]=-Ldir and [CPPFLAGS]=-Idir to specify its location.])
 521         else
 522           with_kmod=no
 523         fi
 524       ]
 525     )
 526   ]
 527 )
 528 AC_SUBST(KMOD_LIBS)
 529
 530 # Check for liblttng-ust-ctl, fail if it's not found,
 531 # it can be explicitly disabled with --without-lttng-ust
 532 AH_TEMPLATE([HAVE_LIBLTTNG_UST_CTL], [Define if you have LTTng-UST control support])
 533 AC_ARG_WITH([lttng-ust],
 534   [AS_HELP_STRING([--without-lttng-ust], [build without LTTng-UST (Userspace Tracing) support])],
 535   [],
 536   [with_lttng_ust=yes]
 537 )
 538
 539 AS_IF([test "x$with_lttng_ust" = "xyes"],
 540   [
 541     AC_CHECK_LIB([lttng-ust-ctl], [ustctl_recv_channel_from_consumer],
 542       [
 543         AC_DEFINE([HAVE_LIBLTTNG_UST_CTL], [1])
 544       ],
 545       [
 546         AC_MSG_FAILURE([Cannot find LTTng-UST >= 2.2.x. Use [LDFLAGS]=-Ldir and [CPPFLAGS]=-Idir to specify its location, or specify --without-lttng-ust to build lttng-tools without LTTng-UST support.])
 547       ],
 548       [-lurcu-common -lurcu-bp -lurcu-cds -lrt -ldl]
 549     )
 550   ]
 551 )
 552 AM_CONDITIONAL([HAVE_LIBLTTNG_UST_CTL], [test "x$with_lttng_ust" = "xyes"])
 553
 554
 555
 556 # check for dlopen
 557 AC_CHECK_LIB([dl], [dlopen],
 558   [DL_LIBS="-ldl"],
 559   [
 560     #libdl not found, check for dlopen in libc.
 561     AC_CHECK_LIB([c], [dlopen],
 562       [DL_LIBS="-lc"],
 563       [AC_MSG_FAILURE([Cannot find dlopen in libdl nor libc. Use [LDFLAGS]=-Ldir to specify their location.])]
 564     )
 565   ]
 566 )
 567 AC_SUBST(DL_LIBS)
 568
 569 # Check for fmemopen
 570 AC_CHECK_LIB([c], [fmemopen],
 571 [
 572         AC_DEFINE_UNQUOTED([LTTNG_HAVE_FMEMOPEN], 1, [Has fmemopen support.])
 573 ]
 574 )
 575
 576 # Check for open_memstream
 577 AC_CHECK_LIB([c], [open_memstream],
 578 [
 579         AC_DEFINE_UNQUOTED([LTTNG_HAVE_OPEN_MEMSTREAM], 1, [Has open_memstream support.])
 580 ]
 581 )
 582
 583 # check for libpfm
 584 AC_CHECK_LIB([pfm], [pfm_initialize],
 585              [
 586               have_libpfm=yes
 587               ])
 588 AM_CONDITIONAL([LTTNG_TOOLS_BUILD_WITH_LIBPFM], [test "x$have_libpfm" = "xyes"])
 589
 590 AC_ARG_ENABLE([git-version],
 591               [AC_HELP_STRING([--disable-git-version],
 592                               [Do not use the git version for the build])],
 593               [have_git_version=$enableval], [have_git_version=yes]
 594 )
 595
 596 AM_CONDITIONAL([LTTNG_TOOLS_BUILD_GIT_SOURCE],
 597         [test "x${have_git_version}" = "xyes"])
 598
 599 # For Python
 600 # SWIG version needed or newer:
 601 swig_version=2.0.0
 602
 603 AC_ARG_ENABLE([python-bindings],
 604               [AC_HELP_STRING([--enable-python-bindings],
 605                               [compile Python bindings])],
 606               [enable_python_binding=$enableval], [enable_python_binding=no])
 607
 608 AM_CONDITIONAL([PYTHON_BINDING], [test "x$enable_python_binding" = xyes])
 609
 610 if test "x$enable_python_binding" = xyes; then
 611   AX_PKG_SWIG($swig_version, [], [ AC_MSG_ERROR([SWIG $swig_version or newer is needed]) ])
 612   AS_IF([test x$enable_shared = xno], [ AC_MSG_ERROR([Python bindings require shared libraries.]) ])
 613   AM_PATH_PYTHON([3.0])
 614
 615   AC_ARG_VAR([PYTHON_INCLUDE], [Include flags for python, bypassing python-config])
 616   AC_ARG_VAR([PYTHON_CONFIG], [Path to python-config])
 617   AS_IF([test -z "$PYTHON_INCLUDE"], [
 618     AS_IF([test -z "$PYTHON_CONFIG"], [
 619       AC_PATH_PROGS([PYTHON_CONFIG],
 620                     [python$PYTHON_VERSION-config python-config],
 621                     [no],
 622                     [`dirname $PYTHON`])
 623       AS_IF([test "$PYTHON_CONFIG" = no], [AC_MSG_ERROR([cannot find python-config for $PYTHON. Do you have python-dev installed?])])
 624     ])
 625     AC_MSG_CHECKING([python include flags])
 626     PYTHON_INCLUDE=`$PYTHON_CONFIG --includes`
 627     AC_MSG_RESULT([$PYTHON_INCLUDE])
 628   ])
 629
 630 else
 631     AC_MSG_NOTICE([You may configure with --enable-python-bindings ]dnl
 632 [if you want Python bindings.])
 633
 634 fi
 635
 636 # Epoll check. If not present, the build will fallback on poll() API
 637 AX_HAVE_EPOLL(
 638         [AX_CONFIG_FEATURE_ENABLE(epoll)],
 639         [AX_CONFIG_FEATURE_DISABLE(epoll)]
 640 )
 641 AX_CONFIG_FEATURE(
 642         [epoll], [This platform supports epoll(7)],
 643         [HAVE_EPOLL], [This platform supports epoll(7).],
 644         [enable_epoll="yes"], [enable_epoll="no"]
 645 )
 646 AM_CONDITIONAL([COMPAT_EPOLL], [ test "$enable_epoll" = "yes" ])
 647
 648 AM_CONDITIONAL([TEST_JAVA_JUL_AGENT], [test "x$test_java_agent_jul" = "xyes"])
 649 AM_CONDITIONAL([TEST_JAVA_LOG4J_AGENT], [test "x$test_java_agent_log4j" = "xyes"])
 650
 651 if test "x$test_java_agent_jul" = "xyes" || test "x$test_java_agent_log4j" = "xyes"; then
 652         AX_JAVA_OPTIONS
 653         AX_PROG_JAVAC
 654         AX_PROG_JAVA
 655         AX_PROG_JAR
 656
 657         AX_CHECK_CLASSPATH
 658
 659         # Check for Java UST agent common class first
 660         AX_CHECK_CLASS(org.lttng.ust.agent.AbstractLttngAgent)
 661         if test "x$ac_cv_class_org_lttng_ust_agent_AbstractLttngAgent" = "xno"; then
 662                 AC_MSG_ERROR([The UST Java agent common class was not found. Please specify the location of the jar via the Java CLASSPATH e.g: export CLASSPATH="/path/to/lttng-ust-agent-common.jar"])
 663         fi
 664
 665         if test "x$test_java_agent_jul" = "xyes"; then
 666                 # Check for JUL agent class
 667                 AX_CHECK_CLASS(org.lttng.ust.agent.jul.LttngLogHandler)
 668                 if test "x$ac_cv_class_org_lttng_ust_agent_jul_LttngLogHandler" = "xno"; then
 669                         AC_MSG_ERROR([The UST Java agent JUL class was not found. Please specify the location of the jar via the Java CLASSPATH e.g: export CLASSPATH="/path/to/lttng-ust-agent-jul.jar"])
 670                 fi
 671         fi
 672
 673         if test "x$test_java_agent_log4j" = "xyes"; then
 674                 # Check for Log4j agent class
 675                 AX_CHECK_CLASS(org.lttng.ust.agent.log4j.LttngLogAppender)
 676                 if test "x$ac_cv_class_org_lttng_ust_agent_log4j_LttngLogAppender" = "xno"; then
 677                         AC_MSG_ERROR([The UST Java agent Log4j class was not found. Please specify the location of the jar via the Java CLASSPATH e.g: export CLASSPATH="/path/to/lttng-ust-agent-log4j.jar"])
 678                 fi
 679
 680                 # Check for Log4j class
 681                 AX_CHECK_CLASS(org.apache.log4j.Logger)
 682                 if test "x$ac_cv_class_org_apache_log4j_Logger" = "xno"; then
 683                         AC_MSG_ERROR([The Log4j class was not found. Please specify the location of the jar via the Java CLASSPATH e.g: export CLASSPATH="/path/to/log4j.jar"])
 684                 fi
 685         fi
 686 fi
 687
 688 # set $IN_GIT_REPO if we're in the Git repository; the `bootstrap` file
 689 # is not distributed in tarballs
 690 AS_IF([test -f "$srcdir/bootstrap"], [in_git_repo=yes], [in_git_repo=no])
 691 AM_CONDITIONAL([IN_GIT_REPO], [test "x$in_git_repo" = "xyes"])
 692
 693 # enable building man pages (user's intention)
 694 AC_ARG_ENABLE(
 695         man-pages,
 696         AS_HELP_STRING(
 697                 [--disable-man-pages],
 698                 [Do not build and install man pages (already built in a distributed tarball)]
 699         ),
 700         [man_pages_opt=$enableval],
 701         [man_pages_opt=yes]
 702 )
 703
 704 # check for asciidoc and xmlto if we enabled building the man pages
 705 have_asciidoc_xmlto=no
 706 warn_prebuilt_man_pages=no
 707
 708 AS_IF([test "x$man_pages_opt" = "xyes"], [
 709         AC_PATH_PROG([ASCIIDOC], [asciidoc], [no])
 710         AC_PATH_PROG([XMLTO], [xmlto], [no])
 711
 712         AS_IF([test "x$ASCIIDOC" = "xno" || test "x$XMLTO" = "xno"], [
 713                 AS_IF([test "x$in_git_repo" = "xyes"], [
 714                         # this is an error because we're in the Git repo, which
 715                         # means the man pages are not already generated for us,
 716                         # thus asciidoc/xmlto are required because we were asked
 717                         # to build the man pages
 718                         AC_MSG_ERROR([
 719 You need asciidoc and xmlto to build the LTTng-tools man pages. Use
 720 --disable-man-pages to disable building the man pages, in which case
 721 they will not be installed.
 722                         ])
 723                 ], [
 724                         # only warn here: since we're in the tarball, the man
 725                         # pages should already be generated at this point, thus
 726                         # asciidoc/xmlto are not strictly required
 727                         warn_prebuilt_man_pages=yes
 728                 ])
 729         ], [
 730                 have_asciidoc_xmlto=yes
 731         ])
 732 ])
 733
 734 # export man page build condition: build the man pages if the user
 735 # asked for it, and if the tools are available
 736 AM_CONDITIONAL([MAN_PAGES_OPT], [test "x$man_pages_opt" != "xno"])
 737 AM_CONDITIONAL([HAVE_ASCIIDOC_XMLTO], [test "x$have_asciidoc_xmlto" = "xyes"])
 738
 739 AC_DEFINE_UNQUOTED([MANPATH], ["`eval eval echo $mandir`"], [Path to man pages.])
 740
 741 # embedded --help message
 742 AC_ARG_ENABLE(
 743         [embedded-help],
 744         AS_HELP_STRING(
 745                 [--enable-embedded-help],
 746                 [Embed the --help messages in the executable files]
 747         ),
 748         [embedded_help=$enableval],
 749         [embedded_help=no]
 750 )
 751 AS_IF([test "x$embedded_help" = "xyes"], [
 752         AS_IF([test "x$man_pages_opt" = "xno"], [
 753                 AC_MSG_ERROR([You need the --enable-man-pages option with the --enable-embedded-help option.])
 754         ])
 755         AC_PATH_PROG([man_prog_path], [man], [no])
 756         AS_IF([test "x$man_prog_path" = "xno"], [
 757                 AC_MSG_ERROR([You need man with the --enable-embedded-help option.])
 758         ])
 759         AC_DEFINE_UNQUOTED([LTTNG_EMBED_HELP], 1, [Embed --help messages.])
 760         AC_SUBST([MANPROG], [$man_prog_path])
 761 ])
 762 AM_CONDITIONAL([EMBED_HELP], [test "x$embedded_help" != "xno"])
 763
 764 # Python agent test
 765 UST_PYTHON_AGENT="lttngust"
 766
 767 AC_ARG_ENABLE(test-python2-agent,
 768         AS_HELP_STRING([--enable-test-python2-agent],
 769                 [enable tests for python2 agent. Python2 interpreter path can be overridden by setting the PYTHON2 environment variable. Default: Autodetect]
 770         ),[:],[test_python2_agent_autodetect=yes]
 771 )
 772
 773 AC_ARG_ENABLE(test-python3-agent,
 774         AS_HELP_STRING([--enable-test-python3-agent],
 775                 [enable tests for python3 agent. Python3 interpreter path can be overridden by setting the PYTHON3 environment variable. Default: Autodetect]
 776         ),[:],[test_python3_agent_autodetect=yes]
 777 )
 778
 779 AC_ARG_ENABLE(test-python-agent-all,
 780         AS_HELP_STRING([--enable-test-python-agent-all],
 781                 [enable test for all python{2/3} agent.]
 782         ),
 783 )
 784
 785 AS_IF([test ! -z "$enable_test_python_agent_all"], [
 786        unset test_python2_agent_autodetect
 787        unset test_python3_agent_autodetect
 788 ])
 789
 790 AS_IF([test "x$enable_test_python_agent_all" = "xyes"], [
 791        enable_test_python2_agent=yes
 792        enable_test_python3_agent=yes
 793 ])
 794
 795 AS_IF([test "x$enable_test_python_agent_all" = "xno"], [
 796        enable_test_python2_agent=no
 797        enable_test_python3_agent=no
 798 ])
 799
 800
 801 AS_IF([test "x$enable_test_python2_agent" = "xyes" -o "x$test_python2_agent_autodetect" = "xyes" ], [
 802         AS_IF([test -z "$PYTHON2"], [
 803                         PYTHON2=python2
 804                 ], [
 805                         AC_MSG_WARN([Using user-defined PYTHON2 ($PYTHON2) for lttng-ust python2 agent check])
 806         ])
 807
 808         AC_PATH_PROG([PYTHON2_BIN],[$PYTHON2])
 809         AS_IF([test -z "$PYTHON2_BIN"], [
 810                 AS_IF([test -z "$test_python2_agent_autodetect"],[
 811                         AC_MSG_ERROR([No python2 interpreter found. PYTHON2 can be set to override default interpreter path])
 812                 ])
 813         ], [
 814                 AC_MSG_CHECKING([for python2 lttng-ust agent])
 815                 AS_IF([$PYTHON2_BIN -c "import $UST_PYTHON_AGENT" 2>/dev/null], [
 816                         PYTHON2_AGENT=$PYTHON2_BIN
 817                         AC_MSG_RESULT([yes])
 818                         RUN_PYTHON_AGENT_TEST=yes
 819                 ], [
 820                         AC_MSG_RESULT([no])
 821                         AS_IF([test -z "$test_python2_agent_autodetect"],[
 822                                 AC_MSG_ERROR([No python2 agent found. The path to the agent can be specified by setting the PYTHONPATH environment variable.])
 823                         ])
 824                 ])
 825
 826         ])
 827
 828 ])
 829
 830 AS_IF([test "x$enable_test_python3_agent" = "xyes" -o "x$test_python3_agent_autodetect" = "xyes" ], [
 831         AS_IF([test -z "$PYTHON3"], [
 832                 PYTHON3=python3
 833         ], [
 834                 AC_MSG_WARN([Using user-defined PYTHON3 ($PYTHON3) for lttng-ust python3 agent check])
 835         ])
 836
 837         AC_PATH_PROG([PYTHON3_BIN],[$PYTHON3])
 838         AS_IF([test -z "$PYTHON3_BIN"], [
 839                 AS_IF([test -z "$test_python3_agent_autodetect"],[
 840                         AC_MSG_ERROR([No python3 interpreter found. PYTHON3 can be set to override default interpreter path])
 841                 ])
 842         ], [
 843                 AC_MSG_CHECKING([for python3 lttng-ust agent])
 844                 AS_IF([$PYTHON3_BIN -c "import $UST_PYTHON_AGENT" 2>/dev/null], [
 845                         PYTHON3_AGENT=$PYTHON3_BIN
 846                         AC_MSG_RESULT([yes])
 847                         RUN_PYTHON_AGENT_TEST=yes
 848                 ], [
 849                         AC_MSG_RESULT([no])
 850                         AS_IF([test -z "$test_python3_agent_autodetect"],[
 851                                 AC_MSG_ERROR([No python3 agent found. The path to the agent can be specified by setting the PYTHONPATH environment variable.])
 852                         ])
 853                 ])
 854
 855         ])
 856 ])
 857 AC_SUBST([RUN_PYTHON_AGENT_TEST])
 858 AC_SUBST([PYTHON2_AGENT])
 859 AC_SUBST([PYTHON3_AGENT])
 860
 861 # Arguments for binaries build exclusion
 862 AC_ARG_ENABLE([bin-lttng], AS_HELP_STRING([--disable-bin-lttng],[Disable the build of lttng binaries]))
 863 AC_ARG_ENABLE([bin-lttng-consumerd], AS_HELP_STRING([--disable-bin-lttng-consumerd],
 864               [Disable the build of lttng-consumerd binaries]))
 865 AC_ARG_ENABLE([bin-lttng-crash], AS_HELP_STRING([--disable-bin-lttng-crash],[Disable the build of lttng-crash binaries]))
 866 AC_ARG_ENABLE([bin-lttng-relayd], AS_HELP_STRING([--disable-bin-lttng-relayd],
 867               [Disable the build of lttng-relayd binaries]))
 868 AC_ARG_ENABLE([bin-lttng-sessiond], AS_HELP_STRING([--disable-bin-lttng-sessiond],
 869               [Disable the build of lttng-sessiond binaries]))
 870 AC_ARG_ENABLE([extras], AS_HELP_STRING([--disable-extras],
 871               [Disable the build of the extra components]))
 872
 873
 874 # Always build libconfig since it a dependency of libcommon
 875 build_lib_config=yes
 876
 877 build_lib_compat=no
 878 build_lib_consumer=no
 879 build_lib_hashtable=no
 880 build_lib_health=no
 881 build_lib_index=no
 882 build_lib_kernel_consumer=no
 883 build_lib_kernel_ctl=no
 884 build_lib_lttng_ctl=no
 885 build_lib_relayd=no
 886 build_lib_sessiond_comm=no
 887 build_lib_testpoint=no
 888 build_lib_ust_consumer=no
 889
 890 # There is an overlap for enabled dependencies, but this makes everything
 891 # simpler. libcommon and libconfig are always compiled so they are not repeated
 892 # here.
 893
 894 # Enable binary dependencies.
 895 AS_IF([test x$enable_bin_lttng != xno],
 896       [
 897        build_lib_lttng_ctl=yes
 898       ]
 899 )
 900
 901 AS_IF([test x$enable_bin_lttng_consumerd != xno],
 902       [
 903        build_lib_consumer=yes
 904        build_lib_sessiond_comm=yes
 905        build_lib_index=yes
 906        build_lib_health=yes
 907        build_lib_testpoint=yes
 908       ]
 909 )
 910
 911 AS_IF([test x$enable_bin_lttng_crash != xno],
 912       # Do nothing since libconfig and libcommon are built by default.
 913       []
 914 )
 915
 916 AS_IF([test x$enable_bin_lttng_relayd != xno],
 917       [
 918        build_lib_lttng_ctl=yes
 919        build_lib_sessiond_comm=yes
 920        build_lib_hashtable=yes
 921        build_lib_compat=yes
 922        build_lib_index=yes
 923        build_lib_health=yes
 924        build_lib_testpoint=yes
 925       ]
 926 )
 927 AS_IF([test x$enable_bin_lttng_sessiond != xno],
 928       [
 929        build_lib_lttng_ctl=yes
 930        build_lib_sessiond_comm=yes
 931        build_lib_kernel_ctl=yes
 932        build_lib_hashtable=yes
 933        build_lib_compat=yes
 934        build_lib_relayd=yes
 935        build_lib_testpoint=yes
 936        build_lib_health=yes
 937        build_lib_health=yes
 938       ]
 939 )
 940
 941 # Libraries dependencies enabling
 942 AS_IF([test x$build_lib_lttng_ctl = xyes],
 943       [
 944        build_lib_sessiond_comm=yes
 945        build_lib_hashtable=yes
 946       ]
 947 )
 948
 949 AS_IF([test x$build_lib_consumer = xyes],
 950       [
 951        build_lib_sessiond_comm=yes
 952        build_lib_kernel_consumer=yes
 953        build_lib_hashtable=yes
 954        build_lib_compat=yes
 955        build_lib_relayd=yes
 956        AS_IF([test "x$with_lttng_ust" = "xyes"], [build_lib_ust_consumer=yes])
 957       ]
 958 )
 959
 960 AS_IF([test x$build_lib_kernel_consumer = xyes],
 961       [
 962        build_lib_kernel_ctl=yes
 963        build_lib_relayd=yes
 964       ]
 965 )
 966
 967 AS_IF([test x$build_lib_relayd = xyes],
 968       [
 969        build_lib_sessiond_comm=yes
 970       ]
 971 )
 972
 973
 974 # Export binaries build conditions.
 975 AM_CONDITIONAL([BUILD_BIN_LTTNG], [test x$enable_bin_lttng != xno])
 976 AM_CONDITIONAL([BUILD_BIN_LTTNG_CONSUMERD], [test x$enable_bin_lttng_consumerd != xno])
 977 AM_CONDITIONAL([BUILD_BIN_LTTNG_CRASH], [test x$enable_bin_lttng_crash != xno])
 978 AM_CONDITIONAL([BUILD_BIN_LTTNG_RELAYD], [test x$enable_bin_lttng_relayd != xno])
 979 AM_CONDITIONAL([BUILD_BIN_LTTNG_SESSIOND], [test x$enable_bin_lttng_sessiond != xno])
 980
 981 # Export the tests and extras build conditions.
 982 AS_IF([\
 983 test "x$enable_bin_lttng" != "xno" && \
 984 test "x$enable_bin_lttng_consumerd" != "xno" && \
 985 test "x$enable_bin_lttng_crash" != "xno" && \
 986 test "x$enable_bin_lttng_relayd" != "xno" && \
 987 test "x$enable_bin_lttng_sessiond" != "xno"],
 988 [build_tests=yes],
 989 [build_tests=no]
 990 )
 991
 992 AM_CONDITIONAL([BUILD_TESTS], [test x$build_tests = xyes])
 993 AM_CONDITIONAL([BUILD_EXTRAS], [test x$enable_extras != xno])
 994
 995 # Export libraries build conditions.
 996 AM_CONDITIONAL([BUILD_LIB_COMPAT], [test x$build_lib_compat = xyes])
 997 AM_CONDITIONAL([BUILD_LIB_CONFIG], [test x$build_lib_config = xyes])
 998 AM_CONDITIONAL([BUILD_LIB_CONSUMER], [test x$build_lib_consumer = xyes])
 999 AM_CONDITIONAL([BUILD_LIB_HASHTABLE], [test x$build_lib_hashtable = xyes])
1000 AM_CONDITIONAL([BUILD_LIB_HEALTH], [test x$build_lib_health = xyes])
1001 AM_CONDITIONAL([BUILD_LIB_INDEX], [test x$build_lib_index = xyes])
1002 AM_CONDITIONAL([BUILD_LIB_KERNEL_CONSUMER], [test x$build_lib_kernel_consumer = xyes])
1003 AM_CONDITIONAL([BUILD_LIB_KERNEL_CTL], [test x$build_lib_kernel_ctl = xyes])
1004 AM_CONDITIONAL([BUILD_LIB_LTTNG_CTL], [test x$build_lib_lttng_ctl = xyes])
1005 AM_CONDITIONAL([BUILD_LIB_RELAYD], [test x$build_lib_relayd = xyes])
1006 AM_CONDITIONAL([BUILD_LIB_SESSIOND_COMM], [test x$build_lib_sessiond_comm = xyes])
1007 AM_CONDITIONAL([BUILD_LIB_TESTPOINT], [test x$build_lib_testpoint = xyes])
1008 AM_CONDITIONAL([BUILD_LIB_UST_CONSUMER], [test x$build_lib_ust_consumer = xyes])
1009
1010 AM_CFLAGS="-Wall -fno-strict-aliasing $PTHREAD_CFLAGS"
1011 AC_SUBST(AM_CFLAGS)
1012
1013 AM_CPPFLAGS="-I\$(top_srcdir)/include -I\$(top_builddir)/include -I\$(top_srcdir)/src -include config.h $AM_CPPFLAGS"
1014 AC_SUBST(AM_CPPFLAGS)
1015
1016 lttngincludedir="${includedir}/lttng"
1017 AC_SUBST(lttngincludedir)
1018
1019 lttngactionincludedir="${includedir}/lttng/action"
1020 AC_SUBST(lttngactionincludedir)
1021
1022 lttngconditionincludedir="${includedir}/lttng/condition"
1023 AC_SUBST(lttngconditionincludedir)
1024
1025 lttngnotificationincludedir="${includedir}/lttng/notification"
1026 AC_SUBST(lttngnotificationincludedir)
1027
1028 lttngtriggerincludedir="${includedir}/lttng/trigger"
1029 AC_SUBST(lttngtriggerincludedir)
1030
1031 lttnglibexecdir="${libdir}/lttng/libexec"
1032 AC_SUBST(lttnglibexecdir)
1033
1034 AC_CONFIG_FILES([
1035         Makefile
1036         doc/Makefile
1037         doc/man/Makefile
1038         doc/man/asciidoc-attrs.conf
1039         include/Makefile
1040         extras/Makefile
1041         extras/bindings/Makefile
1042         extras/bindings/swig/Makefile
1043         extras/bindings/swig/python/Makefile
1044         extras/core-handler/Makefile
1045         src/Makefile
1046         src/common/Makefile
1047         src/common/kernel-ctl/Makefile
1048         src/common/kernel-consumer/Makefile
1049         src/common/consumer/Makefile
1050         src/common/ust-consumer/Makefile
1051         src/common/hashtable/Makefile
1052         src/common/sessiond-comm/Makefile
1053         src/common/compat/Makefile
1054         src/common/relayd/Makefile
1055         src/common/testpoint/Makefile
1056         src/common/index/Makefile
1057         src/common/health/Makefile
1058         src/common/config/Makefile
1059         src/common/string-utils/Makefile
1060         src/lib/Makefile
1061         src/lib/lttng-ctl/Makefile
1062         src/lib/lttng-ctl/filter/Makefile
1063         src/lib/lttng-ctl/lttng-ctl.pc
1064         src/bin/Makefile
1065         src/bin/lttng-consumerd/Makefile
1066         src/bin/lttng-sessiond/Makefile
1067         src/bin/lttng-relayd/Makefile
1068         src/bin/lttng/Makefile
1069         src/bin/lttng-crash/Makefile
1070         tests/Makefile
1071         tests/destructive/Makefile
1072         tests/regression/Makefile
1073         tests/regression/kernel/Makefile
1074         tests/regression/tools/Makefile
1075         tests/regression/tools/streaming/Makefile
1076         tests/regression/tools/filtering/Makefile
1077         tests/regression/tools/health/Makefile
1078         tests/regression/tools/tracefile-limits/Makefile
1079         tests/regression/tools/snapshots/Makefile
1080         tests/regression/tools/live/Makefile
1081         tests/regression/tools/exclusion/Makefile
1082         tests/regression/tools/save-load/Makefile
1083         tests/regression/tools/save-load/configuration/Makefile
1084         tests/regression/tools/mi/Makefile
1085         tests/regression/tools/wildcard/Makefile
1086         tests/regression/tools/crash/Makefile
1087         tests/regression/tools/regen-metadata/Makefile
1088         tests/regression/tools/regen-statedump/Makefile
1089         tests/regression/tools/notification/Makefile
1090         tests/regression/tools/rotation/Makefile
1091         tests/regression/ust/Makefile
1092         tests/regression/ust/nprocesses/Makefile
1093         tests/regression/ust/high-throughput/Makefile
1094         tests/regression/ust/low-throughput/Makefile
1095         tests/regression/ust/before-after/Makefile
1096         tests/regression/ust/buffers-pid/Makefile
1097         tests/regression/ust/periodical-metadata-flush/Makefile
1098         tests/regression/ust/multi-session/Makefile
1099         tests/regression/ust/overlap/Makefile
1100         tests/regression/ust/overlap/demo/Makefile
1101         tests/regression/ust/linking/Makefile
1102         tests/regression/ust/daemon/Makefile
1103         tests/regression/ust/exit-fast/Makefile
1104         tests/regression/ust/fork/Makefile
1105         tests/regression/ust/libc-wrapper/Makefile
1106         tests/regression/ust/baddr-statedump/Makefile
1107         tests/regression/ust/ust-dl/Makefile
1108         tests/regression/ust/java-jul/Makefile
1109         tests/regression/ust/java-log4j/Makefile
1110         tests/regression/ust/python-logging/Makefile
1111         tests/regression/ust/getcpu-override/Makefile
1112         tests/regression/ust/clock-override/Makefile
1113         tests/regression/ust/type-declarations/Makefile
1114         tests/regression/ust/rotation-destroy-flush/Makefile
1115         tests/regression/ust/blocking/Makefile
1116         tests/stress/Makefile
1117         tests/unit/Makefile
1118         tests/unit/ini_config/Makefile
1119         tests/perf/Makefile
1120         tests/utils/Makefile
1121         tests/utils/tap/Makefile
1122         tests/utils/testapp/Makefile
1123         tests/utils/testapp/gen-ust-events/Makefile
1124         tests/utils/testapp/gen-ust-nevents/Makefile
1125         tests/utils/testapp/gen-ust-nevents-str/Makefile
1126         tests/utils/testapp/gen-syscall-events/Makefile
1127         tests/utils/testapp/gen-ust-tracef/Makefile
1128 ])
1129
1130 # Inject variable into python test script.
1131 AC_CONFIG_FILES([tests/regression/ust/python-logging/test_python_logging],[chmod +x tests/regression/ust/python-logging/test_python_logging])
1132 # Inject LTTNG_TOOLS_BUILD_WITH_LIBPFM variable in test script.
1133 AC_CONFIG_FILES([tests/perf/test_perf_raw],[chmod +x tests/perf/test_perf_raw])
1134 AC_CONFIG_FILES([tests/regression/ust/ust-dl/test_ust-dl],[chmod +x tests/regression/ust/ust-dl/test_ust-dl])
1135
1136 AC_OUTPUT
1137
1138 #
1139 # Mini-report on what will be built.
1140 #
1141
1142 PPRINT_INIT
1143 PPRINT_SET_INDENT(1)
1144 PPRINT_SET_TS(38)
1145
1146 AS_ECHO
1147 AS_ECHO("${PPRINT_COLOR_BLDBLU}LTTng-tools $PACKAGE_VERSION \"$version_name\"$PPRINT_COLOR_RST")
1148 AS_ECHO
1149
1150 AS_IF([test -n "$report_fold"], [
1151         AS_ECHO("`AS_ECHO("$version_description") | $report_fold -s`")
1152 ], [
1153         AS_ECHO("$version_description")
1154 ])
1155
1156 AS_ECHO
1157 PPRINT_SUBTITLE([Features])
1158
1159 # Target architecture we're building for.
1160 target_arch=$host_cpu
1161 [
1162 for f in $CFLAGS; do
1163         if test $f = "-m32"; then
1164                         target_arch="32-bit"
1165         elif test $f = "-m64"; then
1166                         target_arch="64-bit"
1167         fi
1168 done
1169 ]
1170 PPRINT_PROP_STRING([Target architecture], $target_arch)
1171
1172 # kmod enabled/disabled
1173 test "x$with_kmod" != "xno" && value=1 || value=0
1174 PPRINT_PROP_BOOL([libkmod support], $value)
1175
1176 # LTTng-UST enabled/disabled
1177 test "x$with_lttng_ust" = "xyes" && value=1 || value=0
1178 PPRINT_PROP_BOOL([LTTng-UST support], $value)
1179
1180 AS_ECHO
1181 PPRINT_SUBTITLE([Binaries])
1182
1183 # List binaries to be built
1184 test x$enable_bin_lttng != xno && value=1 || value=0
1185 PPRINT_PROP_BOOL([lttng], $value)
1186
1187 test x$enable_bin_lttng_consumerd != xno && value=1 || value=0
1188 PPRINT_PROP_BOOL([lttng-consumerd], $value)
1189
1190 test x$enable_bin_lttng_crash != xno && value=1 || value=0
1191 PPRINT_PROP_BOOL([lttng-crash], $value)
1192
1193 test x$enable_bin_lttng_relayd != xno && value=1 || value=0
1194 PPRINT_PROP_BOOL([lttng-relayd], $value)
1195
1196 test x$enable_bin_lttng_sessiond != xno && value=1 || value=0
1197 PPRINT_PROP_BOOL([lttng-sessiond], $value)
1198
1199 # Extras
1200 test x$enable_extras != xno && value=1 || value=0
1201 AS_ECHO
1202 PPRINT_SET_INDENT(0)
1203 PPRINT_PROP_BOOL([Extras], $value, $PPRINT_COLOR_SUBTITLE)
1204 PPRINT_SET_INDENT(1)
1205
1206 AS_ECHO
1207 PPRINT_SUBTITLE([Tests])
1208
1209 # Print clear message that tests won't be built
1210 AS_IF([test "x$build_tests" = "xno"],[
1211         PPRINT_WARN([Tests won't be built since some binaries were disabled])
1212 ])
1213
1214 # LTTng UST Java agent JUL tests enabled/disabled
1215 test "x$test_java_agent_jul" = "xyes" && value=1 || value=0
1216 PPRINT_PROP_BOOL([LTTng-UST Java agent JUL tests], $value)
1217
1218 # LTTng UST Java agent Log4j tests enabled/disabled
1219 test "x$test_java_agent_log4j" = "xyes" && value=1 || value=0
1220 PPRINT_PROP_BOOL([LTTng-UST Java agent Log4j tests], $value)
1221
1222 test ! -z "$PYTHON2_AGENT" && value=1 || value=0
1223 PPRINT_PROP_BOOL([LTTng-UST Python2 agent tests], $value)
1224
1225 test ! -z "$PYTHON3_AGENT" && value=1 || value=0
1226 PPRINT_PROP_BOOL([LTTng-UST Python3 agent tests], $value)
1227
1228 #Python binding enabled/disabled
1229 test "x$enable_python_binding" = xyes && value=1 || value=0
1230 AS_ECHO
1231 PPRINT_SET_INDENT(0)
1232 PPRINT_PROP_BOOL([Python binding], $value, $PPRINT_COLOR_SUBTITLE)
1233
1234 # man pages build enabled/disabled
1235 m4_pushdef([build_man_pages_msg], [Build and install man pages])
1236
1237 AS_IF([test "x$man_pages_opt" != "xno"], [
1238         AS_IF([test "x$in_git_repo" = "xyes"], [
1239                 PPRINT_PROP_BOOL([build_man_pages_msg], 1, $PPRINT_COLOR_SUBTITLE)
1240         ], [
1241                 AS_IF([test "x$have_asciidoc_xmlto" = "xyes"], [
1242                         PPRINT_PROP_BOOL([build_man_pages_msg], 1, $PPRINT_COLOR_SUBTITLE)
1243                 ], [
1244                         PPRINT_PROP_STRING([build_man_pages_msg],
1245                                 [${PPRINT_COLOR_BLDGRN}yes (already built)],
1246                                 $PPRINT_COLOR_SUBTITLE)
1247                 ])
1248         ])
1249 ], [
1250         PPRINT_PROP_BOOL([build_man_pages_msg], 0, $PPRINT_COLOR_SUBTITLE)
1251 ])
1252
1253 m4_popdef([build_man_pages_msg])
1254
1255 test "x$embedded_help" = xyes && value=1 || value=0
1256 PPRINT_PROP_BOOL([Embed --help messages], $value, $PPRINT_COLOR_SUBTITLE)
1257
1258 PPRINT_SET_INDENT(1)
1259
1260 report_bindir="`eval eval echo $bindir`"
1261 report_libdir="`eval eval echo $libdir`"
1262
1263 # Print the bindir and libdir this `make install' will install into.
1264 AS_ECHO
1265 PPRINT_SUBTITLE([Install directories])
1266 PPRINT_PROP_STRING([Binaries], [$report_bindir])
1267 PPRINT_PROP_STRING([Libraries], [$report_libdir])
1268
1269 AS_ECHO
1270 PPRINT_SUBTITLE([Search directories])
1271
1272 # If we build the sessiond, print the paths it will use
1273 AS_IF([test "$SESSIOND_BIN" = ""],[
1274         path="$report_bindir/lttng-sessiond"
1275 ],[
1276         path="$SESSIOND_BIN"
1277 ])
1278 PPRINT_PROP_STRING([lttng-sessiond executable], [$path])
1279
1280 AS_IF([test "$CONSUMERD32_BIN" = ""],[
1281         path="`eval eval echo $lttnglibexecdir`/lttng-consumerd"
1282 ],[
1283         path="$CONSUMERD32_BIN"
1284 ])
1285 PPRINT_PROP_STRING([32-bit lttng-consumerd executable], [$path])
1286
1287 AS_IF([test "$CONSUMERD32_LIBDIR" = ""],[
1288         path="`eval eval echo $libdir`"
1289 ],[
1290         path="$CONSUMERD32_LIBDIR"
1291 ])
1292 PPRINT_PROP_STRING([32-bit consumer libraries], [$path])
1293
1294 AS_IF([test "$CONSUMERD64_BIN" = ""],[
1295         path="`eval eval echo $lttnglibexecdir`/lttng-consumerd"
1296 ],[
1297         path="$CONSUMERD64_BIN"
1298 ])
1299 PPRINT_PROP_STRING([64-bit lttng-consumerd executable], [$path])
1300
1301 AS_IF([test "$CONSUMERD64_LIBDIR" = ""],[
1302         path="`eval eval echo $libdir`"
1303 ],[
1304         path="$CONSUMERD64_LIBDIR"
1305 ])
1306 PPRINT_PROP_STRING([64-bit consumer libraries], [$path])
1307 PPRINT_SET_INDENT(0)
1308
1309 AS_IF([test "x$warn_prebuilt_man_pages" = "xyes" ], [
1310         AS_ECHO
1311         PPRINT_WARN([You need asciidoc and xmlto to build the LTTng-tools man pages.
1312
1313 Note that the man pages are already built in this distribution tarball,
1314 therefore asciidoc and xmlto are only needed if you intend to modify
1315 their sources.
1316
1317 Also note that the installed man pages will contain the project's
1318 default command-line option and environment variable values.
1319
1320 Use --disable-man-pages to completely disable building and installing
1321 the man pages.])
1322 ])