25168ce53d524dda6d5bfc675d40b5d9ab9a605c
[lttng-tools.git] / configure.ac
1 AC_PREREQ([2.64])
2 AC_INIT([lttng-tools],[2.9.0-pre],[jeremie.galarneau@efficios.com],[],[https://lttng.org])
3
4 AC_CONFIG_HEADERS([include/config.h])
5 AC_CONFIG_AUX_DIR([config])
6 AC_CONFIG_MACRO_DIR([m4])
7
8 AC_CANONICAL_TARGET
9 AC_CANONICAL_HOST
10
11 AM_INIT_AUTOMAKE([foreign dist-bzip2 no-dist-gzip tar-pax])
12 AM_MAINTAINER_MODE([enable])
13
14 # Enable silent rules if available (Introduced in AM 1.11)
15 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
16
17 AC_REQUIRE_AUX_FILE([tap-driver.sh])
18
19 # Checks for C compiler
20 AC_USE_SYSTEM_EXTENSIONS
21 AC_SYS_LARGEFILE
22 AC_PROG_CC
23 AC_PROG_CC_STDC
24
25 # Checks for programs.
26 AC_PROG_GREP
27 AC_PROG_LEX
28 AC_PROG_MAKE_SET
29 AC_PROG_SED
30 AC_PROG_YACC
31 AC_PATH_PROG(report_fold, fold)
32 LT_INIT
33
34 # Check for objcopy, required by the base address statedump and dynamic linker tests
35 AC_CHECK_TOOL([OBJCOPY], objcopy, no)
36 AS_IF([test "x$OBJCOPY" = xno],
37 [AC_MSG_WARN([Cannont find objcopy. The base address statedump and dynamic linker tests will be disabled. Install the binutils package to remediate this.])]
38 )
39 AM_CONDITIONAL([HAVE_OBJCOPY], [test "x$OBJCOPY" != xno])
40
41 # Checks for typedefs, structures, and compiler characteristics.
42 AC_C_INLINE
43 AC_TYPE_INT32_T
44 AC_TYPE_INT64_T
45 AC_TYPE_MODE_T
46 AC_TYPE_OFF_T
47 AC_TYPE_PID_T
48 AC_TYPE_SIZE_T
49 AC_TYPE_SSIZE_T
50 AC_TYPE_UID_T
51 AC_TYPE_UINT16_T
52 AC_TYPE_UINT32_T
53 AC_TYPE_UINT64_T
54 AC_TYPE_UINT8_T
55
56 AX_C___ATTRIBUTE__
57 AS_IF([test "x$ax_cv___attribute__" = "xyes"],
58 [:],
59 [AC_MSG_ERROR([The compiler does not support __attribute__ extensions])])
60
61 AX_PTHREAD(,[AC_MSG_ERROR([Could not configure pthreads support])])
62 LIBS="$PTHREAD_LIBS $LIBS"
63 CFLAGS="$CFLAGS $PTHREAD_CFLAGS"
64 CC="$PTHREAD_CC"
65
66 AX_LIB_SOCKET_NSL
67
68 # Compute minor/major/patchlevel version numbers
69 major_version=$(echo AC_PACKAGE_VERSION | $SED 's/^\([[0-9]]\)*\.[[0-9]]*\.[[0-9]]*.*$/\1/')
70 minor_version=$(echo AC_PACKAGE_VERSION | $SED 's/^[[0-9]]*\.\([[0-9]]*\)\.[[0-9]]*.*$/\1/')
71 patchlevel_version=$(echo AC_PACKAGE_VERSION | $SED 's/^[[0-9]]*\.[[0-9]]*\.\([[0-9]]*\).*$/\1/')
72
73 AC_SUBST([MAJOR_VERSION], [$major_version])
74 AC_SUBST([MINOR_VERSION], [$minor_version])
75 AC_SUBST([PATCHLEVEL_VERSION], [$patchlevel_version])
76 AC_DEFINE_UNQUOTED([VERSION_MAJOR], $major_version, [LTTng-Tools major version number])
77 AC_DEFINE_UNQUOTED([VERSION_MINOR], $minor_version, [LTTng-Tools minor version number])
78 AC_DEFINE_UNQUOTED([VERSION_PATCHLEVEL], $patchlevel_version, [LTTng-Tools patchlevel version number])
79
80 version_name="Codename TBD"
81 version_description='Description TBD'
82 version_description_c=$(echo $version_description | $SED 's/"/\\"/g')
83
84 AC_DEFINE_UNQUOTED([VERSION_NAME], ["$version_name"], "")
85 AC_DEFINE_UNQUOTED([VERSION_DESCRIPTION], ["$version_description_c"], "")
86
87 # libtool link_all_deplibs fixup. See http://bugs.lttng.org/issues/321.
88 AC_ARG_ENABLE(libtool-linkdep-fixup,
89 AS_HELP_STRING([--disable-libtool-linkdep-fixup],
90 [disable the libtool fixup for linking all dependent libraries (link_all_deplibs)]),
91 libtool_fixup=$enableval,
92 libtool_fixup=yes)
93
94 AS_IF([test "x$libtool_fixup" = "xyes"],
95 [
96 libtool_m4="$srcdir/m4/libtool.m4"
97 libtool_flag_pattern=".*link_all_deplibs\s*,\s*\$1\s*)"
98 AC_MSG_CHECKING([for occurence(s) of link_all_deplibs = no in $libtool_m4])
99 libtool_flag_pattern_count=$($GREP -c "$libtool_flag_pattern\s*=\s*no" $libtool_m4)
100 AS_IF([test $libtool_flag_pattern_count -ne 0],
101 [
102 AC_MSG_RESULT([$libtool_flag_pattern_count])
103 AC_MSG_WARN([the detected libtool will not link all dependencies, forcing link_all_deplibs = unknown])
104 $SED -i "s/\($libtool_flag_pattern\)\s*=\s*no/\1=unknown/g" $libtool_m4
105 ],
106 [
107 AC_MSG_RESULT([none])
108 ])
109 ])
110
111 AM_CONDITIONAL([NO_SHARED], [test x$enable_shared = xno])
112
113 AC_CHECK_HEADERS([ \
114 sys/types.h unistd.h fcntl.h string.h pthread.h limits.h \
115 signal.h stdlib.h sys/un.h sys/socket.h stdlib.h stdio.h \
116 getopt.h sys/ipc.h sys/shm.h popt.h grp.h arpa/inet.h \
117 netdb.h netinet/in.h paths.h stddef.h sys/file.h sys/ioctl.h \
118 sys/mount.h sys/param.h sys/time.h
119 ])
120
121 # Basic functions check
122 AC_CHECK_FUNCS([ \
123 atexit bzero clock_gettime dup2 fdatasync fls ftruncate \
124 gethostbyname gethostname getpagesize localtime_r memchr memset \
125 mkdir munmap putenv realpath rmdir socket strchr strcspn strdup \
126 strncasecmp strndup strnlen strpbrk strrchr strstr strtol strtoul \
127 strtoull dirfd gethostbyname2 getipnodebyname epoll_create1 \
128 ])
129
130 # Babeltrace viewer check
131 AC_ARG_WITH([babeltrace-bin],
132 AS_HELP_STRING([--with-babeltrace-bin],
133 [Location of the babeltrace viewer executable (including the filename)]),
134 [BABELTRACE_BIN="$withval"],
135 [BABELTRACE_BIN=''])
136 AC_SUBST([BABELTRACE_BIN])
137
138 # lttv-gui
139 AC_ARG_WITH([lttv-gui-bin],
140 AS_HELP_STRING([--with-lttv-gui-bin],
141 [Location of the lttv GUI viewer executable (including the filename)]),
142 [LTTV_GUI_BIN="$withval"],
143 [LTTV_GUI_BIN=''])
144 AC_SUBST([LTTV_GUI_BIN])
145
146 AC_ARG_WITH([consumerd32-bin],
147 AS_HELP_STRING([--with-consumerd32-bin],
148 [Location of the 32-bit consumerd executable (including the filename)]),
149 [CONSUMERD32_BIN="$withval"],
150 [CONSUMERD32_BIN=''])
151 AC_SUBST([CONSUMERD32_BIN])
152
153 AC_ARG_WITH([consumerd64-bin],
154 AS_HELP_STRING([--with-consumerd64-bin],
155 [Location of the 64-bit consumerd executable (including the filename)]),
156 [CONSUMERD64_BIN="$withval"],
157 [CONSUMERD64_BIN=''])
158 AC_SUBST([CONSUMERD64_BIN])
159
160 AC_ARG_WITH([consumerd32-libdir],
161 AS_HELP_STRING([--with-consumerd32-libdir],
162 [Directory containing the 32-bit consumerd libraries]),
163 [CONSUMERD32_LIBDIR="$withval"],
164 [CONSUMERD32_LIBDIR=''])
165 AC_SUBST([CONSUMERD32_LIBDIR])
166
167 AC_ARG_WITH([consumerd64-libdir],
168 AS_HELP_STRING([--with-consumerd64-libdir],
169 [Directory containing the 64-bit consumerd libraries]),
170 [CONSUMERD64_LIBDIR="$withval"],
171 [CONSUMERD64_LIBDIR=''])
172 AC_SUBST([CONSUMERD64_LIBDIR])
173
174 AC_ARG_WITH([sessiond-bin],
175 AS_HELP_STRING([--with-sessiond-bin],
176 [Location of the sessiond executable (including the filename)]),
177 [SESSIOND_BIN="$withval"],
178 [SESSIOND_BIN=''])
179 AC_SUBST([SESSIOND_BIN])
180
181 AC_ARG_WITH([lttng-system-rundir],
182 AS_HELP_STRING([--with-lttng-system-rundir],
183 [Location of the system directory where the system-wide lttng-sessiond runtime files are kept. The default is "/var/run/lttng".]),
184 [LTTNG_SYSTEM_RUNDIR="$withval"],
185 [LTTNG_SYSTEM_RUNDIR="/var/run/lttng"])
186 AC_SUBST([LTTNG_SYSTEM_RUNDIR])
187
188 AC_ARG_ENABLE([test-java-agent-jul],
189 [AS_HELP_STRING([--enable-test-java-agent-jul],[enable the LTTng UST Java agent JUL tests [default=no]])],
190 [test_java_agent_jul=$enableval],
191 [test_java_agent_jul=no]
192 )
193
194 AC_ARG_ENABLE([test-java-agent-log4j],
195 [AS_HELP_STRING([--enable-test-java-agent-log4j],[enable the LTTng UST Java agent Log4j tests [default=no]])],
196 [test_java_agent_log4j=$enableval],
197 [test_java_agent_log4j=no]
198 )
199
200 AC_ARG_ENABLE([test-java-agent-all],
201 [AS_HELP_STRING([--enable-test-java-agent-all],[enable all the LTTng UST Java agent tests [default=no]])],
202 [test_java_agent_jul=$enableval
203 test_java_agent_log4j=$enableval],
204 [:]
205 )
206
207 AC_DEFINE_UNQUOTED([CONFIG_CONSUMERD32_BIN], "$CONSUMERD32_BIN", [Location of the 32-bit consumerd executable.])
208 AC_DEFINE_UNQUOTED([CONFIG_CONSUMERD64_BIN], "$CONSUMERD64_BIN", [Location of the 64-bit consumerd executable])
209 AC_DEFINE_UNQUOTED([CONFIG_CONSUMERD32_LIBDIR], "$CONSUMERD32_LIBDIR", [Search for consumerd 32-bit libraries in this location.])
210 AC_DEFINE_UNQUOTED([CONFIG_CONSUMERD64_LIBDIR], "$CONSUMERD64_LIBDIR", [Search for consumerd 64-bit libraries in this location.])
211 AC_DEFINE_UNQUOTED([CONFIG_BABELTRACE_BIN], "$BABELTRACE_BIN", [Location of the babeltrace viewer executable.])
212 AC_DEFINE_UNQUOTED([CONFIG_LTTV_GUI_BIN], "$LTTV_GUI_BIN", [Location of the lttv GUI viewer executable.])
213 AC_DEFINE_UNQUOTED([CONFIG_SESSIOND_BIN], "$SESSIOND_BIN", [Location of the sessiond executable.])
214 AC_DEFINE_UNQUOTED([CONFIG_LTTNG_SYSTEM_RUNDIR], ["$LTTNG_SYSTEM_RUNDIR"], [LTTng system runtime directory])
215
216 if test "x$prefix" = "xNONE"; then
217 prefix=$ac_default_prefix
218 fi
219 CONFDIR=`eval echo $sysconfdir`
220 AC_SUBST(CONFDIR)
221 AC_DEFINE_UNQUOTED([CONFIG_LTTNG_SYSTEM_CONFIGDIR],"$CONFDIR", [LTTng system configuration directory.])
222
223 AC_DEFINE_DIR([CONFIG_LTTNG_SYSTEM_DATADIR],[datadir], [LTTng system data directory.])
224
225 #
226 # Check for pthread
227 AC_CHECK_LIB([pthread], [pthread_create], [],
228 [AC_MSG_ERROR([Cannot find libpthread. Use LDFLAGS=-Ldir to specify its location.])]
229 )
230
231 # Check libpopt
232 PKG_CHECK_MODULES([POPT], [popt],
233 [LIBS="$LIBS $POPT_LIBS"],
234 [
235 AC_MSG_WARN([pkg-config was unable to find a valid .pc for libpopt. Set PKG_CONFIG_PATH to specify the pkgconfig configuration file location])
236 AC_MSG_WARN([Finding libpopt without pkg-config.])
237 AC_CHECK_LIB([popt],
238 [poptGetContext],
239 [],
240 [
241 AC_MSG_ERROR([Cannot find libpopt. Either set PKG_CONFIG_PATH to the configuration file location or use LDFLAGS=-Ldir to specify the library location])
242 ]
243 )
244 ]
245 )
246
247 AM_PATH_XML2(2.7.6, true, AC_MSG_ERROR(No supported version of libxml2 found.))
248
249 # Check for libuuid
250 PKG_CHECK_MODULES([UUID], [uuid],
251 [
252 LIBS="$LIBS $UUID_LIBS"
253 AC_DEFINE_UNQUOTED([LTTNG_HAVE_LIBUUID], 1, [Has libuuid support.])
254 have_libuuid=yes
255 ],
256 [
257 AC_MSG_WARN([pkg-config was unable to find a valid .pc for libuuid. Set PKG_CONFIG_PATH to specify the pkgconfig configuration file location])
258 AC_MSG_WARN([Finding libuuid without pkg-config.])
259 AC_CHECK_LIB([uuid],
260 [uuid_generate],
261 [
262 AC_DEFINE_UNQUOTED([LTTNG_HAVE_LIBUUID], 1, [Has libuuid support.])
263 have_libuuid=yes
264 ],
265 [
266 # libuuid not found, check for uuid_create in libc.
267 AC_CHECK_LIB([c],
268 [uuid_create],
269 [
270 AC_DEFINE_UNQUOTED([LTTNG_HAVE_LIBC_UUID], 1, [Has libc uuid support.])
271 have_libc_uuid=yes
272 ],
273 [
274 AC_MSG_ERROR([Cannot find libuuid uuid_generate nor libc uuid_create. Either set PKG_CONFIG_PATH to the configuration file location or use LDFLAGS=-Ldir to specify the library location])
275 ]
276 )
277 ]
278 )
279 ])
280 AM_CONDITIONAL([LTTNG_BUILD_WITH_LIBUUID], [test "x$have_libuuid" = "xyes"])
281 AM_CONDITIONAL([LTTNG_BUILD_WITH_LIBC_UUID], [test "x$have_libc_uuid" = "xyes"])
282
283 # URCU library version needed or newer
284 m4_define([WRONG_LIBURCU_MSG], [Userspace RCU (liburcu) >= 0.8.0 is needed])
285
286 # Check liburcu needed function calls
287 AC_CHECK_DECL([cds_list_add], [],
288 [AC_MSG_ERROR([WRONG_LIBURCU_MSG])], [[#include <urcu/list.h>]])
289 AC_CHECK_DECL([cds_wfcq_init], [],
290 [AC_MSG_ERROR([WRONG_LIBURCU_MSG])], [[#include <urcu/wfcqueue.h>]])
291 AC_CHECK_DECL([cds_wfcq_dequeue_blocking], [],
292 [AC_MSG_ERROR([WRONG_LIBURCU_MSG])], [[#include <urcu/wfcqueue.h>]])
293 AC_CHECK_DECL([futex_async], [],
294 [AC_MSG_ERROR([WRONG_LIBURCU_MSG])], [[#include <urcu/futex.h>]])
295 AC_CHECK_DECL([rcu_thread_offline], [],
296 [AC_MSG_ERROR([WRONG_LIBURCU_MSG])], [[#include <urcu.h>]])
297 AC_CHECK_DECL([rcu_thread_online], [],
298 [AC_MSG_ERROR([WRONG_LIBURCU_MSG])], [[#include <urcu.h>]])
299 AC_CHECK_DECL([caa_likely], [],
300 [AC_MSG_ERROR([WRONG_LIBURCU_MSG])], [[#include <urcu.h>]])
301
302 #Function added in urcu 0.7.0
303 AC_CHECK_DECL([cmm_smp_mb__before_uatomic_or], [],
304 [AC_MSG_ERROR([WRONG_LIBURCU_MSG])], [[#include <urcu.h>]]
305 )
306
307 # Check kmod library
308 AC_ARG_WITH(kmod-prefix,
309 AS_HELP_STRING([--with-kmod-prefix=PATH],
310 [Specify the installation prefix of the kmod library.
311 Headers must be in PATH/include; libraries in PATH/lib.]),
312 [
313 CPPFLAGS="$CPPFLAGS -I${withval}/include"
314 LDFLAGS="$LDFLAGS -L${withval}/lib64 -L${withval}/lib"
315 ])
316
317 AC_ARG_ENABLE(kmod,
318 AS_HELP_STRING([--disable-kmod],[build without kmod support]),
319 kmod_support=zz$enableval, kmod_support=yes)
320
321 AS_IF([test "x$kmod_support" = "xyes"], [
322 AC_CHECK_LIB([kmod], [kmod_module_probe_insert_module],
323 [
324 AC_DEFINE([HAVE_KMOD], [1], [has kmod support])
325 LIBS="$LIBS -lkmod"
326 kmod_found=yes
327 ],
328 kmod_found=no
329 )
330 ])
331 AM_CONDITIONAL([HAVE_KMOD], [test "x$kmod_found" = xyes])
332
333 AC_ARG_WITH(lttng-ust-prefix,
334 AS_HELP_STRING([--with-lttng-ust-prefix=PATH],
335 [Specify the installation prefix of the lttng-ust library.
336 Headers must be in PATH/include; libraries in PATH/lib.]),
337 [
338 CPPFLAGS="$CPPFLAGS -I${withval}/include"
339 LDFLAGS="$LDFLAGS -L${withval}/lib64 -L${withval}/lib"
340 ])
341
342 # Check liblttng-ust-ctl library
343 AC_ARG_WITH(lttng-ust,
344 AS_HELP_STRING([--without-lttng-ust],[build without LTTng-UST (Userspace Tracing) support]),
345 lttng_ust_support=$withval, lttng_ust_support=yes)
346
347 AS_IF([test "x$lttng_ust_support" = "xyes"], [
348 AC_CHECK_LIB([lttng-ust-ctl], [ustctl_recv_channel_from_consumer],
349 [
350 AC_DEFINE([HAVE_LIBLTTNG_UST_CTL], [1], [has LTTng-UST control support])
351 lttng_ust_ctl_found=yes
352 ],
353 [AC_MSG_ERROR([Cannot find LTTng-UST >= 2.2.x. Use --with-lttng-ust-prefix=PREFIX to specify its location, or specify --without-lttng-ust to build lttng-tools without LTTng-UST support.])],
354 [-lurcu-common -lurcu-bp -lurcu-cds -lrt -ldl]
355 )
356 ])
357 AM_CONDITIONAL([HAVE_LIBLTTNG_UST_CTL], [test "x$lttng_ust_ctl_found" = xyes])
358 AC_CHECK_FUNCS([sched_getcpu sysconf sync_file_range])
359
360 # check for dlopen
361 AC_CHECK_LIB([dl], [dlopen],
362 [
363 have_libdl=yes
364 ],
365 [
366 #libdl not found, check for dlopen in libc.
367 AC_CHECK_LIB([c], [dlopen],
368 [
369 have_libc_dl=yes
370 ],
371 [
372 AC_MSG_ERROR([Cannot find dlopen in libdl nor libc. Use [LDFLAGS]=-Ldir to specify their location.])
373 ])
374 ])
375 AM_CONDITIONAL([LTTNG_TOOLS_BUILD_WITH_LIBDL], [test "x$have_libdl" = "xyes"])
376 AM_CONDITIONAL([LTTNG_TOOLS_BUILD_WITH_LIBC_DL], [test "x$have_libc_dl" = "xyes"])
377
378 # Check for fmemopen
379 AC_CHECK_LIB([c], [fmemopen],
380 [
381 AC_DEFINE_UNQUOTED([LTTNG_HAVE_FMEMOPEN], 1, [Has fmemopen support.])
382 ]
383 )
384
385 # Check for open_memstream
386 AC_CHECK_LIB([c], [open_memstream],
387 [
388 AC_DEFINE_UNQUOTED([LTTNG_HAVE_OPEN_MEMSTREAM], 1, [Has open_memstream support.])
389 ]
390 )
391
392 AC_ARG_ENABLE([git-version],
393 [AC_HELP_STRING([--disable-git-version],
394 [Do not use the git version for the build])],
395 [have_git_version=$enableval], [have_git_version=yes]
396 )
397
398 AM_CONDITIONAL([LTTNG_TOOLS_BUILD_GIT_SOURCE],
399 [test "x${have_git_version}" = "xyes"])
400
401 # For Python
402 # SWIG version needed or newer:
403 swig_version=2.0.0
404
405 AC_ARG_ENABLE([python-bindings],
406 [AC_HELP_STRING([--enable-python-bindings],
407 [compile Python bindings])],
408 [enable_python_binding=yes], [enable_python_binding=no])
409
410 AM_CONDITIONAL([PYTHON_BINDING], [test "x${enable_python_binding:-yes}" = xyes])
411
412 if test "x${enable_python_binding:-yes}" = xyes; then
413 AX_PKG_SWIG($swig_version, [], [ AC_MSG_ERROR([SWIG $swig_version or newer is needed]) ])
414 AS_IF([test x$enable_shared = xno], [ AC_MSG_ERROR([Python bindings require shared libraries.]) ])
415 AM_PATH_PYTHON([3.0])
416
417 AC_ARG_VAR([PYTHON_INCLUDE], [Include flags for python, bypassing python-config])
418 AC_ARG_VAR([PYTHON_CONFIG], [Path to python-config])
419 AS_IF([test -z "$PYTHON_INCLUDE"], [
420 AS_IF([test -z "$PYTHON_CONFIG"], [
421 AC_PATH_PROGS([PYTHON_CONFIG],
422 [python$PYTHON_VERSION-config python-config],
423 [no],
424 [`dirname $PYTHON`])
425 AS_IF([test "$PYTHON_CONFIG" = no], [AC_MSG_ERROR([cannot find python-config for $PYTHON. Do you have python-dev installed?])])
426 ])
427 AC_MSG_CHECKING([python include flags])
428 PYTHON_INCLUDE=`$PYTHON_CONFIG --includes`
429 AC_MSG_RESULT([$PYTHON_INCLUDE])
430 ])
431
432 else
433 AC_MSG_NOTICE([You may configure with --enable-python-bindings ]dnl
434 [if you want Python bindings.])
435
436 fi
437
438 # Epoll check. If not present, the build will fallback on poll() API
439 AX_HAVE_EPOLL(
440 [AX_CONFIG_FEATURE_ENABLE(epoll)],
441 [AX_CONFIG_FEATURE_DISABLE(epoll)]
442 )
443 AX_CONFIG_FEATURE(
444 [epoll], [This platform supports epoll(7)],
445 [HAVE_EPOLL], [This platform supports epoll(7).],
446 [enable_epoll="yes"], [enable_epoll="no"]
447 )
448 AM_CONDITIONAL([COMPAT_EPOLL], [ test "$enable_epoll" = "yes" ])
449
450 AM_CONDITIONAL([TEST_JAVA_JUL_AGENT], [test "x$test_java_agent_jul" = "xyes"])
451 AM_CONDITIONAL([TEST_JAVA_LOG4J_AGENT], [test "x$test_java_agent_log4j" = "xyes"])
452
453 if test "x$test_java_agent_jul" = "xyes" || test "x$test_java_agent_log4j" = "xyes"; then
454 AX_JAVA_OPTIONS
455 AX_PROG_JAVAC
456 AX_PROG_JAVA
457 AX_PROG_JAR
458
459 AX_CHECK_CLASSPATH
460
461 # Check for Java UST agent common class first
462 AX_CHECK_CLASS(org.lttng.ust.agent.AbstractLttngAgent)
463 if test "x$ac_cv_class_org_lttng_ust_agent_AbstractLttngAgent" = "xno"; then
464 AC_MSG_ERROR([The UST Java agent common class was not found. Please specify the location of the jar via the Java CLASSPATH e.g: export CLASSPATH="/path/to/lttng-ust-agent-common.jar"])
465 fi
466
467 if test "x$test_java_agent_jul" = "xyes"; then
468 # Check for JUL agent class
469 AX_CHECK_CLASS(org.lttng.ust.agent.jul.LttngLogHandler)
470 if test "x$ac_cv_class_org_lttng_ust_agent_jul_LttngLogHandler" = "xno"; then
471 AC_MSG_ERROR([The UST Java agent JUL class was not found. Please specify the location of the jar via the Java CLASSPATH e.g: export CLASSPATH="/path/to/lttng-ust-agent-jul.jar"])
472 fi
473 fi
474
475 if test "x$test_java_agent_log4j" = "xyes"; then
476 # Check for Log4j agent class
477 AX_CHECK_CLASS(org.lttng.ust.agent.log4j.LttngLogAppender)
478 if test "x$ac_cv_class_org_lttng_ust_agent_log4j_LttngLogAppender" = "xno"; then
479 AC_MSG_ERROR([The UST Java agent Log4j class was not found. Please specify the location of the jar via the Java CLASSPATH e.g: export CLASSPATH="/path/to/lttng-ust-agent-log4j.jar"])
480 fi
481
482 # Check for Log4j class
483 AX_CHECK_CLASS(org.apache.log4j.Logger)
484 if test "x$ac_cv_class_org_apache_log4j_Logger" = "xno"; then
485 AC_MSG_ERROR([The Log4j class was not found. Please specify the location of the jar via the Java CLASSPATH e.g: export CLASSPATH="/path/to/log4j.jar"])
486 fi
487 fi
488 fi
489
490 # set $IN_GIT_REPO if we're in the Git repository; the `bootstrap` file
491 # is not distributed in tarballs
492 AS_IF([test -f "$srcdir/bootstrap"], [in_git_repo=yes], [in_git_repo=no])
493 AM_CONDITIONAL([IN_GIT_REPO], [test "x$in_git_repo" = "xyes"])
494
495 # enable building man pages
496 AC_ARG_ENABLE(
497 build-man-pages,
498 AS_HELP_STRING(
499 [--disable-build-man-pages],
500 [Build man pages (already built in a distributed tarball)]
501 ),
502 [build_man_pages=$enableval],
503 [build_man_pages=yes]
504 )
505
506 # export man page build condition
507 AM_CONDITIONAL([BUILD_MAN_PAGES], [test "x$build_man_pages" != "xno"])
508
509 # check for asciidoc and xmlto if we enabled building the man pages
510 AS_IF([test "x$build_man_pages" = "xyes"], [
511 AC_PATH_PROG([ASCIIDOC], [asciidoc], [no])
512 AC_PATH_PROG([XMLTO], [xmlto], [no])
513
514 AS_IF([test "x$ASCIIDOC" = "xno" || test "x$XMLTO" = "xno"], [
515 AC_MSG_ERROR([Both asciidoc and xmlto are needed to build the LTTng man pages.])
516 ])
517 ])
518
519 # Python agent test
520 UST_PYTHON_AGENT="lttngust"
521
522 AC_ARG_ENABLE(test-python2-agent,
523 AS_HELP_STRING([--enable-test-python2-agent],
524 [enable tests for python2 agent. Python2 interpreter path can be overridden by setting the PYTHON2 environment variable. Default: Autodetect]
525 ),[:],[test_python2_agent_autodetect=yes]
526 )
527
528 AC_ARG_ENABLE(test-python3-agent,
529 AS_HELP_STRING([--enable-test-python3-agent],
530 [enable tests for python3 agent. Python3 interpreter path can be overridden by setting the PYTHON3 environment variable. Default: Autodetect]
531 ),[:],[test_python3_agent_autodetect=yes]
532 )
533
534 AC_ARG_ENABLE(test-python-agent-all,
535 AS_HELP_STRING([--enable-test-python-agent-all],
536 [enable test for all python{2/3} agent.]
537 ),
538 )
539
540 AS_IF([test ! -z "$enable_test_python_agent_all"], [
541 unset test_python2_agent_autodetect
542 unset test_python3_agent_autodetect
543 ])
544
545 AS_IF([test "x$enable_test_python_agent_all" = "xyes"], [
546 enable_test_python2_agent=yes
547 enable_test_python3_agent=yes
548 ])
549
550 AS_IF([test "x$enable_test_python_agent_all" = "xno"], [
551 enable_test_python2_agent=no
552 enable_test_python3_agent=no
553 ])
554
555
556 AS_IF([test "x$enable_test_python2_agent" = "xyes" -o "x$test_python2_agent_autodetect" = "xyes" ], [
557 AS_IF([test -z "$PYTHON2"], [
558 PYTHON2=python2
559 ], [
560 AC_MSG_WARN([Using user-defined PYTHON2 ($PYTHON2) for lttng-ust python2 agent check])
561 ])
562
563 AC_PATH_PROG([PYTHON2_BIN],[$PYTHON2])
564 AS_IF([test -z "$PYTHON2_BIN"], [
565 AS_IF([test -z "$test_python2_agent_autodetect"],[
566 AC_MSG_ERROR([No python2 interpreter found. PYTHON2 can be set to override default interpreter path])
567 ])
568 ], [
569 AC_MSG_CHECKING([for python2 lttng-ust agent])
570 AS_IF([$PYTHON2_BIN -c "import $UST_PYTHON_AGENT" 2>/dev/null], [
571 PYTHON2_AGENT=$PYTHON2_BIN
572 AC_MSG_RESULT([yes])
573 RUN_PYTHON_AGENT_TEST=yes
574 ], [
575 AC_MSG_RESULT([no])
576 AS_IF([test -z "$test_python2_agent_autodetect"],[
577 AC_MSG_ERROR([No python2 agent found. The path to the agent can be specified by setting the PYTHONPATH environment variable.])
578 ])
579 ])
580
581 ])
582
583 ])
584
585 AS_IF([test "x$enable_test_python3_agent" = "xyes" -o "x$test_python3_agent_autodetect" = "xyes" ], [
586 AS_IF([test -z "$PYTHON3"], [
587 PYTHON3=python3
588 ], [
589 AC_MSG_WARN([Using user-defined PYTHON3 ($PYTHON3) for lttng-ust python3 agent check])
590 ])
591
592 AC_PATH_PROG([PYTHON3_BIN],[$PYTHON3])
593 AS_IF([test -z "$PYTHON3_BIN"], [
594 AS_IF([test -z "$test_python3_agent_autodetect"],[
595 AC_MSG_ERROR([No python3 interpreter found. PYTHON3 can be set to override default interpreter path])
596 ])
597 ], [
598 AC_MSG_CHECKING([for python3 lttng-ust agent])
599 AS_IF([$PYTHON3_BIN -c "import $UST_PYTHON_AGENT" 2>/dev/null], [
600 PYTHON3_AGENT=$PYTHON3_BIN
601 AC_MSG_RESULT([yes])
602 RUN_PYTHON_AGENT_TEST=yes
603 ], [
604 AC_MSG_RESULT([no])
605 AS_IF([test -z "$test_python3_agent_autodetect"],[
606 AC_MSG_ERROR([No python3 agent found. The path to the agent can be specified by setting the PYTHONPATH environment variable.])
607 ])
608 ])
609
610 ])
611 ])
612 AC_SUBST([RUN_PYTHON_AGENT_TEST])
613 AC_SUBST([PYTHON2_AGENT])
614 AC_SUBST([PYTHON3_AGENT])
615
616 # Arguments for binaries build exclusion
617 AC_ARG_ENABLE([bin-lttng], AS_HELP_STRING([--disable-bin-lttng],[Disable the build of lttng binaries]))
618 AC_ARG_ENABLE([bin-lttng-consumerd], AS_HELP_STRING([--disable-bin-lttng-consumerd],
619 [Disable the build of lttng-consumerd binaries]))
620 AC_ARG_ENABLE([bin-lttng-crash], AS_HELP_STRING([--disable-bin-lttng-crash],[Disable the build of lttng-crash binaries]))
621 AC_ARG_ENABLE([bin-lttng-relayd], AS_HELP_STRING([--disable-bin-lttng-relayd],
622 [Disable the build of lttng-relayd binaries]))
623 AC_ARG_ENABLE([bin-lttng-sessiond], AS_HELP_STRING([--disable-bin-lttng-sessiond],
624 [Disable the build of lttng-sessiond binaries]))
625 AC_ARG_ENABLE([extras], AS_HELP_STRING([--disable-extras],
626 [Disable the build of the extra components]))
627
628
629 # Always build libconfig since it a dependency of libcommon
630 build_lib_config=yes
631
632 build_lib_compat=no
633 build_lib_consumer=no
634 build_lib_hashtable=no
635 build_lib_health=no
636 build_lib_index=no
637 build_lib_kernel_consumer=no
638 build_lib_kernel_ctl=no
639 build_lib_lttng_ctl=no
640 build_lib_relayd=no
641 build_lib_sessiond_comm=no
642 build_lib_testpoint=no
643 build_lib_ust_consumer=no
644
645 # There is an overlap for enabled dependencies, but this makes everything
646 # simpler. libcommon and libconfig are always compiled so they are not repeated
647 # here.
648
649 # Enable binary dependencies.
650 AS_IF([test x$enable_bin_lttng != xno],
651 [
652 build_lib_lttng_ctl=yes
653 ]
654 )
655
656 AS_IF([test x$enable_bin_lttng_consumerd != xno],
657 [
658 build_lib_consumer=yes
659 build_lib_sessiond_comm=yes
660 build_lib_index=yes
661 build_lib_health=yes
662 build_lib_testpoint=yes
663 ]
664 )
665
666 AS_IF([test x$enable_bin_lttng_crash != xno],
667 # Do nothing since libconfig and libcommon are built by default.
668 []
669 )
670
671 AS_IF([test x$enable_bin_lttng_relayd != xno],
672 [
673 build_lib_lttng_ctl=yes
674 build_lib_sessiond_comm=yes
675 build_lib_hashtable=yes
676 build_lib_compat=yes
677 build_lib_index=yes
678 build_lib_health=yes
679 build_lib_testpoint=yes
680 ]
681 )
682 AS_IF([test x$enable_bin_lttng_sessiond != xno],
683 [
684 build_lib_lttng_ctl=yes
685 build_lib_sessiond_comm=yes
686 build_lib_kernel_ctl=yes
687 build_lib_hashtable=yes
688 build_lib_compat=yes
689 build_lib_relayd=yes
690 build_lib_testpoint=yes
691 build_lib_health=yes
692 build_lib_health=yes
693 ]
694 )
695
696 # Libraries dependencies enabling
697 AS_IF([test x$build_lib_lttng_ctl = xyes],
698 [
699 build_lib_sessiond_comm=yes
700 build_lib_hashtable=yes
701 ]
702 )
703
704 AS_IF([test x$build_lib_consumer = xyes],
705 [
706 build_lib_sessiond_comm=yes
707 build_lib_kernel_consumer=yes
708 build_lib_hashtable=yes
709 build_lib_compat=yes
710 build_lib_relayd=yes
711 AS_IF([test x$lttng_ust_ctl_found = xyes],[build_lib_ust_consumer=yes])
712 ]
713 )
714
715 AS_IF([test x$build_lib_kernel_consumer = xyes],
716 [
717 build_lib_kernel_ctl=yes
718 build_lib_relayd=yes
719 ]
720 )
721
722 AS_IF([test x$build_lib_relayd = xyes],
723 [
724 build_lib_sessiond_comm=yes
725 ]
726 )
727
728
729 # Export binaries build conditions.
730 AM_CONDITIONAL([BUILD_BIN_LTTNG], [test x$enable_bin_lttng != xno])
731 AM_CONDITIONAL([BUILD_BIN_LTTNG_CONSUMERD], [test x$enable_bin_lttng_consumerd != xno])
732 AM_CONDITIONAL([BUILD_BIN_LTTNG_CRASH], [test x$enable_bin_lttng_crash != xno])
733 AM_CONDITIONAL([BUILD_BIN_LTTNG_RELAYD], [test x$enable_bin_lttng_relayd != xno])
734 AM_CONDITIONAL([BUILD_BIN_LTTNG_SESSIOND], [test x$enable_bin_lttng_sessiond != xno])
735
736 # Export the tests and extras build conditions.
737 AS_IF([\
738 test "x$enable_bin_lttng" != "xno" && \
739 test "x$enable_bin_lttng_consumerd" != "xno" && \
740 test "x$enable_bin_lttng_crash" != "xno" && \
741 test "x$enable_bin_lttng_relayd" != "xno" && \
742 test "x$enable_bin_lttng_sessiond" != "xno"],
743 [build_tests=yes],
744 [build_tests=no]
745 )
746
747 AM_CONDITIONAL([BUILD_TESTS], [test x$build_tests = xyes])
748 AM_CONDITIONAL([BUILD_EXTRAS], [test x$enable_extras != xno])
749
750 # Export libraries build conditions.
751 AM_CONDITIONAL([BUILD_LIB_COMPAT], [test x$build_lib_compat = xyes])
752 AM_CONDITIONAL([BUILD_LIB_CONFIG], [test x$build_lib_config = xyes])
753 AM_CONDITIONAL([BUILD_LIB_CONSUMER], [test x$build_lib_consumer = xyes])
754 AM_CONDITIONAL([BUILD_LIB_HASHTABLE], [test x$build_lib_hashtable = xyes])
755 AM_CONDITIONAL([BUILD_LIB_HEALTH], [test x$build_lib_health = xyes])
756 AM_CONDITIONAL([BUILD_LIB_INDEX], [test x$build_lib_index = xyes])
757 AM_CONDITIONAL([BUILD_LIB_KERNEL_CONSUMER], [test x$build_lib_kernel_consumer = xyes])
758 AM_CONDITIONAL([BUILD_LIB_KERNEL_CTL], [test x$build_lib_kernel_ctl = xyes])
759 AM_CONDITIONAL([BUILD_LIB_LTTNG_CTL], [test x$build_lib_lttng_ctl = xyes])
760 AM_CONDITIONAL([BUILD_LIB_RELAYD], [test x$build_lib_relayd = xyes])
761 AM_CONDITIONAL([BUILD_LIB_SESSIOND_COMM], [test x$build_lib_sessiond_comm = xyes])
762 AM_CONDITIONAL([BUILD_LIB_TESTPOINT], [test x$build_lib_testpoint = xyes])
763 AM_CONDITIONAL([BUILD_LIB_UST_CONSUMER], [test x$build_lib_ust_consumer = xyes])
764
765 # check for pgrep
766 AC_PATH_PROG([PGREP], [pgrep], [no])
767 AM_CONDITIONAL([HAS_PGREP], [test "x$PGREP" != "xno"])
768
769 if test ! -f "$srcdir/src/lib/lttng-ctl/filter/filter-parser.h"; then
770 if test x"$(basename "$YACC")" != "xbison -y"; then
771 AC_MSG_ERROR([[bison not found and is required when building from git.
772 Please install bison]])
773 fi
774 AC_PATH_PROG([BISON],[bison])
775 AX_PROG_BISON_VERSION([2.4], [],[
776 AC_MSG_ERROR([[Bison >= 2.4 is required when building from git]])
777 ])
778 fi
779
780 if test ! -f "$srcdir/src/lib/lttng-ctl/filter/filter-lexer.c"; then
781 if test x"$LEX" != "xflex"; then
782 AC_MSG_ERROR([[flex not found and is required when building from git.
783 Please install flex]])
784 fi
785 AC_PATH_PROG([FLEX],[flex])
786 AX_PROG_FLEX_VERSION([2.5.35], [],[
787 AC_MSG_ERROR([[Flex >= 2.5.35 is required when building from git]])
788 ])
789 fi
790
791 CFLAGS="-Wall $CFLAGS -g -fno-strict-aliasing"
792
793 DEFAULT_INCLUDES="-I\$(top_srcdir) -I\$(top_builddir) -I\$(top_builddir)/src -I\$(top_builddir)/include -include config.h"
794
795 lttngincludedir="${includedir}/lttng"
796
797 AC_SUBST(lttngincludedir)
798 AC_SUBST(DEFAULT_INCLUDES)
799
800 lttnglibexecdir="${libdir}/lttng/libexec"
801 AC_SUBST(lttnglibexecdir)
802
803 AC_CONFIG_FILES([
804 Makefile
805 doc/Makefile
806 doc/man/Makefile
807 include/Makefile
808 extras/Makefile
809 extras/bindings/Makefile
810 extras/bindings/swig/Makefile
811 extras/bindings/swig/python/Makefile
812 extras/core-handler/Makefile
813 src/Makefile
814 src/common/Makefile
815 src/common/kernel-ctl/Makefile
816 src/common/kernel-consumer/Makefile
817 src/common/consumer/Makefile
818 src/common/ust-consumer/Makefile
819 src/common/hashtable/Makefile
820 src/common/sessiond-comm/Makefile
821 src/common/compat/Makefile
822 src/common/relayd/Makefile
823 src/common/testpoint/Makefile
824 src/common/index/Makefile
825 src/common/health/Makefile
826 src/common/config/Makefile
827 src/lib/Makefile
828 src/lib/lttng-ctl/Makefile
829 src/lib/lttng-ctl/filter/Makefile
830 src/lib/lttng-ctl/lttng-ctl.pc
831 src/bin/Makefile
832 src/bin/lttng-consumerd/Makefile
833 src/bin/lttng-sessiond/Makefile
834 src/bin/lttng-relayd/Makefile
835 src/bin/lttng/Makefile
836 src/bin/lttng-crash/Makefile
837 tests/Makefile
838 tests/destructive/Makefile
839 tests/regression/Makefile
840 tests/regression/kernel/Makefile
841 tests/regression/tools/Makefile
842 tests/regression/tools/streaming/Makefile
843 tests/regression/tools/filtering/Makefile
844 tests/regression/tools/health/Makefile
845 tests/regression/tools/tracefile-limits/Makefile
846 tests/regression/tools/snapshots/Makefile
847 tests/regression/tools/live/Makefile
848 tests/regression/tools/exclusion/Makefile
849 tests/regression/tools/save-load/Makefile
850 tests/regression/tools/mi/Makefile
851 tests/regression/tools/wildcard/Makefile
852 tests/regression/tools/crash/Makefile
853 tests/regression/tools/metadata-regen/Makefile
854 tests/regression/ust/Makefile
855 tests/regression/ust/nprocesses/Makefile
856 tests/regression/ust/high-throughput/Makefile
857 tests/regression/ust/low-throughput/Makefile
858 tests/regression/ust/before-after/Makefile
859 tests/regression/ust/buffers-pid/Makefile
860 tests/regression/ust/periodical-metadata-flush/Makefile
861 tests/regression/ust/multi-session/Makefile
862 tests/regression/ust/overlap/Makefile
863 tests/regression/ust/overlap/demo/Makefile
864 tests/regression/ust/linking/Makefile
865 tests/regression/ust/daemon/Makefile
866 tests/regression/ust/exit-fast/Makefile
867 tests/regression/ust/fork/Makefile
868 tests/regression/ust/libc-wrapper/Makefile
869 tests/regression/ust/baddr-statedump/Makefile
870 tests/regression/ust/ust-dl/Makefile
871 tests/regression/ust/java-jul/Makefile
872 tests/regression/ust/java-log4j/Makefile
873 tests/regression/ust/python-logging/Makefile
874 tests/regression/ust/getcpu-override/Makefile
875 tests/regression/ust/clock-override/Makefile
876 tests/regression/ust/type-declarations/Makefile
877 tests/stress/Makefile
878 tests/unit/Makefile
879 tests/unit/ini_config/Makefile
880 tests/utils/Makefile
881 tests/utils/tap/Makefile
882 tests/utils/testapp/Makefile
883 tests/utils/testapp/gen-ust-events/Makefile
884 tests/utils/testapp/gen-ust-nevents/Makefile
885 tests/utils/testapp/gen-ust-tracef/Makefile
886 ])
887
888 # Inject variable into python test script.
889 AC_CONFIG_FILES([tests/regression/ust/python-logging/test_python_logging],[chmod +x tests/regression/ust/python-logging/test_python_logging])
890
891 AC_OUTPUT
892
893 #
894 # Mini-report on what will be built.
895 #
896
897 PPRINT_INIT
898 PPRINT_SET_INDENT(1)
899 PPRINT_SET_TS(38)
900
901 AS_ECHO
902 AS_ECHO("${PPRINT_COLOR_BLDBLU}LTTng-tools $PACKAGE_VERSION \"$version_name\"$PPRINT_COLOR_RST")
903 AS_ECHO
904
905 AS_IF([test -n "$report_fold"], [
906 AS_ECHO("`AS_ECHO("$version_description") | $report_fold -s`")
907 ], [
908 AS_ECHO("$version_description")
909 ])
910
911 AS_ECHO
912 PPRINT_SUBTITLE([Features])
913
914 # Target architecture we're building for.
915 target_arch=$host_cpu
916 [
917 for f in $CFLAGS; do
918 if test $f = "-m32"; then
919 target_arch="32-bit"
920 elif test $f = "-m64"; then
921 target_arch="64-bit"
922 fi
923 done
924 ]
925 PPRINT_PROP_STRING([Target architecture], $target_arch)
926
927 # kmod enabled/disabled
928 test "x$kmod_found" = "xyes" && value=1 || value=0
929 PPRINT_PROP_BOOL([libkmod support], $value)
930
931 # LTTng-UST enabled/disabled
932 test "x$lttng_ust_support" = "xyes" && value=1 || value=0
933 PPRINT_PROP_BOOL([LTTng-UST support], $value)
934
935 AS_ECHO
936 PPRINT_SUBTITLE([Binaries])
937
938 # List binaries to be built
939 test x$enable_bin_lttng != xno && value=1 || value=0
940 PPRINT_PROP_BOOL([lttng], $value)
941
942 test x$enable_bin_lttng_consumerd != xno && value=1 || value=0
943 PPRINT_PROP_BOOL([lttng-consumerd], $value)
944
945 test x$enable_bin_lttng_crash != xno && value=1 || value=0
946 PPRINT_PROP_BOOL([lttng-crash], $value)
947
948 test x$enable_bin_lttng_relayd != xno && value=1 || value=0
949 PPRINT_PROP_BOOL([lttng-relayd], $value)
950
951 test x$enable_bin_lttng_sessiond != xno && value=1 || value=0
952 PPRINT_PROP_BOOL([lttng-sessiond], $value)
953
954 # Extras
955 test x$enable_extras != xno && value=1 || value=0
956 AS_ECHO
957 PPRINT_SET_INDENT(0)
958 PPRINT_PROP_BOOL([Extras], $value, $PPRINT_COLOR_SUBTITLE)
959 PPRINT_SET_INDENT(1)
960
961 AS_ECHO
962 PPRINT_SUBTITLE([Tests])
963
964 # Print clear message that tests won't be built
965 AS_IF([test "x$build_tests" = "xno"],[
966 PPRINT_WARN([Tests won't be built since some binaries were disabled])
967 ])
968
969 # LTTng UST Java agent JUL tests enabled/disabled
970 test "x$test_java_agent_jul" = "xyes" && value=1 || value=0
971 PPRINT_PROP_BOOL([LTTng-UST Java agent JUL tests], $value)
972
973 # LTTng UST Java agent Log4j tests enabled/disabled
974 test "x$test_java_agent_log4j" = "xyes" && value=1 || value=0
975 PPRINT_PROP_BOOL([LTTng-UST Java agent Log4j tests], $value)
976
977 test ! -z "$PYTHON2_AGENT" && value=1 || value=0
978 PPRINT_PROP_BOOL([LTTng-UST Python2 agent tests], $value)
979
980 test ! -z "$PYTHON3_AGENT" && value=1 || value=0
981 PPRINT_PROP_BOOL([LTTng-UST Python3 agent tests], $value)
982
983 #Python binding enabled/disabled
984 test "x${enable_python_binding:-yes}" = xyes && value=1 || value=0
985 AS_ECHO
986 PPRINT_SET_INDENT(0)
987 PPRINT_PROP_BOOL([Python binding], $value, $PPRINT_COLOR_SUBTITLE)
988 PPRINT_SET_INDENT(1)
989
990 AS_ECHO
991 PPRINT_SUBTITLE([Man pages])
992
993 # man pages build enabled/disabled
994 AS_IF([test "x$build_man_pages" = "xyes"], [
995 PPRINT_PROP_BOOL([Build man pages], 1)
996 ], [
997 AS_IF([test "x$in_git_repo" = "xyes"], [
998 PPRINT_PROP_BOOL([Build man pages], 0)
999 ], [
1000 PPRINT_PROP_STRING([Build man pages], [${PPRINT_COLOR_BLDGRN}Already built])
1001 ])
1002 ])
1003
1004 # man pages install enabled/disabled (always true in tarball)
1005 test "x$build_man_pages" != "xyes" && test "x$in_git_repo" = "xyes" && value=0 || value=1
1006 PPRINT_PROP_BOOL([Install man pages], $value)
1007
1008 report_bindir="`eval eval echo $bindir`"
1009 report_libdir="`eval eval echo $libdir`"
1010
1011 # Print the bindir and libdir this `make install' will install into.
1012 AS_ECHO
1013 PPRINT_SUBTITLE([Install directories])
1014 PPRINT_PROP_STRING([Binaries], [$report_bindir])
1015 PPRINT_PROP_STRING([Libraries], [$report_libdir])
1016
1017 AS_ECHO
1018 PPRINT_SUBTITLE([Search directories])
1019
1020 # If we build the sessiond, print the paths it will use
1021 AS_IF([test "$SESSIOND_BIN" = ""],[
1022 path="$report_bindir/lttng-sessiond"
1023 ],[
1024 path="$SESSIOND_BIN"
1025 ])
1026 PPRINT_PROP_STRING([lttng-sessiond executable], [$path])
1027
1028 AS_IF([test "$CONSUMERD32_BIN" = ""],[
1029 path="`eval eval echo $lttnglibexecdir`/lttng-consumerd"
1030 ],[
1031 path="$CONSUMERD32_BIN"
1032 ])
1033 PPRINT_PROP_STRING([32-bit lttng-consumerd executable], [$path])
1034
1035 AS_IF([test "$CONSUMERD32_LIBDIR" = ""],[
1036 path="`eval eval echo $libdir`"
1037 ],[
1038 path="$CONSUMERD32_LIBDIR"
1039 ])
1040 PPRINT_PROP_STRING([32-bit consumer libraries], [$path])
1041
1042 AS_IF([test "$CONSUMERD64_BIN" = ""],[
1043 path="`eval eval echo $lttnglibexecdir`/lttng-consumerd"
1044 ],[
1045 path="$CONSUMERD64_BIN"
1046 ])
1047 PPRINT_PROP_STRING([64-bit lttng-consumerd executable], [$path])
1048
1049 AS_IF([test "$CONSUMERD64_LIBDIR" = ""],[
1050 path="`eval eval echo $libdir`"
1051 ],[
1052 path="$CONSUMERD64_LIBDIR"
1053 ])
1054 PPRINT_PROP_STRING([64-bit consumer libraries], [$path])
This page took 0.080902 seconds and 3 git commands to generate.