configure.ac

   1 dnl SPDX-License-Identifier: GPL-2.0-only
   2 AC_PREREQ([2.64])
   3 AC_INIT([lttng-tools],[2.13.0-pre],[jeremie.galarneau@efficios.com],[],[https://lttng.org])
   4
   5 AC_CONFIG_HEADERS([include/config.h])
   6 AC_CONFIG_AUX_DIR([config])
   7 AC_CONFIG_MACRO_DIR([m4])
   8
   9 AC_CANONICAL_TARGET
  10 AC_CANONICAL_HOST
  11
  12 AM_INIT_AUTOMAKE([1.12 foreign dist-bzip2 no-dist-gzip tar-pax nostdinc])
  13 AM_MAINTAINER_MODE([enable])
  14
  15 # Enable silent rules if available (Introduced in AM 1.11)
  16 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  17
  18 AC_REQUIRE_AUX_FILE([tap-driver.sh])
  19
  20 # Checks for C compiler
  21 AC_USE_SYSTEM_EXTENSIONS
  22 AC_SYS_LARGEFILE
  23 AC_PROG_CC
  24 # AC_PROG_CC_STDC was merged in AC_PROG_CC in autoconf 2.70
  25 m4_version_prereq([2.70], [], [AC_PROG_CC_STDC])
  26 AC_PROG_CXX
  27 RW_PROG_CXX_WORKS
  28 AM_CONDITIONAL([CXX_WORKS], [test "x$rw_cv_prog_cxx_works" = "xyes"])
  29
  30 # Detect warning flags supported by the compiler, append them to WARN_CFLAGS.
  31 #
  32 # Pass -Werror as an extra flag during the test: this is needed to make the
  33 # -Wunknown-warning-option diagnostic fatal with clang.
  34 AX_APPEND_COMPILE_FLAGS([ dnl
  35                 -Wall dnl
  36                 dnl We currently get this warning when building with Clang:
  37                 dnl
  38                 dnl /usr/include/setjmp.h:54:12: error: declaration of built-in function '__sigsetjmp' requires the declaration of the 'jmp_buf' type, commonly provided in the header <setjmp.h>. [-Werror,-Wincomplete-setjmp-declaration]
  39                 dnl extern int __sigsetjmp (struct __jmp_buf_tag __env[1], int __savemask) __THROWNL;
  40                 dnl            ^
  41                 -Wno-incomplete-setjmp-declaration dnl
  42                 -Wdiscarded-qualifiers dnl
  43                 -Wmissing-declarations dnl
  44                 -Wmissing-prototypes dnl
  45                 -Wmissing-parameter-type dnl
  46                 -Wold-style-definition dnl
  47                 -Wstrict-prototypes dnl
  48         ],
  49         [WARN_CFLAGS],
  50         [-Werror])
  51
  52 # When given, add -Werror to WARN_CFLAGS.
  53 AC_ARG_ENABLE([Werror],
  54         [AS_HELP_STRING([--enable-Werror], [Treat compiler warnings as errors.])]
  55 )
  56 AS_IF([test "x$enable_Werror" = "xyes"],
  57         [WARN_CFLAGS="${WARN_CFLAGS} -Werror"]
  58 )
  59
  60 # Checks for programs.
  61 AC_PROG_GREP
  62 AC_PROG_MAKE_SET
  63 AC_PROG_SED
  64 AC_PATH_PROG([report_fold], [fold])
  65 LT_INIT
  66
  67 # Check for objcopy, required by the base address statedump and dynamic linker tests
  68 AC_CHECK_TOOL([OBJCOPY], [objcopy], [no])
  69 AS_IF([test "x$OBJCOPY" = "xno"],
  70         [AC_MSG_WARN([Cannot find objcopy. The base address statedump and dynamic linker tests will be disabled. Install the binutils package to remediate this.])]
  71 )
  72 AM_CONDITIONAL([HAVE_OBJCOPY], [test "x$OBJCOPY" != xno])
  73
  74 # check for pgrep
  75 AC_PATH_PROG([PGREP], [pgrep], [no])
  76 AM_CONDITIONAL([HAVE_PGREP], [test "x$PGREP" != "xno"])
  77
  78 # set $IN_GIT_REPO if we're in the Git repository; the `bootstrap` file
  79 # is not distributed in tarballs
  80 AS_IF([test -f "$srcdir/bootstrap"], [in_git_repo=yes], [in_git_repo=no])
  81 AM_CONDITIONAL([IN_GIT_REPO], [test "x$in_git_repo" = "xyes"])
  82
  83 # check for bison
  84 AC_PROG_YACC
  85 BISON=$YACC
  86 AX_PROG_BISON_VERSION([2.4], [have_bison=yes])
  87
  88 AS_IF([test "x$have_bison" != "xyes"], [
  89   AS_IF([test "x$in_git_repo" = "xyes"], [
  90     AC_MSG_FAILURE([
  91 Bison >= 2.4 is required when building from the Git repository. You can
  92 set the YACC variable to override automatic detection.
  93     ])
  94   ], [
  95     AC_MSG_WARN([
  96 Missing Bison >= 2.4. Note that the parser files are already built in
  97 this distribution tarball, so Bison is only needed if you intend to
  98 modify their sources. You can set the YACC variable to override automatic
  99 detection.
 100     ])
 101   ])
 102 ])
 103 AM_CONDITIONAL([HAVE_BISON], [test "x$have_bison" = "xyes"])
 104
 105 # check for flex
 106 # Prior to autoconf 2.70, AC_PROG_FLEX did not take an argument. This is not a
 107 # problem since the argument is silently ignored by older versions.
 108 AC_PROG_LEX([noyywrap])
 109 FLEX=$LEX
 110 AX_PROG_FLEX_VERSION([2.5.35], [have_flex=yes])
 111
 112 AS_IF([test "x$have_flex" != "xyes"], [
 113   AS_IF([test "x$in_git_repo" = "xyes"], [
 114     AC_MSG_FAILURE([
 115 Flex >= 2.5.35 is required when building from the Git repository. You can
 116 set the LEX variable to override automatic detection.
 117     ])
 118   ], [
 119     AC_MSG_WARN([
 120 Missing Flex >= 2.5.35. Note that the lexer files are already built in
 121 this distribution tarball, so Flex is only needed if you intend to
 122 modify their sources. You can set the LEX variable to override automatic
 123 detection.
 124     ])
 125   ])
 126 ])
 127 AM_CONDITIONAL([HAVE_FLEX], [test "x$have_flex" = "xyes"])
 128
 129
 130 # Checks for typedefs, structures, and compiler characteristics.
 131 AC_C_INLINE
 132 AC_TYPE_INT32_T
 133 AC_TYPE_INT64_T
 134 AC_TYPE_MODE_T
 135 AC_TYPE_OFF_T
 136 AC_TYPE_PID_T
 137 AC_TYPE_SIZE_T
 138 AC_TYPE_SSIZE_T
 139 AC_TYPE_UID_T
 140 AC_TYPE_UINT16_T
 141 AC_TYPE_UINT32_T
 142 AC_TYPE_UINT64_T
 143 AC_TYPE_UINT8_T
 144
 145 AX_C___ATTRIBUTE__
 146 AS_IF([test "x$ax_cv___attribute__" = "xyes"],
 147         [:],
 148         [AC_MSG_ERROR([The compiler does not support __attribute__ extensions])])
 149
 150 AX_PTHREAD(,[AC_MSG_ERROR([Could not configure pthreads support])])
 151
 152 # Check if linker has the -no-pie option.
 153 AX_CHECK_LINK_FLAG([-no-pie], [linker_have_no_pie_option=yes])
 154 AM_CONDITIONAL([LINKER_HAVE_NO_PIE_OPTION], [test "x$linker_have_no_pie_option" = "xyes"])
 155
 156 AX_LIB_SOCKET_NSL
 157
 158 LT_NO_UNDEFINED=""
 159 AS_CASE([$host_os],
 160   [cygwin*],
 161     [
 162       LT_NO_UNDEFINED="-no-undefined"
 163     ],
 164   [cygwin*|darwin*|mingw*|solaris*],
 165     [
 166       # On platforms where we only support the relayd, disable the other binaries by default
 167       AS_IF([test "x$enable_bin_lttng" = "x" ], [enable_bin_lttng=no])
 168       AS_IF([test "x$enable_bin_lttng_consumerd" = "x" ], [enable_bin_lttng_consumerd=no])
 169       AS_IF([test "x$enable_bin_lttng_crash" = "x" ], [enable_bin_lttng_crash=no])
 170       AS_IF([test "x$enable_bin_lttng_sessiond" = "x" ], [enable_bin_lttng_sessiond=no])
 171       AS_IF([test "x$enable_extras" = "x" ], [enable_extras=no])
 172       AS_IF([test "x$with_lttng_ust" = "x" ], [with_lttng_ust=no])
 173     ]
 174 )
 175
 176 AC_SUBST(LT_NO_UNDEFINED)
 177
 178 # Compute minor/major/patchlevel version numbers
 179 major_version=$(echo AC_PACKAGE_VERSION | $SED 's/^\([[0-9]]\)*\.[[0-9]]*\.[[0-9]]*.*$/\1/')
 180 minor_version=$(echo AC_PACKAGE_VERSION | $SED 's/^[[0-9]]*\.\([[0-9]]*\)\.[[0-9]]*.*$/\1/')
 181 patchlevel_version=$(echo AC_PACKAGE_VERSION | $SED 's/^[[0-9]]*\.[[0-9]]*\.\([[0-9]]*\).*$/\1/')
 182
 183 AC_SUBST([MAJOR_VERSION], [$major_version])
 184 AC_SUBST([MINOR_VERSION], [$minor_version])
 185 AC_SUBST([PATCHLEVEL_VERSION], [$patchlevel_version])
 186 AC_DEFINE_UNQUOTED([VERSION_MAJOR], $major_version, [LTTng-Tools major version number])
 187 AC_DEFINE_UNQUOTED([VERSION_MINOR], $minor_version, [LTTng-Tools minor version number])
 188 AC_DEFINE_UNQUOTED([VERSION_PATCHLEVEL], $patchlevel_version, [LTTng-Tools patchlevel version number])
 189
 190 version_name="N-Beer"
 191 version_description="An alcoholic drink made from yeast-fermented malt flavored with hops."
 192 version_description_c=$(echo $version_description | $SED 's/"/\\"/g')
 193
 194 AC_DEFINE_UNQUOTED([VERSION_NAME], ["$version_name"], "")
 195 AC_DEFINE_UNQUOTED([VERSION_DESCRIPTION], ["$version_description_c"], "")
 196
 197 # libtool link_all_deplibs fixup. See http://bugs.lttng.org/issues/321.
 198 AC_ARG_ENABLE(libtool-linkdep-fixup,
 199         AS_HELP_STRING([--disable-libtool-linkdep-fixup],
 200                         [disable the libtool fixup for linking all dependent libraries (link_all_deplibs)]),
 201         libtool_fixup=$enableval,
 202         libtool_fixup=yes)
 203
 204 AS_IF([test "x$libtool_fixup" = "xyes"],
 205             [
 206             libtool_m4="$srcdir/m4/libtool.m4"
 207             libtool_flag_pattern=".*link_all_deplibs\s*,\s*\$1\s*)"
 208             AC_MSG_CHECKING([for occurence(s) of link_all_deplibs = no in $libtool_m4])
 209             libtool_flag_pattern_count=$($GREP -c "$libtool_flag_pattern\s*=\s*no" $libtool_m4)
 210             AS_IF([test $libtool_flag_pattern_count -ne 0],
 211             [
 212                   AC_MSG_RESULT([$libtool_flag_pattern_count])
 213                   AC_MSG_WARN([the detected libtool will not link all dependencies, forcing link_all_deplibs = unknown])
 214                   $SED -i "s/\($libtool_flag_pattern\)\s*=\s*no/\1=unknown/g" $libtool_m4
 215                   ],
 216                   [
 217                   AC_MSG_RESULT([none])
 218                   ])
 219             ])
 220
 221 AM_CONDITIONAL([NO_SHARED], [test x$enable_shared = xno])
 222
 223 AC_CHECK_HEADERS([ \
 224         sys/types.h unistd.h fcntl.h string.h pthread.h limits.h \
 225         signal.h stdlib.h sys/un.h sys/socket.h stdlib.h stdio.h \
 226         getopt.h sys/ipc.h sys/shm.h popt.h grp.h arpa/inet.h \
 227         netdb.h netinet/in.h paths.h stddef.h sys/file.h sys/ioctl.h \
 228         sys/mount.h sys/param.h sys/time.h elf.h
 229 ])
 230
 231 AM_CONDITIONAL([HAVE_ELF_H], [test x$ac_cv_header_elf_h = xyes])
 232
 233 # Basic functions check
 234 AC_CHECK_FUNCS([ \
 235         atexit bzero clock_gettime dup2 fdatasync fls ftruncate \
 236         gethostbyname gethostname getpagesize localtime_r memchr memrchr memset \
 237         mkdir munmap putenv realpath rmdir socket strchr strcspn strdup \
 238         strncasecmp strndup strnlen strpbrk strrchr strstr strtol strtoul \
 239         strtoull dirfd gethostbyname2 getipnodebyname epoll_create1 \
 240         sched_getcpu sysconf sync_file_range
 241 ])
 242
 243 # Check for pthread_setname_np and pthread_getname_np
 244 LTTNG_PTHREAD_SETNAME_NP
 245 LTTNG_PTHREAD_GETNAME_NP
 246
 247 # Check if clock_gettime, timer_create, timer_settime, and timer_delete are available in lib rt, and if so,
 248 # add -lrt to LIBS
 249 AC_CHECK_LIB([rt], [clock_gettime, timer_create, timer_settime, timer_delete])
 250
 251 # Checks for dl.
 252 AC_CHECK_LIB([dl], [dlopen], [
 253         have_libdl=yes
 254         libdl_name=dl
 255         DL_LIBS="-ldl"
 256 ], [
 257         # libdl not found, check for dlopen in libc.
 258         AC_CHECK_LIB([c], [dlopen], [
 259                 have_libc_dl=yes
 260                 libdl_name=c
 261                 DL_LIBS="-lc"
 262         ], [
 263                 AC_MSG_ERROR([Cannot find dlopen in libdl nor libc. Use [LDFLAGS]=-Ldir to specify their location.])
 264         ])
 265 ])
 266 AC_SUBST(DL_LIBS)
 267
 268 # Check if libdl has dlmopen support.
 269 AH_TEMPLATE([HAVE_DLMOPEN], ["Define to 1 if dlmopen is available."])
 270 AC_CHECK_LIB([$libdl_name], [dlmopen], [
 271         AC_DEFINE([HAVE_DLMOPEN], [1])
 272         HAVE_DLMOPEN=1
 273 ], [
 274         HAVE_DLMOPEN=0
 275 ])
 276 AC_SUBST(HAVE_DLMOPEN)
 277
 278 # Babeltrace viewer check
 279 AC_ARG_WITH([babeltrace-bin],
 280         AS_HELP_STRING([--with-babeltrace-bin],
 281         [Location of the babeltrace viewer executable (including the filename)]),
 282         [BABELTRACE_BIN="$withval"],
 283         [BABELTRACE_BIN=''])
 284 AC_SUBST([BABELTRACE_BIN])
 285
 286 AC_ARG_WITH([babeltrace2-bin],
 287         AS_HELP_STRING([--with-babeltrace2-bin],
 288         [Location of the babeltrace2 viewer executable (including the filename)]),
 289         [BABELTRACE2_BIN="$withval"],
 290         [BABELTRACE2_BIN=''])
 291 AC_SUBST([BABELTRACE2_BIN])
 292
 293 AC_ARG_WITH([consumerd32-bin],
 294         AS_HELP_STRING([--with-consumerd32-bin],
 295         [Location of the 32-bit consumerd executable (including the filename)]),
 296         [CONSUMERD32_BIN="$withval"],
 297         [CONSUMERD32_BIN=''])
 298 AC_SUBST([CONSUMERD32_BIN])
 299
 300 AC_ARG_WITH([consumerd64-bin],
 301         AS_HELP_STRING([--with-consumerd64-bin],
 302         [Location of the 64-bit consumerd executable (including the filename)]),
 303         [CONSUMERD64_BIN="$withval"],
 304         [CONSUMERD64_BIN=''])
 305 AC_SUBST([CONSUMERD64_BIN])
 306
 307 AC_ARG_WITH([consumerd32-libdir],
 308         AS_HELP_STRING([--with-consumerd32-libdir],
 309         [Directory containing the 32-bit consumerd libraries]),
 310         [CONSUMERD32_LIBDIR="$withval"],
 311         [CONSUMERD32_LIBDIR=''])
 312 AC_SUBST([CONSUMERD32_LIBDIR])
 313
 314 AC_ARG_WITH([consumerd64-libdir],
 315         AS_HELP_STRING([--with-consumerd64-libdir],
 316         [Directory containing the 64-bit consumerd libraries]),
 317         [CONSUMERD64_LIBDIR="$withval"],
 318         [CONSUMERD64_LIBDIR=''])
 319 AC_SUBST([CONSUMERD64_LIBDIR])
 320
 321 AC_ARG_WITH([sessiond-bin],
 322         AS_HELP_STRING([--with-sessiond-bin],
 323         [Location of the sessiond executable (including the filename)]),
 324         [SESSIOND_BIN="$withval"],
 325         [SESSIOND_BIN=''])
 326 AC_SUBST([SESSIOND_BIN])
 327
 328 AC_ARG_WITH([lttng-system-rundir],
 329         AS_HELP_STRING([--with-lttng-system-rundir],
 330         [Location of the system directory where the system-wide lttng-sessiond runtime files are kept. The default is "/var/run/lttng".]),
 331         [LTTNG_SYSTEM_RUNDIR="$withval"],
 332         [LTTNG_SYSTEM_RUNDIR="/var/run/lttng"])
 333 AC_SUBST([LTTNG_SYSTEM_RUNDIR])
 334
 335 AC_ARG_ENABLE([test-java-agent-jul],
 336         [AS_HELP_STRING([--enable-test-java-agent-jul],[enable the LTTng UST Java agent JUL tests [default=no]])],
 337         [test_java_agent_jul=$enableval],
 338         [test_java_agent_jul=no]
 339 )
 340
 341 AC_ARG_ENABLE([test-java-agent-log4j],
 342         [AS_HELP_STRING([--enable-test-java-agent-log4j],[enable the LTTng UST Java agent Log4j tests [default=no]])],
 343         [test_java_agent_log4j=$enableval],
 344         [test_java_agent_log4j=no]
 345 )
 346
 347 AC_ARG_ENABLE([test-java-agent-all],
 348         [AS_HELP_STRING([--enable-test-java-agent-all],[enable all the LTTng UST Java agent tests [default=no]])],
 349         [test_java_agent_jul=$enableval
 350          test_java_agent_log4j=$enableval],
 351         [:]
 352 )
 353
 354 AC_DEFINE_UNQUOTED([CONFIG_CONSUMERD32_BIN], "$CONSUMERD32_BIN", [Location of the 32-bit consumerd executable.])
 355 AC_DEFINE_UNQUOTED([CONFIG_CONSUMERD64_BIN], "$CONSUMERD64_BIN", [Location of the 64-bit consumerd executable])
 356 AC_DEFINE_UNQUOTED([CONFIG_CONSUMERD32_LIBDIR], "$CONSUMERD32_LIBDIR", [Search for consumerd 32-bit libraries in this location.])
 357 AC_DEFINE_UNQUOTED([CONFIG_CONSUMERD64_LIBDIR], "$CONSUMERD64_LIBDIR", [Search for consumerd 64-bit libraries in this location.])
 358 AC_DEFINE_UNQUOTED([CONFIG_BABELTRACE_BIN], "$BABELTRACE_BIN", [Location of the babeltrace viewer executable.])
 359 AC_DEFINE_UNQUOTED([CONFIG_BABELTRACE2_BIN], "$BABELTRACE2_BIN", [Location of the babeltrace2 viewer executable.])
 360 AC_DEFINE_UNQUOTED([CONFIG_SESSIOND_BIN], "$SESSIOND_BIN", [Location of the sessiond executable.])
 361 AC_DEFINE_UNQUOTED([CONFIG_LTTNG_SYSTEM_RUNDIR], ["$LTTNG_SYSTEM_RUNDIR"], [LTTng system runtime directory])
 362
 363 AC_DEFUN([_AC_DEFINE_AND_SUBST], [
 364         AC_DEFINE_UNQUOTED([CONFIG_$1], [$2], [$1])
 365         $1="$2"
 366         AC_SUBST([$1])
 367 ])
 368
 369 AC_DEFUN([_AC_DEFINE_QUOTED_AND_SUBST], [
 370         AC_DEFINE_UNQUOTED([CONFIG_$1], ["$2"], [$1])
 371         $1="$2"
 372         AC_SUBST([$1])
 373 ])
 374
 375 # Default values
 376 m4_define([_DEFAULT_CHANNEL_SUBBUF_SIZE], [16384])
 377 m4_define([_DEFAULT_CHANNEL_SUBBUF_NUM], [4])
 378 m4_define([_DEFAULT_CHANNEL_SWITCH_TIMER], [0])
 379 m4_define([_DEFAULT_CHANNEL_LIVE_TIMER], [0])
 380 m4_define([_DEFAULT_CHANNEL_READ_TIMER], [200000])
 381 m4_define([_DEFAULT_CHANNEL_MONITOR_TIMER], [1000000])
 382 m4_define([_DEFAULT_CHANNEL_BLOCKING_TIMEOUT], [0])
 383 _AC_DEFINE_AND_SUBST([DEFAULT_AGENT_TCP_PORT_RANGE_BEGIN], [5345])
 384 _AC_DEFINE_AND_SUBST([DEFAULT_AGENT_TCP_PORT_RANGE_END], [5354])
 385 _AC_DEFINE_AND_SUBST([DEFAULT_APP_SOCKET_RW_TIMEOUT], [5])
 386 _AC_DEFINE_AND_SUBST([DEFAULT_CHANNEL_SUBBUF_SIZE], [_DEFAULT_CHANNEL_SUBBUF_SIZE])
 387 _AC_DEFINE_AND_SUBST([DEFAULT_CHANNEL_TRACEFILE_COUNT], [0])
 388 _AC_DEFINE_AND_SUBST([DEFAULT_CHANNEL_TRACEFILE_SIZE], [0])
 389 _AC_DEFINE_AND_SUBST([DEFAULT_KERNEL_CHANNEL_LIVE_TIMER], [_DEFAULT_CHANNEL_LIVE_TIMER])
 390 _AC_DEFINE_AND_SUBST([DEFAULT_KERNEL_CHANNEL_READ_TIMER], [_DEFAULT_CHANNEL_READ_TIMER])
 391 _AC_DEFINE_AND_SUBST([DEFAULT_KERNEL_CHANNEL_SUBBUF_NUM], [_DEFAULT_CHANNEL_SUBBUF_NUM])
 392 _AC_DEFINE_AND_SUBST([DEFAULT_KERNEL_CHANNEL_SUBBUF_SIZE], [1048576])
 393 _AC_DEFINE_AND_SUBST([DEFAULT_KERNEL_CHANNEL_SWITCH_TIMER], [_DEFAULT_CHANNEL_SWITCH_TIMER])
 394 _AC_DEFINE_AND_SUBST([DEFAULT_KERNEL_CHANNEL_MONITOR_TIMER], [_DEFAULT_CHANNEL_MONITOR_TIMER])
 395 _AC_DEFINE_AND_SUBST([DEFAULT_KERNEL_CHANNEL_BLOCKING_TIMEOUT], [_DEFAULT_CHANNEL_BLOCKING_TIMEOUT])
 396 _AC_DEFINE_AND_SUBST([DEFAULT_LTTNG_LIVE_TIMER], [1000000])
 397 _AC_DEFINE_AND_SUBST([DEFAULT_METADATA_CACHE_SIZE], [4096])
 398 _AC_DEFINE_AND_SUBST([DEFAULT_METADATA_READ_TIMER], [0])
 399 _AC_DEFINE_AND_SUBST([DEFAULT_METADATA_SUBBUF_NUM], [2])
 400 _AC_DEFINE_AND_SUBST([DEFAULT_METADATA_SUBBUF_SIZE], [4096])
 401 _AC_DEFINE_AND_SUBST([DEFAULT_METADATA_SWITCH_TIMER], [_DEFAULT_CHANNEL_SWITCH_TIMER])
 402 _AC_DEFINE_AND_SUBST([DEFAULT_NETWORK_CONTROL_PORT], [5342])
 403 _AC_DEFINE_AND_SUBST([DEFAULT_NETWORK_DATA_PORT], [5343])
 404 _AC_DEFINE_AND_SUBST([DEFAULT_NETWORK_VIEWER_PORT], [5344])
 405 _AC_DEFINE_AND_SUBST([DEFAULT_UST_PID_CHANNEL_LIVE_TIMER], [_DEFAULT_CHANNEL_LIVE_TIMER])
 406 _AC_DEFINE_AND_SUBST([DEFAULT_UST_PID_CHANNEL_READ_TIMER], [0])
 407 _AC_DEFINE_AND_SUBST([DEFAULT_UST_PID_CHANNEL_BLOCKING_TIMEOUT], [0])
 408 _AC_DEFINE_AND_SUBST([DEFAULT_UST_PID_CHANNEL_SUBBUF_NUM], [_DEFAULT_CHANNEL_SUBBUF_NUM])
 409 _AC_DEFINE_AND_SUBST([DEFAULT_UST_PID_CHANNEL_SUBBUF_SIZE], [_DEFAULT_CHANNEL_SUBBUF_SIZE])
 410 _AC_DEFINE_AND_SUBST([DEFAULT_UST_PID_CHANNEL_SWITCH_TIMER], [_DEFAULT_CHANNEL_SWITCH_TIMER])
 411 _AC_DEFINE_AND_SUBST([DEFAULT_UST_PID_CHANNEL_MONITOR_TIMER], [_DEFAULT_CHANNEL_MONITOR_TIMER])
 412 _AC_DEFINE_AND_SUBST([DEFAULT_UST_UID_CHANNEL_LIVE_TIMER], [_DEFAULT_CHANNEL_LIVE_TIMER])
 413 _AC_DEFINE_AND_SUBST([DEFAULT_UST_UID_CHANNEL_READ_TIMER], [0])
 414 _AC_DEFINE_AND_SUBST([DEFAULT_UST_UID_CHANNEL_BLOCKING_TIMEOUT], [0])
 415 _AC_DEFINE_AND_SUBST([DEFAULT_UST_UID_CHANNEL_SUBBUF_NUM], [_DEFAULT_CHANNEL_SUBBUF_NUM])
 416 _AC_DEFINE_AND_SUBST([DEFAULT_UST_UID_CHANNEL_SUBBUF_SIZE], [524288])
 417 _AC_DEFINE_AND_SUBST([DEFAULT_UST_UID_CHANNEL_SWITCH_TIMER], [_DEFAULT_CHANNEL_SWITCH_TIMER])
 418 _AC_DEFINE_AND_SUBST([DEFAULT_UST_UID_CHANNEL_MONITOR_TIMER], [_DEFAULT_CHANNEL_MONITOR_TIMER])
 419 _AC_DEFINE_QUOTED_AND_SUBST([DEFAULT_AGENT_BIND_ADDRESS], [localhost])
 420 _AC_DEFINE_QUOTED_AND_SUBST([DEFAULT_NETWORK_CONTROL_BIND_ADDRESS], [0.0.0.0])
 421 _AC_DEFINE_QUOTED_AND_SUBST([DEFAULT_NETWORK_DATA_BIND_ADDRESS], [0.0.0.0])
 422 _AC_DEFINE_QUOTED_AND_SUBST([DEFAULT_NETWORK_VIEWER_BIND_ADDRESS], [localhost])
 423 _AC_DEFINE_AND_SUBST([DEFAULT_NETWORK_RELAYD_CTRL_MAX_PAYLOAD_SIZE], [134217728])
 424 _AC_DEFINE_AND_SUBST([DEFAULT_ROTATE_PENDING_TIMER], [500000])
 425 _AC_DEFINE_AND_SUBST([DEFAULT_EVENT_NOTIFIER_ERROR_COUNT_MAP_SIZE], [4096])
 426
 427 # Command short descriptions
 428 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_ADD_CONTEXT], [Add context fields to a channel])
 429 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_CREATE], [Create a tracing session])
 430 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_CLEAR], [Clear a tracing session])
 431 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_DESTROY], [Tear down tracing sessions])
 432 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_DISABLE_CHANNEL], [Disable tracing channels])
 433 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_DISABLE_EVENT], [Disable event rules])
 434 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_DISABLE_ROTATION], [Unset a rotation schedule])
 435 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_ENABLE_CHANNEL], [Create or enable tracing channels])
 436 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_ENABLE_EVENT], [Create or enable event rules])
 437 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_ENABLE_ROTATION], [Set a rotation schedule])
 438 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_HELP], [Display help information about a command])
 439 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_LIST], [List tracing sessions, domains, channels, and events])
 440 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_LOAD], [Load tracing session configurations])
 441 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_REGENERATE], [Manage an LTTng tracing session's data regeneration])
 442 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_ROTATE], [Archive a tracing session's current trace chunk])
 443 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_SAVE], [Save tracing session configurations])
 444 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_SET_SESSION], [Set current tracing session])
 445 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_SNAPSHOT], [Snapshot buffers of current tracing session])
 446 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_START], [Start tracing])
 447 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_STATUS], [Get the status of the current tracing session])
 448 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_STOP], [Stop tracing])
 449 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_DISABLE_ROTATION], [Unset a rotation schedule])
 450 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_ENABLE_ROTATION], [Set a rotation schedule])
 451 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_TRACK], [Track specific system resources])
 452 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_UNTRACK], [Untrack specific system resources])
 453 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_VERSION], [Show version information])
 454 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_VIEW], [Start trace viewer])
 455
 456 if test "x$prefix" = "xNONE"; then
 457         prefix=$ac_default_prefix
 458 fi
 459 CONFDIR=`eval echo $sysconfdir`
 460 AC_SUBST(CONFDIR)
 461 AC_DEFINE_UNQUOTED([CONFIG_LTTNG_SYSTEM_CONFIGDIR],"$CONFDIR", [LTTng system configuration directory.])
 462
 463 AX_DEFINE_DIR([CONFIG_LTTNG_SYSTEM_DATADIR], [datadir], [LTTng system data directory.])
 464
 465 # Check libpopt
 466 PKG_CHECK_MODULES([POPT], [popt],
 467   [
 468     dnl PKG_CHECK_MODULES defines POPT_LIBS
 469   ],
 470   [
 471     AC_MSG_WARN([pkg-config was unable to find a valid .pc for libpopt. Set PKG_CONFIG_PATH to specify the pkgconfig configuration file location])
 472     AC_MSG_WARN([Finding libpopt without pkg-config.])
 473     AC_CHECK_LIB([popt],
 474       [poptGetContext],
 475       [POPT_LIBS="-lpopt"],
 476       [
 477         AC_MSG_FAILURE([Cannot find libpopt. Either set PKG_CONFIG_PATH to the configuration file location or use LDFLAGS=-Ldir to specify the library location])
 478       ]
 479     )
 480   ]
 481 )
 482 AC_SUBST(POPT_LIBS)
 483
 484 PKG_CHECK_MODULES([libxml2], [libxml-2.0 >= 2.7.6])
 485
 486 AC_CHECK_FUNC([clock_gettime], [AC_DEFINE_UNQUOTED([LTTNG_HAVE_CLOCK_GETTIME], 1, [Has clock_gettime() support.])])
 487
 488 # URCU library version needed or newer
 489 PKG_CHECK_MODULES([URCU], [liburcu >= 0.9])
 490 PKG_CHECK_MODULES([URCU_BP], [liburcu-bp >= 0.9])
 491 PKG_CHECK_MODULES([URCU_CDS], [liburcu-cds >= 0.9])
 492 AM_CPPFLAGS="$AM_CPPFLAGS $URCU_CFLAGS"
 493
 494 # Check for libkmod, it will be auto-neabled if found but won't fail if it's not,
 495 # it can be explicitly disabled with --without-kmod
 496 AH_TEMPLATE([HAVE_KMOD], [Define if you have kmod support])
 497 AC_ARG_WITH([kmod],
 498   [AS_HELP_STRING([--with-kmod], [build with lkmod support @<:@default=check@:>@])],
 499   [],
 500   [with_kmod=check]
 501 )
 502
 503 AS_IF([test "x$with_kmod" != "xno"],
 504   [
 505     AC_CHECK_LIB([kmod], [kmod_module_probe_insert_module],
 506       [
 507         AC_DEFINE([HAVE_KMOD], [1])
 508         KMOD_LIBS="-lkmod"
 509       ],
 510       [
 511         if test "x$with_kmod" != xcheck; then
 512           AC_MSG_FAILURE([Cannot find libkmod. Use [LDFLAGS]=-Ldir and [CPPFLAGS]=-Idir to specify its location.])
 513         else
 514           with_kmod=no
 515         fi
 516       ]
 517     )
 518   ]
 519 )
 520 AC_SUBST(KMOD_LIBS)
 521
 522 # Check for liblttng-ust-ctl, fail if it's not found,
 523 # it can be explicitly disabled with --without-lttng-ust
 524 AH_TEMPLATE([HAVE_LIBLTTNG_UST_CTL], [Define if you have LTTng-UST control support])
 525 AC_ARG_WITH([lttng-ust],
 526   [AS_HELP_STRING([--without-lttng-ust], [build without LTTng-UST (Userspace Tracing) support])],
 527   [],
 528   [with_lttng_ust=yes]
 529 )
 530
 531 AS_IF([test "x$with_lttng_ust" = "xyes"], [
 532   AC_DEFINE([HAVE_LIBLTTNG_UST_CTL], [1])
 533
 534   # Check for liblttng-ust
 535   PKG_CHECK_MODULES([UST], [lttng-ust >= $major_version.$minor_version])
 536
 537   # Check for liblttng-ust-ctl
 538   PKG_CHECK_MODULES([UST_CTL], [lttng-ust-ctl >= $major_version.$minor_version])
 539
 540   AM_CPPFLAGS="$AM_CPPFLAGS $UST_CFLAGS"
 541 ])
 542
 543 AM_CONDITIONAL([HAVE_LIBLTTNG_UST_CTL], [test "x$with_lttng_ust" = "xyes"])
 544
 545
 546 # Check for fmemopen
 547 AC_CHECK_LIB([c], [fmemopen],
 548 [
 549         AC_DEFINE_UNQUOTED([LTTNG_HAVE_FMEMOPEN], 1, [Has fmemopen support.])
 550 ]
 551 )
 552
 553 # check for libpfm
 554 AC_CHECK_LIB([pfm], [pfm_initialize],
 555              [
 556               have_libpfm=yes
 557               ])
 558 AM_CONDITIONAL([LTTNG_TOOLS_BUILD_WITH_LIBPFM], [test "x$have_libpfm" = "xyes"])
 559
 560 # For Python
 561 # SWIG version needed or newer:
 562 swig_version=2.0.0
 563
 564 AC_ARG_ENABLE([python-bindings],
 565               [AS_HELP_STRING([--enable-python-bindings],
 566                               [compile Python bindings])],
 567               [enable_python_binding=$enableval], [enable_python_binding=no])
 568
 569 AM_CONDITIONAL([PYTHON_BINDING], [test "x$enable_python_binding" = xyes])
 570
 571 if test "x$enable_python_binding" = xyes; then
 572   AX_PKG_SWIG($swig_version, [], [ AC_MSG_ERROR([SWIG $swig_version or newer is needed]) ])
 573   AS_IF([test x$enable_shared = xno], [ AC_MSG_ERROR([Python bindings require shared libraries.]) ])
 574   AM_PATH_PYTHON([3.0])
 575
 576   AC_ARG_VAR([PYTHON_INCLUDE], [Include flags for python, bypassing python-config])
 577   AC_ARG_VAR([PYTHON_CONFIG], [Path to python-config])
 578   AS_IF([test -z "$PYTHON_INCLUDE"], [
 579     AS_IF([test -z "$PYTHON_CONFIG"], [
 580       AC_PATH_PROGS([PYTHON_CONFIG],
 581                     [python$PYTHON_VERSION-config python-config],
 582                     [no],
 583                     [`dirname $PYTHON`])
 584       AS_IF([test "$PYTHON_CONFIG" = no], [AC_MSG_ERROR([cannot find python-config for $PYTHON. Do you have python-dev installed?])])
 585     ])
 586     AC_MSG_CHECKING([python include flags])
 587     PYTHON_INCLUDE=`$PYTHON_CONFIG --includes`
 588     AC_MSG_RESULT([$PYTHON_INCLUDE])
 589   ])
 590
 591 else
 592     AC_MSG_NOTICE([You may configure with --enable-python-bindings ]dnl
 593 [if you want Python bindings.])
 594
 595 fi
 596
 597 # Epoll check. If not present, the build will fallback on poll() API
 598 AX_HAVE_EPOLL(
 599         [AX_CONFIG_FEATURE_ENABLE(epoll)],
 600         [AX_CONFIG_FEATURE_DISABLE(epoll)]
 601 )
 602 AX_CONFIG_FEATURE(
 603         [epoll], [This platform supports epoll(7)],
 604         [HAVE_EPOLL], [This platform supports epoll(7).]
 605 )
 606
 607 AS_IF([test "x$ac_cv_func_dirfd" = "xyes"],
 608         [AX_CONFIG_FEATURE_ENABLE(dirfd)],
 609         [AX_CONFIG_FEATURE_DISABLE(dirfd)]
 610 )
 611 AX_CONFIG_FEATURE(
 612         [dirfd], [Use directory file descriptors],
 613         [HAVE_DIRFD], [This platform supports directory file descriptors.]
 614 )
 615
 616 AM_CONDITIONAL([TEST_JAVA_JUL_AGENT], [test "x$test_java_agent_jul" = "xyes"])
 617 AM_CONDITIONAL([TEST_JAVA_LOG4J_AGENT], [test "x$test_java_agent_log4j" = "xyes"])
 618
 619 if test "x$test_java_agent_jul" = "xyes" || test "x$test_java_agent_log4j" = "xyes"; then
 620         AX_JAVA_OPTIONS
 621         AX_PROG_JAVAC
 622         AX_PROG_JAVA
 623         AX_PROG_JAR
 624
 625         AX_CHECK_CLASSPATH
 626
 627         # Check for Java UST agent common class first
 628         AX_CHECK_CLASS(org.lttng.ust.agent.AbstractLttngAgent)
 629         if test "x$ac_cv_class_org_lttng_ust_agent_AbstractLttngAgent" = "xno"; then
 630                 AC_MSG_ERROR([The UST Java agent common class was not found. Please specify the location of the jar via the Java CLASSPATH e.g: export CLASSPATH="/path/to/lttng-ust-agent-common.jar"])
 631         fi
 632
 633         if test "x$test_java_agent_jul" = "xyes"; then
 634                 # Check for JUL agent class
 635                 AX_CHECK_CLASS(org.lttng.ust.agent.jul.LttngLogHandler)
 636                 if test "x$ac_cv_class_org_lttng_ust_agent_jul_LttngLogHandler" = "xno"; then
 637                         AC_MSG_ERROR([The UST Java agent JUL class was not found. Please specify the location of the jar via the Java CLASSPATH e.g: export CLASSPATH="/path/to/lttng-ust-agent-jul.jar"])
 638                 fi
 639         fi
 640
 641         if test "x$test_java_agent_log4j" = "xyes"; then
 642                 # Check for Log4j agent class
 643                 AX_CHECK_CLASS(org.lttng.ust.agent.log4j.LttngLogAppender)
 644                 if test "x$ac_cv_class_org_lttng_ust_agent_log4j_LttngLogAppender" = "xno"; then
 645                         AC_MSG_ERROR([The UST Java agent Log4j class was not found. Please specify the location of the jar via the Java CLASSPATH e.g: export CLASSPATH="/path/to/lttng-ust-agent-log4j.jar"])
 646                 fi
 647
 648                 # Check for Log4j class
 649                 AX_CHECK_CLASS(org.apache.log4j.Logger)
 650                 if test "x$ac_cv_class_org_apache_log4j_Logger" = "xno"; then
 651                         AC_MSG_ERROR([The Log4j class was not found. Please specify the location of the jar via the Java CLASSPATH e.g: export CLASSPATH="/path/to/log4j.jar"])
 652                 fi
 653         fi
 654 fi
 655
 656 # enable building man pages (user's intention)
 657 AC_ARG_ENABLE(
 658         man-pages,
 659         AS_HELP_STRING(
 660                 [--disable-man-pages],
 661                 [Do not build and install man pages (already built in a distributed tarball)]
 662         ),
 663         [man_pages_opt=$enableval],
 664         [man_pages_opt=yes]
 665 )
 666
 667 # check for asciidoc and xmlto if we enabled building the man pages
 668 have_asciidoc_xmlto=no
 669 warn_prebuilt_man_pages=no
 670
 671 AS_IF([test "x$man_pages_opt" = "xyes"], [
 672         AC_PATH_PROG([ASCIIDOC], [asciidoc], [no])
 673         AC_PATH_PROG([XMLTO], [xmlto], [no])
 674
 675         AS_IF([test "x$ASCIIDOC" = "xno" || test "x$XMLTO" = "xno"], [
 676                 AS_IF([test "x$in_git_repo" = "xyes"], [
 677                         # this is an error because we're in the Git repo, which
 678                         # means the man pages are not already generated for us,
 679                         # thus asciidoc/xmlto are required because we were asked
 680                         # to build the man pages
 681                         AC_MSG_ERROR([
 682 You need asciidoc and xmlto to build the LTTng-tools man pages. Use
 683 --disable-man-pages to disable building the man pages, in which case
 684 they will not be installed.
 685                         ])
 686                 ], [
 687                         # only warn here: since we're in the tarball, the man
 688                         # pages should already be generated at this point, thus
 689                         # asciidoc/xmlto are not strictly required
 690                         warn_prebuilt_man_pages=yes
 691                 ])
 692         ], [
 693                 have_asciidoc_xmlto=yes
 694         ])
 695 ])
 696
 697 # export man page build condition: build the man pages if the user
 698 # asked for it, and if the tools are available
 699 AM_CONDITIONAL([MAN_PAGES_OPT], [test "x$man_pages_opt" != "xno"])
 700 AM_CONDITIONAL([HAVE_ASCIIDOC_XMLTO], [test "x$have_asciidoc_xmlto" = "xyes"])
 701
 702 AC_DEFINE_UNQUOTED([MANPATH], ["`eval eval echo $mandir`"], [Path to man pages.])
 703
 704 # embedded --help message
 705 AC_ARG_ENABLE(
 706         [embedded-help],
 707         AS_HELP_STRING(
 708                 [--enable-embedded-help],
 709                 [Embed the --help messages in the executable files]
 710         ),
 711         [embedded_help=$enableval],
 712         [embedded_help=no]
 713 )
 714 AS_IF([test "x$embedded_help" = "xyes"], [
 715         AS_IF([test "x$man_pages_opt" = "xno"], [
 716                 AC_MSG_ERROR([You need the --enable-man-pages option with the --enable-embedded-help option.])
 717         ])
 718         AC_PATH_PROG([man_prog_path], [man], [no])
 719         AS_IF([test "x$man_prog_path" = "xno"], [
 720                 AC_MSG_ERROR([You need man with the --enable-embedded-help option.])
 721         ])
 722         AC_DEFINE_UNQUOTED([LTTNG_EMBED_HELP], 1, [Embed --help messages.])
 723         AC_SUBST([MANPROG], [$man_prog_path])
 724 ])
 725 AM_CONDITIONAL([EMBED_HELP], [test "x$embedded_help" != "xno"])
 726
 727 # Python agent test
 728 UST_PYTHON_AGENT="lttngust"
 729
 730 AC_ARG_ENABLE(test-python2-agent,
 731         AS_HELP_STRING([--enable-test-python2-agent],
 732                 [enable tests for python2 agent. Python2 interpreter path can be overridden by setting the PYTHON2 environment variable. Default: Autodetect]
 733         ),[:],[test_python2_agent_autodetect=yes]
 734 )
 735
 736 AC_ARG_ENABLE(test-python3-agent,
 737         AS_HELP_STRING([--enable-test-python3-agent],
 738                 [enable tests for python3 agent. Python3 interpreter path can be overridden by setting the PYTHON3 environment variable. Default: Autodetect]
 739         ),[:],[test_python3_agent_autodetect=yes]
 740 )
 741
 742 AC_ARG_ENABLE(test-python-agent-all,
 743         AS_HELP_STRING([--enable-test-python-agent-all],
 744                 [enable test for all python{2/3} agent.]
 745         ),
 746 )
 747
 748 AS_IF([test ! -z "$enable_test_python_agent_all"], [
 749        unset test_python2_agent_autodetect
 750        unset test_python3_agent_autodetect
 751 ])
 752
 753 AS_IF([test "x$enable_test_python_agent_all" = "xyes"], [
 754        enable_test_python2_agent=yes
 755        enable_test_python3_agent=yes
 756 ])
 757
 758 AS_IF([test "x$enable_test_python_agent_all" = "xno"], [
 759        enable_test_python2_agent=no
 760        enable_test_python3_agent=no
 761 ])
 762
 763
 764 AS_IF([test "x$enable_test_python2_agent" = "xyes" -o "x$test_python2_agent_autodetect" = "xyes" ], [
 765         AS_IF([test -z "$PYTHON2"], [
 766                         PYTHON2=python2
 767                 ], [
 768                         AC_MSG_WARN([Using user-defined PYTHON2 ($PYTHON2) for lttng-ust python2 agent check])
 769         ])
 770
 771         AC_PATH_PROG([PYTHON2_BIN],[$PYTHON2])
 772         AS_IF([test -z "$PYTHON2_BIN"], [
 773                 AS_IF([test -z "$test_python2_agent_autodetect"],[
 774                         AC_MSG_ERROR([No python2 interpreter found. PYTHON2 can be set to override default interpreter path])
 775                 ])
 776         ], [
 777                 AC_MSG_CHECKING([for python2 lttng-ust agent])
 778                 AS_IF([$PYTHON2_BIN -c "import $UST_PYTHON_AGENT" 2>/dev/null], [
 779                         PYTHON2_AGENT=$PYTHON2_BIN
 780                         AC_MSG_RESULT([yes])
 781                         RUN_PYTHON_AGENT_TEST=yes
 782                 ], [
 783                         AC_MSG_RESULT([no])
 784                         AS_IF([test -z "$test_python2_agent_autodetect"],[
 785                                 AC_MSG_ERROR([No python2 agent found. The path to the agent can be specified by setting the PYTHONPATH environment variable.])
 786                         ])
 787                 ])
 788
 789         ])
 790
 791 ])
 792
 793 AS_IF([test "x$enable_test_python3_agent" = "xyes" -o "x$test_python3_agent_autodetect" = "xyes" ], [
 794         AS_IF([test -z "$PYTHON3"], [
 795                 PYTHON3=python3
 796         ], [
 797                 AC_MSG_WARN([Using user-defined PYTHON3 ($PYTHON3) for lttng-ust python3 agent check])
 798         ])
 799
 800         AC_PATH_PROG([PYTHON3_BIN],[$PYTHON3])
 801         AS_IF([test -z "$PYTHON3_BIN"], [
 802                 AS_IF([test -z "$test_python3_agent_autodetect"],[
 803                         AC_MSG_ERROR([No python3 interpreter found. PYTHON3 can be set to override default interpreter path])
 804                 ])
 805         ], [
 806                 AC_MSG_CHECKING([for python3 lttng-ust agent])
 807                 AS_IF([$PYTHON3_BIN -c "import $UST_PYTHON_AGENT" 2>/dev/null], [
 808                         PYTHON3_AGENT=$PYTHON3_BIN
 809                         AC_MSG_RESULT([yes])
 810                         RUN_PYTHON_AGENT_TEST=yes
 811                 ], [
 812                         AC_MSG_RESULT([no])
 813                         AS_IF([test -z "$test_python3_agent_autodetect"],[
 814                                 AC_MSG_ERROR([No python3 agent found. The path to the agent can be specified by setting the PYTHONPATH environment variable.])
 815                         ])
 816                 ])
 817
 818         ])
 819 ])
 820 AC_SUBST([RUN_PYTHON_AGENT_TEST])
 821 AC_SUBST([PYTHON2_AGENT])
 822 AC_SUBST([PYTHON3_AGENT])
 823
 824 AC_ARG_ENABLE([test-sdt-uprobe],
 825   [AS_HELP_STRING([--enable-test-sdt-uprobe], [enable the LTTng UST SDT uprobe tests [default=autodetect]])],
 826   [test_sdt_uprobe="$enableval"],
 827   [test_sdt_uprobe=autodetect]
 828 )
 829
 830 AS_IF([test "$test_sdt_uprobe" != "no"], [
 831   LTTNG_CHECK_SDT_WORKS
 832   AC_PATH_PROG([DTRACE], [dtrace])
 833 ])
 834
 835 AS_IF([test "$test_sdt_uprobe" = "yes"], [
 836   AS_IF([test "$lttng_cv_sdt_works" = "no"], [
 837     AC_MSG_ERROR([Cannot find 'sys/sdt.h'.])
 838   ])
 839   AS_IF([test "x$DTRACE" = "x"], [
 840     AC_MSG_ERROR([Cannot find SystemTap dtrace. You can set the DTRACE variable to override automatic detection.])
 841   ])
 842 ])
 843
 844 AS_IF([test "$test_sdt_uprobe" = "autodetect"], [
 845   AS_IF([test "$lttng_cv_sdt_works" = "yes"], [
 846     AS_IF([test "x$DTRACE" != "x"], [
 847       test_sdt_uprobe=yes
 848     ])
 849   ])
 850 ])
 851
 852 AM_CONDITIONAL([TEST_SDT_UPROBE], [test "$test_sdt_uprobe" = "yes"])
 853
 854 # Arguments for binaries build exclusion
 855 AC_ARG_ENABLE([bin-lttng], AS_HELP_STRING([--disable-bin-lttng],[Disable the build of lttng binaries]))
 856 AC_ARG_ENABLE([bin-lttng-consumerd], AS_HELP_STRING([--disable-bin-lttng-consumerd],
 857               [Disable the build of lttng-consumerd binaries]))
 858 AC_ARG_ENABLE([bin-lttng-crash], AS_HELP_STRING([--disable-bin-lttng-crash],[Disable the build of lttng-crash binaries]))
 859 AC_ARG_ENABLE([bin-lttng-relayd], AS_HELP_STRING([--disable-bin-lttng-relayd],
 860               [Disable the build of lttng-relayd binaries]))
 861 AC_ARG_ENABLE([bin-lttng-sessiond], AS_HELP_STRING([--disable-bin-lttng-sessiond],
 862               [Disable the build of lttng-sessiond binaries]))
 863 AC_ARG_ENABLE([extras], AS_HELP_STRING([--disable-extras],
 864               [Disable the build of the extra components]))
 865
 866
 867 # Always build libconfig since it a dependency of libcommon
 868 build_lib_config=yes
 869
 870 build_lib_compat=no
 871 build_lib_consumer=no
 872 build_lib_hashtable=no
 873 build_lib_health=no
 874 build_lib_index=no
 875 build_lib_kernel_consumer=no
 876 build_lib_kernel_ctl=no
 877 build_lib_lttng_ctl=no
 878 build_lib_relayd=no
 879 build_lib_fd_tracker=no
 880 build_lib_sessiond_comm=no
 881 build_lib_testpoint=no
 882 build_lib_ust_consumer=no
 883
 884 # There is an overlap for enabled dependencies, but this makes everything
 885 # simpler. libcommon and libconfig are always compiled so they are not repeated
 886 # here.
 887
 888 # Enable binary dependencies.
 889 AS_IF([test x$enable_bin_lttng != xno],
 890       [
 891        build_lib_lttng_ctl=yes
 892       ]
 893 )
 894
 895 AS_IF([test x$enable_bin_lttng_consumerd != xno],
 896       [
 897        build_lib_consumer=yes
 898        build_lib_sessiond_comm=yes
 899        build_lib_index=yes
 900        build_lib_health=yes
 901        build_lib_testpoint=yes
 902       ]
 903 )
 904
 905 AS_IF([test x$enable_bin_lttng_crash != xno],
 906       # Do nothing since libconfig and libcommon are built by default.
 907       []
 908 )
 909
 910 AS_IF([test x$enable_bin_lttng_relayd != xno],
 911       [
 912        build_lib_lttng_ctl=yes
 913        build_lib_sessiond_comm=yes
 914        build_lib_hashtable=yes
 915        build_lib_compat=yes
 916        build_lib_index=yes
 917        build_lib_health=yes
 918        build_lib_testpoint=yes
 919        build_lib_fd_tracker=yes
 920       ]
 921 )
 922 AS_IF([test x$enable_bin_lttng_sessiond != xno],
 923       [
 924        build_lib_lttng_ctl=yes
 925        build_lib_sessiond_comm=yes
 926        build_lib_kernel_ctl=yes
 927        build_lib_hashtable=yes
 928        build_lib_compat=yes
 929        build_lib_relayd=yes
 930        build_lib_testpoint=yes
 931        build_lib_health=yes
 932       ]
 933 )
 934
 935 # Libraries dependencies enabling
 936 AS_IF([test x$build_lib_lttng_ctl = xyes],
 937       [
 938        build_lib_sessiond_comm=yes
 939        build_lib_hashtable=yes
 940       ]
 941 )
 942
 943 AS_IF([test x$build_lib_consumer = xyes],
 944       [
 945        build_lib_sessiond_comm=yes
 946        build_lib_kernel_consumer=yes
 947        build_lib_hashtable=yes
 948        build_lib_compat=yes
 949        build_lib_relayd=yes
 950        AS_IF([test "x$with_lttng_ust" = "xyes"], [build_lib_ust_consumer=yes])
 951       ]
 952 )
 953
 954 AS_IF([test x$build_lib_kernel_consumer = xyes],
 955       [
 956        build_lib_kernel_ctl=yes
 957        build_lib_relayd=yes
 958       ]
 959 )
 960
 961 AS_IF([test x$build_lib_relayd = xyes],
 962       [
 963        build_lib_sessiond_comm=yes
 964       ]
 965 )
 966
 967 # Find arch type
 968 AS_CASE([$host_cpu],
 969         [k1om], [ARCHTYPE="x86"],
 970         [i386], [ARCHTYPE="x86"],
 971         [i486], [ARCHTYPE="x86"],
 972         [i586], [ARCHTYPE="x86"],
 973         [i686], [ARCHTYPE="x86"],
 974         [amd64], [ARCHTYPE="x86"],
 975         [x86_64], [ARCHTYPE="x86"],
 976         [powerpc], [ARCHTYPE="ppc"],
 977         [ppc64], [ARCHTYPE="ppc"],
 978         [powerpc64], [ARCHTYPE="ppc"],
 979         [powerpc64le], [ARCHTYPE="ppc"],
 980         [ppc], [ARCHTYPE="ppc"],
 981         [s390], [ARCHTYPE="s390"],
 982         [s390x], [ARCHTYPE="s390"],
 983         [sparc], [ARCHTYPE="sparc64"],
 984         [sparc64], [ARCHTYPE="sparc64"],
 985         [alpha*], [ARCHTYPE="alpha"],
 986         [ia64], [ARCHTYPE="ia64"],
 987         [arm*], [ARCHTYPE="arm"],
 988         [aarch64*], [ARCHTYPE="aarch64"],
 989         [mips*], [ARCHTYPE="mips"],
 990         [nios2*], [ARCHTYPE="nios2"],
 991         [tile*], [ARCHTYPE="tile"],
 992         [hppa*], [ARCHTYPE="hppa"],
 993         [m68k], [ARCHTYPE="m68k"],
 994         [riscv*], [ARCHTYPE="riscv"],
 995         [ARCHTYPE="unknown"]
 996 )
 997
 998 AC_SUBST(ARCHTYPE)
 999
