configure.ac

   1 AC_PREREQ([2.64])
   2 AC_INIT([lttng-tools],[2.11.0-pre],[jeremie.galarneau@efficios.com],[],[https://lttng.org])
   3
   4 AC_CONFIG_HEADERS([include/config.h])
   5 AC_CONFIG_AUX_DIR([config])
   6 AC_CONFIG_MACRO_DIR([m4])
   7
   8 AC_CANONICAL_TARGET
   9 AC_CANONICAL_HOST
  10
  11 AM_INIT_AUTOMAKE([foreign dist-bzip2 no-dist-gzip tar-pax nostdinc])
  12 AM_MAINTAINER_MODE([enable])
  13
  14 # Enable silent rules if available (Introduced in AM 1.11)
  15 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  16
  17 AC_REQUIRE_AUX_FILE([tap-driver.sh])
  18
  19 # Checks for C compiler
  20 AC_USE_SYSTEM_EXTENSIONS
  21 AC_SYS_LARGEFILE
  22 AC_PROG_CC
  23 AC_PROG_CC_STDC
  24
  25 # Checks for programs.
  26 AC_PROG_GREP
  27 AC_PROG_MAKE_SET
  28 AC_PROG_SED
  29 AC_PATH_PROG([report_fold], [fold])
  30 LT_INIT
  31
  32 # Check for objcopy, required by the base address statedump and dynamic linker tests
  33 AC_CHECK_TOOL([OBJCOPY], [objcopy], [no])
  34 AS_IF([test "x$OBJCOPY" = "xno"],
  35         [AC_MSG_WARN([Cannot find objcopy. The base address statedump and dynamic linker tests will be disabled. Install the binutils package to remediate this.])]
  36 )
  37 AM_CONDITIONAL([HAVE_OBJCOPY], [test "x$OBJCOPY" != xno])
  38
  39 # check for pgrep
  40 AC_PATH_PROG([PGREP], [pgrep], [no])
  41 AM_CONDITIONAL([HAVE_PGREP], [test "x$PGREP" != "xno"])
  42
  43 # set $IN_GIT_REPO if we're in the Git repository; the `bootstrap` file
  44 # is not distributed in tarballs
  45 AS_IF([test -f "$srcdir/bootstrap"], [in_git_repo=yes], [in_git_repo=no])
  46 AM_CONDITIONAL([IN_GIT_REPO], [test "x$in_git_repo" = "xyes"])
  47
  48 # check for bison
  49 AC_PROG_YACC
  50 BISON=$YACC
  51 AX_PROG_BISON_VERSION([2.4], [have_bison=yes])
  52
  53 AS_IF([test "x$have_bison" != "xyes"], [
  54   AS_IF([test "x$in_git_repo" = "xyes"], [
  55     AC_MSG_FAILURE([
  56 Bison >= 2.4 is required when building from the Git repository. You can
  57 set the YACC variable to override automatic detection.
  58     ])
  59   ], [
  60     AC_MSG_WARN([
  61 Missing Bison >= 2.4. Note that the parser files are already built in
  62 this distribution tarball, so Bison is only needed if you intend to
  63 modify their sources. You can set the YACC variable to override automatic
  64 detection.
  65     ])
  66   ])
  67 ])
  68 AM_CONDITIONAL([HAVE_BISON], [test "x$have_bison" = "xyes"])
  69
  70 # check for flex
  71 AC_PROG_LEX
  72 FLEX=$LEX
  73 AX_PROG_FLEX_VERSION([2.5.35], [have_flex=yes])
  74
  75 AS_IF([test "x$have_flex" != "xyes"], [
  76   AS_IF([test "x$in_git_repo" = "xyes"], [
  77     AC_MSG_FAILURE([
  78 Flex >= 2.5.35 is required when building from the Git repository. You can
  79 set the LEX variable to override automatic detection.
  80     ])
  81   ], [
  82     AC_MSG_WARN([
  83 Missing Flex >= 2.5.35. Note that the lexer files are already built in
  84 this distribution tarball, so Flex is only needed if you intend to
  85 modify their sources. You can set the LEX variable to override automatic
  86 detection.
  87     ])
  88   ])
  89 ])
  90 AM_CONDITIONAL([HAVE_FLEX], [test "x$have_flex" = "xyes"])
  91
  92
  93 # Checks for typedefs, structures, and compiler characteristics.
  94 AC_C_INLINE
  95 AC_TYPE_INT32_T
  96 AC_TYPE_INT64_T
  97 AC_TYPE_MODE_T
  98 AC_TYPE_OFF_T
  99 AC_TYPE_PID_T
 100 AC_TYPE_SIZE_T
 101 AC_TYPE_SSIZE_T
 102 AC_TYPE_UID_T
 103 AC_TYPE_UINT16_T
 104 AC_TYPE_UINT32_T
 105 AC_TYPE_UINT64_T
 106 AC_TYPE_UINT8_T
 107
 108 AX_C___ATTRIBUTE__
 109 AS_IF([test "x$ax_cv___attribute__" = "xyes"],
 110         [:],
 111         [AC_MSG_ERROR([The compiler does not support __attribute__ extensions])])
 112
 113 AX_PTHREAD(,[AC_MSG_ERROR([Could not configure pthreads support])])
 114
 115 AX_LIB_SOCKET_NSL
 116
 117 LT_NO_UNDEFINED=""
 118 AS_CASE([$host_os],
 119   [cygwin*],
 120     [
 121       LT_NO_UNDEFINED="-no-undefined"
 122     ],
 123   [cygwin*|darwin*|mingw*|solaris*],
 124     [
 125       # On platforms where we only support the relayd, disable the other binaries by default
 126       AS_IF([test "x$enable_bin_lttng" = "x" ], [enable_bin_lttng=no])
 127       AS_IF([test "x$enable_bin_lttng_consumerd" = "x" ], [enable_bin_lttng_consumerd=no])
 128       AS_IF([test "x$enable_bin_lttng_crash" = "x" ], [enable_bin_lttng_crash=no])
 129       AS_IF([test "x$enable_bin_lttng_sessiond" = "x" ], [enable_bin_lttng_sessiond=no])
 130       AS_IF([test "x$enable_extras" = "x" ], [enable_extras=no])
 131       AS_IF([test "x$with_lttng_ust" = "x" ], [with_lttng_ust=no])
 132     ]
 133 )
 134
 135 AC_SUBST(LT_NO_UNDEFINED)
 136
 137 # Compute minor/major/patchlevel version numbers
 138 major_version=$(echo AC_PACKAGE_VERSION | $SED 's/^\([[0-9]]\)*\.[[0-9]]*\.[[0-9]]*.*$/\1/')
 139 minor_version=$(echo AC_PACKAGE_VERSION | $SED 's/^[[0-9]]*\.\([[0-9]]*\)\.[[0-9]]*.*$/\1/')
 140 patchlevel_version=$(echo AC_PACKAGE_VERSION | $SED 's/^[[0-9]]*\.[[0-9]]*\.\([[0-9]]*\).*$/\1/')
 141
 142 AC_SUBST([MAJOR_VERSION], [$major_version])
 143 AC_SUBST([MINOR_VERSION], [$minor_version])
 144 AC_SUBST([PATCHLEVEL_VERSION], [$patchlevel_version])
 145 AC_DEFINE_UNQUOTED([VERSION_MAJOR], $major_version, [LTTng-Tools major version number])
 146 AC_DEFINE_UNQUOTED([VERSION_MINOR], $minor_version, [LTTng-Tools minor version number])
 147 AC_DEFINE_UNQUOTED([VERSION_PATCHLEVEL], $patchlevel_version, [LTTng-Tools patchlevel version number])
 148
 149 version_name="Codename TBD"
 150 version_description='Description TBD'
 151 version_description_c=$(echo $version_description | $SED 's/"/\\"/g')
 152
 153 AC_DEFINE_UNQUOTED([VERSION_NAME], ["$version_name"], "")
 154 AC_DEFINE_UNQUOTED([VERSION_DESCRIPTION], ["$version_description_c"], "")
 155
 156 # libtool link_all_deplibs fixup. See http://bugs.lttng.org/issues/321.
 157 AC_ARG_ENABLE(libtool-linkdep-fixup,
 158         AS_HELP_STRING([--disable-libtool-linkdep-fixup],
 159                         [disable the libtool fixup for linking all dependent libraries (link_all_deplibs)]),
 160         libtool_fixup=$enableval,
 161         libtool_fixup=yes)
 162
 163 AS_IF([test "x$libtool_fixup" = "xyes"],
 164             [
 165             libtool_m4="$srcdir/m4/libtool.m4"
 166             libtool_flag_pattern=".*link_all_deplibs\s*,\s*\$1\s*)"
 167             AC_MSG_CHECKING([for occurence(s) of link_all_deplibs = no in $libtool_m4])
 168             libtool_flag_pattern_count=$($GREP -c "$libtool_flag_pattern\s*=\s*no" $libtool_m4)
 169             AS_IF([test $libtool_flag_pattern_count -ne 0],
 170             [
 171                   AC_MSG_RESULT([$libtool_flag_pattern_count])
 172                   AC_MSG_WARN([the detected libtool will not link all dependencies, forcing link_all_deplibs = unknown])
 173                   $SED -i "s/\($libtool_flag_pattern\)\s*=\s*no/\1=unknown/g" $libtool_m4
 174                   ],
 175                   [
 176                   AC_MSG_RESULT([none])
 177                   ])
 178             ])
 179
 180 AM_CONDITIONAL([NO_SHARED], [test x$enable_shared = xno])
 181
 182 AC_CHECK_HEADERS([ \
 183         sys/types.h unistd.h fcntl.h string.h pthread.h limits.h \
 184         signal.h stdlib.h sys/un.h sys/socket.h stdlib.h stdio.h \
 185         getopt.h sys/ipc.h sys/shm.h popt.h grp.h arpa/inet.h \
 186         netdb.h netinet/in.h paths.h stddef.h sys/file.h sys/ioctl.h \
 187         sys/mount.h sys/param.h sys/time.h
 188 ])
 189
 190 # Basic functions check
 191 AC_CHECK_FUNCS([ \
 192         atexit bzero clock_gettime dup2 fdatasync fls ftruncate \
 193         gethostbyname gethostname getpagesize localtime_r memchr memset \
 194         mkdir munmap putenv realpath rmdir socket strchr strcspn strdup \
 195         strncasecmp strndup strnlen strpbrk strrchr strstr strtol strtoul \
 196         strtoull dirfd gethostbyname2 getipnodebyname epoll_create1 \
 197         sched_getcpu sysconf sync_file_range
 198 ])
 199
 200 # Check if clock_gettime, timer_create, timer_settime, and timer_delete are available in lib rt, and if so,
 201 # add -lrt to LIBS
 202 AC_CHECK_LIB([rt], [clock_gettime, timer_create, timer_settime, timer_delete])
 203
 204 # Checks for dl.
 205 AC_CHECK_LIB([dl], [dlopen], [
 206         have_libdl=yes
 207         libdl_name=dl
 208 ], [
 209         # libdl not found, check for dlopen in libc.
 210         AC_CHECK_LIB([c], [dlopen], [
 211                 have_libc_dl=yes
 212                 libdl_name=c
 213         ], [
 214                 AC_MSG_ERROR([Cannot find dlopen in libdl nor libc. Use [LDFLAGS]=-Ldir to specify their location.])
 215         ])
 216 ])
 217
 218 # Check if libdl has dlmopen support.
 219 AH_TEMPLATE([HAVE_DLMOPEN], ["Define to 1 if dlmopen is available."])
 220 AC_CHECK_LIB([$libdl_name], [dlmopen], [
 221         AC_DEFINE([HAVE_DLMOPEN], [1])
 222         HAVE_DLMOPEN=1
 223 ], [
 224         HAVE_DLMOPEN=0
 225 ])
 226 AC_SUBST(HAVE_DLMOPEN)
 227
 228 # Babeltrace viewer check
 229 AC_ARG_WITH([babeltrace-bin],
 230         AS_HELP_STRING([--with-babeltrace-bin],
 231         [Location of the babeltrace viewer executable (including the filename)]),
 232         [BABELTRACE_BIN="$withval"],
 233         [BABELTRACE_BIN=''])
 234 AC_SUBST([BABELTRACE_BIN])
 235
 236 # lttv-gui
 237 AC_ARG_WITH([lttv-gui-bin],
 238         AS_HELP_STRING([--with-lttv-gui-bin],
 239    [Location of the lttv GUI viewer executable (including the filename)]),
 240    [LTTV_GUI_BIN="$withval"],
 241    [LTTV_GUI_BIN=''])
 242 AC_SUBST([LTTV_GUI_BIN])
 243
 244 AC_ARG_WITH([consumerd32-bin],
 245         AS_HELP_STRING([--with-consumerd32-bin],
 246         [Location of the 32-bit consumerd executable (including the filename)]),
 247         [CONSUMERD32_BIN="$withval"],
 248         [CONSUMERD32_BIN=''])
 249 AC_SUBST([CONSUMERD32_BIN])
 250
 251 AC_ARG_WITH([consumerd64-bin],
 252         AS_HELP_STRING([--with-consumerd64-bin],
 253         [Location of the 64-bit consumerd executable (including the filename)]),
 254         [CONSUMERD64_BIN="$withval"],
 255         [CONSUMERD64_BIN=''])
 256 AC_SUBST([CONSUMERD64_BIN])
 257
 258 AC_ARG_WITH([consumerd32-libdir],
 259         AS_HELP_STRING([--with-consumerd32-libdir],
 260         [Directory containing the 32-bit consumerd libraries]),
 261         [CONSUMERD32_LIBDIR="$withval"],
 262         [CONSUMERD32_LIBDIR=''])
 263 AC_SUBST([CONSUMERD32_LIBDIR])
 264
 265 AC_ARG_WITH([consumerd64-libdir],
 266         AS_HELP_STRING([--with-consumerd64-libdir],
 267         [Directory containing the 64-bit consumerd libraries]),
 268         [CONSUMERD64_LIBDIR="$withval"],
 269         [CONSUMERD64_LIBDIR=''])
 270 AC_SUBST([CONSUMERD64_LIBDIR])
 271
 272 AC_ARG_WITH([sessiond-bin],
 273         AS_HELP_STRING([--with-sessiond-bin],
 274         [Location of the sessiond executable (including the filename)]),
 275         [SESSIOND_BIN="$withval"],
 276         [SESSIOND_BIN=''])
 277 AC_SUBST([SESSIOND_BIN])
 278
 279 AC_ARG_WITH([lttng-system-rundir],
 280         AS_HELP_STRING([--with-lttng-system-rundir],
 281         [Location of the system directory where the system-wide lttng-sessiond runtime files are kept. The default is "/var/run/lttng".]),
 282         [LTTNG_SYSTEM_RUNDIR="$withval"],
 283         [LTTNG_SYSTEM_RUNDIR="/var/run/lttng"])
 284 AC_SUBST([LTTNG_SYSTEM_RUNDIR])
 285
 286 AC_ARG_ENABLE([test-java-agent-jul],
 287         [AS_HELP_STRING([--enable-test-java-agent-jul],[enable the LTTng UST Java agent JUL tests [default=no]])],
 288         [test_java_agent_jul=$enableval],
 289         [test_java_agent_jul=no]
 290 )
 291
 292 AC_ARG_ENABLE([test-java-agent-log4j],
 293         [AS_HELP_STRING([--enable-test-java-agent-log4j],[enable the LTTng UST Java agent Log4j tests [default=no]])],
 294         [test_java_agent_log4j=$enableval],
 295         [test_java_agent_log4j=no]
 296 )
 297
 298 AC_ARG_ENABLE([test-java-agent-all],
 299         [AS_HELP_STRING([--enable-test-java-agent-all],[enable all the LTTng UST Java agent tests [default=no]])],
 300         [test_java_agent_jul=$enableval
 301          test_java_agent_log4j=$enableval],
 302         [:]
 303 )
 304
 305 AC_DEFINE_UNQUOTED([CONFIG_CONSUMERD32_BIN], "$CONSUMERD32_BIN", [Location of the 32-bit consumerd executable.])
 306 AC_DEFINE_UNQUOTED([CONFIG_CONSUMERD64_BIN], "$CONSUMERD64_BIN", [Location of the 64-bit consumerd executable])
 307 AC_DEFINE_UNQUOTED([CONFIG_CONSUMERD32_LIBDIR], "$CONSUMERD32_LIBDIR", [Search for consumerd 32-bit libraries in this location.])
 308 AC_DEFINE_UNQUOTED([CONFIG_CONSUMERD64_LIBDIR], "$CONSUMERD64_LIBDIR", [Search for consumerd 64-bit libraries in this location.])
 309 AC_DEFINE_UNQUOTED([CONFIG_BABELTRACE_BIN], "$BABELTRACE_BIN", [Location of the babeltrace viewer executable.])
 310 AC_DEFINE_UNQUOTED([CONFIG_LTTV_GUI_BIN], "$LTTV_GUI_BIN", [Location of the lttv GUI viewer executable.])
 311 AC_DEFINE_UNQUOTED([CONFIG_SESSIOND_BIN], "$SESSIOND_BIN", [Location of the sessiond executable.])
 312 AC_DEFINE_UNQUOTED([CONFIG_LTTNG_SYSTEM_RUNDIR], ["$LTTNG_SYSTEM_RUNDIR"], [LTTng system runtime directory])
 313
 314 AC_DEFUN([_AC_DEFINE_AND_SUBST], [
 315         AC_DEFINE_UNQUOTED([CONFIG_$1], [$2], [$1])
 316         $1="$2"
 317         AC_SUBST([$1])
 318 ])
 319
 320 AC_DEFUN([_AC_DEFINE_QUOTED_AND_SUBST], [
 321         AC_DEFINE_UNQUOTED([CONFIG_$1], ["$2"], [$1])
 322         $1="$2"
 323         AC_SUBST([$1])
 324 ])
 325
 326 # Default values
 327 m4_define([_DEFAULT_CHANNEL_SUBBUF_SIZE], [16384])
 328 m4_define([_DEFAULT_CHANNEL_SUBBUF_NUM], [4])
 329 m4_define([_DEFAULT_CHANNEL_SWITCH_TIMER], [0])
 330 m4_define([_DEFAULT_CHANNEL_LIVE_TIMER], [0])
 331 m4_define([_DEFAULT_CHANNEL_READ_TIMER], [200000])
 332 m4_define([_DEFAULT_CHANNEL_MONITOR_TIMER], [1000000])
 333 m4_define([_DEFAULT_CHANNEL_BLOCKING_TIMEOUT], [0])
 334 _AC_DEFINE_AND_SUBST([DEFAULT_AGENT_TCP_PORT_RANGE_BEGIN], [5345])
 335 _AC_DEFINE_AND_SUBST([DEFAULT_AGENT_TCP_PORT_RANGE_END], [5354])
 336 _AC_DEFINE_AND_SUBST([DEFAULT_APP_SOCKET_RW_TIMEOUT], [5])
 337 _AC_DEFINE_AND_SUBST([DEFAULT_CHANNEL_SUBBUF_SIZE], [_DEFAULT_CHANNEL_SUBBUF_SIZE])
 338 _AC_DEFINE_AND_SUBST([DEFAULT_CHANNEL_TRACEFILE_COUNT], [0])
 339 _AC_DEFINE_AND_SUBST([DEFAULT_CHANNEL_TRACEFILE_SIZE], [0])
 340 _AC_DEFINE_AND_SUBST([DEFAULT_KERNEL_CHANNEL_LIVE_TIMER], [_DEFAULT_CHANNEL_LIVE_TIMER])
 341 _AC_DEFINE_AND_SUBST([DEFAULT_KERNEL_CHANNEL_READ_TIMER], [_DEFAULT_CHANNEL_READ_TIMER])
 342 _AC_DEFINE_AND_SUBST([DEFAULT_KERNEL_CHANNEL_SUBBUF_NUM], [_DEFAULT_CHANNEL_SUBBUF_NUM])
 343 _AC_DEFINE_AND_SUBST([DEFAULT_KERNEL_CHANNEL_SUBBUF_SIZE], [1048576])
 344 _AC_DEFINE_AND_SUBST([DEFAULT_KERNEL_CHANNEL_SWITCH_TIMER], [_DEFAULT_CHANNEL_SWITCH_TIMER])
 345 _AC_DEFINE_AND_SUBST([DEFAULT_KERNEL_CHANNEL_MONITOR_TIMER], [_DEFAULT_CHANNEL_MONITOR_TIMER])
 346 _AC_DEFINE_AND_SUBST([DEFAULT_KERNEL_CHANNEL_BLOCKING_TIMEOUT], [_DEFAULT_CHANNEL_BLOCKING_TIMEOUT])
 347 _AC_DEFINE_AND_SUBST([DEFAULT_LTTNG_LIVE_TIMER], [1000000])
 348 _AC_DEFINE_AND_SUBST([DEFAULT_METADATA_CACHE_SIZE], [4096])
 349 _AC_DEFINE_AND_SUBST([DEFAULT_METADATA_READ_TIMER], [0])
 350 _AC_DEFINE_AND_SUBST([DEFAULT_METADATA_SUBBUF_NUM], [2])
 351 _AC_DEFINE_AND_SUBST([DEFAULT_METADATA_SUBBUF_SIZE], [4096])
 352 _AC_DEFINE_AND_SUBST([DEFAULT_METADATA_SWITCH_TIMER], [_DEFAULT_CHANNEL_SWITCH_TIMER])
 353 _AC_DEFINE_AND_SUBST([DEFAULT_NETWORK_CONTROL_PORT], [5342])
 354 _AC_DEFINE_AND_SUBST([DEFAULT_NETWORK_DATA_PORT], [5343])
 355 _AC_DEFINE_AND_SUBST([DEFAULT_NETWORK_VIEWER_PORT], [5344])
 356 _AC_DEFINE_AND_SUBST([DEFAULT_UST_PID_CHANNEL_LIVE_TIMER], [_DEFAULT_CHANNEL_LIVE_TIMER])
 357 _AC_DEFINE_AND_SUBST([DEFAULT_UST_PID_CHANNEL_READ_TIMER], [0])
 358 _AC_DEFINE_AND_SUBST([DEFAULT_UST_PID_CHANNEL_BLOCKING_TIMEOUT], [0])
 359 _AC_DEFINE_AND_SUBST([DEFAULT_UST_PID_CHANNEL_SUBBUF_NUM], [_DEFAULT_CHANNEL_SUBBUF_NUM])
 360 _AC_DEFINE_AND_SUBST([DEFAULT_UST_PID_CHANNEL_SUBBUF_SIZE], [_DEFAULT_CHANNEL_SUBBUF_SIZE])
 361 _AC_DEFINE_AND_SUBST([DEFAULT_UST_PID_CHANNEL_SWITCH_TIMER], [_DEFAULT_CHANNEL_SWITCH_TIMER])
 362 _AC_DEFINE_AND_SUBST([DEFAULT_UST_PID_CHANNEL_MONITOR_TIMER], [_DEFAULT_CHANNEL_MONITOR_TIMER])
 363 _AC_DEFINE_AND_SUBST([DEFAULT_UST_UID_CHANNEL_LIVE_TIMER], [_DEFAULT_CHANNEL_LIVE_TIMER])
 364 _AC_DEFINE_AND_SUBST([DEFAULT_UST_UID_CHANNEL_READ_TIMER], [0])
 365 _AC_DEFINE_AND_SUBST([DEFAULT_UST_UID_CHANNEL_BLOCKING_TIMEOUT], [0])
 366 _AC_DEFINE_AND_SUBST([DEFAULT_UST_UID_CHANNEL_SUBBUF_NUM], [_DEFAULT_CHANNEL_SUBBUF_NUM])
 367 _AC_DEFINE_AND_SUBST([DEFAULT_UST_UID_CHANNEL_SUBBUF_SIZE], [524288])
 368 _AC_DEFINE_AND_SUBST([DEFAULT_UST_UID_CHANNEL_SWITCH_TIMER], [_DEFAULT_CHANNEL_SWITCH_TIMER])
 369 _AC_DEFINE_AND_SUBST([DEFAULT_UST_UID_CHANNEL_MONITOR_TIMER], [_DEFAULT_CHANNEL_MONITOR_TIMER])
 370 _AC_DEFINE_QUOTED_AND_SUBST([DEFAULT_AGENT_BIND_ADDRESS], [localhost])
 371 _AC_DEFINE_QUOTED_AND_SUBST([DEFAULT_NETWORK_CONTROL_BIND_ADDRESS], [0.0.0.0])
 372 _AC_DEFINE_QUOTED_AND_SUBST([DEFAULT_NETWORK_DATA_BIND_ADDRESS], [0.0.0.0])
 373 _AC_DEFINE_QUOTED_AND_SUBST([DEFAULT_NETWORK_VIEWER_BIND_ADDRESS], [localhost])
 374 _AC_DEFINE_AND_SUBST([DEFAULT_NETWORK_RELAYD_CTRL_MAX_PAYLOAD_SIZE], [134217728])
 375 _AC_DEFINE_AND_SUBST([DEFAULT_ROTATE_PENDING_RELAY_TIMER], [200000])
 376
 377 # Command short descriptions
 378 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_ADD_CONTEXT], [Add context fields to a channel])
 379 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_CREATE], [Create a tracing session])
 380 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_DESTROY], [Tear down tracing sessions])
 381 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_DISABLE_CHANNEL], [Disable tracing channels])
 382 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_DISABLE_EVENT], [Disable event rules])
 383 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_DISABLE_ROTATION], [Unset an automatic rotation schedule])
 384 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_ENABLE_CHANNEL], [Create or enable tracing channels])
 385 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_ENABLE_EVENT], [Create or enable event rules])
 386 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_ENABLE_ROTATION], [Set an automatic rotation schedule])
 387 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_HELP], [Display help information about a command])
 388 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_LIST], [List tracing sessions, domains, channels, and events])
 389 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_LOAD], [Load tracing session configurations])
 390 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_REGENERATE], [Manage an LTTng tracing session's data regeneration])
 391 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_ROTATE], [Archive a tracing session's current trace chunk])
 392 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_SAVE], [Save tracing session configurations])
 393 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_SET_SESSION], [Set current tracing session])
 394 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_SNAPSHOT], [Snapshot buffers of current tracing session])
 395 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_START], [Start tracing])
 396 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_STATUS], [Get the status of the current tracing session])
 397 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_STOP], [Stop tracing])
 398 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_TRACK], [Track specific system resources])
 399 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_UNTRACK], [Untrack specific system resources])
 400 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_VERSION], [Show version information])
 401 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_VIEW], [Start trace viewer])
 402
 403 if test "x$prefix" = "xNONE"; then
 404         prefix=$ac_default_prefix
 405 fi
 406 CONFDIR=`eval echo $sysconfdir`
 407 AC_SUBST(CONFDIR)
 408 AC_DEFINE_UNQUOTED([CONFIG_LTTNG_SYSTEM_CONFIGDIR],"$CONFDIR", [LTTng system configuration directory.])
 409
 410 AC_DEFINE_DIR([CONFIG_LTTNG_SYSTEM_DATADIR],[datadir], [LTTng system data directory.])
 411
 412 # Check libpopt
 413 PKG_CHECK_MODULES([POPT], [popt],
 414   [
 415     dnl PKG_CHECK_MODULES defines POPT_LIBS
 416   ],
 417   [
 418     AC_MSG_WARN([pkg-config was unable to find a valid .pc for libpopt. Set PKG_CONFIG_PATH to specify the pkgconfig configuration file location])
 419     AC_MSG_WARN([Finding libpopt without pkg-config.])
 420     AC_CHECK_LIB([popt],
 421       [poptGetContext],
 422       [POPT_LIBS="-lpopt"],
 423       [
 424         AC_MSG_FAILURE([Cannot find libpopt. Either set PKG_CONFIG_PATH to the configuration file location or use LDFLAGS=-Ldir to specify the library location])
 425       ]
 426     )
 427   ]
 428 )
 429 AC_SUBST(POPT_LIBS)
 430
 431 PKG_CHECK_MODULES([libxml2], [libxml-2.0 >= 2.7.6])
 432
 433 # First, check for uuid in system libs
 434 AH_TEMPLATE([LTTNG_HAVE_LIBUUID], [Define if you have libuuid support])
 435 AC_CHECK_FUNCS([uuid_generate],
 436   [
 437     AC_DEFINE([LTTNG_HAVE_LIBUUID], [1])
 438     UUID_LIBS=""
 439   ],
 440   [
 441     # Then, check if the pkg-config module is available, otherwise explicitly check
 442     # for libuuid, or uuid support in the C-library.
 443     PKG_CHECK_MODULES([UUID], [uuid],
 444       [
 445         AC_DEFINE([LTTNG_HAVE_LIBUUID], [1])
 446         dnl PKG_CHECK_MODULES defines UUID_LIBS
 447       ],
 448       [
 449         AC_MSG_WARN([pkg-config was unable to find a valid .pc for libuuid. Set PKG_CONFIG_PATH to specify the pkgconfig configuration file location])
 450         AC_MSG_WARN([Finding libuuid without pkg-config.])
 451         AC_CHECK_LIB([uuid], [uuid_generate],
 452           [
 453             AC_DEFINE([LTTNG_HAVE_LIBUUID], [1])
 454             UUID_LIBS="-luuid"
 455           ],
 456           [
 457             # libuuid not found, check for uuid_create in libc.
 458             AC_CHECK_LIB([c], [uuid_create],
 459               [
 460                 AC_DEFINE([LTTNG_HAVE_LIBUUID], [1])
 461                 UUID_LIBS="-lc"
 462               ],
 463               [
 464                 AC_MSG_FAILURE([Cannot find libuuid uuid_generate nor libc uuid_create. Either set PKG_CONFIG_PATH to the configuration file location or use LDFLAGS=-Ldir to specify the library location])
 465               ]
 466             )
 467           ]
 468         )
 469       ]
 470     )
 471   ]
 472 )
 473 AC_SUBST(UUID_LIBS)
 474
 475 AC_CHECK_FUNC([clock_gettime], [AC_DEFINE_UNQUOTED([LTTNG_HAVE_CLOCK_GETTIME], 1, [Has clock_gettime() support.])])
 476
 477 # URCU library version needed or newer
 478 m4_define([WRONG_LIBURCU_MSG], [Userspace RCU (liburcu) >= 0.9.0 is needed])
 479
 480 # Check liburcu needed function calls
 481 AC_CHECK_DECL([cds_list_add], [],
 482         [AC_MSG_ERROR([WRONG_LIBURCU_MSG])], [[#include <urcu/list.h>]])
 483 AC_CHECK_DECL([cds_wfcq_init], [],
 484         [AC_MSG_ERROR([WRONG_LIBURCU_MSG])], [[#include <urcu/wfcqueue.h>]])
 485 AC_CHECK_DECL([cds_wfcq_dequeue_blocking], [],
 486         [AC_MSG_ERROR([WRONG_LIBURCU_MSG])], [[#include <urcu/wfcqueue.h>]])
 487 AC_CHECK_DECL([futex_async], [],
 488         [AC_MSG_ERROR([WRONG_LIBURCU_MSG])], [[#include <urcu/futex.h>]])
 489 AC_CHECK_DECL([rcu_thread_offline], [],
 490         [AC_MSG_ERROR([WRONG_LIBURCU_MSG])], [[#include <urcu.h>]])
 491 AC_CHECK_DECL([rcu_thread_online], [],
 492         [AC_MSG_ERROR([WRONG_LIBURCU_MSG])], [[#include <urcu.h>]])
 493 AC_CHECK_DECL([caa_likely], [],
 494         [AC_MSG_ERROR([WRONG_LIBURCU_MSG])], [[#include <urcu.h>]])
 495 AC_CHECK_LIB([urcu-cds], [_cds_lfht_new], [],
 496         [AC_MSG_ERROR([WRONG_LIBURCU_MSG])])
 497
 498 #Function added in urcu 0.7.0
 499 AC_CHECK_DECL([cmm_smp_mb__before_uatomic_or], [],
 500         [AC_MSG_ERROR([WRONG_LIBURCU_MSG])], [[#include <urcu.h>]]
 501 )
 502
 503 #Function added in urcu 0.9.0
 504 AC_CHECK_DECL([urcu_ref_get_unless_zero], [],
 505         [AC_MSG_ERROR([WRONG_LIBURCU_MSG])], [[#include <urcu/ref.h>]]
 506 )
 507
 508 # Check for libkmod, it will be auto-neabled if found but won't fail if it's not,
 509 # it can be explicitly disabled with --without-kmod
 510 AH_TEMPLATE([HAVE_KMOD], [Define if you have kmod support])
 511 AC_ARG_WITH([kmod],
 512   [AS_HELP_STRING([--with-kmod], [build with lkmod support @<:@default=check@:>@])],
 513   [],
 514   [with_kmod=check]
 515 )
 516
 517 AS_IF([test "x$with_kmod" != "xno"],
 518   [
 519     AC_CHECK_LIB([kmod], [kmod_module_probe_insert_module],
 520       [
 521         AC_DEFINE([HAVE_KMOD], [1])
 522         KMOD_LIBS="-lkmod"
 523       ],
 524       [
 525         if test "x$with_kmod" != xcheck; then
 526           AC_MSG_FAILURE([Cannot find libkmod. Use [LDFLAGS]=-Ldir and [CPPFLAGS]=-Idir to specify its location.])
 527         else
 528           with_kmod=no
 529         fi
 530       ]
 531     )
 532   ]
 533 )
 534 AC_SUBST(KMOD_LIBS)
 535
 536 # Check for liblttng-ust-ctl, fail if it's not found,
 537 # it can be explicitly disabled with --without-lttng-ust
 538 AH_TEMPLATE([HAVE_LIBLTTNG_UST_CTL], [Define if you have LTTng-UST control support])
 539 AC_ARG_WITH([lttng-ust],
 540   [AS_HELP_STRING([--without-lttng-ust], [build without LTTng-UST (Userspace Tracing) support])],
 541   [],
 542   [with_lttng_ust=yes]
 543 )
 544
 545 AS_IF([test "x$with_lttng_ust" = "xyes"],
 546   [
 547     AC_CHECK_LIB([lttng-ust-ctl], [ustctl_recv_channel_from_consumer],
 548       [
 549         AC_DEFINE([HAVE_LIBLTTNG_UST_CTL], [1])
 550       ],
 551       [
 552         AC_MSG_FAILURE([Cannot find LTTng-UST >= 2.2.x. Use [LDFLAGS]=-Ldir and [CPPFLAGS]=-Idir to specify its location, or specify --without-lttng-ust to build lttng-tools without LTTng-UST support.])
 553       ],
 554       [-lurcu-common -lurcu-bp -lurcu-cds -lrt -ldl]
 555     )
 556   ]
 557 )
 558 AM_CONDITIONAL([HAVE_LIBLTTNG_UST_CTL], [test "x$with_lttng_ust" = "xyes"])
 559
 560
 561
 562 # check for dlopen
 563 AC_CHECK_LIB([dl], [dlopen],
 564   [DL_LIBS="-ldl"],
 565   [
 566     #libdl not found, check for dlopen in libc.
 567     AC_CHECK_LIB([c], [dlopen],
 568       [DL_LIBS="-lc"],
 569       [AC_MSG_FAILURE([Cannot find dlopen in libdl nor libc. Use [LDFLAGS]=-Ldir to specify their location.])]
 570     )
 571   ]
 572 )
 573 AC_SUBST(DL_LIBS)
 574
 575 # Check for fmemopen
 576 AC_CHECK_LIB([c], [fmemopen],
 577 [
 578         AC_DEFINE_UNQUOTED([LTTNG_HAVE_FMEMOPEN], 1, [Has fmemopen support.])
 579 ]
 580 )
 581
 582 # Check for open_memstream
 583 AC_CHECK_LIB([c], [open_memstream],
 584 [
 585         AC_DEFINE_UNQUOTED([LTTNG_HAVE_OPEN_MEMSTREAM], 1, [Has open_memstream support.])
 586 ]
 587 )
 588
 589 # check for libpfm
 590 AC_CHECK_LIB([pfm], [pfm_initialize],
 591              [
 592               have_libpfm=yes
 593               ])
 594 AM_CONDITIONAL([LTTNG_TOOLS_BUILD_WITH_LIBPFM], [test "x$have_libpfm" = "xyes"])
 595
 596 AC_ARG_ENABLE([git-version],
 597               [AC_HELP_STRING([--disable-git-version],
 598                               [Do not use the git version for the build])],
 599               [have_git_version=$enableval], [have_git_version=yes]
 600 )
 601
 602 AM_CONDITIONAL([LTTNG_TOOLS_BUILD_GIT_SOURCE],
 603         [test "x${have_git_version}" = "xyes"])
 604
 605 # For Python
 606 # SWIG version needed or newer:
 607 swig_version=2.0.0
 608
 609 AC_ARG_ENABLE([python-bindings],
 610               [AC_HELP_STRING([--enable-python-bindings],
 611                               [compile Python bindings])],
 612               [enable_python_binding=$enableval], [enable_python_binding=no])
 613
 614 AM_CONDITIONAL([PYTHON_BINDING], [test "x$enable_python_binding" = xyes])
 615
 616 if test "x$enable_python_binding" = xyes; then
 617   AX_PKG_SWIG($swig_version, [], [ AC_MSG_ERROR([SWIG $swig_version or newer is needed]) ])
 618   AS_IF([test x$enable_shared = xno], [ AC_MSG_ERROR([Python bindings require shared libraries.]) ])
 619   AM_PATH_PYTHON([3.0])
 620
 621   AC_ARG_VAR([PYTHON_INCLUDE], [Include flags for python, bypassing python-config])
 622   AC_ARG_VAR([PYTHON_CONFIG], [Path to python-config])
 623   AS_IF([test -z "$PYTHON_INCLUDE"], [
 624     AS_IF([test -z "$PYTHON_CONFIG"], [
 625       AC_PATH_PROGS([PYTHON_CONFIG],
 626                     [python$PYTHON_VERSION-config python-config],
 627                     [no],
 628                     [`dirname $PYTHON`])
 629       AS_IF([test "$PYTHON_CONFIG" = no], [AC_MSG_ERROR([cannot find python-config for $PYTHON. Do you have python-dev installed?])])
 630     ])
 631     AC_MSG_CHECKING([python include flags])
 632     PYTHON_INCLUDE=`$PYTHON_CONFIG --includes`
 633     AC_MSG_RESULT([$PYTHON_INCLUDE])
 634   ])
 635
 636 else
 637     AC_MSG_NOTICE([You may configure with --enable-python-bindings ]dnl
 638 [if you want Python bindings.])
 639
 640 fi
 641
 642 # Epoll check. If not present, the build will fallback on poll() API
 643 AX_HAVE_EPOLL(
 644         [AX_CONFIG_FEATURE_ENABLE(epoll)],
 645         [AX_CONFIG_FEATURE_DISABLE(epoll)]
 646 )
 647 AX_CONFIG_FEATURE(
 648         [epoll], [This platform supports epoll(7)],
 649         [HAVE_EPOLL], [This platform supports epoll(7).],
 650         [enable_epoll="yes"], [enable_epoll="no"]
 651 )
 652 AM_CONDITIONAL([COMPAT_EPOLL], [ test "$enable_epoll" = "yes" ])
 653
 654 AM_CONDITIONAL([TEST_JAVA_JUL_AGENT], [test "x$test_java_agent_jul" = "xyes"])
 655 AM_CONDITIONAL([TEST_JAVA_LOG4J_AGENT], [test "x$test_java_agent_log4j" = "xyes"])
 656
 657 if test "x$test_java_agent_jul" = "xyes" || test "x$test_java_agent_log4j" = "xyes"; then
 658         AX_JAVA_OPTIONS
 659         AX_PROG_JAVAC
 660         AX_PROG_JAVA
 661         AX_PROG_JAR
 662
 663         AX_CHECK_CLASSPATH
 664
 665         # Check for Java UST agent common class first
 666         AX_CHECK_CLASS(org.lttng.ust.agent.AbstractLttngAgent)
 667         if test "x$ac_cv_class_org_lttng_ust_agent_AbstractLttngAgent" = "xno"; then
 668                 AC_MSG_ERROR([The UST Java agent common class was not found. Please specify the location of the jar via the Java CLASSPATH e.g: export CLASSPATH="/path/to/lttng-ust-agent-common.jar"])
 669         fi
 670
 671         if test "x$test_java_agent_jul" = "xyes"; then
 672                 # Check for JUL agent class
 673                 AX_CHECK_CLASS(org.lttng.ust.agent.jul.LttngLogHandler)
 674                 if test "x$ac_cv_class_org_lttng_ust_agent_jul_LttngLogHandler" = "xno"; then
 675                         AC_MSG_ERROR([The UST Java agent JUL class was not found. Please specify the location of the jar via the Java CLASSPATH e.g: export CLASSPATH="/path/to/lttng-ust-agent-jul.jar"])
 676                 fi
 677         fi
 678
 679         if test "x$test_java_agent_log4j" = "xyes"; then
 680                 # Check for Log4j agent class
 681                 AX_CHECK_CLASS(org.lttng.ust.agent.log4j.LttngLogAppender)
 682                 if test "x$ac_cv_class_org_lttng_ust_agent_log4j_LttngLogAppender" = "xno"; then
 683                         AC_MSG_ERROR([The UST Java agent Log4j class was not found. Please specify the location of the jar via the Java CLASSPATH e.g: export CLASSPATH="/path/to/lttng-ust-agent-log4j.jar"])
 684                 fi
 685
 686                 # Check for Log4j class
 687                 AX_CHECK_CLASS(org.apache.log4j.Logger)
 688                 if test "x$ac_cv_class_org_apache_log4j_Logger" = "xno"; then
 689                         AC_MSG_ERROR([The Log4j class was not found. Please specify the location of the jar via the Java CLASSPATH e.g: export CLASSPATH="/path/to/log4j.jar"])
 690                 fi
 691         fi
 692 fi
 693
 694 # enable building man pages (user's intention)
 695 AC_ARG_ENABLE(
 696         man-pages,
 697         AS_HELP_STRING(
 698                 [--disable-man-pages],
 699                 [Do not build and install man pages (already built in a distributed tarball)]
 700         ),
 701         [man_pages_opt=$enableval],
 702         [man_pages_opt=yes]
 703 )
 704
 705 # check for asciidoc and xmlto if we enabled building the man pages
 706 have_asciidoc_xmlto=no
 707 warn_prebuilt_man_pages=no
 708
 709 AS_IF([test "x$man_pages_opt" = "xyes"], [
 710         AC_PATH_PROG([ASCIIDOC], [asciidoc], [no])
 711         AC_PATH_PROG([XMLTO], [xmlto], [no])
 712
 713         AS_IF([test "x$ASCIIDOC" = "xno" || test "x$XMLTO" = "xno"], [
 714                 AS_IF([test "x$in_git_repo" = "xyes"], [
 715                         # this is an error because we're in the Git repo, which
 716                         # means the man pages are not already generated for us,
 717                         # thus asciidoc/xmlto are required because we were asked
 718                         # to build the man pages
 719                         AC_MSG_ERROR([
 720 You need asciidoc and xmlto to build the LTTng-tools man pages. Use
 721 --disable-man-pages to disable building the man pages, in which case
 722 they will not be installed.
 723                         ])
 724                 ], [
 725                         # only warn here: since we're in the tarball, the man
 726                         # pages should already be generated at this point, thus
 727                         # asciidoc/xmlto are not strictly required
 728                         warn_prebuilt_man_pages=yes
 729                 ])
 730         ], [
 731                 have_asciidoc_xmlto=yes
 732         ])
 733 ])
 734
 735 # export man page build condition: build the man pages if the user
 736 # asked for it, and if the tools are available
 737 AM_CONDITIONAL([MAN_PAGES_OPT], [test "x$man_pages_opt" != "xno"])
 738 AM_CONDITIONAL([HAVE_ASCIIDOC_XMLTO], [test "x$have_asciidoc_xmlto" = "xyes"])
 739
 740 AC_DEFINE_UNQUOTED([MANPATH], ["`eval eval echo $mandir`"], [Path to man pages.])
 741
 742 # embedded --help message
 743 AC_ARG_ENABLE(
 744         [embedded-help],
 745         AS_HELP_STRING(
 746                 [--enable-embedded-help],
 747                 [Embed the --help messages in the executable files]
 748         ),
 749         [embedded_help=$enableval],
 750         [embedded_help=no]
 751 )
 752 AS_IF([test "x$embedded_help" = "xyes"], [
 753         AS_IF([test "x$man_pages_opt" = "xno"], [
 754                 AC_MSG_ERROR([You need the --enable-man-pages option with the --enable-embedded-help option.])
 755         ])
 756         AC_PATH_PROG([man_prog_path], [man], [no])
 757         AS_IF([test "x$man_prog_path" = "xno"], [
 758                 AC_MSG_ERROR([You need man with the --enable-embedded-help option.])
 759         ])
 760         AC_DEFINE_UNQUOTED([LTTNG_EMBED_HELP], 1, [Embed --help messages.])
 761         AC_SUBST([MANPROG], [$man_prog_path])
 762 ])
 763 AM_CONDITIONAL([EMBED_HELP], [test "x$embedded_help" != "xno"])
 764
 765 # Python agent test
 766 UST_PYTHON_AGENT="lttngust"
 767
 768 AC_ARG_ENABLE(test-python2-agent,
 769         AS_HELP_STRING([--enable-test-python2-agent],
 770                 [enable tests for python2 agent. Python2 interpreter path can be overridden by setting the PYTHON2 environment variable. Default: Autodetect]
 771         ),[:],[test_python2_agent_autodetect=yes]
 772 )
 773
 774 AC_ARG_ENABLE(test-python3-agent,
 775         AS_HELP_STRING([--enable-test-python3-agent],
 776                 [enable tests for python3 agent. Python3 interpreter path can be overridden by setting the PYTHON3 environment variable. Default: Autodetect]
 777         ),[:],[test_python3_agent_autodetect=yes]
 778 )
 779
 780 AC_ARG_ENABLE(test-python-agent-all,
 781         AS_HELP_STRING([--enable-test-python-agent-all],
 782                 [enable test for all python{2/3} agent.]
 783         ),
 784 )
 785
 786 AS_IF([test ! -z "$enable_test_python_agent_all"], [
 787        unset test_python2_agent_autodetect
 788        unset test_python3_agent_autodetect
 789 ])
 790
 791 AS_IF([test "x$enable_test_python_agent_all" = "xyes"], [
 792        enable_test_python2_agent=yes
 793        enable_test_python3_agent=yes
 794 ])
 795
 796 AS_IF([test "x$enable_test_python_agent_all" = "xno"], [
 797        enable_test_python2_agent=no
 798        enable_test_python3_agent=no
 799 ])
 800
 801
 802 AS_IF([test "x$enable_test_python2_agent" = "xyes" -o "x$test_python2_agent_autodetect" = "xyes" ], [
 803         AS_IF([test -z "$PYTHON2"], [
 804                         PYTHON2=python2
 805                 ], [
 806                         AC_MSG_WARN([Using user-defined PYTHON2 ($PYTHON2) for lttng-ust python2 agent check])
 807         ])
 808
 809         AC_PATH_PROG([PYTHON2_BIN],[$PYTHON2])
 810         AS_IF([test -z "$PYTHON2_BIN"], [
 811                 AS_IF([test -z "$test_python2_agent_autodetect"],[
 812                         AC_MSG_ERROR([No python2 interpreter found. PYTHON2 can be set to override default interpreter path])
 813                 ])
 814         ], [
 815                 AC_MSG_CHECKING([for python2 lttng-ust agent])
 816                 AS_IF([$PYTHON2_BIN -c "import $UST_PYTHON_AGENT" 2>/dev/null], [
 817                         PYTHON2_AGENT=$PYTHON2_BIN
 818                         AC_MSG_RESULT([yes])
 819                         RUN_PYTHON_AGENT_TEST=yes
 820                 ], [
 821                         AC_MSG_RESULT([no])
 822                         AS_IF([test -z "$test_python2_agent_autodetect"],[
 823                                 AC_MSG_ERROR([No python2 agent found. The path to the agent can be specified by setting the PYTHONPATH environment variable.])
 824                         ])
 825                 ])
 826
 827         ])
 828
 829 ])
 830
 831 AS_IF([test "x$enable_test_python3_agent" = "xyes" -o "x$test_python3_agent_autodetect" = "xyes" ], [
 832         AS_IF([test -z "$PYTHON3"], [
 833                 PYTHON3=python3
 834         ], [
 835                 AC_MSG_WARN([Using user-defined PYTHON3 ($PYTHON3) for lttng-ust python3 agent check])
 836         ])
 837
 838         AC_PATH_PROG([PYTHON3_BIN],[$PYTHON3])
 839         AS_IF([test -z "$PYTHON3_BIN"], [
 840                 AS_IF([test -z "$test_python3_agent_autodetect"],[
 841                         AC_MSG_ERROR([No python3 interpreter found. PYTHON3 can be set to override default interpreter path])
 842                 ])
 843         ], [
 844                 AC_MSG_CHECKING([for python3 lttng-ust agent])
 845                 AS_IF([$PYTHON3_BIN -c "import $UST_PYTHON_AGENT" 2>/dev/null], [
 846                         PYTHON3_AGENT=$PYTHON3_BIN
 847                         AC_MSG_RESULT([yes])
 848                         RUN_PYTHON_AGENT_TEST=yes
 849                 ], [
 850                         AC_MSG_RESULT([no])
 851                         AS_IF([test -z "$test_python3_agent_autodetect"],[
 852                                 AC_MSG_ERROR([No python3 agent found. The path to the agent can be specified by setting the PYTHONPATH environment variable.])
 853                         ])
 854                 ])
 855
 856         ])
 857 ])
 858 AC_SUBST([RUN_PYTHON_AGENT_TEST])
 859 AC_SUBST([PYTHON2_AGENT])
 860 AC_SUBST([PYTHON3_AGENT])
 861
 862 # Arguments for binaries build exclusion
 863 AC_ARG_ENABLE([bin-lttng], AS_HELP_STRING([--disable-bin-lttng],[Disable the build of lttng binaries]))
 864 AC_ARG_ENABLE([bin-lttng-consumerd], AS_HELP_STRING([--disable-bin-lttng-consumerd],
 865               [Disable the build of lttng-consumerd binaries]))
 866 AC_ARG_ENABLE([bin-lttng-crash], AS_HELP_STRING([--disable-bin-lttng-crash],[Disable the build of lttng-crash binaries]))
 867 AC_ARG_ENABLE([bin-lttng-relayd], AS_HELP_STRING([--disable-bin-lttng-relayd],
 868               [Disable the build of lttng-relayd binaries]))
 869 AC_ARG_ENABLE([bin-lttng-sessiond], AS_HELP_STRING([--disable-bin-lttng-sessiond],
 870               [Disable the build of lttng-sessiond binaries]))
 871 AC_ARG_ENABLE([extras], AS_HELP_STRING([--disable-extras],
 872               [Disable the build of the extra components]))
 873
 874
 875 # Always build libconfig since it a dependency of libcommon
 876 build_lib_config=yes
 877
 878 build_lib_compat=no
 879 build_lib_consumer=no
 880 build_lib_hashtable=no
 881 build_lib_health=no
 882 build_lib_index=no
 883 build_lib_kernel_consumer=no
 884 build_lib_kernel_ctl=no
 885 build_lib_lttng_ctl=no
 886 build_lib_relayd=no
 887 build_lib_sessiond_comm=no
 888 build_lib_testpoint=no
 889 build_lib_ust_consumer=no
 890
 891 # There is an overlap for enabled dependencies, but this makes everything
 892 # simpler. libcommon and libconfig are always compiled so they are not repeated
 893 # here.
 894
 895 # Enable binary dependencies.
 896 AS_IF([test x$enable_bin_lttng != xno],
 897       [
 898        build_lib_lttng_ctl=yes
 899       ]
 900 )
 901
 902 AS_IF([test x$enable_bin_lttng_consumerd != xno],
 903       [
 904        build_lib_consumer=yes
 905        build_lib_sessiond_comm=yes
 906        build_lib_index=yes
 907        build_lib_health=yes
 908        build_lib_testpoint=yes
 909       ]
 910 )
 911
 912 AS_IF([test x$enable_bin_lttng_crash != xno],
 913       # Do nothing since libconfig and libcommon are built by default.
 914       []
 915 )
 916
 917 AS_IF([test x$enable_bin_lttng_relayd != xno],
 918       [
 919        build_lib_lttng_ctl=yes
 920        build_lib_sessiond_comm=yes
 921        build_lib_hashtable=yes
 922        build_lib_compat=yes
 923        build_lib_index=yes
 924        build_lib_health=yes
 925        build_lib_testpoint=yes
 926       ]
 927 )
 928 AS_IF([test x$enable_bin_lttng_sessiond != xno],
 929       [
 930        build_lib_lttng_ctl=yes
 931        build_lib_sessiond_comm=yes
 932        build_lib_kernel_ctl=yes
 933        build_lib_hashtable=yes
 934        build_lib_compat=yes
 935        build_lib_relayd=yes
 936        build_lib_testpoint=yes
 937        build_lib_health=yes
 938        build_lib_health=yes
 939       ]
 940 )
 941
 942 # Libraries dependencies enabling
 943 AS_IF([test x$build_lib_lttng_ctl = xyes],
 944       [
 945        build_lib_sessiond_comm=yes
 946        build_lib_hashtable=yes
 947       ]
 948 )
 949
 950 AS_IF([test x$build_lib_consumer = xyes],
 951       [
 952        build_lib_sessiond_comm=yes
 953        build_lib_kernel_consumer=yes
 954        build_lib_hashtable=yes
 955        build_lib_compat=yes
 956        build_lib_relayd=yes
 957        AS_IF([test "x$with_lttng_ust" = "xyes"], [build_lib_ust_consumer=yes])
 958       ]
 959 )
 960
 961 AS_IF([test x$build_lib_kernel_consumer = xyes],
 962       [
 963        build_lib_kernel_ctl=yes
 964        build_lib_relayd=yes
 965       ]
 966 )
 967
 968 AS_IF([test x$build_lib_relayd = xyes],
 969       [
 970        build_lib_sessiond_comm=yes
 971       ]
 972 )
 973
 974
 975 # Export binaries build conditions.
 976 AM_CONDITIONAL([BUILD_BIN_LTTNG], [test x$enable_bin_lttng != xno])
 977 AM_CONDITIONAL([BUILD_BIN_LTTNG_CONSUMERD], [test x$enable_bin_lttng_consumerd != xno])
 978 AM_CONDITIONAL([BUILD_BIN_LTTNG_CRASH], [test x$enable_bin_lttng_crash != xno])
 979 AM_CONDITIONAL([BUILD_BIN_LTTNG_RELAYD], [test x$enable_bin_lttng_relayd != xno])
 980 AM_CONDITIONAL([BUILD_BIN_LTTNG_SESSIOND], [test x$enable_bin_lttng_sessiond != xno])
 981
 982 # Export the tests and extras build conditions.
 983 AS_IF([\
 984 test "x$enable_bin_lttng" != "xno" && \
 985 test "x$enable_bin_lttng_consumerd" != "xno" && \
 986 test "x$enable_bin_lttng_crash" != "xno" && \
 987 test "x$enable_bin_lttng_relayd" != "xno" && \
 988 test "x$enable_bin_lttng_sessiond" != "xno"],
 989 [build_tests=yes],
 990 [build_tests=no]
 991 )
 992
 993 AM_CONDITIONAL([BUILD_TESTS], [test x$build_tests = xyes])
 994 AM_CONDITIONAL([BUILD_EXTRAS], [test x$enable_extras != xno])
 995
 996 # Export libraries build conditions.
 997 AM_CONDITIONAL([BUILD_LIB_COMPAT], [test x$build_lib_compat = xyes])
 998 AM_CONDITIONAL([BUILD_LIB_CONFIG], [test x$build_lib_config = xyes])
 999 AM_CONDITIONAL([BUILD_LIB_CONSUMER], [test x$build_lib_consumer = xyes])
1000 AM_CONDITIONAL([BUILD_LIB_HASHTABLE], [test x$build_lib_hashtable = xyes])
1001 AM_CONDITIONAL([BUILD_LIB_HEALTH], [test x$build_lib_health = xyes])
1002 AM_CONDITIONAL([BUILD_LIB_INDEX], [test x$build_lib_index = xyes])
1003 AM_CONDITIONAL([BUILD_LIB_KERNEL_CONSUMER], [test x$build_lib_kernel_consumer = xyes])
1004 AM_CONDITIONAL([BUILD_LIB_KERNEL_CTL], [test x$build_lib_kernel_ctl = xyes])
1005 AM_CONDITIONAL([BUILD_LIB_LTTNG_CTL], [test x$build_lib_lttng_ctl = xyes])
1006 AM_CONDITIONAL([BUILD_LIB_RELAYD], [test x$build_lib_relayd = xyes])
1007 AM_CONDITIONAL([BUILD_LIB_SESSIOND_COMM], [test x$build_lib_sessiond_comm = xyes])
1008 AM_CONDITIONAL([BUILD_LIB_TESTPOINT], [test x$build_lib_testpoint = xyes])
1009 AM_CONDITIONAL([BUILD_LIB_UST_CONSUMER], [test x$build_lib_ust_consumer = xyes])
1010
1011 AM_CFLAGS="-Wall -fno-strict-aliasing $PTHREAD_CFLAGS"
1012 AC_SUBST(AM_CFLAGS)
1013
1014 AM_CPPFLAGS="-I\$(top_srcdir)/include -I\$(top_builddir)/include -I\$(top_srcdir)/src -include config.h $AM_CPPFLAGS"
1015 AC_SUBST(AM_CPPFLAGS)
1016
1017 lttngincludedir="${includedir}/lttng"
1018 AC_SUBST(lttngincludedir)
1019
1020 lttngactionincludedir="${includedir}/lttng/action"
1021 AC_SUBST(lttngactionincludedir)
1022
1023 lttngconditionincludedir="${includedir}/lttng/condition"
1024 AC_SUBST(lttngconditionincludedir)
1025
1026 lttngnotificationincludedir="${includedir}/lttng/notification"
1027 AC_SUBST(lttngnotificationincludedir)
1028
1029 lttngtriggerincludedir="${includedir}/lttng/trigger"
1030 AC_SUBST(lttngtriggerincludedir)
1031
1032 lttnglibexecdir="${libdir}/lttng/libexec"
1033 AC_SUBST(lttnglibexecdir)
1034
1035 AC_CONFIG_FILES([
1036         Makefile
1037         doc/Makefile
1038         doc/man/Makefile
1039         doc/man/asciidoc-attrs.conf
1040         include/Makefile
1041         extras/Makefile
1042         extras/bindings/Makefile
1043         extras/bindings/swig/Makefile
1044         extras/bindings/swig/python/Makefile
1045         extras/core-handler/Makefile
1046         src/Makefile
1047         src/common/Makefile
1048         src/common/kernel-ctl/Makefile
1049         src/common/kernel-consumer/Makefile
1050         src/common/consumer/Makefile
1051         src/common/ust-consumer/Makefile
1052         src/common/hashtable/Makefile
1053         src/common/sessiond-comm/Makefile
1054         src/common/compat/Makefile
1055         src/common/relayd/Makefile
1056         src/common/testpoint/Makefile
1057         src/common/index/Makefile
1058         src/common/health/Makefile
1059         src/common/config/Makefile
1060         src/common/string-utils/Makefile
1061         src/lib/Makefile
1062         src/lib/lttng-ctl/Makefile
1063         src/lib/lttng-ctl/filter/Makefile
1064         src/lib/lttng-ctl/lttng-ctl.pc
1065         src/bin/Makefile
1066         src/bin/lttng-consumerd/Makefile
1067         src/bin/lttng-sessiond/Makefile
1068         src/bin/lttng-relayd/Makefile
1069         src/bin/lttng/Makefile
1070         src/bin/lttng-crash/Makefile
1071         tests/Makefile
1072         tests/destructive/Makefile
1073         tests/regression/Makefile
1074         tests/regression/kernel/Makefile
1075         tests/regression/tools/Makefile
1076         tests/regression/tools/streaming/Makefile
1077         tests/regression/tools/filtering/Makefile
1078         tests/regression/tools/health/Makefile
1079         tests/regression/tools/tracefile-limits/Makefile
1080         tests/regression/tools/snapshots/Makefile
1081         tests/regression/tools/live/Makefile
1082         tests/regression/tools/exclusion/Makefile
1083         tests/regression/tools/save-load/Makefile
1084         tests/regression/tools/save-load/configuration/Makefile
1085         tests/regression/tools/mi/Makefile
1086         tests/regression/tools/wildcard/Makefile
1087         tests/regression/tools/crash/Makefile
1088         tests/regression/tools/regen-metadata/Makefile
1089         tests/regression/tools/regen-statedump/Makefile
1090         tests/regression/tools/notification/Makefile
1091         tests/regression/tools/rotation/Makefile
1092         tests/regression/ust/Makefile
1093         tests/regression/ust/nprocesses/Makefile
1094         tests/regression/ust/high-throughput/Makefile
1095         tests/regression/ust/low-throughput/Makefile
1096         tests/regression/ust/before-after/Makefile
1097         tests/regression/ust/buffers-pid/Makefile
1098         tests/regression/ust/periodical-metadata-flush/Makefile
1099         tests/regression/ust/multi-session/Makefile
1100         tests/regression/ust/overlap/Makefile
1101         tests/regression/ust/overlap/demo/Makefile
1102         tests/regression/ust/linking/Makefile
1103         tests/regression/ust/daemon/Makefile
1104         tests/regression/ust/exit-fast/Makefile
1105         tests/regression/ust/fork/Makefile
1106         tests/regression/ust/libc-wrapper/Makefile
1107         tests/regression/ust/baddr-statedump/Makefile
1108         tests/regression/ust/ust-dl/Makefile
1109         tests/regression/ust/java-jul/Makefile
1110         tests/regression/ust/java-log4j/Makefile
1111         tests/regression/ust/python-logging/Makefile
1112         tests/regression/ust/getcpu-override/Makefile
1113         tests/regression/ust/clock-override/Makefile
1114         tests/regression/ust/type-declarations/Makefile
1115         tests/regression/ust/rotation-destroy-flush/Makefile
1116         tests/regression/ust/blocking/Makefile
1117         tests/stress/Makefile
1118         tests/unit/Makefile
1119         tests/unit/ini_config/Makefile
1120         tests/perf/Makefile
1121         tests/utils/Makefile
1122         tests/utils/tap/Makefile
1123         tests/utils/testapp/Makefile
1124         tests/utils/testapp/gen-ust-events/Makefile
1125         tests/utils/testapp/gen-ust-nevents/Makefile
1126         tests/utils/testapp/gen-ust-nevents-str/Makefile
1127         tests/utils/testapp/gen-syscall-events/Makefile
1128         tests/utils/testapp/gen-ust-tracef/Makefile
1129 ])
1130
1131 # Inject variable into python test script.
1132 AC_CONFIG_FILES([tests/regression/ust/python-logging/test_python_logging],[chmod +x tests/regression/ust/python-logging/test_python_logging])
1133 # Inject LTTNG_TOOLS_BUILD_WITH_LIBPFM variable in test script.
1134 AC_CONFIG_FILES([tests/perf/test_perf_raw],[chmod +x tests/perf/test_perf_raw])
1135 AC_CONFIG_FILES([tests/regression/ust/ust-dl/test_ust-dl],[chmod +x tests/regression/ust/ust-dl/test_ust-dl])
1136
1137 AC_OUTPUT
1138
1139 #
1140 # Mini-report on what will be built.
1141 #
1142
1143 PPRINT_INIT
1144 PPRINT_SET_INDENT(1)
1145 PPRINT_SET_TS(38)
1146
1147 AS_ECHO
1148 AS_ECHO("${PPRINT_COLOR_BLDBLU}LTTng-tools $PACKAGE_VERSION \"$version_name\"$PPRINT_COLOR_RST")
1149 AS_ECHO
1150
1151 AS_IF([test -n "$report_fold"], [
1152         AS_ECHO("`AS_ECHO("$version_description") | $report_fold -s`")
1153 ], [
1154         AS_ECHO("$version_description")
1155 ])
1156
1157 AS_ECHO
1158 PPRINT_SUBTITLE([Features])
1159
1160 # Target architecture we're building for.
1161 target_arch=$host_cpu
1162 [
1163 for f in $CFLAGS; do
1164         if test $f = "-m32"; then
1165                         target_arch="32-bit"
1166         elif test $f = "-m64"; then
1167                         target_arch="64-bit"
1168         fi
1169 done
1170 ]
1171 PPRINT_PROP_STRING([Target architecture], $target_arch)
1172
1173 # kmod enabled/disabled
1174 test "x$with_kmod" != "xno" && value=1 || value=0
1175 PPRINT_PROP_BOOL([libkmod support], $value)
1176
1177 # LTTng-UST enabled/disabled
1178 test "x$with_lttng_ust" = "xyes" && value=1 || value=0
1179 PPRINT_PROP_BOOL([LTTng-UST support], $value)
1180
1181 AS_ECHO
1182 PPRINT_SUBTITLE([Binaries])
1183
1184 # List binaries to be built
1185 test x$enable_bin_lttng != xno && value=1 || value=0
1186 PPRINT_PROP_BOOL([lttng], $value)
1187
1188 test x$enable_bin_lttng_consumerd != xno && value=1 || value=0
1189 PPRINT_PROP_BOOL([lttng-consumerd], $value)
1190
1191 test x$enable_bin_lttng_crash != xno && value=1 || value=0
1192 PPRINT_PROP_BOOL([lttng-crash], $value)
1193
1194 test x$enable_bin_lttng_relayd != xno && value=1 || value=0
1195 PPRINT_PROP_BOOL([lttng-relayd], $value)
1196
1197 test x$enable_bin_lttng_sessiond != xno && value=1 || value=0
1198 PPRINT_PROP_BOOL([lttng-sessiond], $value)
1199
1200 # Extras
1201 test x$enable_extras != xno && value=1 || value=0
1202 AS_ECHO
1203 PPRINT_SET_INDENT(0)
1204 PPRINT_PROP_BOOL([Extras], $value, $PPRINT_COLOR_SUBTITLE)
1205 PPRINT_SET_INDENT(1)
1206
1207 AS_ECHO
1208 PPRINT_SUBTITLE([Tests])
1209
1210 # Print clear message that tests won't be built
1211 AS_IF([test "x$build_tests" = "xno"],[
1212         PPRINT_WARN([Tests won't be built since some binaries were disabled])
1213 ])
1214
1215 # LTTng UST Java agent JUL tests enabled/disabled
1216 test "x$test_java_agent_jul" = "xyes" && value=1 || value=0
1217 PPRINT_PROP_BOOL([LTTng-UST Java agent JUL tests], $value)
1218
1219 # LTTng UST Java agent Log4j tests enabled/disabled
1220 test "x$test_java_agent_log4j" = "xyes" && value=1 || value=0
1221 PPRINT_PROP_BOOL([LTTng-UST Java agent Log4j tests], $value)
1222
1223 test ! -z "$PYTHON2_AGENT" && value=1 || value=0
1224 PPRINT_PROP_BOOL([LTTng-UST Python2 agent tests], $value)
1225
1226 test ! -z "$PYTHON3_AGENT" && value=1 || value=0
1227 PPRINT_PROP_BOOL([LTTng-UST Python3 agent tests], $value)
1228
1229 #Python binding enabled/disabled
1230 test "x$enable_python_binding" = xyes && value=1 || value=0
1231 AS_ECHO
1232 PPRINT_SET_INDENT(0)
1233 PPRINT_PROP_BOOL([Python binding], $value, $PPRINT_COLOR_SUBTITLE)
1234
1235 # man pages build enabled/disabled
1236 m4_pushdef([build_man_pages_msg], [Build and install man pages])
1237
1238 AS_IF([test "x$man_pages_opt" != "xno"], [
1239         AS_IF([test "x$in_git_repo" = "xyes"], [
1240                 PPRINT_PROP_BOOL([build_man_pages_msg], 1, $PPRINT_COLOR_SUBTITLE)
1241         ], [
1242                 AS_IF([test "x$have_asciidoc_xmlto" = "xyes"], [
1243                         PPRINT_PROP_BOOL([build_man_pages_msg], 1, $PPRINT_COLOR_SUBTITLE)
1244                 ], [
1245                         PPRINT_PROP_STRING([build_man_pages_msg],
1246                                 [${PPRINT_COLOR_BLDGRN}yes (already built)],
1247                                 $PPRINT_COLOR_SUBTITLE)
1248                 ])
1249         ])
1250 ], [
1251         PPRINT_PROP_BOOL([build_man_pages_msg], 0, $PPRINT_COLOR_SUBTITLE)
1252 ])
1253
1254 m4_popdef([build_man_pages_msg])
1255
1256 test "x$embedded_help" = xyes && value=1 || value=0
1257 PPRINT_PROP_BOOL([Embed --help messages], $value, $PPRINT_COLOR_SUBTITLE)
1258
1259 PPRINT_SET_INDENT(1)
1260
1261 report_bindir="`eval eval echo $bindir`"
1262 report_libdir="`eval eval echo $libdir`"
1263
1264 # Print the bindir and libdir this `make install' will install into.
1265 AS_ECHO
1266 PPRINT_SUBTITLE([Install directories])
1267 PPRINT_PROP_STRING([Binaries], [$report_bindir])
1268 PPRINT_PROP_STRING([Libraries], [$report_libdir])
1269
1270 AS_ECHO
1271 PPRINT_SUBTITLE([Search directories])
1272
1273 # If we build the sessiond, print the paths it will use
1274 AS_IF([test "$SESSIOND_BIN" = ""],[
1275         path="$report_bindir/lttng-sessiond"
1276 ],[
1277         path="$SESSIOND_BIN"
1278 ])
1279 PPRINT_PROP_STRING([lttng-sessiond executable], [$path])
1280
1281 AS_IF([test "$CONSUMERD32_BIN" = ""],[
1282         path="`eval eval echo $lttnglibexecdir`/lttng-consumerd"
1283 ],[
1284         path="$CONSUMERD32_BIN"
1285 ])
1286 PPRINT_PROP_STRING([32-bit lttng-consumerd executable], [$path])
1287
1288 AS_IF([test "$CONSUMERD32_LIBDIR" = ""],[
1289         path="`eval eval echo $libdir`"
1290 ],[
1291         path="$CONSUMERD32_LIBDIR"
1292 ])
1293 PPRINT_PROP_STRING([32-bit consumer libraries], [$path])
1294
1295 AS_IF([test "$CONSUMERD64_BIN" = ""],[
1296         path="`eval eval echo $lttnglibexecdir`/lttng-consumerd"
1297 ],[
1298         path="$CONSUMERD64_BIN"
1299 ])
1300 PPRINT_PROP_STRING([64-bit lttng-consumerd executable], [$path])
1301
1302 AS_IF([test "$CONSUMERD64_LIBDIR" = ""],[
1303         path="`eval eval echo $libdir`"
1304 ],[
1305         path="$CONSUMERD64_LIBDIR"
1306 ])
1307 PPRINT_PROP_STRING([64-bit consumer libraries], [$path])
1308 PPRINT_SET_INDENT(0)
1309
1310 AS_IF([test "x$warn_prebuilt_man_pages" = "xyes" ], [
1311         AS_ECHO
1312         PPRINT_WARN([You need asciidoc and xmlto to build the LTTng-tools man pages.
1313
1314 Note that the man pages are already built in this distribution tarball,
1315 therefore asciidoc and xmlto are only needed if you intend to modify
1316 their sources.
1317
1318 Also note that the installed man pages will contain the project's
1319 default command-line option and environment variable values.
1320
1321 Use --disable-man-pages to completely disable building and installing
1322 the man pages.])
1323 ])