configure.ac

   1 AC_PREREQ([2.64])
   2 AC_INIT([lttng-tools],[2.10.0-pre],[jeremie.galarneau@efficios.com],[],[https://lttng.org])
   3
   4 AC_CONFIG_HEADERS([include/config.h])
   5 AC_CONFIG_AUX_DIR([config])
   6 AC_CONFIG_MACRO_DIR([m4])
   7
   8 AC_CANONICAL_TARGET
   9 AC_CANONICAL_HOST
  10
  11 AM_INIT_AUTOMAKE([foreign dist-bzip2 no-dist-gzip tar-pax])
  12 AM_MAINTAINER_MODE([enable])
  13
  14 # Enable silent rules if available (Introduced in AM 1.11)
  15 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  16
  17 AC_REQUIRE_AUX_FILE([tap-driver.sh])
  18
  19 # Checks for C compiler
  20 AC_USE_SYSTEM_EXTENSIONS
  21 AC_SYS_LARGEFILE
  22 AC_PROG_CC
  23 AC_PROG_CC_STDC
  24
  25 # Checks for programs.
  26 AC_PROG_GREP
  27 AC_PROG_LEX
  28 AC_PROG_MAKE_SET
  29 AC_PROG_SED
  30 AC_PROG_YACC
  31 AC_PATH_PROG(report_fold, fold)
  32 LT_INIT
  33
  34 # Check for objcopy, required by the base address statedump and dynamic linker tests
  35 AC_CHECK_TOOL([OBJCOPY], objcopy, no)
  36 AS_IF([test "x$OBJCOPY" = xno],
  37         [AC_MSG_WARN([Cannont find objcopy. The base address statedump and dynamic linker tests will be disabled. Install the binutils package to remediate this.])]
  38 )
  39 AM_CONDITIONAL([HAVE_OBJCOPY], [test "x$OBJCOPY" != xno])
  40
  41 # Checks for typedefs, structures, and compiler characteristics.
  42 AC_C_INLINE
  43 AC_TYPE_INT32_T
  44 AC_TYPE_INT64_T
  45 AC_TYPE_MODE_T
  46 AC_TYPE_OFF_T
  47 AC_TYPE_PID_T
  48 AC_TYPE_SIZE_T
  49 AC_TYPE_SSIZE_T
  50 AC_TYPE_UID_T
  51 AC_TYPE_UINT16_T
  52 AC_TYPE_UINT32_T
  53 AC_TYPE_UINT64_T
  54 AC_TYPE_UINT8_T
  55
  56 AX_C___ATTRIBUTE__
  57 AS_IF([test "x$ax_cv___attribute__" = "xyes"],
  58         [:],
  59         [AC_MSG_ERROR([The compiler does not support __attribute__ extensions])])
  60
  61 AX_PTHREAD(,[AC_MSG_ERROR([Could not configure pthreads support])])
  62 LIBS="$PTHREAD_LIBS $LIBS"
  63 CFLAGS="$CFLAGS $PTHREAD_CFLAGS"
  64 CC="$PTHREAD_CC"
  65
  66 AX_LIB_SOCKET_NSL
  67
  68 LT_NO_UNDEFINED=""
  69 AS_CASE([$host_os],
  70   [cygwin*],
  71     [
  72       LT_NO_UNDEFINED="-no-undefined"
  73     ]
  74 )
  75
  76 AC_SUBST(LT_NO_UNDEFINED)
  77
  78 # Compute minor/major/patchlevel version numbers
  79 major_version=$(echo AC_PACKAGE_VERSION | $SED 's/^\([[0-9]]\)*\.[[0-9]]*\.[[0-9]]*.*$/\1/')
  80 minor_version=$(echo AC_PACKAGE_VERSION | $SED 's/^[[0-9]]*\.\([[0-9]]*\)\.[[0-9]]*.*$/\1/')
  81 patchlevel_version=$(echo AC_PACKAGE_VERSION | $SED 's/^[[0-9]]*\.[[0-9]]*\.\([[0-9]]*\).*$/\1/')
  82
  83 AC_SUBST([MAJOR_VERSION], [$major_version])
  84 AC_SUBST([MINOR_VERSION], [$minor_version])
  85 AC_SUBST([PATCHLEVEL_VERSION], [$patchlevel_version])
  86 AC_DEFINE_UNQUOTED([VERSION_MAJOR], $major_version, [LTTng-Tools major version number])
  87 AC_DEFINE_UNQUOTED([VERSION_MINOR], $minor_version, [LTTng-Tools minor version number])
  88 AC_DEFINE_UNQUOTED([VERSION_PATCHLEVEL], $patchlevel_version, [LTTng-Tools patchlevel version number])
  89
  90 version_name="Codename TBD"
  91 version_description='Description TBD'
  92 version_description_c=$(echo $version_description | $SED 's/"/\\"/g')
  93
  94 AC_DEFINE_UNQUOTED([VERSION_NAME], ["$version_name"], "")
  95 AC_DEFINE_UNQUOTED([VERSION_DESCRIPTION], ["$version_description_c"], "")
  96
  97 # libtool link_all_deplibs fixup. See http://bugs.lttng.org/issues/321.
  98 AC_ARG_ENABLE(libtool-linkdep-fixup,
  99         AS_HELP_STRING([--disable-libtool-linkdep-fixup],
 100                         [disable the libtool fixup for linking all dependent libraries (link_all_deplibs)]),
 101         libtool_fixup=$enableval,
 102         libtool_fixup=yes)
 103
 104 AS_IF([test "x$libtool_fixup" = "xyes"],
 105             [
 106             libtool_m4="$srcdir/m4/libtool.m4"
 107             libtool_flag_pattern=".*link_all_deplibs\s*,\s*\$1\s*)"
 108             AC_MSG_CHECKING([for occurence(s) of link_all_deplibs = no in $libtool_m4])
 109             libtool_flag_pattern_count=$($GREP -c "$libtool_flag_pattern\s*=\s*no" $libtool_m4)
 110             AS_IF([test $libtool_flag_pattern_count -ne 0],
 111             [
 112                   AC_MSG_RESULT([$libtool_flag_pattern_count])
 113                   AC_MSG_WARN([the detected libtool will not link all dependencies, forcing link_all_deplibs = unknown])
 114                   $SED -i "s/\($libtool_flag_pattern\)\s*=\s*no/\1=unknown/g" $libtool_m4
 115                   ],
 116                   [
 117                   AC_MSG_RESULT([none])
 118                   ])
 119             ])
 120
 121 AM_CONDITIONAL([NO_SHARED], [test x$enable_shared = xno])
 122
 123 AC_CHECK_HEADERS([ \
 124         sys/types.h unistd.h fcntl.h string.h pthread.h limits.h \
 125         signal.h stdlib.h sys/un.h sys/socket.h stdlib.h stdio.h \
 126         getopt.h sys/ipc.h sys/shm.h popt.h grp.h arpa/inet.h \
 127         netdb.h netinet/in.h paths.h stddef.h sys/file.h sys/ioctl.h \
 128         sys/mount.h sys/param.h sys/time.h
 129 ])
 130
 131 # Basic functions check
 132 AC_CHECK_FUNCS([ \
 133         atexit bzero clock_gettime dup2 fdatasync fls ftruncate \
 134         gethostbyname gethostname getpagesize localtime_r memchr memset \
 135         mkdir munmap putenv realpath rmdir socket strchr strcspn strdup \
 136         strncasecmp strndup strnlen strpbrk strrchr strstr strtol strtoul \
 137         strtoull dirfd gethostbyname2 getipnodebyname epoll_create1 \
 138 ])
 139
 140 # Check if clock_gettime, timer_create, timer_settime, and timer_delete are available in lib rt, and if so,
 141 # add -lrt to LIBS
 142 AC_CHECK_LIB([rt], [clock_gettime, timer_create, timer_settime, timer_delete])
 143
 144 # Babeltrace viewer check
 145 AC_ARG_WITH([babeltrace-bin],
 146         AS_HELP_STRING([--with-babeltrace-bin],
 147         [Location of the babeltrace viewer executable (including the filename)]),
 148         [BABELTRACE_BIN="$withval"],
 149         [BABELTRACE_BIN=''])
 150 AC_SUBST([BABELTRACE_BIN])
 151
 152 # lttv-gui
 153 AC_ARG_WITH([lttv-gui-bin],
 154         AS_HELP_STRING([--with-lttv-gui-bin],
 155    [Location of the lttv GUI viewer executable (including the filename)]),
 156    [LTTV_GUI_BIN="$withval"],
 157    [LTTV_GUI_BIN=''])
 158 AC_SUBST([LTTV_GUI_BIN])
 159
 160 AC_ARG_WITH([consumerd32-bin],
 161         AS_HELP_STRING([--with-consumerd32-bin],
 162         [Location of the 32-bit consumerd executable (including the filename)]),
 163         [CONSUMERD32_BIN="$withval"],
 164         [CONSUMERD32_BIN=''])
 165 AC_SUBST([CONSUMERD32_BIN])
 166
 167 AC_ARG_WITH([consumerd64-bin],
 168         AS_HELP_STRING([--with-consumerd64-bin],
 169         [Location of the 64-bit consumerd executable (including the filename)]),
 170         [CONSUMERD64_BIN="$withval"],
 171         [CONSUMERD64_BIN=''])
 172 AC_SUBST([CONSUMERD64_BIN])
 173
 174 AC_ARG_WITH([consumerd32-libdir],
 175         AS_HELP_STRING([--with-consumerd32-libdir],
 176         [Directory containing the 32-bit consumerd libraries]),
 177         [CONSUMERD32_LIBDIR="$withval"],
 178         [CONSUMERD32_LIBDIR=''])
 179 AC_SUBST([CONSUMERD32_LIBDIR])
 180
 181 AC_ARG_WITH([consumerd64-libdir],
 182         AS_HELP_STRING([--with-consumerd64-libdir],
 183         [Directory containing the 64-bit consumerd libraries]),
 184         [CONSUMERD64_LIBDIR="$withval"],
 185         [CONSUMERD64_LIBDIR=''])
 186 AC_SUBST([CONSUMERD64_LIBDIR])
 187
 188 AC_ARG_WITH([sessiond-bin],
 189         AS_HELP_STRING([--with-sessiond-bin],
 190         [Location of the sessiond executable (including the filename)]),
 191         [SESSIOND_BIN="$withval"],
 192         [SESSIOND_BIN=''])
 193 AC_SUBST([SESSIOND_BIN])
 194
 195 AC_ARG_WITH([lttng-system-rundir],
 196         AS_HELP_STRING([--with-lttng-system-rundir],
 197         [Location of the system directory where the system-wide lttng-sessiond runtime files are kept. The default is "/var/run/lttng".]),
 198         [LTTNG_SYSTEM_RUNDIR="$withval"],
 199         [LTTNG_SYSTEM_RUNDIR="/var/run/lttng"])
 200 AC_SUBST([LTTNG_SYSTEM_RUNDIR])
 201
 202 AC_ARG_ENABLE([test-java-agent-jul],
 203         [AS_HELP_STRING([--enable-test-java-agent-jul],[enable the LTTng UST Java agent JUL tests [default=no]])],
 204         [test_java_agent_jul=$enableval],
 205         [test_java_agent_jul=no]
 206 )
 207
 208 AC_ARG_ENABLE([test-java-agent-log4j],
 209         [AS_HELP_STRING([--enable-test-java-agent-log4j],[enable the LTTng UST Java agent Log4j tests [default=no]])],
 210         [test_java_agent_log4j=$enableval],
 211         [test_java_agent_log4j=no]
 212 )
 213
 214 AC_ARG_ENABLE([test-java-agent-all],
 215         [AS_HELP_STRING([--enable-test-java-agent-all],[enable all the LTTng UST Java agent tests [default=no]])],
 216         [test_java_agent_jul=$enableval
 217          test_java_agent_log4j=$enableval],
 218         [:]
 219 )
 220
 221 AC_DEFINE_UNQUOTED([CONFIG_CONSUMERD32_BIN], "$CONSUMERD32_BIN", [Location of the 32-bit consumerd executable.])
 222 AC_DEFINE_UNQUOTED([CONFIG_CONSUMERD64_BIN], "$CONSUMERD64_BIN", [Location of the 64-bit consumerd executable])
 223 AC_DEFINE_UNQUOTED([CONFIG_CONSUMERD32_LIBDIR], "$CONSUMERD32_LIBDIR", [Search for consumerd 32-bit libraries in this location.])
 224 AC_DEFINE_UNQUOTED([CONFIG_CONSUMERD64_LIBDIR], "$CONSUMERD64_LIBDIR", [Search for consumerd 64-bit libraries in this location.])
 225 AC_DEFINE_UNQUOTED([CONFIG_BABELTRACE_BIN], "$BABELTRACE_BIN", [Location of the babeltrace viewer executable.])
 226 AC_DEFINE_UNQUOTED([CONFIG_LTTV_GUI_BIN], "$LTTV_GUI_BIN", [Location of the lttv GUI viewer executable.])
 227 AC_DEFINE_UNQUOTED([CONFIG_SESSIOND_BIN], "$SESSIOND_BIN", [Location of the sessiond executable.])
 228 AC_DEFINE_UNQUOTED([CONFIG_LTTNG_SYSTEM_RUNDIR], ["$LTTNG_SYSTEM_RUNDIR"], [LTTng system runtime directory])
 229
 230 AC_DEFUN([_AC_DEFINE_AND_SUBST], [
 231         AC_DEFINE_UNQUOTED([CONFIG_$1], [$2], [$1])
 232         $1="$2"
 233         AC_SUBST([$1])
 234 ])
 235
 236 AC_DEFUN([_AC_DEFINE_QUOTED_AND_SUBST], [
 237         AC_DEFINE_UNQUOTED([CONFIG_$1], ["$2"], [$1])
 238         $1="$2"
 239         AC_SUBST([$1])
 240 ])
 241
 242 # Default values
 243 m4_define([_DEFAULT_CHANNEL_SUBBUF_SIZE], [4096])
 244 m4_define([_DEFAULT_CHANNEL_SUBBUF_NUM], [4])
 245 m4_define([_DEFAULT_CHANNEL_SWITCH_TIMER], [0])
 246 m4_define([_DEFAULT_CHANNEL_LIVE_TIMER], [0])
 247 m4_define([_DEFAULT_CHANNEL_READ_TIMER], [200000])
 248 m4_define([_DEFAULT_CHANNEL_MONITOR_TIMER], [1000000])
 249 _AC_DEFINE_AND_SUBST([DEFAULT_AGENT_TCP_PORT], [5345])
 250 _AC_DEFINE_AND_SUBST([DEFAULT_APP_SOCKET_RW_TIMEOUT], [5])
 251 _AC_DEFINE_AND_SUBST([DEFAULT_CHANNEL_SUBBUF_SIZE], [_DEFAULT_CHANNEL_SUBBUF_SIZE])
 252 _AC_DEFINE_AND_SUBST([DEFAULT_CHANNEL_TRACEFILE_COUNT], [0])
 253 _AC_DEFINE_AND_SUBST([DEFAULT_CHANNEL_TRACEFILE_SIZE], [0])
 254 _AC_DEFINE_AND_SUBST([DEFAULT_KERNEL_CHANNEL_LIVE_TIMER], [_DEFAULT_CHANNEL_LIVE_TIMER])
 255 _AC_DEFINE_AND_SUBST([DEFAULT_KERNEL_CHANNEL_READ_TIMER], [_DEFAULT_CHANNEL_READ_TIMER])
 256 _AC_DEFINE_AND_SUBST([DEFAULT_KERNEL_CHANNEL_SUBBUF_NUM], [_DEFAULT_CHANNEL_SUBBUF_NUM])
 257 _AC_DEFINE_AND_SUBST([DEFAULT_KERNEL_CHANNEL_SUBBUF_SIZE], [262144])
 258 _AC_DEFINE_AND_SUBST([DEFAULT_KERNEL_CHANNEL_SWITCH_TIMER], [_DEFAULT_CHANNEL_SWITCH_TIMER])
 259 _AC_DEFINE_AND_SUBST([DEFAULT_KERNEL_CHANNEL_MONITOR_TIMER], [_DEFAULT_CHANNEL_MONITOR_TIMER])
 260 _AC_DEFINE_AND_SUBST([DEFAULT_LTTNG_LIVE_TIMER], [1000000])
 261 _AC_DEFINE_AND_SUBST([DEFAULT_METADATA_CACHE_SIZE], [4096])
 262 _AC_DEFINE_AND_SUBST([DEFAULT_METADATA_READ_TIMER], [0])
 263 _AC_DEFINE_AND_SUBST([DEFAULT_METADATA_SUBBUF_NUM], [2])
 264 _AC_DEFINE_AND_SUBST([DEFAULT_METADATA_SUBBUF_SIZE], [4096])
 265 _AC_DEFINE_AND_SUBST([DEFAULT_METADATA_SWITCH_TIMER], [_DEFAULT_CHANNEL_SWITCH_TIMER])
 266 _AC_DEFINE_AND_SUBST([DEFAULT_NETWORK_CONTROL_PORT], [5342])
 267 _AC_DEFINE_AND_SUBST([DEFAULT_NETWORK_DATA_PORT], [5343])
 268 _AC_DEFINE_AND_SUBST([DEFAULT_NETWORK_VIEWER_PORT], [5344])
 269 _AC_DEFINE_AND_SUBST([DEFAULT_UST_PID_CHANNEL_LIVE_TIMER], [_DEFAULT_CHANNEL_LIVE_TIMER])
 270 _AC_DEFINE_AND_SUBST([DEFAULT_UST_PID_CHANNEL_READ_TIMER], [0])
 271 _AC_DEFINE_AND_SUBST([DEFAULT_UST_PID_CHANNEL_SUBBUF_NUM], [_DEFAULT_CHANNEL_SUBBUF_NUM])
 272 _AC_DEFINE_AND_SUBST([DEFAULT_UST_PID_CHANNEL_SUBBUF_SIZE], [_DEFAULT_CHANNEL_SUBBUF_SIZE])
 273 _AC_DEFINE_AND_SUBST([DEFAULT_UST_PID_CHANNEL_SWITCH_TIMER], [_DEFAULT_CHANNEL_SWITCH_TIMER])
 274 _AC_DEFINE_AND_SUBST([DEFAULT_UST_PID_CHANNEL_MONITOR_TIMER], [_DEFAULT_CHANNEL_MONITOR_TIMER])
 275 _AC_DEFINE_AND_SUBST([DEFAULT_UST_UID_CHANNEL_LIVE_TIMER], [_DEFAULT_CHANNEL_LIVE_TIMER])
 276 _AC_DEFINE_AND_SUBST([DEFAULT_UST_UID_CHANNEL_READ_TIMER], [0])
 277 _AC_DEFINE_AND_SUBST([DEFAULT_UST_UID_CHANNEL_SUBBUF_NUM], [_DEFAULT_CHANNEL_SUBBUF_NUM])
 278 _AC_DEFINE_AND_SUBST([DEFAULT_UST_UID_CHANNEL_SUBBUF_SIZE], [131072])
 279 _AC_DEFINE_AND_SUBST([DEFAULT_UST_UID_CHANNEL_SWITCH_TIMER], [_DEFAULT_CHANNEL_SWITCH_TIMER])
 280 _AC_DEFINE_AND_SUBST([DEFAULT_UST_UID_CHANNEL_MONITOR_TIMER], [_DEFAULT_CHANNEL_MONITOR_TIMER])
 281 _AC_DEFINE_QUOTED_AND_SUBST([DEFAULT_AGENT_BIND_ADDRESS], [localhost])
 282 _AC_DEFINE_QUOTED_AND_SUBST([DEFAULT_NETWORK_CONTROL_BIND_ADDRESS], [0.0.0.0])
 283 _AC_DEFINE_QUOTED_AND_SUBST([DEFAULT_NETWORK_DATA_BIND_ADDRESS], [0.0.0.0])
 284 _AC_DEFINE_QUOTED_AND_SUBST([DEFAULT_NETWORK_VIEWER_BIND_ADDRESS], [localhost])
 285
 286 # Command short descriptions
 287 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_ADD_CONTEXT], [Add context fields to a channel])
 288 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_CREATE], [Create a tracing session])
 289 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_DESTROY], [Tear down tracing sessions])
 290 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_DISABLE_CHANNEL], [Disable tracing channels])
 291 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_DISABLE_EVENT], [Disable event rules])
 292 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_ENABLE_CHANNEL], [Create or enable tracing channels])
 293 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_ENABLE_EVENT], [Create or enable event rules])
 294 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_HELP], [Display help information about a command])
 295 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_LIST], [List tracing sessions, domains, channels, and events])
 296 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_LOAD], [Load tracing session configurations])
 297 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_REGENERATE], [Manage an LTTng tracing session's data regeneration])
 298 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_SAVE], [Save tracing session configurations])
 299 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_SET_SESSION], [Set current tracing session])
 300 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_SNAPSHOT], [Snapshot buffers of current tracing session])
 301 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_START], [Start tracing])
 302 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_STATUS], [Get the status of the current tracing session])
 303 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_STOP], [Stop tracing])
 304 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_TRACK], [Track specific system resources])
 305 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_UNTRACK], [Untrack specific system resources])
 306 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_VERSION], [Show version information])
 307 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_VIEW], [Start trace viewer])
 308
 309 if test "x$prefix" = "xNONE"; then
 310         prefix=$ac_default_prefix
 311 fi
 312 CONFDIR=`eval echo $sysconfdir`
 313 AC_SUBST(CONFDIR)
 314 AC_DEFINE_UNQUOTED([CONFIG_LTTNG_SYSTEM_CONFIGDIR],"$CONFDIR", [LTTng system configuration directory.])
 315
 316 AC_DEFINE_DIR([CONFIG_LTTNG_SYSTEM_DATADIR],[datadir], [LTTng system data directory.])
 317
 318 #
 319 # Check for pthread
 320 AC_CHECK_LIB([pthread], [pthread_create], [],
 321         [AC_MSG_ERROR([Cannot find libpthread. Use LDFLAGS=-Ldir to specify its location.])]
 322 )
 323
 324 # Check libpopt
 325 PKG_CHECK_MODULES([POPT], [popt],
 326         [LIBS="$LIBS $POPT_LIBS"],
 327         [
 328                 AC_MSG_WARN([pkg-config was unable to find a valid .pc for libpopt. Set PKG_CONFIG_PATH to specify the pkgconfig configuration file location])
 329                 AC_MSG_WARN([Finding libpopt without pkg-config.])
 330                 AC_CHECK_LIB([popt],
 331                         [poptGetContext],
 332                         [],
 333                         [
 334                                  AC_MSG_ERROR([Cannot find libpopt. Either set PKG_CONFIG_PATH to the configuration file location or use LDFLAGS=-Ldir to specify the library location])
 335                         ]
 336                 )
 337         ]
 338 )
 339
 340 PKG_CHECK_MODULES([libxml2], [libxml-2.0 >= 2.7.6])
 341
 342 # Check for uuid in system libs
 343 AC_CHECK_FUNCS([uuid_generate],
 344 [
 345         AC_DEFINE_UNQUOTED([LTTNG_HAVE_LIBUUID], 1, [Has libuuid support.])
 346         link_with_libuuid=no
 347 ],
 348 [
 349 # First, check the pkg-config module is available, otherwise explicitly check
 350 # for libuuid, or uuid support in the C-library.
 351 PKG_CHECK_MODULES([UUID], [uuid],
 352 [
 353         LIBS="$LIBS $UUID_LIBS"
 354         AC_DEFINE_UNQUOTED([LTTNG_HAVE_LIBUUID], 1, [Has libuuid support.])
 355         link_with_libuuid=yes
 356 ],
 357 [
 358         # Check for libuuid
 359         AC_CHECK_LIB([uuid],
 360                 [uuid_generate],
 361                 [
 362                         AC_DEFINE_UNQUOTED([LTTNG_HAVE_LIBUUID], 1, [Has libuuid support.])
 363                         link_with_libuuid=yes
 364                 ],
 365                 [
 366                         # libuuid not found, check for uuid_create in libc.
 367                         AC_CHECK_LIB([c],
 368                                 [uuid_create],
 369                                 [
 370                                         AC_DEFINE_UNQUOTED([LTTNG_HAVE_LIBC_UUID], 1, [Has libc uuid support.])
 371                                         link_with_libc_uuid=yes
 372                                 ],
 373                                 [
 374                                         AC_MSG_ERROR([Cannot find libuuid uuid_generate nor libc uuid_create. Either set PKG_CONFIG_PATH to the configuration file location or use LDFLAGS=-Ldir to specify the library location])
 375                                 ]
 376                         )
 377                 ]
 378         )
 379 ])
 380 ])
 381
 382 AM_CONDITIONAL([LTTNG_BUILD_WITH_LIBUUID], [test "x$link_with_libuuid" = "xyes"])
 383 AM_CONDITIONAL([LTTNG_BUILD_WITH_LIBC_UUID], [test "x$link_with_libc_uuid" = "xyes"])
 384
 385 AC_CHECK_FUNC([clock_gettime], [AC_DEFINE_UNQUOTED([LTTNG_HAVE_CLOCK_GETTIME], 1, [Has clock_gettime() support.])])
 386
 387 # URCU library version needed or newer
 388 m4_define([WRONG_LIBURCU_MSG], [Userspace RCU (liburcu) >= 0.8.0 is needed])
 389
 390 # Check liburcu needed function calls
 391 AC_CHECK_DECL([cds_list_add], [],
 392         [AC_MSG_ERROR([WRONG_LIBURCU_MSG])], [[#include <urcu/list.h>]])
 393 AC_CHECK_DECL([cds_wfcq_init], [],
 394         [AC_MSG_ERROR([WRONG_LIBURCU_MSG])], [[#include <urcu/wfcqueue.h>]])
 395 AC_CHECK_DECL([cds_wfcq_dequeue_blocking], [],
 396         [AC_MSG_ERROR([WRONG_LIBURCU_MSG])], [[#include <urcu/wfcqueue.h>]])
 397 AC_CHECK_DECL([futex_async], [],
 398         [AC_MSG_ERROR([WRONG_LIBURCU_MSG])], [[#include <urcu/futex.h>]])
 399 AC_CHECK_DECL([rcu_thread_offline], [],
 400         [AC_MSG_ERROR([WRONG_LIBURCU_MSG])], [[#include <urcu.h>]])
 401 AC_CHECK_DECL([rcu_thread_online], [],
 402         [AC_MSG_ERROR([WRONG_LIBURCU_MSG])], [[#include <urcu.h>]])
 403 AC_CHECK_DECL([caa_likely], [],
 404         [AC_MSG_ERROR([WRONG_LIBURCU_MSG])], [[#include <urcu.h>]])
 405 AC_CHECK_LIB([urcu-cds], [_cds_lfht_new], [],
 406         [AC_MSG_ERROR([WRONG_LIBURCU_MSG])])
 407
 408 #Function added in urcu 0.7.0
 409 AC_CHECK_DECL([cmm_smp_mb__before_uatomic_or], [],
 410         [AC_MSG_ERROR([WRONG_LIBURCU_MSG])], [[#include <urcu.h>]]
 411 )
 412
 413 # Check kmod library
 414 AC_ARG_WITH(kmod-prefix,
 415   AS_HELP_STRING([--with-kmod-prefix=PATH],
 416                 [Specify the installation prefix of the kmod library.
 417                 Headers must be in PATH/include; libraries in PATH/lib.]),
 418                 [
 419                         CPPFLAGS="$CPPFLAGS -I${withval}/include"
 420                         LDFLAGS="$LDFLAGS -L${withval}/lib64 -L${withval}/lib"
 421                 ])
 422
 423 AC_ARG_ENABLE(kmod,
 424         AS_HELP_STRING([--disable-kmod],[build without kmod support]),
 425         kmod_support=$enableval, kmod_support=yes)
 426
 427 AS_IF([test "x$kmod_support" = "xyes"], [
 428         AC_CHECK_LIB([kmod], [kmod_module_probe_insert_module],
 429                 [
 430                         AC_DEFINE([HAVE_KMOD], [1], [has kmod support])
 431                         LIBS="$LIBS -lkmod"
 432                         kmod_found=yes
 433                 ],
 434                 kmod_found=no
 435         )
 436 ])
 437 AM_CONDITIONAL([HAVE_KMOD], [test "x$kmod_found" = xyes])
 438
 439 AC_ARG_WITH(lttng-ust-prefix,
 440   AS_HELP_STRING([--with-lttng-ust-prefix=PATH],
 441                  [Specify the installation prefix of the lttng-ust library.
 442                   Headers must be in PATH/include; libraries in PATH/lib.]),
 443                   [
 444                     CPPFLAGS="$CPPFLAGS -I${withval}/include"
 445                     LDFLAGS="$LDFLAGS -L${withval}/lib64 -L${withval}/lib"
 446                   ])
 447
 448 # Check liblttng-ust-ctl library
 449 AC_ARG_WITH(lttng-ust,
 450         AS_HELP_STRING([--without-lttng-ust],[build without LTTng-UST (Userspace Tracing) support]),
 451         lttng_ust_support=$withval, lttng_ust_support=yes)
 452
 453 AS_IF([test "x$lttng_ust_support" = "xyes"], [
 454         AC_CHECK_LIB([lttng-ust-ctl], [ustctl_recv_channel_from_consumer],
 455                 [
 456                         AC_DEFINE([HAVE_LIBLTTNG_UST_CTL], [1], [has LTTng-UST control support])
 457                         lttng_ust_ctl_found=yes
 458                 ],
 459                 [AC_MSG_ERROR([Cannot find LTTng-UST >= 2.2.x. Use --with-lttng-ust-prefix=PREFIX to specify its location, or specify --without-lttng-ust to build lttng-tools without LTTng-UST support.])],
 460                 [-lurcu-common -lurcu-bp -lurcu-cds -lrt -ldl]
 461         )
 462 ])
 463 AM_CONDITIONAL([HAVE_LIBLTTNG_UST_CTL], [test "x$lttng_ust_ctl_found" = xyes])
 464 AC_CHECK_FUNCS([sched_getcpu sysconf sync_file_range])
 465
 466 # check for dlopen
 467 AC_CHECK_LIB([dl], [dlopen],
 468 [
 469         have_libdl=yes
 470 ],
 471 [
 472         #libdl not found, check for dlopen in libc.
 473         AC_CHECK_LIB([c], [dlopen],
 474         [
 475                 have_libc_dl=yes
 476         ],
 477         [
 478                 AC_MSG_ERROR([Cannot find dlopen in libdl nor libc. Use [LDFLAGS]=-Ldir to specify their location.])
 479         ])
 480 ])
 481 AM_CONDITIONAL([LTTNG_TOOLS_BUILD_WITH_LIBDL], [test "x$have_libdl" = "xyes"])
 482 AM_CONDITIONAL([LTTNG_TOOLS_BUILD_WITH_LIBC_DL], [test "x$have_libc_dl" = "xyes"])
 483
 484 # Check for fmemopen
 485 AC_CHECK_LIB([c], [fmemopen],
 486 [
 487         AC_DEFINE_UNQUOTED([LTTNG_HAVE_FMEMOPEN], 1, [Has fmemopen support.])
 488 ]
 489 )
 490
 491 # Check for open_memstream
 492 AC_CHECK_LIB([c], [open_memstream],
 493 [
 494         AC_DEFINE_UNQUOTED([LTTNG_HAVE_OPEN_MEMSTREAM], 1, [Has open_memstream support.])
 495 ]
 496 )
 497
 498 # check for libpfm
 499 AC_CHECK_LIB([pfm], [pfm_initialize],
 500              [
 501               have_libpfm=yes
 502               ])
 503 AM_CONDITIONAL([LTTNG_TOOLS_BUILD_WITH_LIBPFM], [test "x$have_libpfm" = "xyes"])
 504
 505 AC_ARG_ENABLE([git-version],
 506               [AC_HELP_STRING([--disable-git-version],
 507                               [Do not use the git version for the build])],
 508               [have_git_version=$enableval], [have_git_version=yes]
 509 )
 510
 511 AM_CONDITIONAL([LTTNG_TOOLS_BUILD_GIT_SOURCE],
 512         [test "x${have_git_version}" = "xyes"])
 513
 514 # For Python
 515 # SWIG version needed or newer:
 516 swig_version=2.0.0
 517
 518 AC_ARG_ENABLE([python-bindings],
 519               [AC_HELP_STRING([--enable-python-bindings],
 520                               [compile Python bindings])],
 521               [enable_python_binding=$enableval], [enable_python_binding=no])
 522
 523 AM_CONDITIONAL([PYTHON_BINDING], [test "x$enable_python_binding" = xyes])
 524
 525 if test "x$enable_python_binding" = xyes; then
 526   AX_PKG_SWIG($swig_version, [], [ AC_MSG_ERROR([SWIG $swig_version or newer is needed]) ])
 527   AS_IF([test x$enable_shared = xno], [ AC_MSG_ERROR([Python bindings require shared libraries.]) ])
 528   AM_PATH_PYTHON([3.0])
 529
 530   AC_ARG_VAR([PYTHON_INCLUDE], [Include flags for python, bypassing python-config])
 531   AC_ARG_VAR([PYTHON_CONFIG], [Path to python-config])
 532   AS_IF([test -z "$PYTHON_INCLUDE"], [
 533     AS_IF([test -z "$PYTHON_CONFIG"], [
 534       AC_PATH_PROGS([PYTHON_CONFIG],
 535                     [python$PYTHON_VERSION-config python-config],
 536                     [no],
 537                     [`dirname $PYTHON`])
 538       AS_IF([test "$PYTHON_CONFIG" = no], [AC_MSG_ERROR([cannot find python-config for $PYTHON. Do you have python-dev installed?])])
 539     ])
 540     AC_MSG_CHECKING([python include flags])
 541     PYTHON_INCLUDE=`$PYTHON_CONFIG --includes`
 542     AC_MSG_RESULT([$PYTHON_INCLUDE])
 543   ])
 544
 545 else
 546     AC_MSG_NOTICE([You may configure with --enable-python-bindings ]dnl
 547 [if you want Python bindings.])
 548
 549 fi
 550
 551 # Epoll check. If not present, the build will fallback on poll() API
 552 AX_HAVE_EPOLL(
 553         [AX_CONFIG_FEATURE_ENABLE(epoll)],
 554         [AX_CONFIG_FEATURE_DISABLE(epoll)]
 555 )
 556 AX_CONFIG_FEATURE(
 557         [epoll], [This platform supports epoll(7)],
 558         [HAVE_EPOLL], [This platform supports epoll(7).],
 559         [enable_epoll="yes"], [enable_epoll="no"]
 560 )
 561 AM_CONDITIONAL([COMPAT_EPOLL], [ test "$enable_epoll" = "yes" ])
 562
 563 AM_CONDITIONAL([TEST_JAVA_JUL_AGENT], [test "x$test_java_agent_jul" = "xyes"])
 564 AM_CONDITIONAL([TEST_JAVA_LOG4J_AGENT], [test "x$test_java_agent_log4j" = "xyes"])
 565
 566 if test "x$test_java_agent_jul" = "xyes" || test "x$test_java_agent_log4j" = "xyes"; then
 567         AX_JAVA_OPTIONS
 568         AX_PROG_JAVAC
 569         AX_PROG_JAVA
 570         AX_PROG_JAR
 571
 572         AX_CHECK_CLASSPATH
 573
 574         # Check for Java UST agent common class first
 575         AX_CHECK_CLASS(org.lttng.ust.agent.AbstractLttngAgent)
 576         if test "x$ac_cv_class_org_lttng_ust_agent_AbstractLttngAgent" = "xno"; then
 577                 AC_MSG_ERROR([The UST Java agent common class was not found. Please specify the location of the jar via the Java CLASSPATH e.g: export CLASSPATH="/path/to/lttng-ust-agent-common.jar"])
 578         fi
 579
 580         if test "x$test_java_agent_jul" = "xyes"; then
 581                 # Check for JUL agent class
 582                 AX_CHECK_CLASS(org.lttng.ust.agent.jul.LttngLogHandler)
 583                 if test "x$ac_cv_class_org_lttng_ust_agent_jul_LttngLogHandler" = "xno"; then
 584                         AC_MSG_ERROR([The UST Java agent JUL class was not found. Please specify the location of the jar via the Java CLASSPATH e.g: export CLASSPATH="/path/to/lttng-ust-agent-jul.jar"])
 585                 fi
 586         fi
 587
 588         if test "x$test_java_agent_log4j" = "xyes"; then
 589                 # Check for Log4j agent class
 590                 AX_CHECK_CLASS(org.lttng.ust.agent.log4j.LttngLogAppender)
 591                 if test "x$ac_cv_class_org_lttng_ust_agent_log4j_LttngLogAppender" = "xno"; then
 592                         AC_MSG_ERROR([The UST Java agent Log4j class was not found. Please specify the location of the jar via the Java CLASSPATH e.g: export CLASSPATH="/path/to/lttng-ust-agent-log4j.jar"])
 593                 fi
 594
 595                 # Check for Log4j class
 596                 AX_CHECK_CLASS(org.apache.log4j.Logger)
 597                 if test "x$ac_cv_class_org_apache_log4j_Logger" = "xno"; then
 598                         AC_MSG_ERROR([The Log4j class was not found. Please specify the location of the jar via the Java CLASSPATH e.g: export CLASSPATH="/path/to/log4j.jar"])
 599                 fi
 600         fi
 601 fi
 602
 603 # set $IN_GIT_REPO if we're in the Git repository; the `bootstrap` file
 604 # is not distributed in tarballs
 605 AS_IF([test -f "$srcdir/bootstrap"], [in_git_repo=yes], [in_git_repo=no])
 606 AM_CONDITIONAL([IN_GIT_REPO], [test "x$in_git_repo" = "xyes"])
 607
 608 # enable building man pages (user's intention)
 609 AC_ARG_ENABLE(
 610         man-pages,
 611         AS_HELP_STRING(
 612                 [--disable-man-pages],
 613                 [Do not build and install man pages (already built in a distributed tarball)]
 614         ),
 615         [man_pages_opt=$enableval],
 616         [man_pages_opt=yes]
 617 )
 618
 619 # check for asciidoc and xmlto if we enabled building the man pages
 620 have_asciidoc_xmlto=no
 621 warn_prebuilt_man_pages=no
 622
 623 AS_IF([test "x$man_pages_opt" = "xyes"], [
 624         AC_PATH_PROG([ASCIIDOC], [asciidoc], [no])
 625         AC_PATH_PROG([XMLTO], [xmlto], [no])
 626
 627         AS_IF([test "x$ASCIIDOC" = "xno" || test "x$XMLTO" = "xno"], [
 628                 AS_IF([test "x$in_git_repo" = "xyes"], [
 629                         # this is an error because we're in the Git repo, which
 630                         # means the man pages are not already generated for us,
 631                         # thus asciidoc/xmlto are required because we were asked
 632                         # to build the man pages
 633                         AC_MSG_ERROR([
 634 You need asciidoc and xmlto to build the LTTng-tools man pages. Use
 635 --disable-man-pages to disable building the man pages, in which case
 636 they will not be installed.
 637                         ])
 638                 ], [
 639                         # only warn here: since we're in the tarball, the man
 640                         # pages should already be generated at this point, thus
 641                         # asciidoc/xmlto are not strictly required
 642                         warn_prebuilt_man_pages=yes
 643                 ])
 644         ], [
 645                 have_asciidoc_xmlto=yes
 646         ])
 647 ])
 648
 649 # export man page build condition: build the man pages if the user
 650 # asked for it, and if the tools are available
 651 AM_CONDITIONAL([MAN_PAGES_OPT], [test "x$man_pages_opt" != "xno"])
 652 AM_CONDITIONAL([HAVE_ASCIIDOC_XMLTO], [test "x$have_asciidoc_xmlto" = "xyes"])
 653
 654 AC_DEFINE_UNQUOTED([MANPATH], ["`eval eval echo $mandir`"], [Path to man pages.])
 655
 656 # Python agent test
 657 UST_PYTHON_AGENT="lttngust"
 658
 659 AC_ARG_ENABLE(test-python2-agent,
 660         AS_HELP_STRING([--enable-test-python2-agent],
 661                 [enable tests for python2 agent. Python2 interpreter path can be overridden by setting the PYTHON2 environment variable. Default: Autodetect]
 662         ),[:],[test_python2_agent_autodetect=yes]
 663 )
 664
 665 AC_ARG_ENABLE(test-python3-agent,
 666         AS_HELP_STRING([--enable-test-python3-agent],
 667                 [enable tests for python3 agent. Python3 interpreter path can be overridden by setting the PYTHON3 environment variable. Default: Autodetect]
 668         ),[:],[test_python3_agent_autodetect=yes]
 669 )
 670
 671 AC_ARG_ENABLE(test-python-agent-all,
 672         AS_HELP_STRING([--enable-test-python-agent-all],
 673                 [enable test for all python{2/3} agent.]
 674         ),
 675 )
 676
 677 AS_IF([test ! -z "$enable_test_python_agent_all"], [
 678        unset test_python2_agent_autodetect
 679        unset test_python3_agent_autodetect
 680 ])
 681
 682 AS_IF([test "x$enable_test_python_agent_all" = "xyes"], [
 683        enable_test_python2_agent=yes
 684        enable_test_python3_agent=yes
 685 ])
 686
 687 AS_IF([test "x$enable_test_python_agent_all" = "xno"], [
 688        enable_test_python2_agent=no
 689        enable_test_python3_agent=no
 690 ])
 691
 692
 693 AS_IF([test "x$enable_test_python2_agent" = "xyes" -o "x$test_python2_agent_autodetect" = "xyes" ], [
 694         AS_IF([test -z "$PYTHON2"], [
 695                         PYTHON2=python2
 696                 ], [
 697                         AC_MSG_WARN([Using user-defined PYTHON2 ($PYTHON2) for lttng-ust python2 agent check])
 698         ])
 699
 700         AC_PATH_PROG([PYTHON2_BIN],[$PYTHON2])
 701         AS_IF([test -z "$PYTHON2_BIN"], [
 702                 AS_IF([test -z "$test_python2_agent_autodetect"],[
 703                         AC_MSG_ERROR([No python2 interpreter found. PYTHON2 can be set to override default interpreter path])
 704                 ])
 705         ], [
 706                 AC_MSG_CHECKING([for python2 lttng-ust agent])
 707                 AS_IF([$PYTHON2_BIN -c "import $UST_PYTHON_AGENT" 2>/dev/null], [
 708                         PYTHON2_AGENT=$PYTHON2_BIN
 709                         AC_MSG_RESULT([yes])
 710                         RUN_PYTHON_AGENT_TEST=yes
 711                 ], [
 712                         AC_MSG_RESULT([no])
 713                         AS_IF([test -z "$test_python2_agent_autodetect"],[
 714                                 AC_MSG_ERROR([No python2 agent found. The path to the agent can be specified by setting the PYTHONPATH environment variable.])
 715                         ])
 716                 ])
 717
 718         ])
 719
 720 ])
 721
 722 AS_IF([test "x$enable_test_python3_agent" = "xyes" -o "x$test_python3_agent_autodetect" = "xyes" ], [
 723         AS_IF([test -z "$PYTHON3"], [
 724                 PYTHON3=python3
 725         ], [
 726                 AC_MSG_WARN([Using user-defined PYTHON3 ($PYTHON3) for lttng-ust python3 agent check])
 727         ])
 728
 729         AC_PATH_PROG([PYTHON3_BIN],[$PYTHON3])
 730         AS_IF([test -z "$PYTHON3_BIN"], [
 731                 AS_IF([test -z "$test_python3_agent_autodetect"],[
 732                         AC_MSG_ERROR([No python3 interpreter found. PYTHON3 can be set to override default interpreter path])
 733                 ])
 734         ], [
 735                 AC_MSG_CHECKING([for python3 lttng-ust agent])
 736                 AS_IF([$PYTHON3_BIN -c "import $UST_PYTHON_AGENT" 2>/dev/null], [
 737                         PYTHON3_AGENT=$PYTHON3_BIN
 738                         AC_MSG_RESULT([yes])
 739                         RUN_PYTHON_AGENT_TEST=yes
 740                 ], [
 741                         AC_MSG_RESULT([no])
 742                         AS_IF([test -z "$test_python3_agent_autodetect"],[
 743                                 AC_MSG_ERROR([No python3 agent found. The path to the agent can be specified by setting the PYTHONPATH environment variable.])
 744                         ])
 745                 ])
 746
 747         ])
 748 ])
 749 AC_SUBST([RUN_PYTHON_AGENT_TEST])
 750 AC_SUBST([PYTHON2_AGENT])
 751 AC_SUBST([PYTHON3_AGENT])
 752
 753 # Arguments for binaries build exclusion
 754 AC_ARG_ENABLE([bin-lttng], AS_HELP_STRING([--disable-bin-lttng],[Disable the build of lttng binaries]))
 755 AC_ARG_ENABLE([bin-lttng-consumerd], AS_HELP_STRING([--disable-bin-lttng-consumerd],
 756               [Disable the build of lttng-consumerd binaries]))
 757 AC_ARG_ENABLE([bin-lttng-crash], AS_HELP_STRING([--disable-bin-lttng-crash],[Disable the build of lttng-crash binaries]))
 758 AC_ARG_ENABLE([bin-lttng-relayd], AS_HELP_STRING([--disable-bin-lttng-relayd],
 759               [Disable the build of lttng-relayd binaries]))
 760 AC_ARG_ENABLE([bin-lttng-sessiond], AS_HELP_STRING([--disable-bin-lttng-sessiond],
 761               [Disable the build of lttng-sessiond binaries]))
 762 AC_ARG_ENABLE([extras], AS_HELP_STRING([--disable-extras],
 763               [Disable the build of the extra components]))
 764
 765
 766 # Always build libconfig since it a dependency of libcommon
 767 build_lib_config=yes
 768
 769 build_lib_compat=no
 770 build_lib_consumer=no
 771 build_lib_hashtable=no
 772 build_lib_health=no
 773 build_lib_index=no
 774 build_lib_kernel_consumer=no
 775 build_lib_kernel_ctl=no
 776 build_lib_lttng_ctl=no
 777 build_lib_relayd=no
 778 build_lib_sessiond_comm=no
 779 build_lib_testpoint=no
 780 build_lib_ust_consumer=no
 781
 782 # There is an overlap for enabled dependencies, but this makes everything
 783 # simpler. libcommon and libconfig are always compiled so they are not repeated
 784 # here.
 785
 786 # Enable binary dependencies.
 787 AS_IF([test x$enable_bin_lttng != xno],
 788       [
 789        build_lib_lttng_ctl=yes
 790       ]
 791 )
 792
 793 AS_IF([test x$enable_bin_lttng_consumerd != xno],
 794       [
 795        build_lib_consumer=yes
 796        build_lib_sessiond_comm=yes
 797        build_lib_index=yes
 798        build_lib_health=yes
 799        build_lib_testpoint=yes
 800       ]
 801 )
 802
 803 AS_IF([test x$enable_bin_lttng_crash != xno],
 804       # Do nothing since libconfig and libcommon are built by default.
 805       []
 806 )
 807
 808 AS_IF([test x$enable_bin_lttng_relayd != xno],
 809       [
 810        build_lib_lttng_ctl=yes
 811        build_lib_sessiond_comm=yes
 812        build_lib_hashtable=yes
 813        build_lib_compat=yes
 814        build_lib_index=yes
 815        build_lib_health=yes
 816        build_lib_testpoint=yes
 817       ]
 818 )
 819 AS_IF([test x$enable_bin_lttng_sessiond != xno],
 820       [
 821        build_lib_lttng_ctl=yes
 822        build_lib_sessiond_comm=yes
 823        build_lib_kernel_ctl=yes
 824        build_lib_hashtable=yes
 825        build_lib_compat=yes
 826        build_lib_relayd=yes
 827        build_lib_testpoint=yes
 828        build_lib_health=yes
 829        build_lib_health=yes
 830       ]
 831 )
 832
 833 # Libraries dependencies enabling
 834 AS_IF([test x$build_lib_lttng_ctl = xyes],
 835       [
 836        build_lib_sessiond_comm=yes
 837        build_lib_hashtable=yes
 838       ]
 839 )
 840
 841 AS_IF([test x$build_lib_consumer = xyes],
 842       [
 843        build_lib_sessiond_comm=yes
 844        build_lib_kernel_consumer=yes
 845        build_lib_hashtable=yes
 846        build_lib_compat=yes
 847        build_lib_relayd=yes
 848        AS_IF([test x$lttng_ust_ctl_found = xyes],[build_lib_ust_consumer=yes])
 849       ]
 850 )
 851
 852 AS_IF([test x$build_lib_kernel_consumer = xyes],
 853       [
 854        build_lib_kernel_ctl=yes
 855        build_lib_relayd=yes
 856       ]
 857 )
 858
 859 AS_IF([test x$build_lib_relayd = xyes],
 860       [
 861        build_lib_sessiond_comm=yes
 862       ]
 863 )
 864
 865
 866 # Export binaries build conditions.
 867 AM_CONDITIONAL([BUILD_BIN_LTTNG], [test x$enable_bin_lttng != xno])
 868 AM_CONDITIONAL([BUILD_BIN_LTTNG_CONSUMERD], [test x$enable_bin_lttng_consumerd != xno])
 869 AM_CONDITIONAL([BUILD_BIN_LTTNG_CRASH], [test x$enable_bin_lttng_crash != xno])
 870 AM_CONDITIONAL([BUILD_BIN_LTTNG_RELAYD], [test x$enable_bin_lttng_relayd != xno])
 871 AM_CONDITIONAL([BUILD_BIN_LTTNG_SESSIOND], [test x$enable_bin_lttng_sessiond != xno])
 872
 873 # Export the tests and extras build conditions.
 874 AS_IF([\
 875 test "x$enable_bin_lttng" != "xno" && \
 876 test "x$enable_bin_lttng_consumerd" != "xno" && \
 877 test "x$enable_bin_lttng_crash" != "xno" && \
 878 test "x$enable_bin_lttng_relayd" != "xno" && \
 879 test "x$enable_bin_lttng_sessiond" != "xno"],
 880 [build_tests=yes],
 881 [build_tests=no]
 882 )
 883
 884 AM_CONDITIONAL([BUILD_TESTS], [test x$build_tests = xyes])
 885 AM_CONDITIONAL([BUILD_EXTRAS], [test x$enable_extras != xno])
 886
 887 # Export libraries build conditions.
 888 AM_CONDITIONAL([BUILD_LIB_COMPAT], [test x$build_lib_compat = xyes])
 889 AM_CONDITIONAL([BUILD_LIB_CONFIG], [test x$build_lib_config = xyes])
 890 AM_CONDITIONAL([BUILD_LIB_CONSUMER], [test x$build_lib_consumer = xyes])
 891 AM_CONDITIONAL([BUILD_LIB_HASHTABLE], [test x$build_lib_hashtable = xyes])
 892 AM_CONDITIONAL([BUILD_LIB_HEALTH], [test x$build_lib_health = xyes])
 893 AM_CONDITIONAL([BUILD_LIB_INDEX], [test x$build_lib_index = xyes])
 894 AM_CONDITIONAL([BUILD_LIB_KERNEL_CONSUMER], [test x$build_lib_kernel_consumer = xyes])
 895 AM_CONDITIONAL([BUILD_LIB_KERNEL_CTL], [test x$build_lib_kernel_ctl = xyes])
 896 AM_CONDITIONAL([BUILD_LIB_LTTNG_CTL], [test x$build_lib_lttng_ctl = xyes])
 897 AM_CONDITIONAL([BUILD_LIB_RELAYD], [test x$build_lib_relayd = xyes])
 898 AM_CONDITIONAL([BUILD_LIB_SESSIOND_COMM], [test x$build_lib_sessiond_comm = xyes])
 899 AM_CONDITIONAL([BUILD_LIB_TESTPOINT], [test x$build_lib_testpoint = xyes])
 900 AM_CONDITIONAL([BUILD_LIB_UST_CONSUMER], [test x$build_lib_ust_consumer = xyes])
 901
 902 # check for pgrep
 903 AC_PATH_PROG([PGREP], [pgrep], [no])
 904 AM_CONDITIONAL([HAS_PGREP], [test "x$PGREP" != "xno"])
 905
 906 # check for bison
 907 have_bison=yes
 908
 909 AS_IF([test "x$(basename "$YACC")" != "xbison -y"], [have_bison=no])
 910 AC_PATH_PROG([BISON], [bison])
 911 AX_PROG_BISON_VERSION([2.4], [], [have_bison=no])
 912
 913 AS_IF([test "x$have_bison" = "xno"], [
 914         AS_IF([test "x$in_git_repo" = "xyes"], [
 915                 AC_MSG_ERROR([Bison >= 2.4 is required when building from the Git repository.])
 916         ], [
 917                 AC_MSG_WARN([
 918 Missing Bison >= 2.4. Note that the parser files are already built in
 919 this distribution tarball, so Bison is only needed if you intend to
 920 modify their sources.
 921                 ])
 922         ])
 923 ])
 924
 925 # export bison condition
 926 AM_CONDITIONAL([HAVE_BISON], [test "x$have_bison" = "xyes"])
 927
 928 # check for flex
 929 have_flex=yes
 930
 931 AS_IF([test "x$LEX" != "xflex"], [have_flex=no])
 932 AC_PATH_PROG([FLEX], [flex])
 933 AX_PROG_FLEX_VERSION([2.5.35], [], [have_flex=no])
 934
 935 AS_IF([test "x$have_flex" = "xno"], [
 936         AS_IF([test "x$in_git_repo" = "xyes"], [
 937                 AC_MSG_ERROR([Flex >= 2.5.35 is required when building from the Git repository.])
 938         ], [
 939                 AC_MSG_WARN([
 940 Missing Flex >= 2.5.35. Note that the lexer files are already built in
 941 this distribution tarball, so Flex is only needed if you intend to
 942 modify their sources.
 943                 ])
 944         ])
 945 ])
 946
 947 # export flex condition
 948 AM_CONDITIONAL([HAVE_FLEX], [test "x$have_flex" = "xyes"])
 949
 950 CFLAGS="-Wall $CFLAGS -g -fno-strict-aliasing"
 951
 952 DEFAULT_INCLUDES="-I\$(top_srcdir) -I\$(top_builddir) -I\$(top_builddir)/src -I\$(top_builddir)/include -include config.h"
 953
 954 lttngincludedir="${includedir}/lttng"
 955 AC_SUBST(lttngincludedir)
 956
 957 lttngactionincludedir="${includedir}/lttng/action"
 958 AC_SUBST(lttngactionincludedir)
 959
 960 lttngconditionincludedir="${includedir}/lttng/condition"
 961 AC_SUBST(lttngconditionincludedir)
 962
 963 lttngnotificationincludedir="${includedir}/lttng/notification"
 964 AC_SUBST(lttngnotificationincludedir)
 965
 966 lttngtriggerincludedir="${includedir}/lttng/trigger"
 967 AC_SUBST(lttngtriggerincludedir)
 968
 969 AC_SUBST(DEFAULT_INCLUDES)
 970
 971 lttnglibexecdir="${libdir}/lttng/libexec"
 972 AC_SUBST(lttnglibexecdir)
 973
 974 AC_CONFIG_FILES([
 975         Makefile
 976         doc/Makefile
 977         doc/man/Makefile
 978         doc/man/asciidoc-attrs.conf
 979         include/Makefile
 980         extras/Makefile
 981         extras/bindings/Makefile
 982         extras/bindings/swig/Makefile
 983         extras/bindings/swig/python/Makefile
 984         extras/core-handler/Makefile
 985         src/Makefile
 986         src/common/Makefile
 987         src/common/kernel-ctl/Makefile
 988         src/common/kernel-consumer/Makefile
 989         src/common/consumer/Makefile
 990         src/common/ust-consumer/Makefile
 991         src/common/hashtable/Makefile
 992         src/common/sessiond-comm/Makefile
 993         src/common/compat/Makefile
 994         src/common/relayd/Makefile
 995         src/common/testpoint/Makefile
 996         src/common/index/Makefile
 997         src/common/health/Makefile
 998         src/common/config/Makefile
 999         src/lib/Makefile
1000         src/lib/lttng-ctl/Makefile
1001         src/lib/lttng-ctl/filter/Makefile
1002         src/lib/lttng-ctl/lttng-ctl.pc
1003         src/bin/Makefile
1004         src/bin/lttng-consumerd/Makefile
1005         src/bin/lttng-sessiond/Makefile
1006         src/bin/lttng-relayd/Makefile
1007         src/bin/lttng/Makefile
1008         src/bin/lttng-crash/Makefile
1009         tests/Makefile
1010         tests/destructive/Makefile
1011         tests/regression/Makefile
1012         tests/regression/kernel/Makefile
1013         tests/regression/tools/Makefile
1014         tests/regression/tools/streaming/Makefile
1015         tests/regression/tools/filtering/Makefile
1016         tests/regression/tools/health/Makefile
1017         tests/regression/tools/tracefile-limits/Makefile
1018         tests/regression/tools/snapshots/Makefile
1019         tests/regression/tools/live/Makefile
1020         tests/regression/tools/exclusion/Makefile
1021         tests/regression/tools/save-load/Makefile
1022         tests/regression/tools/save-load/configuration/Makefile
1023         tests/regression/tools/mi/Makefile
1024         tests/regression/tools/wildcard/Makefile
1025         tests/regression/tools/crash/Makefile
1026         tests/regression/tools/regen-metadata/Makefile
1027         tests/regression/tools/regen-statedump/Makefile
1028         tests/regression/ust/Makefile
1029         tests/regression/ust/nprocesses/Makefile
1030         tests/regression/ust/high-throughput/Makefile
1031         tests/regression/ust/low-throughput/Makefile
1032         tests/regression/ust/before-after/Makefile
1033         tests/regression/ust/buffers-pid/Makefile
1034         tests/regression/ust/periodical-metadata-flush/Makefile
1035         tests/regression/ust/multi-session/Makefile
1036         tests/regression/ust/overlap/Makefile
1037         tests/regression/ust/overlap/demo/Makefile
1038         tests/regression/ust/linking/Makefile
1039         tests/regression/ust/daemon/Makefile
1040         tests/regression/ust/exit-fast/Makefile
1041         tests/regression/ust/fork/Makefile
1042         tests/regression/ust/libc-wrapper/Makefile
1043         tests/regression/ust/baddr-statedump/Makefile
1044         tests/regression/ust/ust-dl/Makefile
1045         tests/regression/ust/java-jul/Makefile
1046         tests/regression/ust/java-log4j/Makefile
1047         tests/regression/ust/python-logging/Makefile
1048         tests/regression/ust/getcpu-override/Makefile
1049         tests/regression/ust/clock-override/Makefile
1050         tests/regression/ust/type-declarations/Makefile
1051         tests/regression/ust/rotation-destroy-flush/Makefile
1052         tests/regression/ust/blocking/Makefile
1053         tests/stress/Makefile
1054         tests/unit/Makefile
1055         tests/unit/ini_config/Makefile
1056         tests/perf/Makefile
1057         tests/utils/Makefile
1058         tests/utils/tap/Makefile
1059         tests/utils/testapp/Makefile
1060         tests/utils/testapp/gen-ust-events/Makefile
1061         tests/utils/testapp/gen-ust-nevents/Makefile
1062         tests/utils/testapp/gen-ust-tracef/Makefile
1063 ])
1064
1065 # Inject variable into python test script.
1066 AC_CONFIG_FILES([tests/regression/ust/python-logging/test_python_logging],[chmod +x tests/regression/ust/python-logging/test_python_logging])
1067 # Inject LTTNG_TOOLS_BUILD_WITH_LIBPFM variable in test script.
1068 AC_CONFIG_FILES([tests/perf/test_perf_raw],[chmod +x tests/perf/test_perf_raw])
1069
1070 AC_OUTPUT
1071
1072 #
1073 # Mini-report on what will be built.
1074 #
1075
1076 PPRINT_INIT
1077 PPRINT_SET_INDENT(1)
1078 PPRINT_SET_TS(38)
1079
1080 AS_ECHO
1081 AS_ECHO("${PPRINT_COLOR_BLDBLU}LTTng-tools $PACKAGE_VERSION \"$version_name\"$PPRINT_COLOR_RST")
1082 AS_ECHO
1083
1084 AS_IF([test -n "$report_fold"], [
1085         AS_ECHO("`AS_ECHO("$version_description") | $report_fold -s`")
1086 ], [
1087         AS_ECHO("$version_description")
1088 ])
1089
1090 AS_ECHO
1091 PPRINT_SUBTITLE([Features])
1092
1093 # Target architecture we're building for.
1094 target_arch=$host_cpu
1095 [
1096 for f in $CFLAGS; do
1097         if test $f = "-m32"; then
1098                         target_arch="32-bit"
1099         elif test $f = "-m64"; then
1100                         target_arch="64-bit"
1101         fi
1102 done
1103 ]
1104 PPRINT_PROP_STRING([Target architecture], $target_arch)
1105
1106 # kmod enabled/disabled
1107 test "x$kmod_found" = "xyes" && value=1 || value=0
1108 PPRINT_PROP_BOOL([libkmod support], $value)
1109
1110 # LTTng-UST enabled/disabled
1111 test "x$lttng_ust_support" = "xyes" && value=1 || value=0
1112 PPRINT_PROP_BOOL([LTTng-UST support], $value)
1113
1114 AS_ECHO
1115 PPRINT_SUBTITLE([Binaries])
1116
1117 # List binaries to be built
1118 test x$enable_bin_lttng != xno && value=1 || value=0
1119 PPRINT_PROP_BOOL([lttng], $value)
1120
1121 test x$enable_bin_lttng_consumerd != xno && value=1 || value=0
1122 PPRINT_PROP_BOOL([lttng-consumerd], $value)
1123
1124 test x$enable_bin_lttng_crash != xno && value=1 || value=0
1125 PPRINT_PROP_BOOL([lttng-crash], $value)
1126
1127 test x$enable_bin_lttng_relayd != xno && value=1 || value=0
1128 PPRINT_PROP_BOOL([lttng-relayd], $value)
1129
1130 test x$enable_bin_lttng_sessiond != xno && value=1 || value=0
1131 PPRINT_PROP_BOOL([lttng-sessiond], $value)
1132
1133 # Extras
1134 test x$enable_extras != xno && value=1 || value=0
1135 AS_ECHO
1136 PPRINT_SET_INDENT(0)
1137 PPRINT_PROP_BOOL([Extras], $value, $PPRINT_COLOR_SUBTITLE)
1138 PPRINT_SET_INDENT(1)
1139
1140 AS_ECHO
1141 PPRINT_SUBTITLE([Tests])
1142
1143 # Print clear message that tests won't be built
1144 AS_IF([test "x$build_tests" = "xno"],[
1145         PPRINT_WARN([Tests won't be built since some binaries were disabled])
1146 ])
1147
1148 # LTTng UST Java agent JUL tests enabled/disabled
1149 test "x$test_java_agent_jul" = "xyes" && value=1 || value=0
1150 PPRINT_PROP_BOOL([LTTng-UST Java agent JUL tests], $value)
1151
1152 # LTTng UST Java agent Log4j tests enabled/disabled
1153 test "x$test_java_agent_log4j" = "xyes" && value=1 || value=0
1154 PPRINT_PROP_BOOL([LTTng-UST Java agent Log4j tests], $value)
1155
1156 test ! -z "$PYTHON2_AGENT" && value=1 || value=0
1157 PPRINT_PROP_BOOL([LTTng-UST Python2 agent tests], $value)
1158
1159 test ! -z "$PYTHON3_AGENT" && value=1 || value=0
1160 PPRINT_PROP_BOOL([LTTng-UST Python3 agent tests], $value)
1161
1162 #Python binding enabled/disabled
1163 test "x$enable_python_binding" = xyes && value=1 || value=0
1164 AS_ECHO
1165 PPRINT_SET_INDENT(0)
1166 PPRINT_PROP_BOOL([Python binding], $value, $PPRINT_COLOR_SUBTITLE)
1167
1168 # man pages build enabled/disabled
1169 m4_pushdef([build_man_pages_msg], [Build and install man pages])
1170
1171 AS_IF([test "x$man_pages_opt" != "xno"], [
1172         AS_IF([test "x$in_git_repo" = "xyes"], [
1173                 PPRINT_PROP_BOOL([build_man_pages_msg], 1, $PPRINT_COLOR_SUBTITLE)
1174         ], [
1175                 AS_IF([test "x$have_asciidoc_xmlto" = "xyes"], [
1176                         PPRINT_PROP_BOOL([build_man_pages_msg], 1, $PPRINT_COLOR_SUBTITLE)
1177                 ], [
1178                         PPRINT_PROP_STRING([build_man_pages_msg],
1179                                 [${PPRINT_COLOR_BLDGRN}yes (already built)],
1180                                 $PPRINT_COLOR_SUBTITLE)
1181                 ])
1182         ])
1183 ], [
1184         PPRINT_PROP_BOOL([build_man_pages_msg], 0, $PPRINT_COLOR_SUBTITLE)
1185 ])
1186
1187 m4_popdef([build_man_pages_msg])
1188
1189 PPRINT_SET_INDENT(1)
1190
1191 report_bindir="`eval eval echo $bindir`"
1192 report_libdir="`eval eval echo $libdir`"
1193
1194 # Print the bindir and libdir this `make install' will install into.
1195 AS_ECHO
1196 PPRINT_SUBTITLE([Install directories])
1197 PPRINT_PROP_STRING([Binaries], [$report_bindir])
1198 PPRINT_PROP_STRING([Libraries], [$report_libdir])
1199
1200 AS_ECHO
1201 PPRINT_SUBTITLE([Search directories])
1202
1203 # If we build the sessiond, print the paths it will use
1204 AS_IF([test "$SESSIOND_BIN" = ""],[
1205         path="$report_bindir/lttng-sessiond"
1206 ],[
1207         path="$SESSIOND_BIN"
1208 ])
1209 PPRINT_PROP_STRING([lttng-sessiond executable], [$path])
1210
1211 AS_IF([test "$CONSUMERD32_BIN" = ""],[
1212         path="`eval eval echo $lttnglibexecdir`/lttng-consumerd"
1213 ],[
1214         path="$CONSUMERD32_BIN"
1215 ])
1216 PPRINT_PROP_STRING([32-bit lttng-consumerd executable], [$path])
1217
1218 AS_IF([test "$CONSUMERD32_LIBDIR" = ""],[
1219         path="`eval eval echo $libdir`"
1220 ],[
1221         path="$CONSUMERD32_LIBDIR"
1222 ])
1223 PPRINT_PROP_STRING([32-bit consumer libraries], [$path])
1224
1225 AS_IF([test "$CONSUMERD64_BIN" = ""],[
1226         path="`eval eval echo $lttnglibexecdir`/lttng-consumerd"
1227 ],[
1228         path="$CONSUMERD64_BIN"
1229 ])
1230 PPRINT_PROP_STRING([64-bit lttng-consumerd executable], [$path])
1231
1232 AS_IF([test "$CONSUMERD64_LIBDIR" = ""],[
1233         path="`eval eval echo $libdir`"
1234 ],[
1235         path="$CONSUMERD64_LIBDIR"
1236 ])
1237 PPRINT_PROP_STRING([64-bit consumer libraries], [$path])
1238 PPRINT_SET_INDENT(0)
1239
1240 AS_IF([test "x$warn_prebuilt_man_pages" = "xyes" ], [
1241         AS_ECHO
1242         PPRINT_WARN([You need asciidoc and xmlto to build the LTTng-tools man pages.
1243
1244 Note that the man pages are already built in this distribution tarball,
1245 therefore asciidoc and xmlto are only needed if you intend to modify
1246 their sources.
1247
1248 Also note that the installed man pages will contain the project's
1249 default command-line option and environment variable values.
1250
1251 Use --disable-man-pages to completely disable building and installing
1252 the man pages.])
1253 ])