configure.ac

   1 AC_PREREQ([2.64])
   2 AC_INIT([lttng-tools],[2.10.0-pre],[jeremie.galarneau@efficios.com],[],[https://lttng.org])
   3
   4 AC_CONFIG_HEADERS([include/config.h])
   5 AC_CONFIG_AUX_DIR([config])
   6 AC_CONFIG_MACRO_DIR([m4])
   7
   8 AC_CANONICAL_TARGET
   9 AC_CANONICAL_HOST
  10
  11 AM_INIT_AUTOMAKE([foreign dist-bzip2 no-dist-gzip tar-pax])
  12 AM_MAINTAINER_MODE([enable])
  13
  14 # Enable silent rules if available (Introduced in AM 1.11)
  15 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  16
  17 AC_REQUIRE_AUX_FILE([tap-driver.sh])
  18
  19 # Checks for C compiler
  20 AC_USE_SYSTEM_EXTENSIONS
  21 AC_SYS_LARGEFILE
  22 AC_PROG_CC
  23 AC_PROG_CC_STDC
  24
  25 # Checks for programs.
  26 AC_PROG_GREP
  27 AC_PROG_LEX
  28 AC_PROG_MAKE_SET
  29 AC_PROG_SED
  30 AC_PROG_YACC
  31 AC_PATH_PROG(report_fold, fold)
  32 LT_INIT
  33
  34 # Check for objcopy, required by the base address statedump and dynamic linker tests
  35 AC_CHECK_TOOL([OBJCOPY], objcopy, no)
  36 AS_IF([test "x$OBJCOPY" = xno],
  37         [AC_MSG_WARN([Cannont find objcopy. The base address statedump and dynamic linker tests will be disabled. Install the binutils package to remediate this.])]
  38 )
  39 AM_CONDITIONAL([HAVE_OBJCOPY], [test "x$OBJCOPY" != xno])
  40
  41 # Checks for typedefs, structures, and compiler characteristics.
  42 AC_C_INLINE
  43 AC_TYPE_INT32_T
  44 AC_TYPE_INT64_T
  45 AC_TYPE_MODE_T
  46 AC_TYPE_OFF_T
  47 AC_TYPE_PID_T
  48 AC_TYPE_SIZE_T
  49 AC_TYPE_SSIZE_T
  50 AC_TYPE_UID_T
  51 AC_TYPE_UINT16_T
  52 AC_TYPE_UINT32_T
  53 AC_TYPE_UINT64_T
  54 AC_TYPE_UINT8_T
  55
  56 AX_C___ATTRIBUTE__
  57 AS_IF([test "x$ax_cv___attribute__" = "xyes"],
  58         [:],
  59         [AC_MSG_ERROR([The compiler does not support __attribute__ extensions])])
  60
  61 AX_PTHREAD(,[AC_MSG_ERROR([Could not configure pthreads support])])
  62 LIBS="$PTHREAD_LIBS $LIBS"
  63 CFLAGS="$CFLAGS $PTHREAD_CFLAGS"
  64 CC="$PTHREAD_CC"
  65
  66 AX_LIB_SOCKET_NSL
  67
  68 LT_NO_UNDEFINED=""
  69 AS_CASE([$host_os],
  70   [cygwin*],
  71     [
  72       LT_NO_UNDEFINED="-no-undefined"
  73     ]
  74 )
  75
  76 AC_SUBST(LT_NO_UNDEFINED)
  77
  78 # Compute minor/major/patchlevel version numbers
  79 major_version=$(echo AC_PACKAGE_VERSION | $SED 's/^\([[0-9]]\)*\.[[0-9]]*\.[[0-9]]*.*$/\1/')
  80 minor_version=$(echo AC_PACKAGE_VERSION | $SED 's/^[[0-9]]*\.\([[0-9]]*\)\.[[0-9]]*.*$/\1/')
  81 patchlevel_version=$(echo AC_PACKAGE_VERSION | $SED 's/^[[0-9]]*\.[[0-9]]*\.\([[0-9]]*\).*$/\1/')
  82
  83 AC_SUBST([MAJOR_VERSION], [$major_version])
  84 AC_SUBST([MINOR_VERSION], [$minor_version])
  85 AC_SUBST([PATCHLEVEL_VERSION], [$patchlevel_version])
  86 AC_DEFINE_UNQUOTED([VERSION_MAJOR], $major_version, [LTTng-Tools major version number])
  87 AC_DEFINE_UNQUOTED([VERSION_MINOR], $minor_version, [LTTng-Tools minor version number])
  88 AC_DEFINE_UNQUOTED([VERSION_PATCHLEVEL], $patchlevel_version, [LTTng-Tools patchlevel version number])
  89
  90 version_name="Codename TBD"
  91 version_description='Description TBD'
  92 version_description_c=$(echo $version_description | $SED 's/"/\\"/g')
  93
  94 AC_DEFINE_UNQUOTED([VERSION_NAME], ["$version_name"], "")
  95 AC_DEFINE_UNQUOTED([VERSION_DESCRIPTION], ["$version_description_c"], "")
  96
  97 # libtool link_all_deplibs fixup. See http://bugs.lttng.org/issues/321.
  98 AC_ARG_ENABLE(libtool-linkdep-fixup,
  99         AS_HELP_STRING([--disable-libtool-linkdep-fixup],
 100                         [disable the libtool fixup for linking all dependent libraries (link_all_deplibs)]),
 101         libtool_fixup=$enableval,
 102         libtool_fixup=yes)
 103
 104 AS_IF([test "x$libtool_fixup" = "xyes"],
 105             [
 106             libtool_m4="$srcdir/m4/libtool.m4"
 107             libtool_flag_pattern=".*link_all_deplibs\s*,\s*\$1\s*)"
 108             AC_MSG_CHECKING([for occurence(s) of link_all_deplibs = no in $libtool_m4])
 109             libtool_flag_pattern_count=$($GREP -c "$libtool_flag_pattern\s*=\s*no" $libtool_m4)
 110             AS_IF([test $libtool_flag_pattern_count -ne 0],
 111             [
 112                   AC_MSG_RESULT([$libtool_flag_pattern_count])
 113                   AC_MSG_WARN([the detected libtool will not link all dependencies, forcing link_all_deplibs = unknown])
 114                   $SED -i "s/\($libtool_flag_pattern\)\s*=\s*no/\1=unknown/g" $libtool_m4
 115                   ],
 116                   [
 117                   AC_MSG_RESULT([none])
 118                   ])
 119             ])
 120
 121 AM_CONDITIONAL([NO_SHARED], [test x$enable_shared = xno])
 122
 123 AC_CHECK_HEADERS([ \
 124         sys/types.h unistd.h fcntl.h string.h pthread.h limits.h \
 125         signal.h stdlib.h sys/un.h sys/socket.h stdlib.h stdio.h \
 126         getopt.h sys/ipc.h sys/shm.h popt.h grp.h arpa/inet.h \
 127         netdb.h netinet/in.h paths.h stddef.h sys/file.h sys/ioctl.h \
 128         sys/mount.h sys/param.h sys/time.h
 129 ])
 130
 131 # Basic functions check
 132 AC_CHECK_FUNCS([ \
 133         atexit bzero clock_gettime dup2 fdatasync fls ftruncate \
 134         gethostbyname gethostname getpagesize localtime_r memchr memset \
 135         mkdir munmap putenv realpath rmdir socket strchr strcspn strdup \
 136         strncasecmp strndup strnlen strpbrk strrchr strstr strtol strtoul \
 137         strtoull dirfd gethostbyname2 getipnodebyname epoll_create1 \
 138 ])
 139
 140 # Check if clock_gettime, timer_create, timer_settime, and timer_delete are available in lib rt, and if so,
 141 # add -lrt to LIBS
 142 AC_CHECK_LIB([rt], [clock_gettime, timer_create, timer_settime, timer_delete])
 143
 144 # Babeltrace viewer check
 145 AC_ARG_WITH([babeltrace-bin],
 146         AS_HELP_STRING([--with-babeltrace-bin],
 147         [Location of the babeltrace viewer executable (including the filename)]),
 148         [BABELTRACE_BIN="$withval"],
 149         [BABELTRACE_BIN=''])
 150 AC_SUBST([BABELTRACE_BIN])
 151
 152 # lttv-gui
 153 AC_ARG_WITH([lttv-gui-bin],
 154         AS_HELP_STRING([--with-lttv-gui-bin],
 155    [Location of the lttv GUI viewer executable (including the filename)]),
 156    [LTTV_GUI_BIN="$withval"],
 157    [LTTV_GUI_BIN=''])
 158 AC_SUBST([LTTV_GUI_BIN])
 159
 160 AC_ARG_WITH([consumerd32-bin],
 161         AS_HELP_STRING([--with-consumerd32-bin],
 162         [Location of the 32-bit consumerd executable (including the filename)]),
 163         [CONSUMERD32_BIN="$withval"],
 164         [CONSUMERD32_BIN=''])
 165 AC_SUBST([CONSUMERD32_BIN])
 166
 167 AC_ARG_WITH([consumerd64-bin],
 168         AS_HELP_STRING([--with-consumerd64-bin],
 169         [Location of the 64-bit consumerd executable (including the filename)]),
 170         [CONSUMERD64_BIN="$withval"],
 171         [CONSUMERD64_BIN=''])
 172 AC_SUBST([CONSUMERD64_BIN])
 173
 174 AC_ARG_WITH([consumerd32-libdir],
 175         AS_HELP_STRING([--with-consumerd32-libdir],
 176         [Directory containing the 32-bit consumerd libraries]),
 177         [CONSUMERD32_LIBDIR="$withval"],
 178         [CONSUMERD32_LIBDIR=''])
 179 AC_SUBST([CONSUMERD32_LIBDIR])
 180
 181 AC_ARG_WITH([consumerd64-libdir],
 182         AS_HELP_STRING([--with-consumerd64-libdir],
 183         [Directory containing the 64-bit consumerd libraries]),
 184         [CONSUMERD64_LIBDIR="$withval"],
 185         [CONSUMERD64_LIBDIR=''])
 186 AC_SUBST([CONSUMERD64_LIBDIR])
 187
 188 AC_ARG_WITH([sessiond-bin],
 189         AS_HELP_STRING([--with-sessiond-bin],
 190         [Location of the sessiond executable (including the filename)]),
 191         [SESSIOND_BIN="$withval"],
 192         [SESSIOND_BIN=''])
 193 AC_SUBST([SESSIOND_BIN])
 194
 195 AC_ARG_WITH([lttng-system-rundir],
 196         AS_HELP_STRING([--with-lttng-system-rundir],
 197         [Location of the system directory where the system-wide lttng-sessiond runtime files are kept. The default is "/var/run/lttng".]),
 198         [LTTNG_SYSTEM_RUNDIR="$withval"],
 199         [LTTNG_SYSTEM_RUNDIR="/var/run/lttng"])
 200 AC_SUBST([LTTNG_SYSTEM_RUNDIR])
 201
 202 AC_ARG_ENABLE([test-java-agent-jul],
 203         [AS_HELP_STRING([--enable-test-java-agent-jul],[enable the LTTng UST Java agent JUL tests [default=no]])],
 204         [test_java_agent_jul=$enableval],
 205         [test_java_agent_jul=no]
 206 )
 207
 208 AC_ARG_ENABLE([test-java-agent-log4j],
 209         [AS_HELP_STRING([--enable-test-java-agent-log4j],[enable the LTTng UST Java agent Log4j tests [default=no]])],
 210         [test_java_agent_log4j=$enableval],
 211         [test_java_agent_log4j=no]
 212 )
 213
 214 AC_ARG_ENABLE([test-java-agent-all],
 215         [AS_HELP_STRING([--enable-test-java-agent-all],[enable all the LTTng UST Java agent tests [default=no]])],
 216         [test_java_agent_jul=$enableval
 217          test_java_agent_log4j=$enableval],
 218         [:]
 219 )
 220
 221 AC_DEFINE_UNQUOTED([CONFIG_CONSUMERD32_BIN], "$CONSUMERD32_BIN", [Location of the 32-bit consumerd executable.])
 222 AC_DEFINE_UNQUOTED([CONFIG_CONSUMERD64_BIN], "$CONSUMERD64_BIN", [Location of the 64-bit consumerd executable])
 223 AC_DEFINE_UNQUOTED([CONFIG_CONSUMERD32_LIBDIR], "$CONSUMERD32_LIBDIR", [Search for consumerd 32-bit libraries in this location.])
 224 AC_DEFINE_UNQUOTED([CONFIG_CONSUMERD64_LIBDIR], "$CONSUMERD64_LIBDIR", [Search for consumerd 64-bit libraries in this location.])
 225 AC_DEFINE_UNQUOTED([CONFIG_BABELTRACE_BIN], "$BABELTRACE_BIN", [Location of the babeltrace viewer executable.])
 226 AC_DEFINE_UNQUOTED([CONFIG_LTTV_GUI_BIN], "$LTTV_GUI_BIN", [Location of the lttv GUI viewer executable.])
 227 AC_DEFINE_UNQUOTED([CONFIG_SESSIOND_BIN], "$SESSIOND_BIN", [Location of the sessiond executable.])
 228 AC_DEFINE_UNQUOTED([CONFIG_LTTNG_SYSTEM_RUNDIR], ["$LTTNG_SYSTEM_RUNDIR"], [LTTng system runtime directory])
 229
 230 AC_DEFUN([_AC_DEFINE_AND_SUBST], [
 231         AC_DEFINE_UNQUOTED([CONFIG_$1], [$2], [$1])
 232         $1="$2"
 233         AC_SUBST([$1])
 234 ])
 235
 236 AC_DEFUN([_AC_DEFINE_QUOTED_AND_SUBST], [
 237         AC_DEFINE_UNQUOTED([CONFIG_$1], ["$2"], [$1])
 238         $1="$2"
 239         AC_SUBST([$1])
 240 ])
 241
 242 # Default values
 243 m4_define([_DEFAULT_CHANNEL_SUBBUF_SIZE], [4096])
 244 m4_define([_DEFAULT_CHANNEL_SUBBUF_NUM], [4])
 245 m4_define([_DEFAULT_CHANNEL_SWITCH_TIMER], [0])
 246 m4_define([_DEFAULT_CHANNEL_LIVE_TIMER], [0])
 247 m4_define([_DEFAULT_CHANNEL_READ_TIMER], [200000])
 248 _AC_DEFINE_AND_SUBST([DEFAULT_AGENT_TCP_PORT], [5345])
 249 _AC_DEFINE_AND_SUBST([DEFAULT_APP_SOCKET_RW_TIMEOUT], [5])
 250 _AC_DEFINE_AND_SUBST([DEFAULT_CHANNEL_SUBBUF_SIZE], [_DEFAULT_CHANNEL_SUBBUF_SIZE])
 251 _AC_DEFINE_AND_SUBST([DEFAULT_CHANNEL_TRACEFILE_COUNT], [0])
 252 _AC_DEFINE_AND_SUBST([DEFAULT_CHANNEL_TRACEFILE_SIZE], [0])
 253 _AC_DEFINE_AND_SUBST([DEFAULT_KERNEL_CHANNEL_LIVE_TIMER], [_DEFAULT_CHANNEL_LIVE_TIMER])
 254 _AC_DEFINE_AND_SUBST([DEFAULT_KERNEL_CHANNEL_READ_TIMER], [_DEFAULT_CHANNEL_READ_TIMER])
 255 _AC_DEFINE_AND_SUBST([DEFAULT_KERNEL_CHANNEL_SUBBUF_NUM], [_DEFAULT_CHANNEL_SUBBUF_NUM])
 256 _AC_DEFINE_AND_SUBST([DEFAULT_KERNEL_CHANNEL_SUBBUF_SIZE], [262144])
 257 _AC_DEFINE_AND_SUBST([DEFAULT_KERNEL_CHANNEL_SWITCH_TIMER], [_DEFAULT_CHANNEL_SWITCH_TIMER])
 258 _AC_DEFINE_AND_SUBST([DEFAULT_LTTNG_LIVE_TIMER], [1000000])
 259 _AC_DEFINE_AND_SUBST([DEFAULT_METADATA_CACHE_SIZE], [4096])
 260 _AC_DEFINE_AND_SUBST([DEFAULT_METADATA_READ_TIMER], [0])
 261 _AC_DEFINE_AND_SUBST([DEFAULT_METADATA_SUBBUF_NUM], [2])
 262 _AC_DEFINE_AND_SUBST([DEFAULT_METADATA_SUBBUF_SIZE], [4096])
 263 _AC_DEFINE_AND_SUBST([DEFAULT_METADATA_SWITCH_TIMER], [_DEFAULT_CHANNEL_SWITCH_TIMER])
 264 _AC_DEFINE_AND_SUBST([DEFAULT_NETWORK_CONTROL_PORT], [5342])
 265 _AC_DEFINE_AND_SUBST([DEFAULT_NETWORK_DATA_PORT], [5343])
 266 _AC_DEFINE_AND_SUBST([DEFAULT_NETWORK_VIEWER_PORT], [5344])
 267 _AC_DEFINE_AND_SUBST([DEFAULT_UST_PID_CHANNEL_LIVE_TIMER], [_DEFAULT_CHANNEL_LIVE_TIMER])
 268 _AC_DEFINE_AND_SUBST([DEFAULT_UST_PID_CHANNEL_READ_TIMER], [0])
 269 _AC_DEFINE_AND_SUBST([DEFAULT_UST_PID_CHANNEL_SUBBUF_NUM], [_DEFAULT_CHANNEL_SUBBUF_NUM])
 270 _AC_DEFINE_AND_SUBST([DEFAULT_UST_PID_CHANNEL_SUBBUF_SIZE], [_DEFAULT_CHANNEL_SUBBUF_SIZE])
 271 _AC_DEFINE_AND_SUBST([DEFAULT_UST_PID_CHANNEL_SWITCH_TIMER], [_DEFAULT_CHANNEL_SWITCH_TIMER])
 272 _AC_DEFINE_AND_SUBST([DEFAULT_UST_UID_CHANNEL_LIVE_TIMER], [_DEFAULT_CHANNEL_LIVE_TIMER])
 273 _AC_DEFINE_AND_SUBST([DEFAULT_UST_UID_CHANNEL_READ_TIMER], [0])
 274 _AC_DEFINE_AND_SUBST([DEFAULT_UST_UID_CHANNEL_SUBBUF_NUM], [_DEFAULT_CHANNEL_SUBBUF_NUM])
 275 _AC_DEFINE_AND_SUBST([DEFAULT_UST_UID_CHANNEL_SUBBUF_SIZE], [131072])
 276 _AC_DEFINE_AND_SUBST([DEFAULT_UST_UID_CHANNEL_SWITCH_TIMER], [_DEFAULT_CHANNEL_SWITCH_TIMER])
 277 _AC_DEFINE_QUOTED_AND_SUBST([DEFAULT_AGENT_BIND_ADDRESS], [localhost])
 278 _AC_DEFINE_QUOTED_AND_SUBST([DEFAULT_NETWORK_CONTROL_BIND_ADDRESS], [0.0.0.0])
 279 _AC_DEFINE_QUOTED_AND_SUBST([DEFAULT_NETWORK_DATA_BIND_ADDRESS], [0.0.0.0])
 280 _AC_DEFINE_QUOTED_AND_SUBST([DEFAULT_NETWORK_VIEWER_BIND_ADDRESS], [localhost])
 281
 282 # Command short descriptions
 283 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_ADD_CONTEXT], [Add context fields to a channel])
 284 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_CREATE], [Create a tracing session])
 285 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_DESTROY], [Tear down tracing sessions])
 286 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_DISABLE_CHANNEL], [Disable tracing channels])
 287 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_DISABLE_EVENT], [Disable event rules])
 288 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_ENABLE_CHANNEL], [Create or enable tracing channels])
 289 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_ENABLE_EVENT], [Create or enable event rules])
 290 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_HELP], [Display help information about a command])
 291 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_LIST], [List tracing sessions, domains, channels, and events])
 292 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_LOAD], [Load tracing session configurations])
 293 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_REGENERATE], [Manage an LTTng tracing session's data regeneration])
 294 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_SAVE], [Save tracing session configurations])
 295 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_SET_SESSION], [Set current tracing session])
 296 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_SNAPSHOT], [Snapshot buffers of current tracing session])
 297 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_START], [Start tracing])
 298 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_STATUS], [Get the status of the current tracing session])
 299 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_STOP], [Stop tracing])
 300 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_TRACK], [Track specific system resources])
 301 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_UNTRACK], [Untrack specific system resources])
 302 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_VERSION], [Show version information])
 303 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_VIEW], [Start trace viewer])
 304
 305 if test "x$prefix" = "xNONE"; then
 306         prefix=$ac_default_prefix
 307 fi
 308 CONFDIR=`eval echo $sysconfdir`
 309 AC_SUBST(CONFDIR)
 310 AC_DEFINE_UNQUOTED([CONFIG_LTTNG_SYSTEM_CONFIGDIR],"$CONFDIR", [LTTng system configuration directory.])
 311
 312 AC_DEFINE_DIR([CONFIG_LTTNG_SYSTEM_DATADIR],[datadir], [LTTng system data directory.])
 313
 314 #
 315 # Check for pthread
 316 AC_CHECK_LIB([pthread], [pthread_create], [],
 317         [AC_MSG_ERROR([Cannot find libpthread. Use LDFLAGS=-Ldir to specify its location.])]
 318 )
 319
 320 # Check libpopt
 321 PKG_CHECK_MODULES([POPT], [popt],
 322         [LIBS="$LIBS $POPT_LIBS"],
 323         [
 324                 AC_MSG_WARN([pkg-config was unable to find a valid .pc for libpopt. Set PKG_CONFIG_PATH to specify the pkgconfig configuration file location])
 325                 AC_MSG_WARN([Finding libpopt without pkg-config.])
 326                 AC_CHECK_LIB([popt],
 327                         [poptGetContext],
 328                         [],
 329                         [
 330                                  AC_MSG_ERROR([Cannot find libpopt. Either set PKG_CONFIG_PATH to the configuration file location or use LDFLAGS=-Ldir to specify the library location])
 331                         ]
 332                 )
 333         ]
 334 )
 335
 336 PKG_CHECK_MODULES([libxml2], [libxml-2.0 >= 2.7.6])
 337
 338 # Check for uuid in system libs
 339 AC_CHECK_FUNCS([uuid_generate],
 340 [
 341         AC_DEFINE_UNQUOTED([LTTNG_HAVE_LIBUUID], 1, [Has libuuid support.])
 342         link_with_libuuid=no
 343 ],
 344 [
 345 # First, check the pkg-config module is available, otherwise explicitly check
 346 # for libuuid, or uuid support in the C-library.
 347 PKG_CHECK_MODULES([UUID], [uuid],
 348 [
 349         LIBS="$LIBS $UUID_LIBS"
 350         AC_DEFINE_UNQUOTED([LTTNG_HAVE_LIBUUID], 1, [Has libuuid support.])
 351         link_with_libuuid=yes
 352 ],
 353 [
 354         # Check for libuuid
 355         AC_CHECK_LIB([uuid],
 356                 [uuid_generate],
 357                 [
 358                         AC_DEFINE_UNQUOTED([LTTNG_HAVE_LIBUUID], 1, [Has libuuid support.])
 359                         link_with_libuuid=yes
 360                 ],
 361                 [
 362                         # libuuid not found, check for uuid_create in libc.
 363                         AC_CHECK_LIB([c],
 364                                 [uuid_create],
 365                                 [
 366                                         AC_DEFINE_UNQUOTED([LTTNG_HAVE_LIBC_UUID], 1, [Has libc uuid support.])
 367                                         link_with_libc_uuid=yes
 368                                 ],
 369                                 [
 370                                         AC_MSG_ERROR([Cannot find libuuid uuid_generate nor libc uuid_create. Either set PKG_CONFIG_PATH to the configuration file location or use LDFLAGS=-Ldir to specify the library location])
 371                                 ]
 372                         )
 373                 ]
 374         )
 375 ])
 376 ])
 377
 378 AM_CONDITIONAL([LTTNG_BUILD_WITH_LIBUUID], [test "x$link_with_libuuid" = "xyes"])
 379 AM_CONDITIONAL([LTTNG_BUILD_WITH_LIBC_UUID], [test "x$link_with_libc_uuid" = "xyes"])
 380
 381 AC_CHECK_FUNC([clock_gettime], [AC_DEFINE_UNQUOTED([LTTNG_HAVE_CLOCK_GETTIME], 1, [Has clock_gettime() support.])])
 382
 383 # URCU library version needed or newer
 384 m4_define([WRONG_LIBURCU_MSG], [Userspace RCU (liburcu) >= 0.8.0 is needed])
 385
 386 # Check liburcu needed function calls
 387 AC_CHECK_DECL([cds_list_add], [],
 388         [AC_MSG_ERROR([WRONG_LIBURCU_MSG])], [[#include <urcu/list.h>]])
 389 AC_CHECK_DECL([cds_wfcq_init], [],
 390         [AC_MSG_ERROR([WRONG_LIBURCU_MSG])], [[#include <urcu/wfcqueue.h>]])
 391 AC_CHECK_DECL([cds_wfcq_dequeue_blocking], [],
 392         [AC_MSG_ERROR([WRONG_LIBURCU_MSG])], [[#include <urcu/wfcqueue.h>]])
 393 AC_CHECK_DECL([futex_async], [],
 394         [AC_MSG_ERROR([WRONG_LIBURCU_MSG])], [[#include <urcu/futex.h>]])
 395 AC_CHECK_DECL([rcu_thread_offline], [],
 396         [AC_MSG_ERROR([WRONG_LIBURCU_MSG])], [[#include <urcu.h>]])
 397 AC_CHECK_DECL([rcu_thread_online], [],
 398         [AC_MSG_ERROR([WRONG_LIBURCU_MSG])], [[#include <urcu.h>]])
 399 AC_CHECK_DECL([caa_likely], [],
 400         [AC_MSG_ERROR([WRONG_LIBURCU_MSG])], [[#include <urcu.h>]])
 401 AC_CHECK_LIB([urcu-cds], [_cds_lfht_new], [],
 402         [AC_MSG_ERROR([WRONG_LIBURCU_MSG])])
 403
 404 #Function added in urcu 0.7.0
 405 AC_CHECK_DECL([cmm_smp_mb__before_uatomic_or], [],
 406         [AC_MSG_ERROR([WRONG_LIBURCU_MSG])], [[#include <urcu.h>]]
 407 )
 408
 409 # Check kmod library
 410 AC_ARG_WITH(kmod-prefix,
 411   AS_HELP_STRING([--with-kmod-prefix=PATH],
 412                 [Specify the installation prefix of the kmod library.
 413                 Headers must be in PATH/include; libraries in PATH/lib.]),
 414                 [
 415                         CPPFLAGS="$CPPFLAGS -I${withval}/include"
 416                         LDFLAGS="$LDFLAGS -L${withval}/lib64 -L${withval}/lib"
 417                 ])
 418
 419 AC_ARG_ENABLE(kmod,
 420         AS_HELP_STRING([--disable-kmod],[build without kmod support]),
 421         kmod_support=$enableval, kmod_support=yes)
 422
 423 AS_IF([test "x$kmod_support" = "xyes"], [
 424         AC_CHECK_LIB([kmod], [kmod_module_probe_insert_module],
 425                 [
 426                         AC_DEFINE([HAVE_KMOD], [1], [has kmod support])
 427                         LIBS="$LIBS -lkmod"
 428                         kmod_found=yes
 429                 ],
 430                 kmod_found=no
 431         )
 432 ])
 433 AM_CONDITIONAL([HAVE_KMOD], [test "x$kmod_found" = xyes])
 434
 435 AC_ARG_WITH(lttng-ust-prefix,
 436   AS_HELP_STRING([--with-lttng-ust-prefix=PATH],
 437                  [Specify the installation prefix of the lttng-ust library.
 438                   Headers must be in PATH/include; libraries in PATH/lib.]),
 439                   [
 440                     CPPFLAGS="$CPPFLAGS -I${withval}/include"
 441                     LDFLAGS="$LDFLAGS -L${withval}/lib64 -L${withval}/lib"
 442                   ])
 443
 444 # Check liblttng-ust-ctl library
 445 AC_ARG_WITH(lttng-ust,
 446         AS_HELP_STRING([--without-lttng-ust],[build without LTTng-UST (Userspace Tracing) support]),
 447         lttng_ust_support=$withval, lttng_ust_support=yes)
 448
 449 AS_IF([test "x$lttng_ust_support" = "xyes"], [
 450         AC_CHECK_LIB([lttng-ust-ctl], [ustctl_recv_channel_from_consumer],
 451                 [
 452                         AC_DEFINE([HAVE_LIBLTTNG_UST_CTL], [1], [has LTTng-UST control support])
 453                         lttng_ust_ctl_found=yes
 454                 ],
 455                 [AC_MSG_ERROR([Cannot find LTTng-UST >= 2.2.x. Use --with-lttng-ust-prefix=PREFIX to specify its location, or specify --without-lttng-ust to build lttng-tools without LTTng-UST support.])],
 456                 [-lurcu-common -lurcu-bp -lurcu-cds -lrt -ldl]
 457         )
 458 ])
 459 AM_CONDITIONAL([HAVE_LIBLTTNG_UST_CTL], [test "x$lttng_ust_ctl_found" = xyes])
 460 AC_CHECK_FUNCS([sched_getcpu sysconf sync_file_range])
 461
 462 # check for dlopen
 463 AC_CHECK_LIB([dl], [dlopen],
 464 [
 465         have_libdl=yes
 466 ],
 467 [
 468         #libdl not found, check for dlopen in libc.
 469         AC_CHECK_LIB([c], [dlopen],
 470         [
 471                 have_libc_dl=yes
 472         ],
 473         [
 474                 AC_MSG_ERROR([Cannot find dlopen in libdl nor libc. Use [LDFLAGS]=-Ldir to specify their location.])
 475         ])
 476 ])
 477 AM_CONDITIONAL([LTTNG_TOOLS_BUILD_WITH_LIBDL], [test "x$have_libdl" = "xyes"])
 478 AM_CONDITIONAL([LTTNG_TOOLS_BUILD_WITH_LIBC_DL], [test "x$have_libc_dl" = "xyes"])
 479
 480 # Check for fmemopen
 481 AC_CHECK_LIB([c], [fmemopen],
 482 [
 483         AC_DEFINE_UNQUOTED([LTTNG_HAVE_FMEMOPEN], 1, [Has fmemopen support.])
 484 ]
 485 )
 486
 487 # Check for open_memstream
 488 AC_CHECK_LIB([c], [open_memstream],
 489 [
 490         AC_DEFINE_UNQUOTED([LTTNG_HAVE_OPEN_MEMSTREAM], 1, [Has open_memstream support.])
 491 ]
 492 )
 493
 494 # check for libpfm
 495 AC_CHECK_LIB([pfm], [pfm_initialize],
 496              [
 497               have_libpfm=yes
 498               ])
 499 AM_CONDITIONAL([LTTNG_TOOLS_BUILD_WITH_LIBPFM], [test "x$have_libpfm" = "xyes"])
 500
 501 AC_ARG_ENABLE([git-version],
 502               [AC_HELP_STRING([--disable-git-version],
 503                               [Do not use the git version for the build])],
 504               [have_git_version=$enableval], [have_git_version=yes]
 505 )
 506
 507 AM_CONDITIONAL([LTTNG_TOOLS_BUILD_GIT_SOURCE],
 508         [test "x${have_git_version}" = "xyes"])
 509
 510 # For Python
 511 # SWIG version needed or newer:
 512 swig_version=2.0.0
 513
 514 AC_ARG_ENABLE([python-bindings],
 515               [AC_HELP_STRING([--enable-python-bindings],
 516                               [compile Python bindings])],
 517               [enable_python_binding=$enableval], [enable_python_binding=no])
 518
 519 AM_CONDITIONAL([PYTHON_BINDING], [test "x$enable_python_binding" = xyes])
 520
 521 if test "x$enable_python_binding" = xyes; then
 522   AX_PKG_SWIG($swig_version, [], [ AC_MSG_ERROR([SWIG $swig_version or newer is needed]) ])
 523   AS_IF([test x$enable_shared = xno], [ AC_MSG_ERROR([Python bindings require shared libraries.]) ])
 524   AM_PATH_PYTHON([3.0])
 525
 526   AC_ARG_VAR([PYTHON_INCLUDE], [Include flags for python, bypassing python-config])
 527   AC_ARG_VAR([PYTHON_CONFIG], [Path to python-config])
 528   AS_IF([test -z "$PYTHON_INCLUDE"], [
 529     AS_IF([test -z "$PYTHON_CONFIG"], [
 530       AC_PATH_PROGS([PYTHON_CONFIG],
 531                     [python$PYTHON_VERSION-config python-config],
 532                     [no],
 533                     [`dirname $PYTHON`])
 534       AS_IF([test "$PYTHON_CONFIG" = no], [AC_MSG_ERROR([cannot find python-config for $PYTHON. Do you have python-dev installed?])])
 535     ])
 536     AC_MSG_CHECKING([python include flags])
 537     PYTHON_INCLUDE=`$PYTHON_CONFIG --includes`
 538     AC_MSG_RESULT([$PYTHON_INCLUDE])
 539   ])
 540
 541 else
 542     AC_MSG_NOTICE([You may configure with --enable-python-bindings ]dnl
 543 [if you want Python bindings.])
 544
 545 fi
 546
 547 # Epoll check. If not present, the build will fallback on poll() API
 548 AX_HAVE_EPOLL(
 549         [AX_CONFIG_FEATURE_ENABLE(epoll)],
 550         [AX_CONFIG_FEATURE_DISABLE(epoll)]
 551 )
 552 AX_CONFIG_FEATURE(
 553         [epoll], [This platform supports epoll(7)],
 554         [HAVE_EPOLL], [This platform supports epoll(7).],
 555         [enable_epoll="yes"], [enable_epoll="no"]
 556 )
 557 AM_CONDITIONAL([COMPAT_EPOLL], [ test "$enable_epoll" = "yes" ])
 558
 559 AM_CONDITIONAL([TEST_JAVA_JUL_AGENT], [test "x$test_java_agent_jul" = "xyes"])
 560 AM_CONDITIONAL([TEST_JAVA_LOG4J_AGENT], [test "x$test_java_agent_log4j" = "xyes"])
 561
 562 if test "x$test_java_agent_jul" = "xyes" || test "x$test_java_agent_log4j" = "xyes"; then
 563         AX_JAVA_OPTIONS
 564         AX_PROG_JAVAC
 565         AX_PROG_JAVA
 566         AX_PROG_JAR
 567
 568         AX_CHECK_CLASSPATH
 569
 570         # Check for Java UST agent common class first
 571         AX_CHECK_CLASS(org.lttng.ust.agent.AbstractLttngAgent)
 572         if test "x$ac_cv_class_org_lttng_ust_agent_AbstractLttngAgent" = "xno"; then
 573                 AC_MSG_ERROR([The UST Java agent common class was not found. Please specify the location of the jar via the Java CLASSPATH e.g: export CLASSPATH="/path/to/lttng-ust-agent-common.jar"])
 574         fi
 575
 576         if test "x$test_java_agent_jul" = "xyes"; then
 577                 # Check for JUL agent class
 578                 AX_CHECK_CLASS(org.lttng.ust.agent.jul.LttngLogHandler)
 579                 if test "x$ac_cv_class_org_lttng_ust_agent_jul_LttngLogHandler" = "xno"; then
 580                         AC_MSG_ERROR([The UST Java agent JUL class was not found. Please specify the location of the jar via the Java CLASSPATH e.g: export CLASSPATH="/path/to/lttng-ust-agent-jul.jar"])
 581                 fi
 582         fi
 583
 584         if test "x$test_java_agent_log4j" = "xyes"; then
 585                 # Check for Log4j agent class
 586                 AX_CHECK_CLASS(org.lttng.ust.agent.log4j.LttngLogAppender)
 587                 if test "x$ac_cv_class_org_lttng_ust_agent_log4j_LttngLogAppender" = "xno"; then
 588                         AC_MSG_ERROR([The UST Java agent Log4j class was not found. Please specify the location of the jar via the Java CLASSPATH e.g: export CLASSPATH="/path/to/lttng-ust-agent-log4j.jar"])
 589                 fi
 590
 591                 # Check for Log4j class
 592                 AX_CHECK_CLASS(org.apache.log4j.Logger)
 593                 if test "x$ac_cv_class_org_apache_log4j_Logger" = "xno"; then
 594                         AC_MSG_ERROR([The Log4j class was not found. Please specify the location of the jar via the Java CLASSPATH e.g: export CLASSPATH="/path/to/log4j.jar"])
 595                 fi
 596         fi
 597 fi
 598
 599 # set $IN_GIT_REPO if we're in the Git repository; the `bootstrap` file
 600 # is not distributed in tarballs
 601 AS_IF([test -f "$srcdir/bootstrap"], [in_git_repo=yes], [in_git_repo=no])
 602 AM_CONDITIONAL([IN_GIT_REPO], [test "x$in_git_repo" = "xyes"])
 603
 604 # enable building man pages (user's intention)
 605 AC_ARG_ENABLE(
 606         man-pages,
 607         AS_HELP_STRING(
 608                 [--disable-man-pages],
 609                 [Do not build and install man pages (already built in a distributed tarball)]
 610         ),
 611         [man_pages_opt=$enableval],
 612         [man_pages_opt=yes]
 613 )
 614
 615 # check for asciidoc and xmlto if we enabled building the man pages
 616 have_asciidoc_xmlto=no
 617 warn_prebuilt_man_pages=no
 618
 619 AS_IF([test "x$man_pages_opt" = "xyes"], [
 620         AC_PATH_PROG([ASCIIDOC], [asciidoc], [no])
 621         AC_PATH_PROG([XMLTO], [xmlto], [no])
 622
 623         AS_IF([test "x$ASCIIDOC" = "xno" || test "x$XMLTO" = "xno"], [
 624                 AS_IF([test "x$in_git_repo" = "xyes"], [
 625                         # this is an error because we're in the Git repo, which
 626                         # means the man pages are not already generated for us,
 627                         # thus asciidoc/xmlto are required because we were asked
 628                         # to build the man pages
 629                         AC_MSG_ERROR([
 630 You need asciidoc and xmlto to build the LTTng-tools man pages. Use
 631 --disable-man-pages to disable building the man pages, in which case
 632 they will not be installed.
 633                         ])
 634                 ], [
 635                         # only warn here: since we're in the tarball, the man
 636                         # pages should already be generated at this point, thus
 637                         # asciidoc/xmlto are not strictly required
 638                         warn_prebuilt_man_pages=yes
 639                 ])
 640         ], [
 641                 have_asciidoc_xmlto=yes
 642         ])
 643 ])
 644
 645 # export man page build condition: build the man pages if the user
 646 # asked for it, and if the tools are available
 647 AM_CONDITIONAL([MAN_PAGES_OPT], [test "x$man_pages_opt" != "xno"])
 648 AM_CONDITIONAL([HAVE_ASCIIDOC_XMLTO], [test "x$have_asciidoc_xmlto" = "xyes"])
 649
 650 AC_DEFINE_UNQUOTED([MANPATH], ["`eval eval echo $mandir`"], [Path to man pages.])
 651
 652 # Python agent test
 653 UST_PYTHON_AGENT="lttngust"
 654
 655 AC_ARG_ENABLE(test-python2-agent,
 656         AS_HELP_STRING([--enable-test-python2-agent],
 657                 [enable tests for python2 agent. Python2 interpreter path can be overridden by setting the PYTHON2 environment variable. Default: Autodetect]
 658         ),[:],[test_python2_agent_autodetect=yes]
 659 )
 660
 661 AC_ARG_ENABLE(test-python3-agent,
 662         AS_HELP_STRING([--enable-test-python3-agent],
 663                 [enable tests for python3 agent. Python3 interpreter path can be overridden by setting the PYTHON3 environment variable. Default: Autodetect]
 664         ),[:],[test_python3_agent_autodetect=yes]
 665 )
 666
 667 AC_ARG_ENABLE(test-python-agent-all,
 668         AS_HELP_STRING([--enable-test-python-agent-all],
 669                 [enable test for all python{2/3} agent.]
 670         ),
 671 )
 672
 673 AS_IF([test ! -z "$enable_test_python_agent_all"], [
 674        unset test_python2_agent_autodetect
 675        unset test_python3_agent_autodetect
 676 ])
 677
 678 AS_IF([test "x$enable_test_python_agent_all" = "xyes"], [
 679        enable_test_python2_agent=yes
 680        enable_test_python3_agent=yes
 681 ])
 682
 683 AS_IF([test "x$enable_test_python_agent_all" = "xno"], [
 684        enable_test_python2_agent=no
 685        enable_test_python3_agent=no
 686 ])
 687
 688
 689 AS_IF([test "x$enable_test_python2_agent" = "xyes" -o "x$test_python2_agent_autodetect" = "xyes" ], [
 690         AS_IF([test -z "$PYTHON2"], [
 691                         PYTHON2=python2
 692                 ], [
 693                         AC_MSG_WARN([Using user-defined PYTHON2 ($PYTHON2) for lttng-ust python2 agent check])
 694         ])
 695
 696         AC_PATH_PROG([PYTHON2_BIN],[$PYTHON2])
 697         AS_IF([test -z "$PYTHON2_BIN"], [
 698                 AS_IF([test -z "$test_python2_agent_autodetect"],[
 699                         AC_MSG_ERROR([No python2 interpreter found. PYTHON2 can be set to override default interpreter path])
 700                 ])
 701         ], [
 702                 AC_MSG_CHECKING([for python2 lttng-ust agent])
 703                 AS_IF([$PYTHON2_BIN -c "import $UST_PYTHON_AGENT" 2>/dev/null], [
 704                         PYTHON2_AGENT=$PYTHON2_BIN
 705                         AC_MSG_RESULT([yes])
 706                         RUN_PYTHON_AGENT_TEST=yes
 707                 ], [
 708                         AC_MSG_RESULT([no])
 709                         AS_IF([test -z "$test_python2_agent_autodetect"],[
 710                                 AC_MSG_ERROR([No python2 agent found. The path to the agent can be specified by setting the PYTHONPATH environment variable.])
 711                         ])
 712                 ])
 713
 714         ])
 715
 716 ])
 717
 718 AS_IF([test "x$enable_test_python3_agent" = "xyes" -o "x$test_python3_agent_autodetect" = "xyes" ], [
 719         AS_IF([test -z "$PYTHON3"], [
 720                 PYTHON3=python3
 721         ], [
 722                 AC_MSG_WARN([Using user-defined PYTHON3 ($PYTHON3) for lttng-ust python3 agent check])
 723         ])
 724
 725         AC_PATH_PROG([PYTHON3_BIN],[$PYTHON3])
 726         AS_IF([test -z "$PYTHON3_BIN"], [
 727                 AS_IF([test -z "$test_python3_agent_autodetect"],[
 728                         AC_MSG_ERROR([No python3 interpreter found. PYTHON3 can be set to override default interpreter path])
 729                 ])
 730         ], [
 731                 AC_MSG_CHECKING([for python3 lttng-ust agent])
 732                 AS_IF([$PYTHON3_BIN -c "import $UST_PYTHON_AGENT" 2>/dev/null], [
 733                         PYTHON3_AGENT=$PYTHON3_BIN
 734                         AC_MSG_RESULT([yes])
 735                         RUN_PYTHON_AGENT_TEST=yes
 736                 ], [
 737                         AC_MSG_RESULT([no])
 738                         AS_IF([test -z "$test_python3_agent_autodetect"],[
 739                                 AC_MSG_ERROR([No python3 agent found. The path to the agent can be specified by setting the PYTHONPATH environment variable.])
 740                         ])
 741                 ])
 742
 743         ])
 744 ])
 745 AC_SUBST([RUN_PYTHON_AGENT_TEST])
 746 AC_SUBST([PYTHON2_AGENT])
 747 AC_SUBST([PYTHON3_AGENT])
 748
 749 # Arguments for binaries build exclusion
 750 AC_ARG_ENABLE([bin-lttng], AS_HELP_STRING([--disable-bin-lttng],[Disable the build of lttng binaries]))
 751 AC_ARG_ENABLE([bin-lttng-consumerd], AS_HELP_STRING([--disable-bin-lttng-consumerd],
 752               [Disable the build of lttng-consumerd binaries]))
 753 AC_ARG_ENABLE([bin-lttng-crash], AS_HELP_STRING([--disable-bin-lttng-crash],[Disable the build of lttng-crash binaries]))
 754 AC_ARG_ENABLE([bin-lttng-relayd], AS_HELP_STRING([--disable-bin-lttng-relayd],
 755               [Disable the build of lttng-relayd binaries]))
 756 AC_ARG_ENABLE([bin-lttng-sessiond], AS_HELP_STRING([--disable-bin-lttng-sessiond],
 757               [Disable the build of lttng-sessiond binaries]))
 758 AC_ARG_ENABLE([extras], AS_HELP_STRING([--disable-extras],
 759               [Disable the build of the extra components]))
 760
 761
 762 # Always build libconfig since it a dependency of libcommon
 763 build_lib_config=yes
 764
 765 build_lib_compat=no
 766 build_lib_consumer=no
 767 build_lib_hashtable=no
 768 build_lib_health=no
 769 build_lib_index=no
 770 build_lib_kernel_consumer=no
 771 build_lib_kernel_ctl=no
 772 build_lib_lttng_ctl=no
 773 build_lib_relayd=no
 774 build_lib_sessiond_comm=no
 775 build_lib_testpoint=no
 776 build_lib_ust_consumer=no
 777
 778 # There is an overlap for enabled dependencies, but this makes everything
 779 # simpler. libcommon and libconfig are always compiled so they are not repeated
 780 # here.
 781
 782 # Enable binary dependencies.
 783 AS_IF([test x$enable_bin_lttng != xno],
 784       [
 785        build_lib_lttng_ctl=yes
 786       ]
 787 )
 788
 789 AS_IF([test x$enable_bin_lttng_consumerd != xno],
 790       [
 791        build_lib_consumer=yes
 792        build_lib_sessiond_comm=yes
 793        build_lib_index=yes
 794        build_lib_health=yes
 795        build_lib_testpoint=yes
 796       ]
 797 )
 798
 799 AS_IF([test x$enable_bin_lttng_crash != xno],
 800       # Do nothing since libconfig and libcommon are built by default.
 801       []
 802 )
 803
 804 AS_IF([test x$enable_bin_lttng_relayd != xno],
 805       [
 806        build_lib_lttng_ctl=yes
 807        build_lib_sessiond_comm=yes
 808        build_lib_hashtable=yes
 809        build_lib_compat=yes
 810        build_lib_index=yes
 811        build_lib_health=yes
 812        build_lib_testpoint=yes
 813       ]
 814 )
 815 AS_IF([test x$enable_bin_lttng_sessiond != xno],
 816       [
 817        build_lib_lttng_ctl=yes
 818        build_lib_sessiond_comm=yes
 819        build_lib_kernel_ctl=yes
 820        build_lib_hashtable=yes
 821        build_lib_compat=yes
 822        build_lib_relayd=yes
 823        build_lib_testpoint=yes
 824        build_lib_health=yes
 825        build_lib_health=yes
 826       ]
 827 )
 828
 829 # Libraries dependencies enabling
 830 AS_IF([test x$build_lib_lttng_ctl = xyes],
 831       [
 832        build_lib_sessiond_comm=yes
 833        build_lib_hashtable=yes
 834       ]
 835 )
 836
 837 AS_IF([test x$build_lib_consumer = xyes],
 838       [
 839        build_lib_sessiond_comm=yes
 840        build_lib_kernel_consumer=yes
 841        build_lib_hashtable=yes
 842        build_lib_compat=yes
 843        build_lib_relayd=yes
 844        AS_IF([test x$lttng_ust_ctl_found = xyes],[build_lib_ust_consumer=yes])
 845       ]
 846 )
 847
 848 AS_IF([test x$build_lib_kernel_consumer = xyes],
 849       [
 850        build_lib_kernel_ctl=yes
 851        build_lib_relayd=yes
 852       ]
 853 )
 854
 855 AS_IF([test x$build_lib_relayd = xyes],
 856       [
 857        build_lib_sessiond_comm=yes
 858       ]
 859 )
 860
 861
 862 # Export binaries build conditions.
 863 AM_CONDITIONAL([BUILD_BIN_LTTNG], [test x$enable_bin_lttng != xno])
 864 AM_CONDITIONAL([BUILD_BIN_LTTNG_CONSUMERD], [test x$enable_bin_lttng_consumerd != xno])
 865 AM_CONDITIONAL([BUILD_BIN_LTTNG_CRASH], [test x$enable_bin_lttng_crash != xno])
 866 AM_CONDITIONAL([BUILD_BIN_LTTNG_RELAYD], [test x$enable_bin_lttng_relayd != xno])
 867 AM_CONDITIONAL([BUILD_BIN_LTTNG_SESSIOND], [test x$enable_bin_lttng_sessiond != xno])
 868
 869 # Export the tests and extras build conditions.
 870 AS_IF([\
 871 test "x$enable_bin_lttng" != "xno" && \
 872 test "x$enable_bin_lttng_consumerd" != "xno" && \
 873 test "x$enable_bin_lttng_crash" != "xno" && \
 874 test "x$enable_bin_lttng_relayd" != "xno" && \
 875 test "x$enable_bin_lttng_sessiond" != "xno"],
 876 [build_tests=yes],
 877 [build_tests=no]
 878 )
 879
 880 AM_CONDITIONAL([BUILD_TESTS], [test x$build_tests = xyes])
 881 AM_CONDITIONAL([BUILD_EXTRAS], [test x$enable_extras != xno])
 882
 883 # Export libraries build conditions.
 884 AM_CONDITIONAL([BUILD_LIB_COMPAT], [test x$build_lib_compat = xyes])
 885 AM_CONDITIONAL([BUILD_LIB_CONFIG], [test x$build_lib_config = xyes])
 886 AM_CONDITIONAL([BUILD_LIB_CONSUMER], [test x$build_lib_consumer = xyes])
 887 AM_CONDITIONAL([BUILD_LIB_HASHTABLE], [test x$build_lib_hashtable = xyes])
 888 AM_CONDITIONAL([BUILD_LIB_HEALTH], [test x$build_lib_health = xyes])
 889 AM_CONDITIONAL([BUILD_LIB_INDEX], [test x$build_lib_index = xyes])
 890 AM_CONDITIONAL([BUILD_LIB_KERNEL_CONSUMER], [test x$build_lib_kernel_consumer = xyes])
 891 AM_CONDITIONAL([BUILD_LIB_KERNEL_CTL], [test x$build_lib_kernel_ctl = xyes])
 892 AM_CONDITIONAL([BUILD_LIB_LTTNG_CTL], [test x$build_lib_lttng_ctl = xyes])
 893 AM_CONDITIONAL([BUILD_LIB_RELAYD], [test x$build_lib_relayd = xyes])
 894 AM_CONDITIONAL([BUILD_LIB_SESSIOND_COMM], [test x$build_lib_sessiond_comm = xyes])
 895 AM_CONDITIONAL([BUILD_LIB_TESTPOINT], [test x$build_lib_testpoint = xyes])
 896 AM_CONDITIONAL([BUILD_LIB_UST_CONSUMER], [test x$build_lib_ust_consumer = xyes])
 897
 898 # check for pgrep
 899 AC_PATH_PROG([PGREP], [pgrep], [no])
 900 AM_CONDITIONAL([HAS_PGREP], [test "x$PGREP" != "xno"])
 901
 902 # check for bison
 903 have_bison=yes
 904
 905 AS_IF([test "x$(basename "$YACC")" != "xbison -y"], [have_bison=no])
 906 AC_PATH_PROG([BISON], [bison])
 907 AX_PROG_BISON_VERSION([2.4], [], [have_bison=no])
 908
 909 AS_IF([test "x$have_bison" = "xno"], [
 910         AS_IF([test "x$in_git_repo" = "xyes"], [
 911                 AC_MSG_ERROR([Bison >= 2.4 is required when building from the Git repository.])
 912         ], [
 913                 AC_MSG_WARN([
 914 Missing Bison >= 2.4. Note that the parser files are already built in
 915 this distribution tarball, so Bison is only needed if you intend to
 916 modify their sources.
 917                 ])
 918         ])
 919 ])
 920
 921 # export bison condition
 922 AM_CONDITIONAL([HAVE_BISON], [test "x$have_bison" = "xyes"])
 923
 924 # check for flex
 925 have_flex=yes
 926
 927 AS_IF([test "x$LEX" != "xflex"], [have_flex=no])
 928 AC_PATH_PROG([FLEX], [flex])
 929 AX_PROG_FLEX_VERSION([2.5.35], [], [have_flex=no])
 930
 931 AS_IF([test "x$have_flex" = "xno"], [
 932         AS_IF([test "x$in_git_repo" = "xyes"], [
 933                 AC_MSG_ERROR([Flex >= 2.5.35 is required when building from the Git repository.])
 934         ], [
 935                 AC_MSG_WARN([
 936 Missing Flex >= 2.5.35. Note that the lexer files are already built in
 937 this distribution tarball, so Flex is only needed if you intend to
 938 modify their sources.
 939                 ])
 940         ])
 941 ])
 942
 943 # export flex condition
 944 AM_CONDITIONAL([HAVE_FLEX], [test "x$have_flex" = "xyes"])
 945
 946 CFLAGS="-Wall $CFLAGS -g -fno-strict-aliasing"
 947
 948 DEFAULT_INCLUDES="-I\$(top_srcdir) -I\$(top_builddir) -I\$(top_builddir)/src -I\$(top_builddir)/include -include config.h"
 949
 950 lttngincludedir="${includedir}/lttng"
 951
 952 AC_SUBST(lttngincludedir)
 953 AC_SUBST(DEFAULT_INCLUDES)
 954
 955 lttnglibexecdir="${libdir}/lttng/libexec"
 956 AC_SUBST(lttnglibexecdir)
 957
 958 AC_CONFIG_FILES([
 959         Makefile
 960         doc/Makefile
 961         doc/man/Makefile
 962         doc/man/asciidoc-attrs.conf
 963         include/Makefile
 964         extras/Makefile
 965         extras/bindings/Makefile
 966         extras/bindings/swig/Makefile
 967         extras/bindings/swig/python/Makefile
 968         extras/core-handler/Makefile
 969         src/Makefile
 970         src/common/Makefile
 971         src/common/kernel-ctl/Makefile
 972         src/common/kernel-consumer/Makefile
 973         src/common/consumer/Makefile
 974         src/common/ust-consumer/Makefile
 975         src/common/hashtable/Makefile
 976         src/common/sessiond-comm/Makefile
 977         src/common/compat/Makefile
 978         src/common/relayd/Makefile
 979         src/common/testpoint/Makefile
 980         src/common/index/Makefile
 981         src/common/health/Makefile
 982         src/common/config/Makefile
 983         src/lib/Makefile
 984         src/lib/lttng-ctl/Makefile
 985         src/lib/lttng-ctl/filter/Makefile
 986         src/lib/lttng-ctl/lttng-ctl.pc
 987         src/bin/Makefile
 988         src/bin/lttng-consumerd/Makefile
 989         src/bin/lttng-sessiond/Makefile
 990         src/bin/lttng-relayd/Makefile
 991         src/bin/lttng/Makefile
 992         src/bin/lttng-crash/Makefile
 993         tests/Makefile
 994         tests/destructive/Makefile
 995         tests/regression/Makefile
 996         tests/regression/kernel/Makefile
 997         tests/regression/tools/Makefile
 998         tests/regression/tools/streaming/Makefile
 999         tests/regression/tools/filtering/Makefile
1000         tests/regression/tools/health/Makefile
1001         tests/regression/tools/tracefile-limits/Makefile
1002         tests/regression/tools/snapshots/Makefile
1003         tests/regression/tools/live/Makefile
1004         tests/regression/tools/exclusion/Makefile
1005         tests/regression/tools/save-load/Makefile
1006         tests/regression/tools/save-load/configuration/Makefile
1007         tests/regression/tools/mi/Makefile
1008         tests/regression/tools/wildcard/Makefile
1009         tests/regression/tools/crash/Makefile
1010         tests/regression/tools/regen-metadata/Makefile
1011         tests/regression/tools/regen-statedump/Makefile
1012         tests/regression/ust/Makefile
1013         tests/regression/ust/nprocesses/Makefile
1014         tests/regression/ust/high-throughput/Makefile
1015         tests/regression/ust/low-throughput/Makefile
1016         tests/regression/ust/before-after/Makefile
1017         tests/regression/ust/buffers-pid/Makefile
1018         tests/regression/ust/periodical-metadata-flush/Makefile
1019         tests/regression/ust/multi-session/Makefile
1020         tests/regression/ust/overlap/Makefile
1021         tests/regression/ust/overlap/demo/Makefile
1022         tests/regression/ust/linking/Makefile
1023         tests/regression/ust/daemon/Makefile
1024         tests/regression/ust/exit-fast/Makefile
1025         tests/regression/ust/fork/Makefile
1026         tests/regression/ust/libc-wrapper/Makefile
1027         tests/regression/ust/baddr-statedump/Makefile
1028         tests/regression/ust/ust-dl/Makefile
1029         tests/regression/ust/java-jul/Makefile
1030         tests/regression/ust/java-log4j/Makefile
1031         tests/regression/ust/python-logging/Makefile
1032         tests/regression/ust/getcpu-override/Makefile
1033         tests/regression/ust/clock-override/Makefile
1034         tests/regression/ust/type-declarations/Makefile
1035         tests/regression/ust/rotation-destroy-flush/Makefile
1036         tests/regression/ust/blocking/Makefile
1037         tests/stress/Makefile
1038         tests/unit/Makefile
1039         tests/unit/ini_config/Makefile
1040         tests/perf/Makefile
1041         tests/utils/Makefile
1042         tests/utils/tap/Makefile
1043         tests/utils/testapp/Makefile
1044         tests/utils/testapp/gen-ust-events/Makefile
1045         tests/utils/testapp/gen-ust-nevents/Makefile
1046         tests/utils/testapp/gen-ust-tracef/Makefile
1047 ])
1048
1049 # Inject variable into python test script.
1050 AC_CONFIG_FILES([tests/regression/ust/python-logging/test_python_logging],[chmod +x tests/regression/ust/python-logging/test_python_logging])
1051 # Inject LTTNG_TOOLS_BUILD_WITH_LIBPFM variable in test script.
1052 AC_CONFIG_FILES([tests/perf/test_perf_raw],[chmod +x tests/perf/test_perf_raw])
1053
1054 AC_OUTPUT
1055
1056 #
1057 # Mini-report on what will be built.
1058 #
1059
1060 PPRINT_INIT
1061 PPRINT_SET_INDENT(1)
1062 PPRINT_SET_TS(38)
1063
1064 AS_ECHO
1065 AS_ECHO("${PPRINT_COLOR_BLDBLU}LTTng-tools $PACKAGE_VERSION \"$version_name\"$PPRINT_COLOR_RST")
1066 AS_ECHO
1067
1068 AS_IF([test -n "$report_fold"], [
1069         AS_ECHO("`AS_ECHO("$version_description") | $report_fold -s`")
1070 ], [
1071         AS_ECHO("$version_description")
1072 ])
1073
1074 AS_ECHO
1075 PPRINT_SUBTITLE([Features])
1076
1077 # Target architecture we're building for.
1078 target_arch=$host_cpu
1079 [
1080 for f in $CFLAGS; do
1081         if test $f = "-m32"; then
1082                         target_arch="32-bit"
1083         elif test $f = "-m64"; then
1084                         target_arch="64-bit"
1085         fi
1086 done
1087 ]
1088 PPRINT_PROP_STRING([Target architecture], $target_arch)
1089
1090 # kmod enabled/disabled
1091 test "x$kmod_found" = "xyes" && value=1 || value=0
1092 PPRINT_PROP_BOOL([libkmod support], $value)
1093
1094 # LTTng-UST enabled/disabled
1095 test "x$lttng_ust_support" = "xyes" && value=1 || value=0
1096 PPRINT_PROP_BOOL([LTTng-UST support], $value)
1097
1098 AS_ECHO
1099 PPRINT_SUBTITLE([Binaries])
1100
1101 # List binaries to be built
1102 test x$enable_bin_lttng != xno && value=1 || value=0
1103 PPRINT_PROP_BOOL([lttng], $value)
1104
1105 test x$enable_bin_lttng_consumerd != xno && value=1 || value=0
1106 PPRINT_PROP_BOOL([lttng-consumerd], $value)
1107
1108 test x$enable_bin_lttng_crash != xno && value=1 || value=0
1109 PPRINT_PROP_BOOL([lttng-crash], $value)
1110
1111 test x$enable_bin_lttng_relayd != xno && value=1 || value=0
1112 PPRINT_PROP_BOOL([lttng-relayd], $value)
1113
1114 test x$enable_bin_lttng_sessiond != xno && value=1 || value=0
1115 PPRINT_PROP_BOOL([lttng-sessiond], $value)
1116
1117 # Extras
1118 test x$enable_extras != xno && value=1 || value=0
1119 AS_ECHO
1120 PPRINT_SET_INDENT(0)
1121 PPRINT_PROP_BOOL([Extras], $value, $PPRINT_COLOR_SUBTITLE)
1122 PPRINT_SET_INDENT(1)
1123
1124 AS_ECHO
1125 PPRINT_SUBTITLE([Tests])
1126
1127 # Print clear message that tests won't be built
1128 AS_IF([test "x$build_tests" = "xno"],[
1129         PPRINT_WARN([Tests won't be built since some binaries were disabled])
1130 ])
1131
1132 # LTTng UST Java agent JUL tests enabled/disabled
1133 test "x$test_java_agent_jul" = "xyes" && value=1 || value=0
1134 PPRINT_PROP_BOOL([LTTng-UST Java agent JUL tests], $value)
1135
1136 # LTTng UST Java agent Log4j tests enabled/disabled
1137 test "x$test_java_agent_log4j" = "xyes" && value=1 || value=0
1138 PPRINT_PROP_BOOL([LTTng-UST Java agent Log4j tests], $value)
1139
1140 test ! -z "$PYTHON2_AGENT" && value=1 || value=0
1141 PPRINT_PROP_BOOL([LTTng-UST Python2 agent tests], $value)
1142
1143 test ! -z "$PYTHON3_AGENT" && value=1 || value=0
1144 PPRINT_PROP_BOOL([LTTng-UST Python3 agent tests], $value)
1145
1146 #Python binding enabled/disabled
1147 test "x$enable_python_binding" = xyes && value=1 || value=0
1148 AS_ECHO
1149 PPRINT_SET_INDENT(0)
1150 PPRINT_PROP_BOOL([Python binding], $value, $PPRINT_COLOR_SUBTITLE)
1151
1152 # man pages build enabled/disabled
1153 m4_pushdef([build_man_pages_msg], [Build and install man pages])
1154
1155 AS_IF([test "x$man_pages_opt" != "xno"], [
1156         AS_IF([test "x$in_git_repo" = "xyes"], [
1157                 PPRINT_PROP_BOOL([build_man_pages_msg], 1, $PPRINT_COLOR_SUBTITLE)
1158         ], [
1159                 AS_IF([test "x$have_asciidoc_xmlto" = "xyes"], [
1160                         PPRINT_PROP_BOOL([build_man_pages_msg], 1, $PPRINT_COLOR_SUBTITLE)
1161                 ], [
1162                         PPRINT_PROP_STRING([build_man_pages_msg],
1163                                 [${PPRINT_COLOR_BLDGRN}yes (already built)],
1164                                 $PPRINT_COLOR_SUBTITLE)
1165                 ])
1166         ])
1167 ], [
1168         PPRINT_PROP_BOOL([build_man_pages_msg], 0, $PPRINT_COLOR_SUBTITLE)
1169 ])
1170
1171 m4_popdef([build_man_pages_msg])
1172
1173 PPRINT_SET_INDENT(1)
1174
1175 report_bindir="`eval eval echo $bindir`"
1176 report_libdir="`eval eval echo $libdir`"
1177
1178 # Print the bindir and libdir this `make install' will install into.
1179 AS_ECHO
1180 PPRINT_SUBTITLE([Install directories])
1181 PPRINT_PROP_STRING([Binaries], [$report_bindir])
1182 PPRINT_PROP_STRING([Libraries], [$report_libdir])
1183
1184 AS_ECHO
1185 PPRINT_SUBTITLE([Search directories])
1186
1187 # If we build the sessiond, print the paths it will use
1188 AS_IF([test "$SESSIOND_BIN" = ""],[
1189         path="$report_bindir/lttng-sessiond"
1190 ],[
1191         path="$SESSIOND_BIN"
1192 ])
1193 PPRINT_PROP_STRING([lttng-sessiond executable], [$path])
1194
1195 AS_IF([test "$CONSUMERD32_BIN" = ""],[
1196         path="`eval eval echo $lttnglibexecdir`/lttng-consumerd"
1197 ],[
1198         path="$CONSUMERD32_BIN"
1199 ])
1200 PPRINT_PROP_STRING([32-bit lttng-consumerd executable], [$path])
1201
1202 AS_IF([test "$CONSUMERD32_LIBDIR" = ""],[
1203         path="`eval eval echo $libdir`"
1204 ],[
1205         path="$CONSUMERD32_LIBDIR"
1206 ])
1207 PPRINT_PROP_STRING([32-bit consumer libraries], [$path])
1208
1209 AS_IF([test "$CONSUMERD64_BIN" = ""],[
1210         path="`eval eval echo $lttnglibexecdir`/lttng-consumerd"
1211 ],[
1212         path="$CONSUMERD64_BIN"
1213 ])
1214 PPRINT_PROP_STRING([64-bit lttng-consumerd executable], [$path])
1215
1216 AS_IF([test "$CONSUMERD64_LIBDIR" = ""],[
1217         path="`eval eval echo $libdir`"
1218 ],[
1219         path="$CONSUMERD64_LIBDIR"
1220 ])
1221 PPRINT_PROP_STRING([64-bit consumer libraries], [$path])
1222 PPRINT_SET_INDENT(0)
1223
1224 AS_IF([test "x$warn_prebuilt_man_pages" = "xyes" ], [
1225         AS_ECHO
1226         PPRINT_WARN([You need asciidoc and xmlto to build the LTTng-tools man pages.
1227
1228 Note that the man pages are already built in this distribution tarball,
1229 therefore asciidoc and xmlto are only needed if you intend to modify
1230 their sources.
1231
1232 Also note that the installed man pages will contain the project's
1233 default command-line option and environment variable values.
1234
1235 Use --disable-man-pages to completely disable building and installing
1236 the man pages.])
1237 ])