Make fd_count function static in test_fd_tracker.c
[lttng-tools.git] / configure.ac
1 dnl SPDX-License-Identifier: GPL-2.0-only
2 AC_PREREQ([2.64])
3 AC_INIT([lttng-tools],[2.12.0-rc1],[jeremie.galarneau@efficios.com],[],[https://lttng.org])
4
5 AC_CONFIG_HEADERS([include/config.h])
6 AC_CONFIG_AUX_DIR([config])
7 AC_CONFIG_MACRO_DIR([m4])
8
9 AC_CANONICAL_TARGET
10 AC_CANONICAL_HOST
11
12 AM_INIT_AUTOMAKE([1.12 foreign dist-bzip2 no-dist-gzip tar-pax nostdinc])
13 AM_MAINTAINER_MODE([enable])
14
15 # Enable silent rules if available (Introduced in AM 1.11)
16 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
17
18 AC_REQUIRE_AUX_FILE([tap-driver.sh])
19
20 # Checks for C compiler
21 AC_USE_SYSTEM_EXTENSIONS
22 AC_SYS_LARGEFILE
23 AC_PROG_CC
24 AC_PROG_CC_STDC
25 AC_PROG_CXX
26 RW_PROG_CXX_WORKS
27 AM_CONDITIONAL([CXX_WORKS], [test "x$rw_cv_prog_cxx_works" = "xyes"])
28
29 # Detect warning flags supported by the compiler, append them to WARN_CFLAGS.
30 #
31 # Pass -Werror as an extra flag during the test: this is needed to make the
32 # -Wunknown-warning-option diagnostic fatal with clang.
33 AX_APPEND_COMPILE_FLAGS([ dnl
34 -Wall dnl
35 ],
36 [WARN_CFLAGS],
37 [-Werror])
38
39 # When given, add -Werror to WARN_CFLAGS.
40 AC_ARG_ENABLE([Werror],
41 [AS_HELP_STRING([--enable-Werror], [Treat compiler warnings as errors.])]
42 )
43 AS_IF([test "x$enable_Werror" = "xyes"],
44 [WARN_CFLAGS="${WARN_CFLAGS} -Werror"]
45 )
46
47 # Checks for programs.
48 AC_PROG_GREP
49 AC_PROG_MAKE_SET
50 AC_PROG_SED
51 AC_PATH_PROG([report_fold], [fold])
52 LT_INIT
53
54 # Check for objcopy, required by the base address statedump and dynamic linker tests
55 AC_CHECK_TOOL([OBJCOPY], [objcopy], [no])
56 AS_IF([test "x$OBJCOPY" = "xno"],
57 [AC_MSG_WARN([Cannot find objcopy. The base address statedump and dynamic linker tests will be disabled. Install the binutils package to remediate this.])]
58 )
59 AM_CONDITIONAL([HAVE_OBJCOPY], [test "x$OBJCOPY" != xno])
60
61 # check for pgrep
62 AC_PATH_PROG([PGREP], [pgrep], [no])
63 AM_CONDITIONAL([HAVE_PGREP], [test "x$PGREP" != "xno"])
64
65 # set $IN_GIT_REPO if we're in the Git repository; the `bootstrap` file
66 # is not distributed in tarballs
67 AS_IF([test -f "$srcdir/bootstrap"], [in_git_repo=yes], [in_git_repo=no])
68 AM_CONDITIONAL([IN_GIT_REPO], [test "x$in_git_repo" = "xyes"])
69
70 # check for bison
71 AC_PROG_YACC
72 BISON=$YACC
73 AX_PROG_BISON_VERSION([2.4], [have_bison=yes])
74
75 AS_IF([test "x$have_bison" != "xyes"], [
76 AS_IF([test "x$in_git_repo" = "xyes"], [
77 AC_MSG_FAILURE([
78 Bison >= 2.4 is required when building from the Git repository. You can
79 set the YACC variable to override automatic detection.
80 ])
81 ], [
82 AC_MSG_WARN([
83 Missing Bison >= 2.4. Note that the parser files are already built in
84 this distribution tarball, so Bison is only needed if you intend to
85 modify their sources. You can set the YACC variable to override automatic
86 detection.
87 ])
88 ])
89 ])
90 AM_CONDITIONAL([HAVE_BISON], [test "x$have_bison" = "xyes"])
91
92 # check for flex
93 AC_PROG_LEX
94 FLEX=$LEX
95 AX_PROG_FLEX_VERSION([2.5.35], [have_flex=yes])
96
97 AS_IF([test "x$have_flex" != "xyes"], [
98 AS_IF([test "x$in_git_repo" = "xyes"], [
99 AC_MSG_FAILURE([
100 Flex >= 2.5.35 is required when building from the Git repository. You can
101 set the LEX variable to override automatic detection.
102 ])
103 ], [
104 AC_MSG_WARN([
105 Missing Flex >= 2.5.35. Note that the lexer files are already built in
106 this distribution tarball, so Flex is only needed if you intend to
107 modify their sources. You can set the LEX variable to override automatic
108 detection.
109 ])
110 ])
111 ])
112 AM_CONDITIONAL([HAVE_FLEX], [test "x$have_flex" = "xyes"])
113
114
115 # Checks for typedefs, structures, and compiler characteristics.
116 AC_C_INLINE
117 AC_TYPE_INT32_T
118 AC_TYPE_INT64_T
119 AC_TYPE_MODE_T
120 AC_TYPE_OFF_T
121 AC_TYPE_PID_T
122 AC_TYPE_SIZE_T
123 AC_TYPE_SSIZE_T
124 AC_TYPE_UID_T
125 AC_TYPE_UINT16_T
126 AC_TYPE_UINT32_T
127 AC_TYPE_UINT64_T
128 AC_TYPE_UINT8_T
129
130 AX_C___ATTRIBUTE__
131 AS_IF([test "x$ax_cv___attribute__" = "xyes"],
132 [:],
133 [AC_MSG_ERROR([The compiler does not support __attribute__ extensions])])
134
135 AX_PTHREAD(,[AC_MSG_ERROR([Could not configure pthreads support])])
136
137 # Check if linker has the -no-pie option.
138 AX_CHECK_LINK_FLAG([-no-pie], [linker_have_no_pie_option=yes])
139 AM_CONDITIONAL([LINKER_HAVE_NO_PIE_OPTION], [test "x$linker_have_no_pie_option" = "xyes"])
140
141 AX_LIB_SOCKET_NSL
142
143 LT_NO_UNDEFINED=""
144 AS_CASE([$host_os],
145 [cygwin*],
146 [
147 LT_NO_UNDEFINED="-no-undefined"
148 ],
149 [cygwin*|darwin*|mingw*|solaris*],
150 [
151 # On platforms where we only support the relayd, disable the other binaries by default
152 AS_IF([test "x$enable_bin_lttng" = "x" ], [enable_bin_lttng=no])
153 AS_IF([test "x$enable_bin_lttng_consumerd" = "x" ], [enable_bin_lttng_consumerd=no])
154 AS_IF([test "x$enable_bin_lttng_crash" = "x" ], [enable_bin_lttng_crash=no])
155 AS_IF([test "x$enable_bin_lttng_sessiond" = "x" ], [enable_bin_lttng_sessiond=no])
156 AS_IF([test "x$enable_extras" = "x" ], [enable_extras=no])
157 AS_IF([test "x$with_lttng_ust" = "x" ], [with_lttng_ust=no])
158 ]
159 )
160
161 AC_SUBST(LT_NO_UNDEFINED)
162
163 # Compute minor/major/patchlevel version numbers
164 major_version=$(echo AC_PACKAGE_VERSION | $SED 's/^\([[0-9]]\)*\.[[0-9]]*\.[[0-9]]*.*$/\1/')
165 minor_version=$(echo AC_PACKAGE_VERSION | $SED 's/^[[0-9]]*\.\([[0-9]]*\)\.[[0-9]]*.*$/\1/')
166 patchlevel_version=$(echo AC_PACKAGE_VERSION | $SED 's/^[[0-9]]*\.[[0-9]]*\.\([[0-9]]*\).*$/\1/')
167
168 AC_SUBST([MAJOR_VERSION], [$major_version])
169 AC_SUBST([MINOR_VERSION], [$minor_version])
170 AC_SUBST([PATCHLEVEL_VERSION], [$patchlevel_version])
171 AC_DEFINE_UNQUOTED([VERSION_MAJOR], $major_version, [LTTng-Tools major version number])
172 AC_DEFINE_UNQUOTED([VERSION_MINOR], $minor_version, [LTTng-Tools minor version number])
173 AC_DEFINE_UNQUOTED([VERSION_PATCHLEVEL], $patchlevel_version, [LTTng-Tools patchlevel version number])
174
175 version_name="(Ta) Meilleure"
176 version_description="Ta Meilleure is a Northeast IPA beer brewed by Lagabière. Translating to \"Your best one\", this beer gives out strong aromas of passion fruit, lemon, and peaches. Tastewise, expect a lot of fruit, a creamy texture, and a smooth lingering hop bitterness."
177 version_description_c=$(echo $version_description | $SED 's/"/\\"/g')
178
179 AC_DEFINE_UNQUOTED([VERSION_NAME], ["$version_name"], "")
180 AC_DEFINE_UNQUOTED([VERSION_DESCRIPTION], ["$version_description_c"], "")
181
182 # libtool link_all_deplibs fixup. See http://bugs.lttng.org/issues/321.
183 AC_ARG_ENABLE(libtool-linkdep-fixup,
184 AS_HELP_STRING([--disable-libtool-linkdep-fixup],
185 [disable the libtool fixup for linking all dependent libraries (link_all_deplibs)]),
186 libtool_fixup=$enableval,
187 libtool_fixup=yes)
188
189 AS_IF([test "x$libtool_fixup" = "xyes"],
190 [
191 libtool_m4="$srcdir/m4/libtool.m4"
192 libtool_flag_pattern=".*link_all_deplibs\s*,\s*\$1\s*)"
193 AC_MSG_CHECKING([for occurence(s) of link_all_deplibs = no in $libtool_m4])
194 libtool_flag_pattern_count=$($GREP -c "$libtool_flag_pattern\s*=\s*no" $libtool_m4)
195 AS_IF([test $libtool_flag_pattern_count -ne 0],
196 [
197 AC_MSG_RESULT([$libtool_flag_pattern_count])
198 AC_MSG_WARN([the detected libtool will not link all dependencies, forcing link_all_deplibs = unknown])
199 $SED -i "s/\($libtool_flag_pattern\)\s*=\s*no/\1=unknown/g" $libtool_m4
200 ],
201 [
202 AC_MSG_RESULT([none])
203 ])
204 ])
205
206 AM_CONDITIONAL([NO_SHARED], [test x$enable_shared = xno])
207
208 AC_CHECK_HEADERS([ \
209 sys/types.h unistd.h fcntl.h string.h pthread.h limits.h \
210 signal.h stdlib.h sys/un.h sys/socket.h stdlib.h stdio.h \
211 getopt.h sys/ipc.h sys/shm.h popt.h grp.h arpa/inet.h \
212 netdb.h netinet/in.h paths.h stddef.h sys/file.h sys/ioctl.h \
213 sys/mount.h sys/param.h sys/time.h elf.h
214 ])
215
216 AM_CONDITIONAL([HAVE_ELF_H], [test x$ac_cv_header_elf_h = xyes])
217
218 # Basic functions check
219 AC_CHECK_FUNCS([ \
220 atexit bzero clock_gettime dup2 fdatasync fls ftruncate \
221 gethostbyname gethostname getpagesize localtime_r memchr memrchr memset \
222 mkdir munmap putenv realpath rmdir socket strchr strcspn strdup \
223 strncasecmp strndup strnlen strpbrk strrchr strstr strtol strtoul \
224 strtoull dirfd gethostbyname2 getipnodebyname epoll_create1 \
225 sched_getcpu sysconf sync_file_range
226 ])
227
228 # Check if clock_gettime, timer_create, timer_settime, and timer_delete are available in lib rt, and if so,
229 # add -lrt to LIBS
230 AC_CHECK_LIB([rt], [clock_gettime, timer_create, timer_settime, timer_delete])
231
232 # Checks for dl.
233 AC_CHECK_LIB([dl], [dlopen], [
234 have_libdl=yes
235 libdl_name=dl
236 DL_LIBS="-ldl"
237 ], [
238 # libdl not found, check for dlopen in libc.
239 AC_CHECK_LIB([c], [dlopen], [
240 have_libc_dl=yes
241 libdl_name=c
242 DL_LIBS="-lc"
243 ], [
244 AC_MSG_ERROR([Cannot find dlopen in libdl nor libc. Use [LDFLAGS]=-Ldir to specify their location.])
245 ])
246 ])
247 AC_SUBST(DL_LIBS)
248
249 # Check if libdl has dlmopen support.
250 AH_TEMPLATE([HAVE_DLMOPEN], ["Define to 1 if dlmopen is available."])
251 AC_CHECK_LIB([$libdl_name], [dlmopen], [
252 AC_DEFINE([HAVE_DLMOPEN], [1])
253 HAVE_DLMOPEN=1
254 ], [
255 HAVE_DLMOPEN=0
256 ])
257 AC_SUBST(HAVE_DLMOPEN)
258
259 # Babeltrace viewer check
260 AC_ARG_WITH([babeltrace-bin],
261 AS_HELP_STRING([--with-babeltrace-bin],
262 [Location of the babeltrace viewer executable (including the filename)]),
263 [BABELTRACE_BIN="$withval"],
264 [BABELTRACE_BIN=''])
265 AC_SUBST([BABELTRACE_BIN])
266
267 AC_ARG_WITH([babeltrace2-bin],
268 AS_HELP_STRING([--with-babeltrace2-bin],
269 [Location of the babeltrace2 viewer executable (including the filename)]),
270 [BABELTRACE2_BIN="$withval"],
271 [BABELTRACE2_BIN=''])
272 AC_SUBST([BABELTRACE2_BIN])
273
274 AC_ARG_WITH([consumerd32-bin],
275 AS_HELP_STRING([--with-consumerd32-bin],
276 [Location of the 32-bit consumerd executable (including the filename)]),
277 [CONSUMERD32_BIN="$withval"],
278 [CONSUMERD32_BIN=''])
279 AC_SUBST([CONSUMERD32_BIN])
280
281 AC_ARG_WITH([consumerd64-bin],
282 AS_HELP_STRING([--with-consumerd64-bin],
283 [Location of the 64-bit consumerd executable (including the filename)]),
284 [CONSUMERD64_BIN="$withval"],
285 [CONSUMERD64_BIN=''])
286 AC_SUBST([CONSUMERD64_BIN])
287
288 AC_ARG_WITH([consumerd32-libdir],
289 AS_HELP_STRING([--with-consumerd32-libdir],
290 [Directory containing the 32-bit consumerd libraries]),
291 [CONSUMERD32_LIBDIR="$withval"],
292 [CONSUMERD32_LIBDIR=''])
293 AC_SUBST([CONSUMERD32_LIBDIR])
294
295 AC_ARG_WITH([consumerd64-libdir],
296 AS_HELP_STRING([--with-consumerd64-libdir],
297 [Directory containing the 64-bit consumerd libraries]),
298 [CONSUMERD64_LIBDIR="$withval"],
299 [CONSUMERD64_LIBDIR=''])
300 AC_SUBST([CONSUMERD64_LIBDIR])
301
302 AC_ARG_WITH([sessiond-bin],
303 AS_HELP_STRING([--with-sessiond-bin],
304 [Location of the sessiond executable (including the filename)]),
305 [SESSIOND_BIN="$withval"],
306 [SESSIOND_BIN=''])
307 AC_SUBST([SESSIOND_BIN])
308
309 AC_ARG_WITH([lttng-system-rundir],
310 AS_HELP_STRING([--with-lttng-system-rundir],
311 [Location of the system directory where the system-wide lttng-sessiond runtime files are kept. The default is "/var/run/lttng".]),
312 [LTTNG_SYSTEM_RUNDIR="$withval"],
313 [LTTNG_SYSTEM_RUNDIR="/var/run/lttng"])
314 AC_SUBST([LTTNG_SYSTEM_RUNDIR])
315
316 AC_ARG_ENABLE([test-java-agent-jul],
317 [AS_HELP_STRING([--enable-test-java-agent-jul],[enable the LTTng UST Java agent JUL tests [default=no]])],
318 [test_java_agent_jul=$enableval],
319 [test_java_agent_jul=no]
320 )
321
322 AC_ARG_ENABLE([test-java-agent-log4j],
323 [AS_HELP_STRING([--enable-test-java-agent-log4j],[enable the LTTng UST Java agent Log4j tests [default=no]])],
324 [test_java_agent_log4j=$enableval],
325 [test_java_agent_log4j=no]
326 )
327
328 AC_ARG_ENABLE([test-java-agent-all],
329 [AS_HELP_STRING([--enable-test-java-agent-all],[enable all the LTTng UST Java agent tests [default=no]])],
330 [test_java_agent_jul=$enableval
331 test_java_agent_log4j=$enableval],
332 [:]
333 )
334
335 AC_DEFINE_UNQUOTED([CONFIG_CONSUMERD32_BIN], "$CONSUMERD32_BIN", [Location of the 32-bit consumerd executable.])
336 AC_DEFINE_UNQUOTED([CONFIG_CONSUMERD64_BIN], "$CONSUMERD64_BIN", [Location of the 64-bit consumerd executable])
337 AC_DEFINE_UNQUOTED([CONFIG_CONSUMERD32_LIBDIR], "$CONSUMERD32_LIBDIR", [Search for consumerd 32-bit libraries in this location.])
338 AC_DEFINE_UNQUOTED([CONFIG_CONSUMERD64_LIBDIR], "$CONSUMERD64_LIBDIR", [Search for consumerd 64-bit libraries in this location.])
339 AC_DEFINE_UNQUOTED([CONFIG_BABELTRACE_BIN], "$BABELTRACE_BIN", [Location of the babeltrace viewer executable.])
340 AC_DEFINE_UNQUOTED([CONFIG_BABELTRACE2_BIN], "$BABELTRACE2_BIN", [Location of the babeltrace2 viewer executable.])
341 AC_DEFINE_UNQUOTED([CONFIG_SESSIOND_BIN], "$SESSIOND_BIN", [Location of the sessiond executable.])
342 AC_DEFINE_UNQUOTED([CONFIG_LTTNG_SYSTEM_RUNDIR], ["$LTTNG_SYSTEM_RUNDIR"], [LTTng system runtime directory])
343
344 AC_DEFUN([_AC_DEFINE_AND_SUBST], [
345 AC_DEFINE_UNQUOTED([CONFIG_$1], [$2], [$1])
346 $1="$2"
347 AC_SUBST([$1])
348 ])
349
350 AC_DEFUN([_AC_DEFINE_QUOTED_AND_SUBST], [
351 AC_DEFINE_UNQUOTED([CONFIG_$1], ["$2"], [$1])
352 $1="$2"
353 AC_SUBST([$1])
354 ])
355
356 # Default values
357 m4_define([_DEFAULT_CHANNEL_SUBBUF_SIZE], [16384])
358 m4_define([_DEFAULT_CHANNEL_SUBBUF_NUM], [4])
359 m4_define([_DEFAULT_CHANNEL_SWITCH_TIMER], [0])
360 m4_define([_DEFAULT_CHANNEL_LIVE_TIMER], [0])
361 m4_define([_DEFAULT_CHANNEL_READ_TIMER], [200000])
362 m4_define([_DEFAULT_CHANNEL_MONITOR_TIMER], [1000000])
363 m4_define([_DEFAULT_CHANNEL_BLOCKING_TIMEOUT], [0])
364 _AC_DEFINE_AND_SUBST([DEFAULT_AGENT_TCP_PORT_RANGE_BEGIN], [5345])
365 _AC_DEFINE_AND_SUBST([DEFAULT_AGENT_TCP_PORT_RANGE_END], [5354])
366 _AC_DEFINE_AND_SUBST([DEFAULT_APP_SOCKET_RW_TIMEOUT], [5])
367 _AC_DEFINE_AND_SUBST([DEFAULT_CHANNEL_SUBBUF_SIZE], [_DEFAULT_CHANNEL_SUBBUF_SIZE])
368 _AC_DEFINE_AND_SUBST([DEFAULT_CHANNEL_TRACEFILE_COUNT], [0])
369 _AC_DEFINE_AND_SUBST([DEFAULT_CHANNEL_TRACEFILE_SIZE], [0])
370 _AC_DEFINE_AND_SUBST([DEFAULT_KERNEL_CHANNEL_LIVE_TIMER], [_DEFAULT_CHANNEL_LIVE_TIMER])
371 _AC_DEFINE_AND_SUBST([DEFAULT_KERNEL_CHANNEL_READ_TIMER], [_DEFAULT_CHANNEL_READ_TIMER])
372 _AC_DEFINE_AND_SUBST([DEFAULT_KERNEL_CHANNEL_SUBBUF_NUM], [_DEFAULT_CHANNEL_SUBBUF_NUM])
373 _AC_DEFINE_AND_SUBST([DEFAULT_KERNEL_CHANNEL_SUBBUF_SIZE], [1048576])
374 _AC_DEFINE_AND_SUBST([DEFAULT_KERNEL_CHANNEL_SWITCH_TIMER], [_DEFAULT_CHANNEL_SWITCH_TIMER])
375 _AC_DEFINE_AND_SUBST([DEFAULT_KERNEL_CHANNEL_MONITOR_TIMER], [_DEFAULT_CHANNEL_MONITOR_TIMER])
376 _AC_DEFINE_AND_SUBST([DEFAULT_KERNEL_CHANNEL_BLOCKING_TIMEOUT], [_DEFAULT_CHANNEL_BLOCKING_TIMEOUT])
377 _AC_DEFINE_AND_SUBST([DEFAULT_LTTNG_LIVE_TIMER], [1000000])
378 _AC_DEFINE_AND_SUBST([DEFAULT_METADATA_CACHE_SIZE], [4096])
379 _AC_DEFINE_AND_SUBST([DEFAULT_METADATA_READ_TIMER], [0])
380 _AC_DEFINE_AND_SUBST([DEFAULT_METADATA_SUBBUF_NUM], [2])
381 _AC_DEFINE_AND_SUBST([DEFAULT_METADATA_SUBBUF_SIZE], [4096])
382 _AC_DEFINE_AND_SUBST([DEFAULT_METADATA_SWITCH_TIMER], [_DEFAULT_CHANNEL_SWITCH_TIMER])
383 _AC_DEFINE_AND_SUBST([DEFAULT_NETWORK_CONTROL_PORT], [5342])
384 _AC_DEFINE_AND_SUBST([DEFAULT_NETWORK_DATA_PORT], [5343])
385 _AC_DEFINE_AND_SUBST([DEFAULT_NETWORK_VIEWER_PORT], [5344])
386 _AC_DEFINE_AND_SUBST([DEFAULT_UST_PID_CHANNEL_LIVE_TIMER], [_DEFAULT_CHANNEL_LIVE_TIMER])
387 _AC_DEFINE_AND_SUBST([DEFAULT_UST_PID_CHANNEL_READ_TIMER], [0])
388 _AC_DEFINE_AND_SUBST([DEFAULT_UST_PID_CHANNEL_BLOCKING_TIMEOUT], [0])
389 _AC_DEFINE_AND_SUBST([DEFAULT_UST_PID_CHANNEL_SUBBUF_NUM], [_DEFAULT_CHANNEL_SUBBUF_NUM])
390 _AC_DEFINE_AND_SUBST([DEFAULT_UST_PID_CHANNEL_SUBBUF_SIZE], [_DEFAULT_CHANNEL_SUBBUF_SIZE])
391 _AC_DEFINE_AND_SUBST([DEFAULT_UST_PID_CHANNEL_SWITCH_TIMER], [_DEFAULT_CHANNEL_SWITCH_TIMER])
392 _AC_DEFINE_AND_SUBST([DEFAULT_UST_PID_CHANNEL_MONITOR_TIMER], [_DEFAULT_CHANNEL_MONITOR_TIMER])
393 _AC_DEFINE_AND_SUBST([DEFAULT_UST_UID_CHANNEL_LIVE_TIMER], [_DEFAULT_CHANNEL_LIVE_TIMER])
394 _AC_DEFINE_AND_SUBST([DEFAULT_UST_UID_CHANNEL_READ_TIMER], [0])
395 _AC_DEFINE_AND_SUBST([DEFAULT_UST_UID_CHANNEL_BLOCKING_TIMEOUT], [0])
396 _AC_DEFINE_AND_SUBST([DEFAULT_UST_UID_CHANNEL_SUBBUF_NUM], [_DEFAULT_CHANNEL_SUBBUF_NUM])
397 _AC_DEFINE_AND_SUBST([DEFAULT_UST_UID_CHANNEL_SUBBUF_SIZE], [524288])
398 _AC_DEFINE_AND_SUBST([DEFAULT_UST_UID_CHANNEL_SWITCH_TIMER], [_DEFAULT_CHANNEL_SWITCH_TIMER])
399 _AC_DEFINE_AND_SUBST([DEFAULT_UST_UID_CHANNEL_MONITOR_TIMER], [_DEFAULT_CHANNEL_MONITOR_TIMER])
400 _AC_DEFINE_QUOTED_AND_SUBST([DEFAULT_AGENT_BIND_ADDRESS], [localhost])
401 _AC_DEFINE_QUOTED_AND_SUBST([DEFAULT_NETWORK_CONTROL_BIND_ADDRESS], [0.0.0.0])
402 _AC_DEFINE_QUOTED_AND_SUBST([DEFAULT_NETWORK_DATA_BIND_ADDRESS], [0.0.0.0])
403 _AC_DEFINE_QUOTED_AND_SUBST([DEFAULT_NETWORK_VIEWER_BIND_ADDRESS], [localhost])
404 _AC_DEFINE_AND_SUBST([DEFAULT_NETWORK_RELAYD_CTRL_MAX_PAYLOAD_SIZE], [134217728])
405 _AC_DEFINE_AND_SUBST([DEFAULT_ROTATE_PENDING_TIMER], [500000])
406
407 # Command short descriptions
408 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_ADD_CONTEXT], [Add context fields to a channel])
409 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_CREATE], [Create a tracing session])
410 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_CLEAR], [Clear a tracing session])
411 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_DESTROY], [Tear down tracing sessions])
412 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_DISABLE_CHANNEL], [Disable tracing channels])
413 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_DISABLE_EVENT], [Disable event rules])
414 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_DISABLE_ROTATION], [Unset a rotation schedule])
415 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_ENABLE_CHANNEL], [Create or enable tracing channels])
416 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_ENABLE_EVENT], [Create or enable event rules])
417 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_ENABLE_ROTATION], [Set a rotation schedule])
418 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_HELP], [Display help information about a command])
419 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_LIST], [List tracing sessions, domains, channels, and events])
420 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_LOAD], [Load tracing session configurations])
421 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_REGENERATE], [Manage an LTTng tracing session's data regeneration])
422 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_ROTATE], [Archive a tracing session's current trace chunk])
423 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_SAVE], [Save tracing session configurations])
424 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_SET_SESSION], [Set current tracing session])
425 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_SNAPSHOT], [Snapshot buffers of current tracing session])
426 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_START], [Start tracing])
427 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_STATUS], [Get the status of the current tracing session])
428 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_STOP], [Stop tracing])
429 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_DISABLE_ROTATION], [Unset a rotation schedule])
430 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_ENABLE_ROTATION], [Set a rotation schedule])
431 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_TRACK], [Track specific system resources])
432 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_UNTRACK], [Untrack specific system resources])
433 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_VERSION], [Show version information])
434 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_VIEW], [Start trace viewer])
435
436 if test "x$prefix" = "xNONE"; then
437 prefix=$ac_default_prefix
438 fi
439 CONFDIR=`eval echo $sysconfdir`
440 AC_SUBST(CONFDIR)
441 AC_DEFINE_UNQUOTED([CONFIG_LTTNG_SYSTEM_CONFIGDIR],"$CONFDIR", [LTTng system configuration directory.])
442
443 AX_DEFINE_DIR([CONFIG_LTTNG_SYSTEM_DATADIR], [datadir], [LTTng system data directory.])
444
445 # Check libpopt
446 PKG_CHECK_MODULES([POPT], [popt],
447 [
448 dnl PKG_CHECK_MODULES defines POPT_LIBS
449 ],
450 [
451 AC_MSG_WARN([pkg-config was unable to find a valid .pc for libpopt. Set PKG_CONFIG_PATH to specify the pkgconfig configuration file location])
452 AC_MSG_WARN([Finding libpopt without pkg-config.])
453 AC_CHECK_LIB([popt],
454 [poptGetContext],
455 [POPT_LIBS="-lpopt"],
456 [
457 AC_MSG_FAILURE([Cannot find libpopt. Either set PKG_CONFIG_PATH to the configuration file location or use LDFLAGS=-Ldir to specify the library location])
458 ]
459 )
460 ]
461 )
462 AC_SUBST(POPT_LIBS)
463
464 PKG_CHECK_MODULES([libxml2], [libxml-2.0 >= 2.7.6])
465
466 AC_CHECK_FUNC([clock_gettime], [AC_DEFINE_UNQUOTED([LTTNG_HAVE_CLOCK_GETTIME], 1, [Has clock_gettime() support.])])
467
468 # URCU library version needed or newer
469 m4_define([WRONG_LIBURCU_MSG], [Userspace RCU (liburcu) >= 0.9.0 is needed])
470
471 # Check liburcu needed function calls
472 AC_CHECK_DECL([cds_list_add], [],
473 [AC_MSG_ERROR([WRONG_LIBURCU_MSG])], [[#include <urcu/list.h>]])
474 AC_CHECK_DECL([cds_wfcq_init], [],
475 [AC_MSG_ERROR([WRONG_LIBURCU_MSG])], [[#include <urcu/wfcqueue.h>]])
476 AC_CHECK_DECL([cds_wfcq_dequeue_blocking], [],
477 [AC_MSG_ERROR([WRONG_LIBURCU_MSG])], [[#include <urcu/wfcqueue.h>]])
478 AC_CHECK_DECL([futex_async], [],
479 [AC_MSG_ERROR([WRONG_LIBURCU_MSG])], [[#include <urcu/futex.h>]])
480 AC_CHECK_DECL([rcu_thread_offline], [],
481 [AC_MSG_ERROR([WRONG_LIBURCU_MSG])], [[#include <urcu.h>]])
482 AC_CHECK_DECL([rcu_thread_online], [],
483 [AC_MSG_ERROR([WRONG_LIBURCU_MSG])], [[#include <urcu.h>]])
484 AC_CHECK_DECL([caa_likely], [],
485 [AC_MSG_ERROR([WRONG_LIBURCU_MSG])], [[#include <urcu.h>]])
486 AC_CHECK_LIB([urcu-cds], [_cds_lfht_new], [],
487 [AC_MSG_ERROR([WRONG_LIBURCU_MSG])])
488
489 #Function added in urcu 0.7.0
490 AC_CHECK_DECL([cmm_smp_mb__before_uatomic_or], [],
491 [AC_MSG_ERROR([WRONG_LIBURCU_MSG])], [[#include <urcu.h>]]
492 )
493
494 #Function added in urcu 0.9.0
495 AC_CHECK_DECL([urcu_ref_get_unless_zero], [],
496 [AC_MSG_ERROR([WRONG_LIBURCU_MSG])], [[#include <urcu/ref.h>]]
497 )
498
499 # Check for libkmod, it will be auto-neabled if found but won't fail if it's not,
500 # it can be explicitly disabled with --without-kmod
501 AH_TEMPLATE([HAVE_KMOD], [Define if you have kmod support])
502 AC_ARG_WITH([kmod],
503 [AS_HELP_STRING([--with-kmod], [build with lkmod support @<:@default=check@:>@])],
504 [],
505 [with_kmod=check]
506 )
507
508 AS_IF([test "x$with_kmod" != "xno"],
509 [
510 AC_CHECK_LIB([kmod], [kmod_module_probe_insert_module],
511 [
512 AC_DEFINE([HAVE_KMOD], [1])
513 KMOD_LIBS="-lkmod"
514 ],
515 [
516 if test "x$with_kmod" != xcheck; then
517 AC_MSG_FAILURE([Cannot find libkmod. Use [LDFLAGS]=-Ldir and [CPPFLAGS]=-Idir to specify its location.])
518 else
519 with_kmod=no
520 fi
521 ]
522 )
523 ]
524 )
525 AC_SUBST(KMOD_LIBS)
526
527 # Check for liblttng-ust-ctl, fail if it's not found,
528 # it can be explicitly disabled with --without-lttng-ust
529 AH_TEMPLATE([HAVE_LIBLTTNG_UST_CTL], [Define if you have LTTng-UST control support])
530 AC_ARG_WITH([lttng-ust],
531 [AS_HELP_STRING([--without-lttng-ust], [build without LTTng-UST (Userspace Tracing) support])],
532 [],
533 [with_lttng_ust=yes]
534 )
535
536 AS_IF([test "x$with_lttng_ust" = "xyes"], [
537 AC_DEFINE([HAVE_LIBLTTNG_UST_CTL], [1])
538
539 # Check for liblttng-ust
540 PKG_CHECK_MODULES([UST], [lttng-ust >= $major_version.$minor_version])
541
542 # Check for liblttng-ust-ctl
543 PKG_CHECK_MODULES([UST_CTL], [lttng-ust-ctl >= $major_version.$minor_version])
544
545 AM_CPPFLAGS="$AM_CPPFLAGS $UST_CFLAGS"
546 ])
547
548 AM_CONDITIONAL([HAVE_LIBLTTNG_UST_CTL], [test "x$with_lttng_ust" = "xyes"])
549
550
551 # Check for fmemopen
552 AC_CHECK_LIB([c], [fmemopen],
553 [
554 AC_DEFINE_UNQUOTED([LTTNG_HAVE_FMEMOPEN], 1, [Has fmemopen support.])
555 ]
556 )
557
558 # check for libpfm
559 AC_CHECK_LIB([pfm], [pfm_initialize],
560 [
561 have_libpfm=yes
562 ])
563 AM_CONDITIONAL([LTTNG_TOOLS_BUILD_WITH_LIBPFM], [test "x$have_libpfm" = "xyes"])
564
565 # For Python
566 # SWIG version needed or newer:
567 swig_version=2.0.0
568
569 AC_ARG_ENABLE([python-bindings],
570 [AC_HELP_STRING([--enable-python-bindings],
571 [compile Python bindings])],
572 [enable_python_binding=$enableval], [enable_python_binding=no])
573
574 AM_CONDITIONAL([PYTHON_BINDING], [test "x$enable_python_binding" = xyes])
575
576 if test "x$enable_python_binding" = xyes; then
577 AX_PKG_SWIG($swig_version, [], [ AC_MSG_ERROR([SWIG $swig_version or newer is needed]) ])
578 AS_IF([test x$enable_shared = xno], [ AC_MSG_ERROR([Python bindings require shared libraries.]) ])
579 AM_PATH_PYTHON([3.0])
580
581 AC_ARG_VAR([PYTHON_INCLUDE], [Include flags for python, bypassing python-config])
582 AC_ARG_VAR([PYTHON_CONFIG], [Path to python-config])
583 AS_IF([test -z "$PYTHON_INCLUDE"], [
584 AS_IF([test -z "$PYTHON_CONFIG"], [
585 AC_PATH_PROGS([PYTHON_CONFIG],
586 [python$PYTHON_VERSION-config python-config],
587 [no],
588 [`dirname $PYTHON`])
589 AS_IF([test "$PYTHON_CONFIG" = no], [AC_MSG_ERROR([cannot find python-config for $PYTHON. Do you have python-dev installed?])])
590 ])
591 AC_MSG_CHECKING([python include flags])
592 PYTHON_INCLUDE=`$PYTHON_CONFIG --includes`
593 AC_MSG_RESULT([$PYTHON_INCLUDE])
594 ])
595
596 else
597 AC_MSG_NOTICE([You may configure with --enable-python-bindings ]dnl
598 [if you want Python bindings.])
599
600 fi
601
602 # Epoll check. If not present, the build will fallback on poll() API
603 AX_HAVE_EPOLL(
604 [AX_CONFIG_FEATURE_ENABLE(epoll)],
605 [AX_CONFIG_FEATURE_DISABLE(epoll)]
606 )
607 AX_CONFIG_FEATURE(
608 [epoll], [This platform supports epoll(7)],
609 [HAVE_EPOLL], [This platform supports epoll(7).],
610 [enable_epoll="yes"], [enable_epoll="no"]
611 )
612 AM_CONDITIONAL([COMPAT_EPOLL], [ test "$enable_epoll" = "yes" ])
613
614 AS_IF([test "x$ac_cv_func_dirfd" = "xyes"],
615 [AX_CONFIG_FEATURE_ENABLE(dirfd)],
616 [AX_CONFIG_FEATURE_DISABLE(dirfd)]
617 )
618 AX_CONFIG_FEATURE(
619 [dirfd], [Use directory file descriptors],
620 [COMPAT_DIRFD], [This platform supports directory file descriptors.],
621 [enable_dirfd="yes"], [enable_dirfd="no"]
622 )
623 AM_CONDITIONAL([COMPAT_DIRFD], [ test "$enable_dirfd" = "yes" ])
624
625 AM_CONDITIONAL([TEST_JAVA_JUL_AGENT], [test "x$test_java_agent_jul" = "xyes"])
626 AM_CONDITIONAL([TEST_JAVA_LOG4J_AGENT], [test "x$test_java_agent_log4j" = "xyes"])
627
628 if test "x$test_java_agent_jul" = "xyes" || test "x$test_java_agent_log4j" = "xyes"; then
629 AX_JAVA_OPTIONS
630 AX_PROG_JAVAC
631 AX_PROG_JAVA
632 AX_PROG_JAR
633
634 AX_CHECK_CLASSPATH
635
636 # Check for Java UST agent common class first
637 AX_CHECK_CLASS(org.lttng.ust.agent.AbstractLttngAgent)
638 if test "x$ac_cv_class_org_lttng_ust_agent_AbstractLttngAgent" = "xno"; then
639 AC_MSG_ERROR([The UST Java agent common class was not found. Please specify the location of the jar via the Java CLASSPATH e.g: export CLASSPATH="/path/to/lttng-ust-agent-common.jar"])
640 fi
641
642 if test "x$test_java_agent_jul" = "xyes"; then
643 # Check for JUL agent class
644 AX_CHECK_CLASS(org.lttng.ust.agent.jul.LttngLogHandler)
645 if test "x$ac_cv_class_org_lttng_ust_agent_jul_LttngLogHandler" = "xno"; then
646 AC_MSG_ERROR([The UST Java agent JUL class was not found. Please specify the location of the jar via the Java CLASSPATH e.g: export CLASSPATH="/path/to/lttng-ust-agent-jul.jar"])
647 fi
648 fi
649
650 if test "x$test_java_agent_log4j" = "xyes"; then
651 # Check for Log4j agent class
652 AX_CHECK_CLASS(org.lttng.ust.agent.log4j.LttngLogAppender)
653 if test "x$ac_cv_class_org_lttng_ust_agent_log4j_LttngLogAppender" = "xno"; then
654 AC_MSG_ERROR([The UST Java agent Log4j class was not found. Please specify the location of the jar via the Java CLASSPATH e.g: export CLASSPATH="/path/to/lttng-ust-agent-log4j.jar"])
655 fi
656
657 # Check for Log4j class
658 AX_CHECK_CLASS(org.apache.log4j.Logger)
659 if test "x$ac_cv_class_org_apache_log4j_Logger" = "xno"; then
660 AC_MSG_ERROR([The Log4j class was not found. Please specify the location of the jar via the Java CLASSPATH e.g: export CLASSPATH="/path/to/log4j.jar"])
661 fi
662 fi
663 fi
664
665 # enable building man pages (user's intention)
666 AC_ARG_ENABLE(
667 man-pages,
668 AS_HELP_STRING(
669 [--disable-man-pages],
670 [Do not build and install man pages (already built in a distributed tarball)]
671 ),
672 [man_pages_opt=$enableval],
673 [man_pages_opt=yes]
674 )
675
676 # check for asciidoc and xmlto if we enabled building the man pages
677 have_asciidoc_xmlto=no
678 warn_prebuilt_man_pages=no
679
680 AS_IF([test "x$man_pages_opt" = "xyes"], [
681 AC_PATH_PROG([ASCIIDOC], [asciidoc], [no])
682 AC_PATH_PROG([XMLTO], [xmlto], [no])
683
684 AS_IF([test "x$ASCIIDOC" = "xno" || test "x$XMLTO" = "xno"], [
685 AS_IF([test "x$in_git_repo" = "xyes"], [
686 # this is an error because we're in the Git repo, which
687 # means the man pages are not already generated for us,
688 # thus asciidoc/xmlto are required because we were asked
689 # to build the man pages
690 AC_MSG_ERROR([
691 You need asciidoc and xmlto to build the LTTng-tools man pages. Use
692 --disable-man-pages to disable building the man pages, in which case
693 they will not be installed.
694 ])
695 ], [
696 # only warn here: since we're in the tarball, the man
697 # pages should already be generated at this point, thus
698 # asciidoc/xmlto are not strictly required
699 warn_prebuilt_man_pages=yes
700 ])
701 ], [
702 have_asciidoc_xmlto=yes
703 ])
704 ])
705
706 # export man page build condition: build the man pages if the user
707 # asked for it, and if the tools are available
708 AM_CONDITIONAL([MAN_PAGES_OPT], [test "x$man_pages_opt" != "xno"])
709 AM_CONDITIONAL([HAVE_ASCIIDOC_XMLTO], [test "x$have_asciidoc_xmlto" = "xyes"])
710
711 AC_DEFINE_UNQUOTED([MANPATH], ["`eval eval echo $mandir`"], [Path to man pages.])
712
713 # embedded --help message
714 AC_ARG_ENABLE(
715 [embedded-help],
716 AS_HELP_STRING(
717 [--enable-embedded-help],
718 [Embed the --help messages in the executable files]
719 ),
720 [embedded_help=$enableval],
721 [embedded_help=no]
722 )
723 AS_IF([test "x$embedded_help" = "xyes"], [
724 AS_IF([test "x$man_pages_opt" = "xno"], [
725 AC_MSG_ERROR([You need the --enable-man-pages option with the --enable-embedded-help option.])
726 ])
727 AC_PATH_PROG([man_prog_path], [man], [no])
728 AS_IF([test "x$man_prog_path" = "xno"], [
729 AC_MSG_ERROR([You need man with the --enable-embedded-help option.])
730 ])
731 AC_DEFINE_UNQUOTED([LTTNG_EMBED_HELP], 1, [Embed --help messages.])
732 AC_SUBST([MANPROG], [$man_prog_path])
733 ])
734 AM_CONDITIONAL([EMBED_HELP], [test "x$embedded_help" != "xno"])
735
736 # Python agent test
737 UST_PYTHON_AGENT="lttngust"
738
739 AC_ARG_ENABLE(test-python2-agent,
740 AS_HELP_STRING([--enable-test-python2-agent],
741 [enable tests for python2 agent. Python2 interpreter path can be overridden by setting the PYTHON2 environment variable. Default: Autodetect]
742 ),[:],[test_python2_agent_autodetect=yes]
743 )
744
745 AC_ARG_ENABLE(test-python3-agent,
746 AS_HELP_STRING([--enable-test-python3-agent],
747 [enable tests for python3 agent. Python3 interpreter path can be overridden by setting the PYTHON3 environment variable. Default: Autodetect]
748 ),[:],[test_python3_agent_autodetect=yes]
749 )
750
751 AC_ARG_ENABLE(test-python-agent-all,
752 AS_HELP_STRING([--enable-test-python-agent-all],
753 [enable test for all python{2/3} agent.]
754 ),
755 )
756
757 AS_IF([test ! -z "$enable_test_python_agent_all"], [
758 unset test_python2_agent_autodetect
759 unset test_python3_agent_autodetect
760 ])
761
762 AS_IF([test "x$enable_test_python_agent_all" = "xyes"], [
763 enable_test_python2_agent=yes
764 enable_test_python3_agent=yes
765 ])
766
767 AS_IF([test "x$enable_test_python_agent_all" = "xno"], [
768 enable_test_python2_agent=no
769 enable_test_python3_agent=no
770 ])
771
772
773 AS_IF([test "x$enable_test_python2_agent" = "xyes" -o "x$test_python2_agent_autodetect" = "xyes" ], [
774 AS_IF([test -z "$PYTHON2"], [
775 PYTHON2=python2
776 ], [
777 AC_MSG_WARN([Using user-defined PYTHON2 ($PYTHON2) for lttng-ust python2 agent check])
778 ])
779
780 AC_PATH_PROG([PYTHON2_BIN],[$PYTHON2])
781 AS_IF([test -z "$PYTHON2_BIN"], [
782 AS_IF([test -z "$test_python2_agent_autodetect"],[
783 AC_MSG_ERROR([No python2 interpreter found. PYTHON2 can be set to override default interpreter path])
784 ])
785 ], [
786 AC_MSG_CHECKING([for python2 lttng-ust agent])
787 AS_IF([$PYTHON2_BIN -c "import $UST_PYTHON_AGENT" 2>/dev/null], [
788 PYTHON2_AGENT=$PYTHON2_BIN
789 AC_MSG_RESULT([yes])
790 RUN_PYTHON_AGENT_TEST=yes
791 ], [
792 AC_MSG_RESULT([no])
793 AS_IF([test -z "$test_python2_agent_autodetect"],[
794 AC_MSG_ERROR([No python2 agent found. The path to the agent can be specified by setting the PYTHONPATH environment variable.])
795 ])
796 ])
797
798 ])
799
800 ])
801
802 AS_IF([test "x$enable_test_python3_agent" = "xyes" -o "x$test_python3_agent_autodetect" = "xyes" ], [
803 AS_IF([test -z "$PYTHON3"], [
804 PYTHON3=python3
805 ], [
806 AC_MSG_WARN([Using user-defined PYTHON3 ($PYTHON3) for lttng-ust python3 agent check])
807 ])
808
809 AC_PATH_PROG([PYTHON3_BIN],[$PYTHON3])
810 AS_IF([test -z "$PYTHON3_BIN"], [
811 AS_IF([test -z "$test_python3_agent_autodetect"],[
812 AC_MSG_ERROR([No python3 interpreter found. PYTHON3 can be set to override default interpreter path])
813 ])
814 ], [
815 AC_MSG_CHECKING([for python3 lttng-ust agent])
816 AS_IF([$PYTHON3_BIN -c "import $UST_PYTHON_AGENT" 2>/dev/null], [
817 PYTHON3_AGENT=$PYTHON3_BIN
818 AC_MSG_RESULT([yes])
819 RUN_PYTHON_AGENT_TEST=yes
820 ], [
821 AC_MSG_RESULT([no])
822 AS_IF([test -z "$test_python3_agent_autodetect"],[
823 AC_MSG_ERROR([No python3 agent found. The path to the agent can be specified by setting the PYTHONPATH environment variable.])
824 ])
825 ])
826
827 ])
828 ])
829 AC_SUBST([RUN_PYTHON_AGENT_TEST])
830 AC_SUBST([PYTHON2_AGENT])
831 AC_SUBST([PYTHON3_AGENT])
832
833 AC_ARG_ENABLE([test-sdt-uprobe],
834 [AS_HELP_STRING([--enable-test-sdt-uprobe], [enable the LTTng UST SDT uprobe tests [default=autodetect]])],
835 [test_sdt_uprobe="$enableval"],
836 [test_sdt_uprobe=autodetect]
837 )
838
839 AS_IF([test "$test_sdt_uprobe" != "no"], [
840 LTTNG_CHECK_SDT_WORKS
841 AC_PATH_PROG([DTRACE], [dtrace])
842 ])
843
844 AS_IF([test "$test_sdt_uprobe" = "yes"], [
845 AS_IF([test "$lttng_cv_sdt_works" = "no"], [
846 AC_MSG_ERROR([Cannot find 'sys/sdt.h'.])
847 ])
848 AS_IF([test "x$DTRACE" = "x"], [
849 AC_MSG_ERROR([Cannot find SystemTap dtrace. You can set the DTRACE variable to override automatic detection.])
850 ])
851 ])
852
853 AS_IF([test "$test_sdt_uprobe" = "autodetect"], [
854 AS_IF([test "$lttng_cv_sdt_works" = "yes"], [
855 AS_IF([test "x$DTRACE" != "x"], [
856 test_sdt_uprobe=yes
857 ])
858 ])
859 ])
860
861 AM_CONDITIONAL([TEST_SDT_UPROBE], [test "$test_sdt_uprobe" = "yes"])
862
863 # Arguments for binaries build exclusion
864 AC_ARG_ENABLE([bin-lttng], AS_HELP_STRING([--disable-bin-lttng],[Disable the build of lttng binaries]))
865 AC_ARG_ENABLE([bin-lttng-consumerd], AS_HELP_STRING([--disable-bin-lttng-consumerd],
866 [Disable the build of lttng-consumerd binaries]))
867 AC_ARG_ENABLE([bin-lttng-crash], AS_HELP_STRING([--disable-bin-lttng-crash],[Disable the build of lttng-crash binaries]))
868 AC_ARG_ENABLE([bin-lttng-relayd], AS_HELP_STRING([--disable-bin-lttng-relayd],
869 [Disable the build of lttng-relayd binaries]))
870 AC_ARG_ENABLE([bin-lttng-sessiond], AS_HELP_STRING([--disable-bin-lttng-sessiond],
871 [Disable the build of lttng-sessiond binaries]))
872 AC_ARG_ENABLE([extras], AS_HELP_STRING([--disable-extras],
873 [Disable the build of the extra components]))
874
875
876 # Always build libconfig since it a dependency of libcommon
877 build_lib_config=yes
878
879 build_lib_compat=no
880 build_lib_consumer=no
881 build_lib_hashtable=no
882 build_lib_health=no
883 build_lib_index=no
884 build_lib_kernel_consumer=no
885 build_lib_kernel_ctl=no
886 build_lib_lttng_ctl=no
887 build_lib_relayd=no
888 build_lib_fd_tracker=no
889 build_lib_sessiond_comm=no
890 build_lib_testpoint=no
891 build_lib_ust_consumer=no
892
893 # There is an overlap for enabled dependencies, but this makes everything
894 # simpler. libcommon and libconfig are always compiled so they are not repeated
895 # here.
896
897 # Enable binary dependencies.
898 AS_IF([test x$enable_bin_lttng != xno],
899 [
900 build_lib_lttng_ctl=yes
901 ]
902 )
903
904 AS_IF([test x$enable_bin_lttng_consumerd != xno],
905 [
906 build_lib_consumer=yes
907 build_lib_sessiond_comm=yes
908 build_lib_index=yes
909 build_lib_health=yes
910 build_lib_testpoint=yes
911 ]
912 )
913
914 AS_IF([test x$enable_bin_lttng_crash != xno],
915 # Do nothing since libconfig and libcommon are built by default.
916 []
917 )
918
919 AS_IF([test x$enable_bin_lttng_relayd != xno],
920 [
921 build_lib_lttng_ctl=yes
922 build_lib_sessiond_comm=yes
923 build_lib_hashtable=yes
924 build_lib_compat=yes
925 build_lib_index=yes
926 build_lib_health=yes
927 build_lib_testpoint=yes
928 build_lib_fd_tracker=yes
929 ]
930 )
931 AS_IF([test x$enable_bin_lttng_sessiond != xno],
932 [
933 build_lib_lttng_ctl=yes
934 build_lib_sessiond_comm=yes
935 build_lib_kernel_ctl=yes
936 build_lib_hashtable=yes
937 build_lib_compat=yes
938 build_lib_relayd=yes
939 build_lib_testpoint=yes
940 build_lib_health=yes
941 ]
942 )
943
944 # Libraries dependencies enabling
945 AS_IF([test x$build_lib_lttng_ctl = xyes],
946 [
947 build_lib_sessiond_comm=yes
948 build_lib_hashtable=yes
949 ]
950 )
951
952 AS_IF([test x$build_lib_consumer = xyes],
953 [
954 build_lib_sessiond_comm=yes
955 build_lib_kernel_consumer=yes
956 build_lib_hashtable=yes
957 build_lib_compat=yes
958 build_lib_relayd=yes
959 AS_IF([test "x$with_lttng_ust" = "xyes"], [build_lib_ust_consumer=yes])
960 ]
961 )
962
963 AS_IF([test x$build_lib_kernel_consumer = xyes],
964 [
965 build_lib_kernel_ctl=yes
966 build_lib_relayd=yes
967 ]
968 )
969
970 AS_IF([test x$build_lib_relayd = xyes],
971 [
972 build_lib_sessiond_comm=yes
973 ]
974 )
975
976 # Find arch type
977 AS_CASE([$host_cpu],
978 [k1om], [ARCHTYPE="x86"],
979 [i386], [ARCHTYPE="x86"],
980 [i486], [ARCHTYPE="x86"],
981 [i586], [ARCHTYPE="x86"],
982 [i686], [ARCHTYPE="x86"],
983 [amd64], [ARCHTYPE="x86"],
984 [x86_64], [ARCHTYPE="x86"],
985 [powerpc], [ARCHTYPE="ppc"],
986 [ppc64], [ARCHTYPE="ppc"],
987 [powerpc64], [ARCHTYPE="ppc"],
988 [powerpc64le], [ARCHTYPE="ppc"],
989 [ppc], [ARCHTYPE="ppc"],
990 [s390], [ARCHTYPE="s390"],
991 [s390x], [ARCHTYPE="s390"],
992 [sparc], [ARCHTYPE="sparc64"],
993 [sparc64], [ARCHTYPE="sparc64"],
994 [alpha*], [ARCHTYPE="alpha"],
995 [ia64], [ARCHTYPE="ia64"],
996 [arm*], [ARCHTYPE="arm"],
997 [aarch64*], [ARCHTYPE="aarch64"],
998 [mips*], [ARCHTYPE="mips"],
999 [nios2*], [ARCHTYPE="nios2"],
1000 [tile*], [ARCHTYPE="tile"],
1001 [hppa*], [ARCHTYPE="hppa"],
1002 [m68k], [ARCHTYPE="m68k"],
1003 [riscv*], [ARCHTYPE="riscv"],
1004 [ARCHTYPE="unknown"]
1005 )
1006
1007 AC_SUBST(ARCHTYPE)
1008
1009 AH_TEMPLATE([HAVE_MODULES_USERSPACE_CALLSTACK_CONTEXT], [Define if you have LTTng-modules userspace callstack tracing support])
1010 AC_MSG_CHECKING([for architecture support of userspace callstack tracing from the kernel])
1011 AS_IF([test "x$ARCHTYPE" = "xx86"],[
1012 # Userspace callstack capture is only supported by the Linux kernel on x86.
1013 AC_MSG_RESULT([yes])
1014 have_modules_userspace_callstack_context=yes
1015 AC_DEFINE([HAVE_MODULES_USERSPACE_CALLSTACK_CONTEXT], [1])
1016 ], [
1017 AC_MSG_RESULT([no])
1018 have_modules_userspace_callstack_context=no
1019 ])
1020 AM_CONDITIONAL([HAVE_MODULES_USERSPACE_CALLSTACK_CONTEXT], [test x$have_modules_userspace_callstack_context != xno])
1021
1022 # Export binaries build conditions.
1023 AM_CONDITIONAL([BUILD_BIN_LTTNG], [test x$enable_bin_lttng != xno])
1024 AM_CONDITIONAL([BUILD_BIN_LTTNG_CONSUMERD], [test x$enable_bin_lttng_consumerd != xno])
1025 AM_CONDITIONAL([BUILD_BIN_LTTNG_CRASH], [test x$enable_bin_lttng_crash != xno])
1026 AM_CONDITIONAL([BUILD_BIN_LTTNG_RELAYD], [test x$enable_bin_lttng_relayd != xno])
1027 AM_CONDITIONAL([BUILD_BIN_LTTNG_SESSIOND], [test x$enable_bin_lttng_sessiond != xno])
1028
1029 # Export the tests and extras build conditions.
1030 AS_IF([\
1031 test "x$enable_bin_lttng" != "xno" && \
1032 test "x$enable_bin_lttng_consumerd" != "xno" && \
1033 test "x$enable_bin_lttng_crash" != "xno" && \
1034 test "x$enable_bin_lttng_relayd" != "xno" && \
1035 test "x$enable_bin_lttng_sessiond" != "xno"],
1036 [build_tests=yes],
1037 [build_tests=no]
1038 )
1039
1040 AM_CONDITIONAL([BUILD_TESTS], [test x$build_tests = xyes])
1041 AM_CONDITIONAL([BUILD_EXTRAS], [test x$enable_extras != xno])
1042
1043 # Export libraries build conditions.
1044 AM_CONDITIONAL([BUILD_LIB_COMPAT], [test x$build_lib_compat = xyes])
1045 AM_CONDITIONAL([BUILD_LIB_CONFIG], [test x$build_lib_config = xyes])
1046 AM_CONDITIONAL([BUILD_LIB_CONSUMER], [test x$build_lib_consumer = xyes])
1047 AM_CONDITIONAL([BUILD_LIB_HASHTABLE], [test x$build_lib_hashtable = xyes])
1048 AM_CONDITIONAL([BUILD_LIB_HEALTH], [test x$build_lib_health = xyes])
1049 AM_CONDITIONAL([BUILD_LIB_INDEX], [test x$build_lib_index = xyes])
1050 AM_CONDITIONAL([BUILD_LIB_KERNEL_CONSUMER], [test x$build_lib_kernel_consumer = xyes])
1051 AM_CONDITIONAL([BUILD_LIB_KERNEL_CTL], [test x$build_lib_kernel_ctl = xyes])
1052 AM_CONDITIONAL([BUILD_LIB_LTTNG_CTL], [test x$build_lib_lttng_ctl = xyes])
1053 AM_CONDITIONAL([BUILD_LIB_RELAYD], [test x$build_lib_relayd = xyes])
1054 AM_CONDITIONAL([BUILD_LIB_FD_TRACKER], [test x$build_lib_fd_tracker = xyes])
1055 AM_CONDITIONAL([BUILD_LIB_SESSIOND_COMM], [test x$build_lib_sessiond_comm = xyes])
1056 AM_CONDITIONAL([BUILD_LIB_TESTPOINT], [test x$build_lib_testpoint = xyes])
1057 AM_CONDITIONAL([BUILD_LIB_UST_CONSUMER], [test x$build_lib_ust_consumer = xyes])
1058
1059 AM_CFLAGS="${WARN_CFLAGS} -fno-strict-aliasing $PTHREAD_CFLAGS"
1060 AC_SUBST(AM_CFLAGS)
1061
1062 # The order in which the include folders are searched is important.
1063 # The top_builddir should always be searched first in the event that a build
1064 # time generated file is included. An example of this is the "version.i" file.
1065 # In a scenario where lttng-tools is built from a distribution tarball and in a
1066 # out-of-tree manner, the generated "version.i" has priority on the one from
1067 # the source (distribution tarball) and must be found first.
1068 AM_CPPFLAGS="-I\$(top_builddir)/include -I\$(top_srcdir)/include -I\$(top_srcdir)/src -include config.h $AM_CPPFLAGS"
1069 AC_SUBST(AM_CPPFLAGS)
1070
1071 lttngincludedir="${includedir}/lttng"
1072 AC_SUBST(lttngincludedir)
1073
1074 lttngactionincludedir="${includedir}/lttng/action"
1075 AC_SUBST(lttngactionincludedir)
1076
1077 lttngconditionincludedir="${includedir}/lttng/condition"
1078 AC_SUBST(lttngconditionincludedir)
1079
1080 lttngnotificationincludedir="${includedir}/lttng/notification"
1081 AC_SUBST(lttngnotificationincludedir)
1082
1083 lttngtriggerincludedir="${includedir}/lttng/trigger"
1084 AC_SUBST(lttngtriggerincludedir)
1085
1086 lttnglibexecdir="${libdir}/lttng/libexec"
1087 AC_SUBST(lttnglibexecdir)
1088
1089 AC_CONFIG_FILES([
1090 Makefile
1091 doc/Makefile
1092 doc/man/Makefile
1093 doc/man/asciidoc-attrs.conf
1094 include/Makefile
1095 extras/Makefile
1096 extras/bindings/Makefile
1097 extras/bindings/swig/Makefile
1098 extras/bindings/swig/python/Makefile
1099 extras/core-handler/Makefile
1100 src/Makefile
1101 src/common/Makefile
1102 src/common/kernel-ctl/Makefile
1103 src/common/kernel-consumer/Makefile
1104 src/common/consumer/Makefile
1105 src/common/ust-consumer/Makefile
1106 src/common/hashtable/Makefile
1107 src/common/sessiond-comm/Makefile
1108 src/common/compat/Makefile
1109 src/common/relayd/Makefile
1110 src/common/testpoint/Makefile
1111 src/common/index/Makefile
1112 src/common/health/Makefile
1113 src/common/config/Makefile
1114 src/common/string-utils/Makefile
1115 src/common/fd-tracker/Makefile
1116 src/lib/Makefile
1117 src/lib/lttng-ctl/Makefile
1118 src/lib/lttng-ctl/filter/Makefile
1119 src/lib/lttng-ctl/lttng-ctl.pc
1120 src/bin/Makefile
1121 src/bin/lttng-consumerd/Makefile
1122 src/bin/lttng-sessiond/Makefile
1123 src/bin/lttng-relayd/Makefile
1124 src/bin/lttng/Makefile
1125 src/bin/lttng-crash/Makefile
1126 tests/Makefile
1127 tests/destructive/Makefile
1128 tests/regression/Makefile
1129 tests/regression/kernel/Makefile
1130 tests/regression/tools/Makefile
1131 tests/regression/tools/streaming/Makefile
1132 tests/regression/tools/filtering/Makefile
1133 tests/regression/tools/health/Makefile
1134 tests/regression/tools/tracefile-limits/Makefile
1135 tests/regression/tools/snapshots/Makefile
1136 tests/regression/tools/live/Makefile
1137 tests/regression/tools/exclusion/Makefile
1138 tests/regression/tools/save-load/Makefile
1139 tests/regression/tools/save-load/configuration/Makefile
1140 tests/regression/tools/mi/Makefile
1141 tests/regression/tools/wildcard/Makefile
1142 tests/regression/tools/crash/Makefile
1143 tests/regression/tools/regen-metadata/Makefile
1144 tests/regression/tools/regen-statedump/Makefile
1145 tests/regression/tools/notification/Makefile
1146 tests/regression/tools/rotation/Makefile
1147 tests/regression/tools/base-path/Makefile
1148 tests/regression/tools/metadata/Makefile
1149 tests/regression/tools/tracker/Makefile
1150 tests/regression/tools/working-directory/Makefile
1151 tests/regression/tools/relayd-grouping/Makefile
1152 tests/regression/tools/clear/Makefile
1153 tests/regression/ust/Makefile
1154 tests/regression/ust/nprocesses/Makefile
1155 tests/regression/ust/high-throughput/Makefile
1156 tests/regression/ust/low-throughput/Makefile
1157 tests/regression/ust/before-after/Makefile
1158 tests/regression/ust/buffers-pid/Makefile
1159 tests/regression/ust/periodical-metadata-flush/Makefile
1160 tests/regression/ust/multi-session/Makefile
1161 tests/regression/ust/multi-lib/Makefile
1162 tests/regression/ust/overlap/Makefile
1163 tests/regression/ust/overlap/demo/Makefile
1164 tests/regression/ust/linking/Makefile
1165 tests/regression/ust/daemon/Makefile
1166 tests/regression/ust/exit-fast/Makefile
1167 tests/regression/ust/fork/Makefile
1168 tests/regression/ust/libc-wrapper/Makefile
1169 tests/regression/ust/baddr-statedump/Makefile
1170 tests/regression/ust/ust-dl/Makefile
1171 tests/regression/ust/java-jul/Makefile
1172 tests/regression/ust/java-log4j/Makefile
1173 tests/regression/ust/python-logging/Makefile
1174 tests/regression/ust/getcpu-override/Makefile
1175 tests/regression/ust/clock-override/Makefile
1176 tests/regression/ust/type-declarations/Makefile
1177 tests/regression/ust/rotation-destroy-flush/Makefile
1178 tests/regression/ust/blocking/Makefile
1179 tests/regression/ust/namespaces/Makefile
1180 tests/stress/Makefile
1181 tests/unit/Makefile
1182 tests/unit/ini_config/Makefile
1183 tests/perf/Makefile
1184 tests/utils/Makefile
1185 tests/utils/tap/Makefile
1186 tests/utils/testapp/Makefile
1187 tests/utils/testapp/gen-ns-events/Makefile
1188 tests/utils/testapp/gen-kernel-test-events/Makefile
1189 tests/utils/testapp/gen-ust-events/Makefile
1190 tests/utils/testapp/gen-ust-events-ns/Makefile
1191 tests/utils/testapp/gen-syscall-events-callstack/Makefile
1192 tests/utils/testapp/gen-ust-nevents/Makefile
1193 tests/utils/testapp/gen-ust-nevents-str/Makefile
1194 tests/utils/testapp/gen-syscall-events/Makefile
1195 tests/utils/testapp/gen-ust-tracef/Makefile
1196 tests/utils/testapp/userspace-probe-elf-binary/Makefile
1197 tests/utils/testapp/userspace-probe-elf-cxx-binary/Makefile
1198 tests/utils/testapp/userspace-probe-sdt-binary/Makefile
1199 ])
1200
1201 # Inject variable into python test script.
1202 AC_CONFIG_FILES([tests/regression/ust/python-logging/test_python_logging],[chmod +x tests/regression/ust/python-logging/test_python_logging])
1203 # Inject LTTNG_TOOLS_BUILD_WITH_LIBPFM variable in test script.
1204 AC_CONFIG_FILES([tests/perf/test_perf_raw],[chmod +x tests/perf/test_perf_raw])
1205 AC_CONFIG_FILES([tests/regression/ust/ust-dl/test_ust-dl],[chmod +x tests/regression/ust/ust-dl/test_ust-dl])
1206
1207 AC_OUTPUT
1208
1209 #
1210 # Mini-report on what will be built.
1211 #
1212
1213 PPRINT_INIT
1214 PPRINT_SET_INDENT(1)
1215 PPRINT_SET_TS(38)
1216
1217 AS_ECHO
1218 AS_ECHO("${PPRINT_COLOR_BLDBLU}LTTng-tools $PACKAGE_VERSION \"$version_name\"$PPRINT_COLOR_RST")
1219 AS_ECHO
1220
1221 AS_IF([test -n "$report_fold"], [
1222 AS_ECHO("`AS_ECHO("$version_description") | $report_fold -s`")
1223 ], [
1224 AS_ECHO("$version_description")
1225 ])
1226
1227 AS_ECHO
1228 PPRINT_SUBTITLE([Features])
1229
1230 # Target architecture we're building for.
1231 target_arch=$host_cpu
1232 [
1233 for f in $CFLAGS; do
1234 if test $f = "-m32"; then
1235 target_arch="32-bit"
1236 elif test $f = "-m64"; then
1237 target_arch="64-bit"
1238 fi
1239 done
1240 ]
1241 PPRINT_PROP_STRING([Target architecture], $target_arch)
1242
1243 # kmod enabled/disabled
1244 test "x$with_kmod" != "xno" && value=1 || value=0
1245 PPRINT_PROP_BOOL([libkmod support], $value)
1246
1247 # LTTng-UST enabled/disabled
1248 test "x$with_lttng_ust" = "xyes" && value=1 || value=0
1249 PPRINT_PROP_BOOL([LTTng-UST support], $value)
1250
1251 AS_ECHO
1252 PPRINT_SUBTITLE([Binaries])
1253
1254 # List binaries to be built
1255 test x$enable_bin_lttng != xno && value=1 || value=0
1256 PPRINT_PROP_BOOL([lttng], $value)
1257
1258 test x$enable_bin_lttng_consumerd != xno && value=1 || value=0
1259 PPRINT_PROP_BOOL([lttng-consumerd], $value)
1260
1261 test x$enable_bin_lttng_crash != xno && value=1 || value=0
1262 PPRINT_PROP_BOOL([lttng-crash], $value)
1263
1264 test x$enable_bin_lttng_relayd != xno && value=1 || value=0
1265 PPRINT_PROP_BOOL([lttng-relayd], $value)
1266
1267 test x$enable_bin_lttng_sessiond != xno && value=1 || value=0
1268 PPRINT_PROP_BOOL([lttng-sessiond], $value)
1269
1270 # Extras
1271 test x$enable_extras != xno && value=1 || value=0
1272 AS_ECHO
1273 PPRINT_SET_INDENT(0)
1274 PPRINT_PROP_BOOL([Extras], $value, $PPRINT_COLOR_SUBTITLE)
1275 PPRINT_SET_INDENT(1)
1276
1277 AS_ECHO
1278 PPRINT_SUBTITLE([Tests])
1279
1280 # Print clear message that tests won't be built
1281 AS_IF([test "x$build_tests" = "xno"],[
1282 PPRINT_WARN([Tests won't be built since some binaries were disabled])
1283 ])
1284
1285 # LTTng UST Java agent JUL tests enabled/disabled
1286 test "x$test_java_agent_jul" = "xyes" && value=1 || value=0
1287 PPRINT_PROP_BOOL([LTTng-UST Java agent JUL tests], $value)
1288
1289 # LTTng UST Java agent Log4j tests enabled/disabled
1290 test "x$test_java_agent_log4j" = "xyes" && value=1 || value=0
1291 PPRINT_PROP_BOOL([LTTng-UST Java agent Log4j tests], $value)
1292
1293 test ! -z "$PYTHON2_AGENT" && value=1 || value=0
1294 PPRINT_PROP_BOOL([LTTng-UST Python2 agent tests], $value)
1295
1296 test ! -z "$PYTHON3_AGENT" && value=1 || value=0
1297 PPRINT_PROP_BOOL([LTTng-UST Python3 agent tests], $value)
1298
1299 # LTTng UST Java agent Log4j tests enabled/disabled
1300 test "x$test_sdt_uprobe" = "xyes" && value=1 || value=0
1301 PPRINT_PROP_BOOL([LTTng-UST SDT uprobe tests], $value)
1302
1303 #Python binding enabled/disabled
1304 test "x$enable_python_binding" = xyes && value=1 || value=0
1305 AS_ECHO
1306 PPRINT_SET_INDENT(0)
1307 PPRINT_PROP_BOOL([Python binding], $value, $PPRINT_COLOR_SUBTITLE)
1308
1309 # man pages build enabled/disabled
1310 m4_pushdef([build_man_pages_msg], [Build and install man pages])
1311
1312 AS_IF([test "x$man_pages_opt" != "xno"], [
1313 AS_IF([test "x$in_git_repo" = "xyes"], [
1314 PPRINT_PROP_BOOL([build_man_pages_msg], 1, $PPRINT_COLOR_SUBTITLE)
1315 ], [
1316 AS_IF([test "x$have_asciidoc_xmlto" = "xyes"], [
1317 PPRINT_PROP_BOOL([build_man_pages_msg], 1, $PPRINT_COLOR_SUBTITLE)
1318 ], [
1319 PPRINT_PROP_STRING([build_man_pages_msg],
1320 [${PPRINT_COLOR_BLDGRN}yes (already built)],
1321 $PPRINT_COLOR_SUBTITLE)
1322 ])
1323 ])
1324 ], [
1325 PPRINT_PROP_BOOL([build_man_pages_msg], 0, $PPRINT_COLOR_SUBTITLE)
1326 ])
1327
1328 m4_popdef([build_man_pages_msg])
1329
1330 test "x$embedded_help" = xyes && value=1 || value=0
1331 PPRINT_PROP_BOOL([Embed --help messages], $value, $PPRINT_COLOR_SUBTITLE)
1332
1333 PPRINT_SET_INDENT(1)
1334
1335 report_bindir="`eval eval echo $bindir`"
1336 report_libdir="`eval eval echo $libdir`"
1337
1338 # Print the bindir and libdir this `make install' will install into.
1339 AS_ECHO
1340 PPRINT_SUBTITLE([Install directories])
1341 PPRINT_PROP_STRING([Binaries], [$report_bindir])
1342 PPRINT_PROP_STRING([Libraries], [$report_libdir])
1343
1344 AS_ECHO
1345 PPRINT_SUBTITLE([Search directories])
1346
1347 # If we build the sessiond, print the paths it will use
1348 AS_IF([test "$SESSIOND_BIN" = ""],[
1349 path="$report_bindir/lttng-sessiond"
1350 ],[
1351 path="$SESSIOND_BIN"
1352 ])
1353 PPRINT_PROP_STRING([lttng-sessiond executable], [$path])
1354
1355 AS_IF([test "$CONSUMERD32_BIN" = ""],[
1356 path="`eval eval echo $lttnglibexecdir`/lttng-consumerd"
1357 ],[
1358 path="$CONSUMERD32_BIN"
1359 ])
1360 PPRINT_PROP_STRING([32-bit lttng-consumerd executable], [$path])
1361
1362 AS_IF([test "$CONSUMERD32_LIBDIR" = ""],[
1363 path="`eval eval echo $libdir`"
1364 ],[
1365 path="$CONSUMERD32_LIBDIR"
1366 ])
1367 PPRINT_PROP_STRING([32-bit consumer libraries], [$path])
1368
1369 AS_IF([test "$CONSUMERD64_BIN" = ""],[
1370 path="`eval eval echo $lttnglibexecdir`/lttng-consumerd"
1371 ],[
1372 path="$CONSUMERD64_BIN"
1373 ])
1374 PPRINT_PROP_STRING([64-bit lttng-consumerd executable], [$path])
1375
1376 AS_IF([test "$CONSUMERD64_LIBDIR" = ""],[
1377 path="`eval eval echo $libdir`"
1378 ],[
1379 path="$CONSUMERD64_LIBDIR"
1380 ])
1381 PPRINT_PROP_STRING([64-bit consumer libraries], [$path])
1382 PPRINT_SET_INDENT(0)
1383
1384 AS_IF([test "x$warn_prebuilt_man_pages" = "xyes" ], [
1385 AS_ECHO
1386 PPRINT_WARN([You need asciidoc and xmlto to build the LTTng-tools man pages.
1387
1388 Note that the man pages are already built in this distribution tarball,
1389 therefore asciidoc and xmlto are only needed if you intend to modify
1390 their sources.
1391
1392 Also note that the installed man pages will contain the project's
1393 default command-line option and environment variable values.
1394
1395 Use --disable-man-pages to completely disable building and installing
1396 the man pages.])
1397 ])
This page took 0.097785 seconds and 4 git commands to generate.