Tests: expand UST wildcard tests, move to regression/tools
[lttng-tools.git] / configure.ac
1 AC_PREREQ([2.64])
2 AC_INIT([lttng-tools],[2.8.0-pre],[jeremie.galarneau@efficios.com],[],[https://lttng.org])
3 AC_CONFIG_AUX_DIR([config])
4 AC_CANONICAL_TARGET
5 AC_CANONICAL_HOST
6 AC_CONFIG_MACRO_DIR([config])
7 AM_INIT_AUTOMAKE([foreign dist-bzip2 no-dist-gzip])
8 AM_MAINTAINER_MODE([enable])
9 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
10
11 # Compute minor/major/patchlevel version numbers
12 AC_PROG_SED
13 major_version=$(echo AC_PACKAGE_VERSION | sed 's/^\([[0-9]]\)*\.[[0-9]]*\.[[0-9]]*.*$/\1/')
14 minor_version=$(echo AC_PACKAGE_VERSION | sed 's/^[[0-9]]*\.\([[0-9]]*\)\.[[0-9]]*.*$/\1/')
15 patchlevel_version=$(echo AC_PACKAGE_VERSION | sed 's/^[[0-9]]*\.[[0-9]]*\.\([[0-9]]*\).*$/\1/')
16 AC_SUBST([MAJOR_VERSION], [$major_version])
17 AC_SUBST([MINOR_VERSION], [$minor_version])
18 AC_SUBST([PATCHLEVEL_VERSION], [$patchlevel_version])
19 AC_DEFINE_UNQUOTED([VERSION_MAJOR], $major_version, [LTTng-Tools major version number])
20 AC_DEFINE_UNQUOTED([VERSION_MINOR], $minor_version, [LTTng-Tools minor version number])
21 AC_DEFINE_UNQUOTED([VERSION_PATCHLEVEL], $patchlevel_version, [LTTng-Tools patchlevel version number])
22
23 version_name="Herbe à Détourne"
24 version_description='Brewed with unrestrained amounts of Citra hop, the Herbe à Détourne is a fantastic New World Tripel brewed by "Dieu du Ciel!". Aromas of mango, cantaloupe melon and passion fruit, combined with a controlled bitter finish, unite in making this smooth golden-orange beer stand apart.'
25 version_description_c=$(echo $version_description | sed 's/"/\\"/g')
26
27 AC_DEFINE_UNQUOTED([VERSION_NAME], ["$version_name"], "")
28 AC_DEFINE_UNQUOTED([VERSION_DESCRIPTION], ["$version_description_c"], "")
29
30 AC_CONFIG_HEADERS([include/config.h])
31
32 AC_PROG_GREP
33 # libtool link_all_deplibs fixup. See http://bugs.lttng.org/issues/321.
34 AC_ARG_ENABLE(libtool-linkdep-fixup,
35 AS_HELP_STRING([--disable-libtool-linkdep-fixup],
36 [disable the libtool fixup for linking all dependent libraries (link_all_deplibs)]),
37 libtool_fixup=$enableval,
38 libtool_fixup=yes)
39
40 AS_IF([test "x$libtool_fixup" = "xyes"],
41 [
42 libtool_m4="$srcdir/config/libtool.m4"
43 libtool_flag_pattern=".*link_all_deplibs\s*,\s*\$1\s*)"
44 AC_MSG_CHECKING([for occurence(s) of link_all_deplibs = no in $libtool_m4])
45 libtool_flag_pattern_count=$(grep -c "$libtool_flag_pattern\s*=\s*no" $libtool_m4)
46 AS_IF([test $libtool_flag_pattern_count -ne 0],
47 [
48 AC_MSG_RESULT([$libtool_flag_pattern_count])
49 AC_MSG_WARN([the detected libtool will not link all dependencies, forcing link_all_deplibs = unknown])
50 sed -i "s/\($libtool_flag_pattern\)\s*=\s*no/\1=unknown/g" $libtool_m4
51 ],
52 [
53 AC_MSG_RESULT([none])
54 ])
55 ])
56
57 AM_CONDITIONAL([NO_SHARED], [test x$enable_shared = xno])
58
59 AC_CHECK_HEADERS([ \
60 sys/types.h unistd.h fcntl.h string.h pthread.h limits.h \
61 signal.h stdlib.h sys/un.h sys/socket.h stdlib.h stdio.h \
62 getopt.h sys/ipc.h sys/shm.h popt.h grp.h arpa/inet.h \
63 netdb.h netinet/in.h paths.h stddef.h sys/file.h sys/ioctl.h \
64 sys/mount.h sys/param.h sys/time.h
65 ])
66
67 # Basic functions check
68 AC_CHECK_FUNCS([ \
69 atexit bzero clock_gettime dup2 fdatasync ftruncate \
70 gethostbyname gethostname getpagesize localtime_r memchr memset \
71 mkdir munmap putenv realpath rmdir socket strchr strcspn strdup \
72 strncasecmp strndup strpbrk strrchr strstr strtol strtoul \
73 strtoull \
74 ])
75
76 # Babeltrace viewer check
77 AC_ARG_WITH([babeltrace-bin],
78 AS_HELP_STRING([--with-babeltrace-bin],
79 [Location of the babeltrace viewer executable (including the filename)]),
80 [BABELTRACE_BIN="$withval"],
81 [BABELTRACE_BIN=''])
82 AC_SUBST([BABELTRACE_BIN])
83
84 # lttv-gui
85 AC_ARG_WITH([lttv-gui-bin],
86 AS_HELP_STRING([--with-lttv-gui-bin],
87 [Location of the lttv GUI viewer executable (including the filename)]),
88 [LTTV_GUI_BIN="$withval"],
89 [LTTV_GUI_BIN=''])
90 AC_SUBST([LTTV_GUI_BIN])
91
92 AC_ARG_WITH([consumerd32-bin],
93 AS_HELP_STRING([--with-consumerd32-bin],
94 [Location of the 32-bit consumerd executable (including the filename)]),
95 [CONSUMERD32_BIN="$withval"],
96 [CONSUMERD32_BIN=''])
97 AC_SUBST([CONSUMERD32_BIN])
98
99 AC_ARG_WITH([consumerd64-bin],
100 AS_HELP_STRING([--with-consumerd64-bin],
101 [Location of the 64-bit consumerd executable (including the filename)]),
102 [CONSUMERD64_BIN="$withval"],
103 [CONSUMERD64_BIN=''])
104 AC_SUBST([CONSUMERD64_BIN])
105
106 AC_ARG_WITH([consumerd32-libdir],
107 AS_HELP_STRING([--with-consumerd32-libdir],
108 [Directory containing the 32-bit consumerd libraries]),
109 [CONSUMERD32_LIBDIR="$withval"],
110 [CONSUMERD32_LIBDIR=''])
111 AC_SUBST([CONSUMERD32_LIBDIR])
112
113 AC_ARG_WITH([consumerd64-libdir],
114 AS_HELP_STRING([--with-consumerd64-libdir],
115 [Directory containing the 64-bit consumerd libraries]),
116 [CONSUMERD64_LIBDIR="$withval"],
117 [CONSUMERD64_LIBDIR=''])
118 AC_SUBST([CONSUMERD64_LIBDIR])
119
120 AC_ARG_WITH([sessiond-bin],
121 AS_HELP_STRING([--with-sessiond-bin],
122 [Location of the sessiond executable (including the filename)]),
123 [SESSIOND_BIN="$withval"],
124 [SESSIOND_BIN=''])
125 AC_SUBST([SESSIOND_BIN])
126
127 AC_ARG_WITH([lttng-system-rundir],
128 AS_HELP_STRING([--with-lttng-system-rundir],
129 [Location of the system directory where the system-wide lttng-sessiond runtime files are kept. The default is "/var/run/lttng".]),
130 [LTTNG_SYSTEM_RUNDIR="$withval"],
131 [LTTNG_SYSTEM_RUNDIR="/var/run/lttng"])
132 AC_SUBST([LTTNG_SYSTEM_RUNDIR])
133
134 AC_ARG_ENABLE([test-java-agent-jul],
135 [AS_HELP_STRING([--enable-test-java-agent-jul],[enable the LTTng UST Java agent JUL tests [default=no]])],
136 [test_java_agent_jul=$enableval],
137 [test_java_agent_jul=no]
138 )
139
140 AC_ARG_ENABLE([test-java-agent-log4j],
141 [AS_HELP_STRING([--enable-test-java-agent-log4j],[enable the LTTng UST Java agent Log4j tests [default=no]])],
142 [test_java_agent_log4j=$enableval],
143 [test_java_agent_log4j=no]
144 )
145
146 AC_ARG_ENABLE([test-java-agent-all],
147 [AS_HELP_STRING([--enable-test-java-agent-all],[enable all the LTTng UST Java agent tests [default=no]])],
148 [test_java_agent_jul=$enableval
149 test_java_agent_log4j=$enableval],
150 [:]
151 )
152
153 AC_DEFINE_UNQUOTED([CONFIG_CONSUMERD32_BIN], "$CONSUMERD32_BIN", [Location of the 32-bit consumerd executable.])
154 AC_DEFINE_UNQUOTED([CONFIG_CONSUMERD64_BIN], "$CONSUMERD64_BIN", [Location of the 64-bit consumerd executable])
155 AC_DEFINE_UNQUOTED([CONFIG_CONSUMERD32_LIBDIR], "$CONSUMERD32_LIBDIR", [Search for consumerd 32-bit libraries in this location.])
156 AC_DEFINE_UNQUOTED([CONFIG_CONSUMERD64_LIBDIR], "$CONSUMERD64_LIBDIR", [Search for consumerd 64-bit libraries in this location.])
157 AC_DEFINE_UNQUOTED([CONFIG_BABELTRACE_BIN], "$BABELTRACE_BIN", [Location of the babeltrace viewer executable.])
158 AC_DEFINE_UNQUOTED([CONFIG_LTTV_GUI_BIN], "$LTTV_GUI_BIN", [Location of the lttv GUI viewer executable.])
159 AC_DEFINE_UNQUOTED([CONFIG_SESSIOND_BIN], "$SESSIOND_BIN", [Location of the sessiond executable.])
160 AC_DEFINE_UNQUOTED([CONFIG_LTTNG_SYSTEM_RUNDIR], ["$LTTNG_SYSTEM_RUNDIR"], [LTTng system runtime directory])
161
162 if test "x$prefix" = "xNONE"; then
163 prefix=$ac_default_prefix
164 fi
165 CONFDIR=`eval echo $sysconfdir`
166 AC_SUBST(CONFDIR)
167 AC_DEFINE_UNQUOTED([CONFIG_LTTNG_SYSTEM_CONFIGDIR],"$CONFDIR", [LTTng system configuration directory.])
168
169 AC_DEFINE_DIR([CONFIG_LTTNG_SYSTEM_DATADIR],[datadir], [LTTng system data directory.])
170
171 #
172 # Check for pthread
173 AC_CHECK_LIB([pthread], [pthread_create], [],
174 [AC_MSG_ERROR([Cannot find libpthread. Use [LDFLAGS]=-Ldir to specify its location.])]
175 )
176
177 # Check libpopt
178 AC_CHECK_LIB([popt], [poptGetContext], [],
179 [AC_MSG_ERROR([Cannot find libpopt. Use [LDFLAGS]=-Ldir to specify its location.])]
180 )
181
182 AM_PATH_XML2(2.7.6, true, AC_MSG_ERROR(No supported version of libxml2 found.))
183
184 # Check for libuuid
185 AC_CHECK_LIB([uuid], [uuid_generate],
186 [
187 AC_DEFINE_UNQUOTED([LTTNG_HAVE_LIBUUID], 1, [Has libuuid support.])
188 have_libuuid=yes
189 ],
190 [
191 # libuuid not found, check for uuid_create in libc.
192 AC_CHECK_LIB([c], [uuid_create],
193 [
194 AC_DEFINE_UNQUOTED([LTTNG_HAVE_LIBC_UUID], 1, [Has libc uuid support.])
195 have_libc_uuid=yes
196 ],
197 [
198 AC_MSG_ERROR([Cannot find libuuid uuid_generate nor libc uuid_create. Use [LDFLAGS]=-Ldir to specify their location.])
199 ])
200 ]
201 )
202 AM_CONDITIONAL([LTTNG_BUILD_WITH_LIBUUID], [test "x$have_libuuid" = "xyes"])
203 AM_CONDITIONAL([LTTNG_BUILD_WITH_LIBC_UUID], [test "x$have_libc_uuid" = "xyes"])
204
205 # URCU library version needed or newer
206 liburcu_version=">= 0.8.0"
207
208 # Check liburcu needed function calls
209 AC_CHECK_DECL([cds_list_add], [],
210 [AC_MSG_ERROR([liburcu $liburcu_version or newer is needed])], [[#include <urcu/list.h>]]
211 )
212 AC_CHECK_DECL([cds_wfcq_init], [],
213 [AC_MSG_ERROR([liburcu $liburcu_version or newer is needed])], [[#include <urcu/wfcqueue.h>]]
214 )
215 AC_CHECK_DECL([cds_wfcq_dequeue_blocking], [],
216 [AC_MSG_ERROR([liburcu $liburcu_version or newer is needed])], [[#include <urcu/wfcqueue.h>]]
217 )
218 AC_CHECK_DECL([futex_async], [],
219 [AC_MSG_ERROR([liburcu $liburcu_version or newer is needed])], [[#include <urcu/futex.h>]]
220 )
221 AC_CHECK_DECL([rcu_thread_offline], [],
222 [AC_MSG_ERROR([liburcu $liburcu_version or newer is needed])], [[#include <urcu.h>]]
223 )
224 AC_CHECK_DECL([rcu_thread_online], [],
225 [AC_MSG_ERROR([liburcu $liburcu_version or newer is needed])], [[#include <urcu.h>]]
226 )
227 AC_CHECK_DECL([caa_likely], [],
228 [AC_MSG_ERROR([liburcu $liburcu_version or newer is needed])], [[#include <urcu.h>]]
229 )
230 #Function added in urcu 0.7.0
231 AC_CHECK_DECL([cmm_smp_mb__before_uatomic_or], [],
232 [AC_MSG_ERROR([liburcu $liburcu_version or newer is needed])], [[#include <urcu.h>]]
233 )
234
235 # Check kmod library
236 AC_ARG_WITH(kmod-prefix,
237 AS_HELP_STRING([--with-kmod-prefix=PATH],
238 [Specify the installation prefix of the kmod library.
239 Headers must be in PATH/include; libraries in PATH/lib.]),
240 [
241 CPPFLAGS="$CPPFLAGS -I${withval}/include"
242 LDFLAGS="$LDFLAGS -L${withval}/lib64 -L${withval}/lib"
243 ])
244
245 AC_ARG_ENABLE(kmod,
246 AS_HELP_STRING([--disable-kmod],[build without kmod support]),
247 kmod_support=zz$enableval, kmod_support=yes)
248
249 AS_IF([test "x$kmod_support" = "xyes"], [
250 AC_CHECK_LIB([kmod], [kmod_module_probe_insert_module],
251 [
252 AC_DEFINE([HAVE_KMOD], [1], [has kmod support])
253 LIBS="$LIBS -lkmod"
254 kmod_found=yes
255 ],
256 kmod_found=no
257 )
258 ])
259 AM_CONDITIONAL([HAVE_KMOD], [test "x$kmod_found" = xyes])
260
261 AC_ARG_WITH(lttng-ust-prefix,
262 AS_HELP_STRING([--with-lttng-ust-prefix=PATH],
263 [Specify the installation prefix of the lttng-ust library.
264 Headers must be in PATH/include; libraries in PATH/lib.]),
265 [
266 CPPFLAGS="$CPPFLAGS -I${withval}/include"
267 LDFLAGS="$LDFLAGS -L${withval}/lib64 -L${withval}/lib"
268 ])
269
270 # Check liblttng-ust-ctl library
271 AC_ARG_ENABLE(lttng-ust,
272 AS_HELP_STRING([--disable-lttng-ust],[build without LTTng-UST (Userspace Tracing) support]),
273 lttng_ust_support=$enableval, lttng_ust_support=yes)
274
275 AS_IF([test "x$lttng_ust_support" = "xyes"], [
276 AC_CHECK_LIB([lttng-ust-ctl], [ustctl_recv_channel_from_consumer],
277 [
278 AC_DEFINE([HAVE_LIBLTTNG_UST_CTL], [1], [has LTTng-UST control support])
279 lttng_ust_ctl_found=yes
280 ],
281 [AC_MSG_ERROR([Cannot find LTTng-UST >= 2.2.x. Use --with-lttng-ust-prefix=PREFIX to specify its location, or specify --disable-lttng-ust to build lttng-tools without LTTng-UST support.])],
282 [-lurcu-common -lurcu-bp -lurcu-cds -lrt -ldl]
283 )
284 ])
285 AM_CONDITIONAL([HAVE_LIBLTTNG_UST_CTL], [test "x$lttng_ust_ctl_found" = xyes])
286 AC_CHECK_FUNCS([sched_getcpu sysconf sync_file_range])
287
288 # check for dlopen
289 AC_CHECK_LIB([dl], [dlopen],
290 [
291 have_libdl=yes
292 ],
293 [
294 #libdl not found, check for dlopen in libc.
295 AC_CHECK_LIB([c], [dlopen],
296 [
297 have_libc_dl=yes
298 ],
299 [
300 AC_MSG_ERROR([Cannot find dlopen in libdl nor libc. Use [LDFLAGS]=-Ldir to specify their location.])
301 ])
302 ])
303 AM_CONDITIONAL([LTTNG_TOOLS_BUILD_WITH_LIBDL], [test "x$have_libdl" = "xyes"])
304 AM_CONDITIONAL([LTTNG_TOOLS_BUILD_WITH_LIBC_DL], [test "x$have_libc_dl" = "xyes"])
305
306 # Check for fmemopen
307 AC_CHECK_LIB([c], [fmemopen],
308 [
309 AC_DEFINE_UNQUOTED([LTTNG_HAVE_FMEMOPEN], 1, [Has fmemopen support.])
310 ]
311 )
312
313 # Check for open_memstream
314 AC_CHECK_LIB([c], [open_memstream],
315 [
316 AC_DEFINE_UNQUOTED([LTTNG_HAVE_OPEN_MEMSTREAM], 1, [Has open_memstream support.])
317 ]
318 )
319
320 AC_ARG_ENABLE([git-version],
321 [AC_HELP_STRING([--disable-git-version],
322 [Do not use the git version for the build])],
323 [have_git_version=$enableval], [have_git_version=yes]
324 )
325
326 AM_CONDITIONAL([LTTNG_TOOLS_BUILD_GIT_SOURCE],
327 [test "x${have_git_version}" = "xyes"])
328
329 # For Python
330 # SWIG version needed or newer:
331 swig_version=2.0.0
332
333 AC_ARG_ENABLE([python-bindings],
334 [AC_HELP_STRING([--enable-python-bindings],
335 [compile Python bindings])],
336 [enable_python_binding=yes], [enable_python_binding=no])
337
338 AM_CONDITIONAL([PYTHON_BINDING], [test "x${enable_python_binding:-yes}" = xyes])
339
340 if test "x${enable_python_binding:-yes}" = xyes; then
341 AX_PKG_SWIG($swig_version, [], [ AC_MSG_ERROR([SWIG $swig_version or newer is needed]) ])
342 AM_PATH_PYTHON([3.0])
343
344 AC_ARG_VAR([PYTHON_INCLUDE], [Include flags for python, bypassing python-config])
345 AC_ARG_VAR([PYTHON_CONFIG], [Path to python-config])
346 AS_IF([test -z "$PYTHON_INCLUDE"], [
347 AS_IF([test -z "$PYTHON_CONFIG"], [
348 AC_PATH_PROGS([PYTHON_CONFIG],
349 [python$PYTHON_VERSION-config python-config],
350 [no],
351 [`dirname $PYTHON`])
352 AS_IF([test "$PYTHON_CONFIG" = no], [AC_MSG_ERROR([cannot find python-config for $PYTHON. Do you have python-dev installed?])])
353 ])
354 AC_MSG_CHECKING([python include flags])
355 PYTHON_INCLUDE=`$PYTHON_CONFIG --includes`
356 AC_MSG_RESULT([$PYTHON_INCLUDE])
357 ])
358
359 else
360 AC_MSG_NOTICE([You may configure with --enable-python-bindings ]dnl
361 [if you want Python bindings.])
362
363 fi
364
365 # Epoll check. If not present, the build will fallback on poll() API
366 AX_HAVE_EPOLL(
367 [AX_CONFIG_FEATURE_ENABLE(epoll)],
368 [AX_CONFIG_FEATURE_DISABLE(epoll)]
369 )
370 AX_CONFIG_FEATURE(
371 [epoll], [This platform supports epoll(7)],
372 [HAVE_EPOLL], [This platform supports epoll(7).],
373 [enable_epoll="yes"], [enable_epoll="no"]
374 )
375 AM_CONDITIONAL([COMPAT_EPOLL], [ test "$enable_epoll" = "yes" ])
376
377 AM_CONDITIONAL([TEST_JAVA_JUL_AGENT], [test "x$test_java_agent_jul" = "xyes"])
378 AM_CONDITIONAL([TEST_JAVA_LOG4J_AGENT], [test "x$test_java_agent_log4j" = "xyes"])
379
380 if test "x$test_java_agent_jul" = "xyes" || test "x$test_java_agent_log4j" = "xyes"; then
381 AX_JAVA_OPTIONS
382 AX_PROG_JAVAC
383 AX_PROG_JAVA
384 AX_PROG_JAR
385
386 AX_CHECK_CLASSPATH
387
388 # Check for Java UST agent common class first
389 AX_CHECK_CLASS(org.lttng.ust.agent.AbstractLttngAgent)
390 if test "x$ac_cv_class_org_lttng_ust_agent_AbstractLttngAgent" = "xno"; then
391 AC_MSG_ERROR([The UST Java agent common class was not found. Please specify the location of the jar via the Java CLASSPATH e.g: export CLASSPATH="/path/to/lttng-ust-agent-common.jar"])
392 fi
393
394 if test "x$test_java_agent_jul" = "xyes"; then
395 # Check for JUL agent class
396 AX_CHECK_CLASS(org.lttng.ust.agent.jul.LttngLogHandler)
397 if test "x$ac_cv_class_org_lttng_ust_agent_jul_LttngLogHandler" = "xno"; then
398 AC_MSG_ERROR([The UST Java agent JUL class was not found. Please specify the location of the jar via the Java CLASSPATH e.g: export CLASSPATH="/path/to/lttng-ust-agent-jul.jar"])
399 fi
400 fi
401
402 if test "x$test_java_agent_log4j" = "xyes"; then
403 # Check for Log4j agent class
404 AX_CHECK_CLASS(org.lttng.ust.agent.log4j.LttngLogAppender)
405 if test "x$ac_cv_class_org_lttng_ust_agent_log4j_LttngLogAppender" = "xno"; then
406 AC_MSG_ERROR([The UST Java agent Log4j class was not found. Please specify the location of the jar via the Java CLASSPATH e.g: export CLASSPATH="/path/to/lttng-ust-agent-log4j.jar"])
407 fi
408
409 # Check for Log4j class
410 AX_CHECK_CLASS(org.apache.log4j.Logger)
411 if test "x$ac_cv_class_org_apache_log4j_Logger" = "xno"; then
412 AC_MSG_ERROR([The Log4j class was not found. Please specify the location of the jar via the Java CLASSPATH e.g: export CLASSPATH="/path/to/log4j.jar"])
413 fi
414 fi
415 fi
416
417 # Python agent test
418 UST_PYTHON_AGENT="lttngust"
419
420 AC_ARG_ENABLE(test-python2-agent,
421 AS_HELP_STRING([--enable-test-python2-agent],
422 [enable tests for python2 agent. Python2 interpreter path can be overridden by setting the PYTHON2 environment variable. Default: Autodetect]
423 ),[:],[test_python2_agent_autodetect=yes]
424 )
425
426 AC_ARG_ENABLE(test-python3-agent,
427 AS_HELP_STRING([--enable-test-python3-agent],
428 [enable tests for python3 agent. Python3 interpreter path can be overridden by setting the PYTHON3 environment variable. Default: Autodetect]
429 ),[:],[test_python3_agent_autodetect=yes]
430 )
431
432 AC_ARG_ENABLE(test-python-agent-all,
433 AS_HELP_STRING([--enable-test-python-agent-all],
434 [enable test for all python{2/3} agent.]
435 ),
436 )
437
438 AS_IF([test ! -z "$enable_test_python_agent_all"], [
439 unset test_python2_agent_autodetect
440 unset test_python3_agent_autodetect
441 ])
442
443 AS_IF([test "x$enable_test_python_agent_all" = "xyes"], [
444 enable_test_python2_agent=yes
445 enable_test_python3_agent=yes
446 ])
447
448 AS_IF([test "x$enable_test_python_agent_all" = "xno"], [
449 enable_test_python2_agent=no
450 enable_test_python3_agent=no
451 ])
452
453
454 AS_IF([test "x$enable_test_python2_agent" = "xyes" -o "x$test_python2_agent_autodetect" = "xyes" ], [
455 AS_IF([test -z "$PYTHON2"], [
456 PYTHON2=python2
457 ], [
458 AC_MSG_WARN([Using user-defined PYTHON2 ($PYTHON2) for lttng-ust python2 agent check])
459 ])
460
461 AC_PATH_PROG([PYTHON2_BIN],[$PYTHON2])
462 AS_IF([test -z "$PYTHON2_BIN"], [
463 AS_IF([test -z "$test_python2_agent_autodetect"],[
464 AC_MSG_ERROR([No python2 interpreter found. PYTHON2 can be set to override default interpreter path])
465 ])
466 ], [
467 AC_MSG_CHECKING([for python2 lttng-ust agent])
468 AS_IF([$PYTHON2_BIN -c "import $UST_PYTHON_AGENT" 2>/dev/null], [
469 PYTHON2_AGENT=$PYTHON2_BIN
470 AC_MSG_RESULT([yes])
471 RUN_PYTHON_AGENT_TEST=yes
472 ], [
473 AC_MSG_RESULT([no])
474 AS_IF([test -z "$test_python2_agent_autodetect"],[
475 AC_MSG_ERROR([No python2 agent found. The path to the agent can be specified by setting the PYTHONPATH environment variable.])
476 ])
477 ])
478
479 ])
480
481 ])
482
483 AS_IF([test "x$enable_test_python3_agent" = "xyes" -o "x$test_python3_agent_autodetect" = "xyes" ], [
484 AS_IF([test -z "$PYTHON3"], [
485 PYTHON3=python3
486 ], [
487 AC_MSG_WARN([Using user-defined PYTHON3 ($PYTHON3) for lttng-ust python3 agent check])
488 ])
489
490 AC_PATH_PROG([PYTHON3_BIN],[$PYTHON3])
491 AS_IF([test -z "$PYTHON3_BIN"], [
492 AS_IF([test -z "$test_python3_agent_autodetect"],[
493 AC_MSG_ERROR([No python3 interpreter found. PYTHON3 can be set to override default interpreter path])
494 ])
495 ], [
496 AC_MSG_CHECKING([for python3 lttng-ust agent])
497 AS_IF([$PYTHON3_BIN -c "import $UST_PYTHON_AGENT" 2>/dev/null], [
498 PYTHON3_AGENT=$PYTHON3_BIN
499 AC_MSG_RESULT([yes])
500 RUN_PYTHON_AGENT_TEST=yes
501 ], [
502 AC_MSG_RESULT([no])
503 AS_IF([test -z "$test_python3_agent_autodetect"],[
504 AC_MSG_ERROR([No python3 agent found. The path to the agent can be specified by setting the PYTHONPATH environment variable.])
505 ])
506 ])
507
508 ])
509 ])
510
511 AC_SUBST([RUN_PYTHON_AGENT_TEST])
512 AC_SUBST([PYTHON2_AGENT])
513 AC_SUBST([PYTHON3_AGENT])
514
515 AC_SYS_LARGEFILE
516
517 # C compiler tests
518 AC_PROG_CC
519 AC_C_INLINE
520
521 # Type availability checking
522 AC_TYPE_INT32_T
523 AC_TYPE_INT64_T
524 AC_TYPE_MODE_T
525 AC_TYPE_OFF_T
526 AC_TYPE_PID_T
527 AC_TYPE_SIZE_T
528 AC_TYPE_SSIZE_T
529 AC_TYPE_UID_T
530 AC_TYPE_UINT16_T
531 AC_TYPE_UINT32_T
532 AC_TYPE_UINT64_T
533 AC_TYPE_UINT8_T
534
535 LT_INIT
536 AC_PROG_YACC
537 AC_PROG_LEX
538
539 if test ! -f "$srcdir/src/lib/lttng-ctl/filter/filter-parser.h"; then
540 if test x"$YACC" != "xbison -y"; then
541 AC_MSG_ERROR([[bison not found and is required when building from git.
542 Please install bison]])
543 fi
544 AC_PATH_PROG([BISON],[bison])
545 AX_PROG_BISON_VERSION([2.4], [],[
546 AC_MSG_ERROR([[Bison >= 2.4 is required when building from git]])
547 ])
548 fi
549
550 if test ! -f "$srcdir/src/lib/lttng-ctl/filter/filter-lexer.c"; then
551 if test x"$LEX" != "xflex"; then
552 AC_MSG_ERROR([[flex not found and is required when building from git.
553 Please install flex]])
554 fi
555 AC_PATH_PROG([FLEX],[flex])
556 AX_PROG_FLEX_VERSION([2.5.35], [],[
557 AC_MSG_ERROR([[Flex >= 2.5.35 is required when building from git]])
558 ])
559 fi
560
561 CFLAGS="-Wall $CFLAGS -g -fno-strict-aliasing"
562
563 DEFAULT_INCLUDES="-I\$(top_srcdir) -I\$(top_builddir) -I\$(top_builddir)/src -I\$(top_builddir)/include -include config.h"
564
565 lttngincludedir="${includedir}/lttng"
566
567 AC_SUBST(lttngincludedir)
568 AC_SUBST(DEFAULT_INCLUDES)
569
570 lttnglibexecdir="${libdir}/lttng/libexec"
571 AC_SUBST(lttnglibexecdir)
572
573 AC_CONFIG_FILES([
574 Makefile
575 doc/Makefile
576 doc/man/Makefile
577 include/Makefile
578 extras/Makefile
579 extras/bindings/Makefile
580 extras/bindings/swig/Makefile
581 extras/bindings/swig/python/Makefile
582 extras/core-handler/Makefile
583 src/Makefile
584 src/common/Makefile
585 src/common/kernel-ctl/Makefile
586 src/common/kernel-consumer/Makefile
587 src/common/ust-consumer/Makefile
588 src/common/hashtable/Makefile
589 src/common/sessiond-comm/Makefile
590 src/common/compat/Makefile
591 src/common/relayd/Makefile
592 src/common/testpoint/Makefile
593 src/common/index/Makefile
594 src/common/health/Makefile
595 src/common/config/Makefile
596 src/lib/Makefile
597 src/lib/lttng-ctl/Makefile
598 src/lib/lttng-ctl/filter/Makefile
599 src/lib/lttng-ctl/lttng-ctl.pc
600 src/bin/Makefile
601 src/bin/lttng-consumerd/Makefile
602 src/bin/lttng-sessiond/Makefile
603 src/bin/lttng-relayd/Makefile
604 src/bin/lttng/Makefile
605 src/bin/lttng-crash/Makefile
606 tests/Makefile
607 tests/regression/Makefile
608 tests/regression/kernel/Makefile
609 tests/regression/tools/Makefile
610 tests/regression/tools/streaming/Makefile
611 tests/regression/tools/filtering/Makefile
612 tests/regression/tools/health/Makefile
613 tests/regression/tools/tracefile-limits/Makefile
614 tests/regression/tools/snapshots/Makefile
615 tests/regression/tools/live/Makefile
616 tests/regression/tools/exclusion/Makefile
617 tests/regression/tools/save-load/Makefile
618 tests/regression/tools/mi/Makefile
619 tests/regression/tools/wildcard/Makefile
620 tests/regression/ust/Makefile
621 tests/regression/ust/nprocesses/Makefile
622 tests/regression/ust/high-throughput/Makefile
623 tests/regression/ust/low-throughput/Makefile
624 tests/regression/ust/before-after/Makefile
625 tests/regression/ust/buffers-pid/Makefile
626 tests/regression/ust/periodical-metadata-flush/Makefile
627 tests/regression/ust/multi-session/Makefile
628 tests/regression/ust/overlap/Makefile
629 tests/regression/ust/overlap/demo/Makefile
630 tests/regression/ust/linking/Makefile
631 tests/regression/ust/daemon/Makefile
632 tests/regression/ust/exit-fast/Makefile
633 tests/regression/ust/fork/Makefile
634 tests/regression/ust/libc-wrapper/Makefile
635 tests/regression/ust/java-jul/Makefile
636 tests/regression/ust/java-log4j/Makefile
637 tests/regression/ust/python-logging/Makefile
638 tests/regression/ust/getcpu-override/Makefile
639 tests/regression/ust/clock-override/Makefile
640 tests/stress/Makefile
641 tests/unit/Makefile
642 tests/unit/ini_config/Makefile
643 tests/utils/Makefile
644 tests/utils/tap/Makefile
645 tests/utils/testapp/Makefile
646 tests/utils/testapp/gen-ust-events/Makefile
647 tests/utils/testapp/gen-ust-nevents/Makefile
648 tests/utils/testapp/gen-ust-tracef/Makefile
649 ])
650
651 # Inject variable into python test script
652 AC_CONFIG_FILES([tests/regression/ust/python-logging/test_python_logging],[chmod +x tests/regression/ust/python-logging/test_python_logging])
653
654 AC_OUTPUT
655
656 #
657 # Mini-report on what will be built
658 #
659 AS_ECHO()
660
661 AS_ECHO("Version name: $version_name")
662 AS_ECHO("$version_description")
663
664 AS_ECHO()
665
666 # Target architecture we're building for
667 target_arch=$host_cpu
668 [
669 for f in $CFLAGS; do
670 if test $f = "-m32"; then
671 target_arch="32-bit"
672 elif test $f = "-m64"; then
673 target_arch="64-bit"
674 fi
675 done
676 ]
677 AS_ECHO_N("Target architecture: ")
678 AS_ECHO($target_arch)
679
680 # kmod enabled/disabled
681 AS_ECHO_N("libkmod support: ")
682 AS_IF([test "x$kmod_found" = "xyes"],[
683 AS_ECHO("Enabled")
684 ],[
685 AS_ECHO("Disabled")
686 ])
687
688 # LTTng-UST enabled/disabled
689 AS_ECHO_N("Lttng-UST support: ")
690 AS_IF([test "x$lttng_ust_support" = "xyes"],[
691 AS_ECHO("Enabled")
692 ],[
693 AS_ECHO("Disabled")
694 ])
695
696 # LTTng UST Java agent JUL tests enabled/disabled
697 AS_ECHO_N("LTTng-UST Java agent JUL tests: ")
698 AS_IF([test "x$test_java_agent_jul" = "xyes"],[
699 AS_ECHO("Enabled")
700 ],[
701 AS_ECHO("Disabled")
702 ])
703
704 # LTTng UST Java agent Log4j tests enabled/disabled
705 AS_ECHO_N("LTTng-UST Java agent Log4j tests: ")
706 AS_IF([test "x$test_java_agent_log4j" = "xyes"],[
707 AS_ECHO("Enabled")
708 ],[
709 AS_ECHO("Disabled")
710 ])
711
712 AS_ECHO_N("LTTng-UST Python2 agent tests: ")
713 AS_IF([test ! -z "$PYTHON2_AGENT"],[
714 AS_ECHO("Enabled")
715 ],[
716 AS_ECHO("Disabled")
717 ])
718
719 AS_ECHO_N("LTTng-UST Python3 agent tests: ")
720 AS_IF([test ! -z "$PYTHON3_AGENT"],[
721 AS_ECHO("Enabled")
722 ],[
723 AS_ECHO("Disabled")
724 ])
725
726 #Python binding enabled/disabled
727 AS_ECHO_N("Python binding: ")
728 AS_IF([test "x${enable_python_binding:-yes}" = xyes], [
729 AS_ECHO("Enabled")
730 ],[
731 AS_ECHO("Disabled")
732 ])
733
734 # Do we build only the consumerd, or everything
735 AS_IF([test "x$consumerd_only" = "xyes"],[
736 AS_ECHO("Only the consumerd daemon will be built.")
737 ],[
738 AS_ECHO("All binaries will be built.")
739 ])
740
741 # Print the bindir and libdir this `make install' will install into.
742 AS_ECHO()
743 AS_ECHO_N("Binaries will be installed in: ")
744 AS_ECHO("`eval eval echo $bindir`")
745 AS_ECHO_N("Libraries will be installed in: ")
746 AS_ECHO("`eval eval echo $libdir`")
747
748 # If we build the sessiond, print the paths it will use
749 AS_IF([test "x$consumerd_only" = "xno"],[
750 AS_ECHO()
751 AS_ECHO_N("The lttng command will look for the lttng-sessiond executable at: ")
752 AS_IF([test "$SESSIOND_BIN" = ""],[
753 AS_ECHO_N("`eval eval echo $bindir`")
754 AS_ECHO("/lttng-sessiond")
755 ],[
756 AS_ECHO("$SESSIOND_BIN")
757 ])
758
759 AS_ECHO()
760 AS_ECHO("The sessiond daemon will look in the following directories: ")
761 AS_ECHO_N("32-bit consumerd executable at: ")
762 AS_IF([test "$CONSUMERD32_BIN" = ""],[
763 AS_ECHO_N("`eval eval echo $lttnglibexecdir`")
764 AS_ECHO("/lttng-consumerd")
765 ],[
766 AS_ECHO("$CONSUMERD32_BIN")
767 ])
768
769 AS_ECHO_N("32-bit consumer libraries in: ")
770 AS_IF([test "$CONSUMERD32_LIBDIR" = ""],[
771 AS_ECHO("`eval eval echo $libdir`")
772 ],[
773 AS_ECHO("$CONSUMERD32_LIBDIR")
774 ])
775
776 AS_ECHO_N("64-bit consumerd executable at: ")
777 AS_IF([test "$CONSUMERD64_BIN" = ""],[
778 AS_ECHO_N("`eval eval echo $lttnglibexecdir`")
779 AS_ECHO("/lttng-consumerd")
780 ],[
781 AS_ECHO("$CONSUMERD64_BIN")
782 ])
783
784 AS_ECHO_N("64-bit consumer libraries in: ")
785 AS_IF([test "$CONSUMERD64_LIBDIR" = ""],[
786 AS_ECHO("`eval eval echo $libdir`")
787 ],[
788 AS_ECHO("$CONSUMERD64_LIBDIR")
789 ])
790 ])
791
792 AS_ECHO()
793
This page took 0.074392 seconds and 4 git commands to generate.