1000 AS_CASE([$host_os],
1001         [linux*], [OSTYPE="linux"],
1002         [freebsd*], [OSTYPE="freebsd"],
1003         [solaris*], [OSTYPE="solaris"],
1004         [cygwin*], [OSTYPE="cygwin"],
1005         [mingw*], [OSTYPE="mingw"],
1006         [OSTYPE="unknown"]
1007 )
1008 AC_SUBST(OSTYPE)
1009 AM_CONDITIONAL([IS_LINUX], [test $OSTYPE = "linux"])
1010
1011
1012
1013 # Userspace callstack capture is only supported by the Linux kernel on x86.
1014 AH_TEMPLATE([HAVE_MODULES_USERSPACE_CALLSTACK_CONTEXT], [Define if you have LTTng-modules userspace callstack tracing support])
1015 AS_IF([test "x$ARCHTYPE" = "xx86" && test "x$OSTYPE" = "xlinux"],[
1016         have_modules_userspace_callstack_context=yes
1017         AC_DEFINE([HAVE_MODULES_USERSPACE_CALLSTACK_CONTEXT], [1])
1018 ])
1019 AM_CONDITIONAL([HAVE_MODULES_USERSPACE_CALLSTACK_CONTEXT], [test x$have_modules_userspace_callstack_context = xyes])
1020
1021 # Export binaries build conditions.
1022 AM_CONDITIONAL([BUILD_BIN_LTTNG], [test x$enable_bin_lttng != xno])
1023 AM_CONDITIONAL([BUILD_BIN_LTTNG_CONSUMERD], [test x$enable_bin_lttng_consumerd != xno])
1024 AM_CONDITIONAL([BUILD_BIN_LTTNG_CRASH], [test x$enable_bin_lttng_crash != xno])
1025 AM_CONDITIONAL([BUILD_BIN_LTTNG_RELAYD], [test x$enable_bin_lttng_relayd != xno])
1026 AM_CONDITIONAL([BUILD_BIN_LTTNG_SESSIOND], [test x$enable_bin_lttng_sessiond != xno])
1027
1028 # Export the tests and extras build conditions.
1029 AS_IF([\
1030 test "x$enable_bin_lttng" != "xno" && \
1031 test "x$enable_bin_lttng_consumerd" != "xno" && \
1032 test "x$enable_bin_lttng_crash" != "xno" && \
1033 test "x$enable_bin_lttng_relayd" != "xno" && \
1034 test "x$enable_bin_lttng_sessiond" != "xno"],
1035 [build_tests=yes],
1036 [build_tests=no]
1037 )
1038
1039 AM_CONDITIONAL([BUILD_TESTS], [test x$build_tests = xyes])
1040 AM_CONDITIONAL([BUILD_EXTRAS], [test x$enable_extras != xno])
1041
1042 # Export libraries build conditions.
1043 AM_CONDITIONAL([BUILD_LIB_COMPAT], [test x$build_lib_compat = xyes])
1044 AM_CONDITIONAL([BUILD_LIB_CONFIG], [test x$build_lib_config = xyes])
1045 AM_CONDITIONAL([BUILD_LIB_CONSUMER], [test x$build_lib_consumer = xyes])
1046 AM_CONDITIONAL([BUILD_LIB_HASHTABLE], [test x$build_lib_hashtable = xyes])
1047 AM_CONDITIONAL([BUILD_LIB_HEALTH], [test x$build_lib_health = xyes])
1048 AM_CONDITIONAL([BUILD_LIB_INDEX], [test x$build_lib_index = xyes])
1049 AM_CONDITIONAL([BUILD_LIB_KERNEL_CONSUMER], [test x$build_lib_kernel_consumer = xyes])
1050 AM_CONDITIONAL([BUILD_LIB_KERNEL_CTL], [test x$build_lib_kernel_ctl = xyes])
1051 AM_CONDITIONAL([BUILD_LIB_LTTNG_CTL], [test x$build_lib_lttng_ctl = xyes])
1052 AM_CONDITIONAL([BUILD_LIB_RELAYD], [test x$build_lib_relayd = xyes])
1053 AM_CONDITIONAL([BUILD_LIB_FD_TRACKER], [test x$build_lib_fd_tracker = xyes])
1054 AM_CONDITIONAL([BUILD_LIB_SESSIOND_COMM], [test x$build_lib_sessiond_comm = xyes])
1055 AM_CONDITIONAL([BUILD_LIB_TESTPOINT], [test x$build_lib_testpoint = xyes])
1056 AM_CONDITIONAL([BUILD_LIB_UST_CONSUMER], [test x$build_lib_ust_consumer = xyes])
1057
1058 AM_CFLAGS="${WARN_CFLAGS} -fno-strict-aliasing $PTHREAD_CFLAGS"
1059 AC_SUBST(AM_CFLAGS)
1060
1061 # This is set even though it is empty, so Makefiles can do "AM_LDFLAGS += ...".
1062 AM_LDFLAGS=""
1063 AC_SUBST(AM_LDFLAGS)
1064
1065 # The order in which the include folders are searched is important.
1066 # The top_builddir should always be searched first in the event that a build
1067 # time generated file is included. An example of this is the "version.i" file.
1068 # In a scenario where lttng-tools is built from a distribution tarball and in a
1069 # out-of-tree manner, the generated "version.i" has priority on the one from
1070 # the source (distribution tarball) and must be found first.
1071 AM_CPPFLAGS="-I\$(top_builddir)/include -I\$(top_srcdir)/include -I\$(top_builddir)/src -I\$(top_srcdir)/src -include config.h $AM_CPPFLAGS"
1072 AC_SUBST(AM_CPPFLAGS)
1073
1074 lttngincludedir="${includedir}/lttng"
1075 AC_SUBST(lttngincludedir)
1076
1077 lttngactionincludedir="${includedir}/lttng/action"
1078 AC_SUBST(lttngactionincludedir)
1079
1080 lttngconditionincludedir="${includedir}/lttng/condition"
1081 AC_SUBST(lttngconditionincludedir)
1082
1083 lttngnotificationincludedir="${includedir}/lttng/notification"
1084 AC_SUBST(lttngnotificationincludedir)
1085
1086 lttngtriggerincludedir="${includedir}/lttng/trigger"
1087 AC_SUBST(lttngtriggerincludedir)
1088
1089 lttngeventruleincludedir="${includedir}/lttng/event-rule"
1090 AC_SUBST(lttngeventruleincludedir)
1091
1092 lttnglibexecdir="${libdir}/lttng/libexec"
1093 AC_SUBST(lttnglibexecdir)
1094
1095 AC_CONFIG_FILES([
1096         Makefile
1097         doc/Makefile
1098         doc/man/Makefile
1099         doc/man/asciidoc-attrs.conf
1100         include/Makefile
1101         extras/Makefile
1102         extras/bindings/Makefile
1103         extras/bindings/swig/Makefile
1104         extras/bindings/swig/python/Makefile
1105         extras/core-handler/Makefile
1106         src/Makefile
1107         src/common/Makefile
1108         src/common/argpar/Makefile
1109         src/common/bytecode/Makefile
1110         src/common/kernel-ctl/Makefile
1111         src/common/kernel-consumer/Makefile
1112         src/common/consumer/Makefile
1113         src/common/ust-consumer/Makefile
1114         src/common/hashtable/Makefile
1115         src/common/sessiond-comm/Makefile
1116         src/common/compat/Makefile
1117         src/common/relayd/Makefile
1118         src/common/testpoint/Makefile
1119         src/common/index/Makefile
1120         src/common/health/Makefile
1121         src/common/config/Makefile
1122         src/common/string-utils/Makefile
1123         src/common/fd-tracker/Makefile
1124         src/common/filter/Makefile
1125         src/lib/Makefile
1126         src/lib/lttng-ctl/Makefile
1127         src/lib/lttng-ctl/lttng-ctl.pc
1128         src/bin/Makefile
1129         src/bin/lttng-consumerd/Makefile
1130         src/bin/lttng-sessiond/Makefile
1131         src/bin/lttng-relayd/Makefile
1132         src/bin/lttng/Makefile
1133         src/bin/lttng-crash/Makefile
1134         src/vendor/Makefile
1135         src/vendor/msgpack/Makefile
1136         tests/Makefile
1137         tests/destructive/Makefile
1138         tests/regression/Makefile
1139         tests/regression/kernel/Makefile
1140         tests/regression/tools/Makefile
1141         tests/regression/tools/streaming/Makefile
1142         tests/regression/tools/filtering/Makefile
1143         tests/regression/tools/health/Makefile
1144         tests/regression/tools/tracefile-limits/Makefile
1145         tests/regression/tools/snapshots/Makefile
1146         tests/regression/tools/live/Makefile
1147         tests/regression/tools/exclusion/Makefile
1148         tests/regression/tools/save-load/Makefile
1149         tests/regression/tools/save-load/configuration/Makefile
1150         tests/regression/tools/mi/Makefile
1151         tests/regression/tools/wildcard/Makefile
1152         tests/regression/tools/crash/Makefile
1153         tests/regression/tools/regen-metadata/Makefile
1154         tests/regression/tools/regen-statedump/Makefile
1155         tests/regression/tools/notification/Makefile
1156         tests/regression/tools/rotation/Makefile
1157         tests/regression/tools/base-path/Makefile
1158         tests/regression/tools/metadata/Makefile
1159         tests/regression/tools/tracker/Makefile
1160         tests/regression/tools/working-directory/Makefile
1161         tests/regression/tools/relayd-grouping/Makefile
1162         tests/regression/tools/clear/Makefile
1163         tests/regression/tools/trigger/Makefile
1164         tests/regression/tools/trigger/start-stop/Makefile
1165         tests/regression/tools/trigger/utils/Makefile
1166         tests/regression/ust/Makefile
1167         tests/regression/ust/nprocesses/Makefile
1168         tests/regression/ust/high-throughput/Makefile
1169         tests/regression/ust/low-throughput/Makefile
1170         tests/regression/ust/before-after/Makefile
1171         tests/regression/ust/buffers-pid/Makefile
1172         tests/regression/ust/periodical-metadata-flush/Makefile
1173         tests/regression/ust/multi-session/Makefile
1174         tests/regression/ust/multi-lib/Makefile
1175         tests/regression/ust/overlap/Makefile
1176         tests/regression/ust/overlap/demo/Makefile
1177         tests/regression/ust/linking/Makefile
1178         tests/regression/ust/daemon/Makefile
1179         tests/regression/ust/exit-fast/Makefile
1180         tests/regression/ust/fork/Makefile
1181         tests/regression/ust/libc-wrapper/Makefile
1182         tests/regression/ust/baddr-statedump/Makefile
1183         tests/regression/ust/ust-dl/Makefile
1184         tests/regression/ust/java-jul/Makefile
1185         tests/regression/ust/java-log4j/Makefile
1186         tests/regression/ust/python-logging/Makefile
1187         tests/regression/ust/getcpu-override/Makefile
1188         tests/regression/ust/clock-override/Makefile
1189         tests/regression/ust/type-declarations/Makefile
1190         tests/regression/ust/rotation-destroy-flush/Makefile
1191         tests/regression/ust/blocking/Makefile
1192         tests/regression/ust/namespaces/Makefile
1193         tests/stress/Makefile
1194         tests/unit/Makefile
1195         tests/unit/ini_config/Makefile
1196         tests/perf/Makefile
1197         tests/utils/Makefile
1198         tests/utils/tap/Makefile
1199         tests/utils/testapp/Makefile
1200         tests/utils/testapp/gen-ns-events/Makefile
1201         tests/utils/testapp/gen-kernel-test-events/Makefile
1202         tests/utils/testapp/gen-ust-events/Makefile
1203         tests/utils/testapp/gen-ust-events-ns/Makefile
1204         tests/utils/testapp/gen-syscall-events-callstack/Makefile
1205         tests/utils/testapp/gen-ust-nevents/Makefile
1206         tests/utils/testapp/gen-ust-nevents-str/Makefile
1207         tests/utils/testapp/gen-syscall-events/Makefile
1208         tests/utils/testapp/gen-ust-tracef/Makefile
1209         tests/utils/testapp/userspace-probe-elf-binary/Makefile
1210         tests/utils/testapp/userspace-probe-elf-cxx-binary/Makefile
1211         tests/utils/testapp/userspace-probe-sdt-binary/Makefile
1212 ])
1213
1214 # Inject variable into python test script.
1215 AC_CONFIG_FILES([tests/regression/ust/python-logging/test_python_logging],[chmod +x tests/regression/ust/python-logging/test_python_logging])
1216 # Inject LTTNG_TOOLS_BUILD_WITH_LIBPFM variable in test script.
1217 AC_CONFIG_FILES([tests/perf/test_perf_raw],[chmod +x tests/perf/test_perf_raw])
1218 AC_CONFIG_FILES([tests/regression/ust/ust-dl/test_ust-dl],[chmod +x tests/regression/ust/ust-dl/test_ust-dl])
1219
1220 AC_OUTPUT
1221
1222 #
1223 # Mini-report on what will be built.
1224 #
1225
1226 PPRINT_INIT
1227 PPRINT_SET_INDENT(1)
1228 PPRINT_SET_TS(38)
1229
1230 AS_ECHO
1231 AS_ECHO("${PPRINT_COLOR_BLDBLU}LTTng-tools $PACKAGE_VERSION \"$version_name\"$PPRINT_COLOR_RST")
1232 AS_ECHO
1233
1234 AS_IF([test -n "$report_fold"], [
1235         AS_ECHO("`AS_ECHO("$version_description") | $report_fold -s`")
1236 ], [
1237         AS_ECHO("$version_description")
1238 ])
1239
1240 AS_ECHO
1241 PPRINT_SUBTITLE([Features])
1242
1243 # Target architecture we're building for.
1244 target_arch=$host_cpu
1245 [
1246 for f in $CFLAGS; do
1247         if test $f = "-m32"; then
1248                         target_arch="32-bit"
1249         elif test $f = "-m64"; then
1250                         target_arch="64-bit"
1251         fi
1252 done
1253 ]
1254 PPRINT_PROP_STRING([Target architecture], $target_arch)
1255
1256 # kmod enabled/disabled
1257 test "x$with_kmod" != "xno" && value=1 || value=0
1258 PPRINT_PROP_BOOL([libkmod support], $value)
1259
1260 # LTTng-UST enabled/disabled
1261 test "x$with_lttng_ust" = "xyes" && value=1 || value=0
1262 PPRINT_PROP_BOOL([LTTng-UST support], $value)
1263
1264 AS_ECHO
1265 PPRINT_SUBTITLE([Binaries])
1266
1267 # List binaries to be built
1268 test x$enable_bin_lttng != xno && value=1 || value=0
1269 PPRINT_PROP_BOOL([lttng], $value)
1270
1271 test x$enable_bin_lttng_consumerd != xno && value=1 || value=0
1272 PPRINT_PROP_BOOL([lttng-consumerd], $value)
1273
1274 test x$enable_bin_lttng_crash != xno && value=1 || value=0
1275 PPRINT_PROP_BOOL([lttng-crash], $value)
1276
1277 test x$enable_bin_lttng_relayd != xno && value=1 || value=0
1278 PPRINT_PROP_BOOL([lttng-relayd], $value)
1279
1280 test x$enable_bin_lttng_sessiond != xno && value=1 || value=0
1281 PPRINT_PROP_BOOL([lttng-sessiond], $value)
1282
1283 # Extras
1284 test x$enable_extras != xno && value=1 || value=0
1285 AS_ECHO
1286 PPRINT_SET_INDENT(0)
1287 PPRINT_PROP_BOOL([Extras], $value, $PPRINT_COLOR_SUBTITLE)
1288 PPRINT_SET_INDENT(1)
1289
1290 AS_ECHO
1291 PPRINT_SUBTITLE([Tests])
1292
1293 # Print clear message that tests won't be built
1294 AS_IF([test "x$build_tests" = "xno"],[
1295         PPRINT_WARN([Tests won't be built since some binaries were disabled])
1296 ])
1297
1298 # LTTng UST Java agent JUL tests enabled/disabled
1299 test "x$test_java_agent_jul" = "xyes" && value=1 || value=0
1300 PPRINT_PROP_BOOL([LTTng-UST Java agent JUL tests], $value)
1301
1302 # LTTng UST Java agent Log4j tests enabled/disabled
1303 test "x$test_java_agent_log4j" = "xyes" && value=1 || value=0
1304 PPRINT_PROP_BOOL([LTTng-UST Java agent Log4j tests], $value)
1305
1306 test ! -z "$PYTHON2_AGENT" && value=1 || value=0
1307 PPRINT_PROP_BOOL([LTTng-UST Python2 agent tests], $value)
1308
1309 test ! -z "$PYTHON3_AGENT" && value=1 || value=0
1310 PPRINT_PROP_BOOL([LTTng-UST Python3 agent tests], $value)
1311
1312 # LTTng UST Java agent Log4j tests enabled/disabled
1313 test "x$test_sdt_uprobe" = "xyes" && value=1 || value=0
1314 PPRINT_PROP_BOOL([LTTng-UST SDT uprobe tests], $value)
1315
1316 #Python binding enabled/disabled
1317 test "x$enable_python_binding" = xyes && value=1 || value=0
1318 AS_ECHO
1319 PPRINT_SET_INDENT(0)
1320 PPRINT_PROP_BOOL([Python binding], $value, $PPRINT_COLOR_SUBTITLE)
1321
1322 # man pages build enabled/disabled
1323 m4_pushdef([build_man_pages_msg], [Build and install man pages])
1324
1325 AS_IF([test "x$man_pages_opt" != "xno"], [
1326         AS_IF([test "x$in_git_repo" = "xyes"], [
1327                 PPRINT_PROP_BOOL([build_man_pages_msg], 1, $PPRINT_COLOR_SUBTITLE)
1328         ], [
1329                 AS_IF([test "x$have_asciidoc_xmlto" = "xyes"], [
1330                         PPRINT_PROP_BOOL([build_man_pages_msg], 1, $PPRINT_COLOR_SUBTITLE)
1331                 ], [
1332                         PPRINT_PROP_STRING([build_man_pages_msg],
1333                                 [${PPRINT_COLOR_BLDGRN}yes (already built)],
1334                                 $PPRINT_COLOR_SUBTITLE)
1335                 ])
1336         ])
1337 ], [
1338         PPRINT_PROP_BOOL([build_man_pages_msg], 0, $PPRINT_COLOR_SUBTITLE)
1339 ])
1340
1341 m4_popdef([build_man_pages_msg])
1342
1343 test "x$embedded_help" = xyes && value=1 || value=0
1344 PPRINT_PROP_BOOL([Embed --help messages], $value, $PPRINT_COLOR_SUBTITLE)
1345
1346 PPRINT_SET_INDENT(1)
1347
1348 report_bindir="`eval eval echo $bindir`"
1349 report_libdir="`eval eval echo $libdir`"
1350
1351 # Print the bindir and libdir this `make install' will install into.
1352 AS_ECHO
1353 PPRINT_SUBTITLE([Install directories])
1354 PPRINT_PROP_STRING([Binaries], [$report_bindir])
1355 PPRINT_PROP_STRING([Libraries], [$report_libdir])
1356
1357 AS_ECHO
1358 PPRINT_SUBTITLE([Search directories])
1359
1360 # If we build the sessiond, print the paths it will use
1361 AS_IF([test "$SESSIOND_BIN" = ""],[
1362         path="$report_bindir/lttng-sessiond"
1363 ],[
1364         path="$SESSIOND_BIN"
1365 ])
1366 PPRINT_PROP_STRING([lttng-sessiond executable], [$path])
1367
1368 AS_IF([test "$CONSUMERD32_BIN" = ""],[
1369         path="`eval eval echo $lttnglibexecdir`/lttng-consumerd"
1370 ],[
1371         path="$CONSUMERD32_BIN"
1372 ])
1373 PPRINT_PROP_STRING([32-bit lttng-consumerd executable], [$path])
1374
1375 AS_IF([test "$CONSUMERD32_LIBDIR" = ""],[
1376         path="`eval eval echo $libdir`"
1377 ],[
1378         path="$CONSUMERD32_LIBDIR"
1379 ])
1380 PPRINT_PROP_STRING([32-bit consumer libraries], [$path])
1381
1382 AS_IF([test "$CONSUMERD64_BIN" = ""],[
1383         path="`eval eval echo $lttnglibexecdir`/lttng-consumerd"
1384 ],[
1385         path="$CONSUMERD64_BIN"
1386 ])
1387 PPRINT_PROP_STRING([64-bit lttng-consumerd executable], [$path])
1388
1389 AS_IF([test "$CONSUMERD64_LIBDIR" = ""],[
1390         path="`eval eval echo $libdir`"
1391 ],[
1392         path="$CONSUMERD64_LIBDIR"
1393 ])
1394 PPRINT_PROP_STRING([64-bit consumer libraries], [$path])
1395 PPRINT_SET_INDENT(0)
1396
1397 AS_IF([test "x$warn_prebuilt_man_pages" = "xyes" ], [
1398         AS_ECHO
1399         PPRINT_WARN([You need asciidoc and xmlto to build the LTTng-tools man pages.
1400
1401 Note that the man pages are already built in this distribution tarball,
1402 therefore asciidoc and xmlto are only needed if you intend to modify
1403 their sources.
1404
1405 Also note that the installed man pages will contain the project's
1406 default command-line option and environment variable values.
1407
1408 Use --disable-man-pages to completely disable building and installing
1409 the man pages.])
1410 ])