configure.ac

   1 dnl SPDX-License-Identifier: LGPL-2.1-only
   2 dnl
   3 dnl Copyright (C) 2021 EfficiOS, Inc.
   4 dnl
   5 dnl Process this file with autoconf to produce a configure script.
   6
   7 # Project version information
   8 m4_define([urcu_version_major], [0])
   9 m4_define([urcu_version_minor], [13])
  10 m4_define([urcu_version_patch], [0])
  11 m4_define([urcu_version_dev_stage], [])
  12 m4_define([urcu_version], urcu_version_major[.]urcu_version_minor[.]urcu_version_patch[]urcu_version_dev_stage)
  13
  14 # Library version information of "liburcu"
  15 # Following the numbering scheme proposed by libtool for the library version
  16 # http://www.gnu.org/software/libtool/manual/html_node/Updating-version-info.html
  17 m4_define([urcu_lib_version_current], [8])
  18 m4_define([urcu_lib_version_revision], [0])
  19 m4_define([urcu_lib_version_age], [0])
  20 m4_define([urcu_lib_version], urcu_lib_version_current[:]urcu_lib_version_revision[:]urcu_lib_version_age)
  21
  22
  23 ##                     ##
  24 ## Autoconf base setup ##
  25 ##                     ##
  26
  27 AC_PREREQ([2.69])
  28 AC_INIT([userspace-rcu],[urcu_version],[mathieu dot desnoyers at efficios dot com],[],[http://liburcu.org/])
  29
  30 AC_CONFIG_HEADERS([include/config.h include/urcu/config.h])
  31 AC_CONFIG_AUX_DIR([config])
  32 AC_CONFIG_MACRO_DIR([m4])
  33
  34 AC_CANONICAL_TARGET
  35 AC_CANONICAL_HOST
  36
  37
  38 ##                     ##
  39 ## Automake base setup ##
  40 ##                     ##
  41
  42 AM_INIT_AUTOMAKE([1.12 foreign dist-bzip2 no-dist-gzip nostdinc -Wall -Wno-portability -Werror])
  43 AM_MAINTAINER_MODE([enable])
  44
  45 # Enable silent rules by default
  46 AM_SILENT_RULES([yes])
  47
  48
  49 ##                               ##
  50 ## OS and Arch specific defaults ##
  51 ##                               ##
  52
  53 AS_CASE([$host],
  54   [*-cygwin*], [LT_NO_UNDEFINED="-no-undefined"]
  55 )
  56
  57
  58 ##                   ##
  59 ## C compiler checks ##
  60 ##                   ##
  61
  62 # Choose the C compiler
  63 AC_PROG_CC
  64 # AC_PROG_CC_STDC was merged in AC_PROG_CC in autoconf 2.70
  65 m4_version_prereq([2.70], [], [AC_PROG_CC_STDC])
  66
  67 # Make sure the C compiler supports C99
  68 AS_IF([test "$ac_cv_prog_cc_c99" = "no"], [AC_MSG_ERROR([The compiler does not support C99])])
  69
  70 # Enable available system extensions and LFS support
  71 AC_USE_SYSTEM_EXTENSIONS
  72 AC_SYS_LARGEFILE
  73
  74 # Make sure the C compiler supports __attribute__
  75 AX_C___ATTRIBUTE__
  76 AS_IF([test "x$ax_cv___attribute__" != "xyes"],
  77   [AC_MSG_ERROR([The compiler does not support __attribute__ extensions])])
  78
  79 # Make sure we have pthread support
  80 AX_PTHREAD([], [AC_MSG_ERROR([Could not configure pthread support])])
  81
  82 # Checks for typedefs, structures, and compiler characteristics.
  83 AC_C_INLINE
  84 AC_C_TYPEOF
  85 AC_TYPE_INT32_T
  86 AC_TYPE_PID_T
  87 AC_TYPE_SIZE_T
  88 AC_TYPE_SSIZE_T
  89 AC_TYPE_UINT16_T
  90 AC_TYPE_UINT32_T
  91 AC_TYPE_UINT64_T
  92 AC_TYPE_UINT8_T
  93
  94 # Detect warning flags supported by the C compiler and append them to
  95 # WARN_CFLAGS.
  96 m4_define([WARN_FLAGS_LIST], [ dnl
  97   -Wall dnl
  98   -Wextra dnl
  99   -Wmissing-prototypes dnl
 100   -Wmissing-declarations dnl
 101   -Wnull-dereference dnl
 102   -Wundef dnl
 103   -Wshadow dnl
 104   -Wjump-misses-init dnl
 105   -Wsuggest-attribute=format dnl
 106   -Wtautological-constant-out-of-range-compare dnl
 107   -Wnested-externs dnl
 108   -Wwrite-strings dnl
 109   -Wformat=2 dnl
 110   -Wstrict-aliasing dnl
 111   -Wmissing-noreturn dnl
 112   -Winit-self dnl
 113   -Wduplicated-cond dnl
 114   -Wduplicated-branches dnl
 115   -Wlogical-op dnl
 116   dnl
 117   dnl-Wredundant-decls dnl
 118   -Wno-null-dereference dnl
 119 ])
 120
 121 # Pass -Werror as an extra flag during the test: this is needed to make the
 122 # -Wunknown-warning-option diagnostic fatal with clang.
 123 AC_LANG_PUSH([C])
 124 AX_APPEND_COMPILE_FLAGS([WARN_FLAGS_LIST], [WARN_CFLAGS], [-Werror])
 125 AC_LANG_POP([C])
 126
 127
 128 ##               ##
 129 ## Header checks ##
 130 ##               ##
 131
 132 AC_HEADER_STDBOOL
 133 AC_CHECK_HEADERS([ \
 134         limits.h \
 135         stddef.h \
 136         sys/param.h \
 137         sys/time.h \
 138 ])
 139
 140
 141 ##                 ##
 142 ## Programs checks ##
 143 ##                 ##
 144
 145 AC_PROG_AWK
 146 AC_PROG_GREP
 147 AC_PROG_MAKE_SET
 148 AC_CHECK_PROGS(NPROC, [nproc gnproc])
 149 AC_CHECK_PROGS(GETCONF, [getconf])
 150 AS_IF([test "x$NPROC" != "x"],
 151         [NPROC_CMD=$NPROC],
 152         [AS_IF([test "x$GETCONF" != "x"],
 153                 [NPROC_CMD="$GETCONF _NPROCESSORS_ONLN"],
 154                 [NPROC_CMD="echo 1"]
 155         )]
 156 )
 157 AC_SUBST([NPROC_CMD], [$NPROC_CMD])
 158
 159 # Initialize and configure libtool
 160 LT_INIT
 161
 162
 163 ##                ##
 164 ## Library checks ##
 165 ##                ##
 166
 167 # Checks for library functions.
 168 AC_FUNC_MMAP
 169 AC_FUNC_FORK
 170 AC_CHECK_FUNCS([ \
 171         atexit \
 172         getcpuid \
 173         gettid \
 174         gettimeofday \
 175         memeset \
 176         memset \
 177         munmap \
 178         rand_r \
 179         sched_getcpu \
 180         sched_setaffinity \
 181         strerror \
 182         strtoul \
 183         sysconf \
 184 ])
 185
 186 # AC_FUNC_MALLOC causes problems when cross-compiling.
 187 #AC_FUNC_MALLOC
 188
 189 # Search for clock_gettime() in -lrt
 190 AC_SEARCH_LIBS([clock_gettime], [rt], [
 191   AC_DEFINE([CONFIG_RCU_HAVE_CLOCK_GETTIME], [1], [clock_gettime() is detected.])
 192 ])
 193
 194
 195 ##                              ##
 196 ## Optionnal features selection ##
 197 ##                              ##
 198
 199 # Allow to fallback to FIXME if the membarrier syscall is unavailable on the
 200 # running kernel, when disabled, abort if the syscall is unavailable. Applies
 201 # to default and bulletproof flavors.
 202 # Enabled by default
 203 AE_FEATURE_DEFAULT_ENABLE
 204 AE_FEATURE([sys-membarrier-fallback], [Abort if sys-membarrier is needed but not available rather than using a fallback.])
 205
 206 # Use compiler Thread Local Storage, when disabled use pthread_getspecific() to emulate TLS.
 207 # Enabled by default
 208 AE_FEATURE_DEFAULT_ENABLE
 209 AE_FEATURE([compiler-tls], [Use pthread_getspecific() to emulate Thread Local Storage (TLS) variables.])
 210
 211 # smp-support configure option
 212 # Enabled by default
 213 AE_FEATURE_DEFAULT_ENABLE
 214 AE_FEATURE([smp-support], [Disable SMP support. Warning: only use this on uniprocessor systems.])
 215
 216 # RCU debugging option
 217 # Disabled by default
 218 AE_FEATURE_DEFAULT_DISABLE
 219 AE_FEATURE([rcu-debug], [Enable internal debugging self-checks. Introduces a performance penalty.])
 220
 221 # rculfhash iterator debugging
 222 # Disabled by default
 223 AE_FEATURE_DEFAULT_DISABLE
 224 AE_FEATURE([cds-lfht-iter-debug], [Enable extra debugging checks for lock-free hash table iterator traversal. Alters the rculfhash ABI. Make sure to compile both library and application with matching configuration.])
 225
 226
 227 ##                                                                    ##
 228 ## Set defines for optional features conditionnals in the source code ##
 229 ##                                                                    ##
 230
 231 AE_IF_FEATURE_DISABLED([sys-membarrier-fallback], [
 232   AC_DEFINE([CONFIG_RCU_FORCE_SYS_MEMBARRIER], [1], [Require the operating system to support the membarrier system call for default and bulletproof flavors.])
 233 ])
 234
 235 AE_IF_FEATURE_ENABLED([compiler-tls], [
 236   AC_DEFINE([CONFIG_RCU_TLS], [1], [Use compiler provided Thread Local Storage.])
 237 ])
 238
 239 AE_IF_FEATURE_ENABLED([smp-support], [
 240   AC_DEFINE([CONFIG_RCU_SMP], [1], [Enable SMP support. With SMP support enabled, uniprocessors are also supported. With SMP support disabled, UP systems work fine, but the behavior of SMP systems is undefined.])
 241 ])
 242
 243 AE_IF_FEATURE_ENABLED([rcu-debug], [
 244   AC_DEFINE([CONFIG_RCU_DEBUG], [1], [Enable internal debugging self-checks. Introduces a performance penalty.])
 245 ])
 246
 247 AE_IF_FEATURE_ENABLED([cds-lfht-iter-debug], [
 248   AC_DEFINE([CONFIG_CDS_LFHT_ITER_DEBUG], [1], [Enable extra debugging checks for lock-free hash table iterator traversal. Alters the rculfhash ABI. Make sure to compile both library and application with matching configuration.])
 249 ])
 250
 251
 252 ##                                                                          ##
 253 ## Set automake variables for optional feature conditionnals in Makefile.am ##
 254 ##                                                                          ##
 255
 256 # Building the examples requires the shared libraries to be enabled
 257 AM_CONDITIONAL([ENABLE_EXAMPLES], AE_IS_FEATURE_ENABLED([shared]))
 258
 259
 260 ##                                             ##
 261 ## Substitute variables for use in Makefile.am ##
 262 ##                                             ##
 263
 264 # Library versions for libtool
 265 AC_SUBST([URCU_LIBRARY_VERSION], [urcu_lib_version])
 266
 267 AC_SUBST(LT_NO_UNDEFINED)
 268
 269 # The order in which the include folders are searched is important.
 270 # The top_builddir should always be searched first in the event that a build
 271 # time generated file is included.
 272 AM_CPPFLAGS="-I\$(top_builddir)/include -I\$(top_srcdir)/include -include config.h"
 273 AC_SUBST(AM_CPPFLAGS)
 274
 275 AM_CFLAGS="$WARN_CFLAGS $PTHREAD_CFLAGS"
 276 AC_SUBST(AM_CFLAGS)
 277
 278
 279 ##                                     ##
 280 ## Output files generated by configure ##
 281 ##                                     ##
 282
 283 AC_CONFIG_FILES([
 284         Makefile
 285         doc/Makefile
 286         doc/examples/Makefile
 287         extras/Makefile
 288         include/Makefile
 289         src/Makefile
 290         tests/Makefile
 291         tests/common/Makefile
 292         tests/unit/Makefile
 293         tests/benchmark/Makefile
 294         tests/regression/Makefile
 295         tests/utils/Makefile
 296         src/liburcu.pc
 297         src/liburcu-bp.pc
 298         src/liburcu-cds.pc
 299         src/liburcu-qsbr.pc
 300         src/liburcu-mb.pc
 301         src/liburcu-signal.pc
 302 ])
 303
 304 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_bp_perf_global.tap], [chmod +x tests/regression/rcutorture_urcu_bp_perf_global.tap])
 305 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_bp_perf_percpu.tap], [chmod +x tests/regression/rcutorture_urcu_bp_perf_percpu.tap])
 306 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_bp_perf_perthread.tap], [chmod +x tests/regression/rcutorture_urcu_bp_perf_perthread.tap])
 307 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_bp_rperf_global.tap], [chmod +x tests/regression/rcutorture_urcu_bp_rperf_global.tap])
 308 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_bp_rperf_percpu.tap], [chmod +x tests/regression/rcutorture_urcu_bp_rperf_percpu.tap])
 309 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_bp_rperf_perthread.tap], [chmod +x tests/regression/rcutorture_urcu_bp_rperf_perthread.tap])
 310 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_bp_stress_global.tap], [chmod +x tests/regression/rcutorture_urcu_bp_stress_global.tap])
 311 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_bp_stress_percpu.tap], [chmod +x tests/regression/rcutorture_urcu_bp_stress_percpu.tap])
 312 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_bp_stress_perthread.tap], [chmod +x tests/regression/rcutorture_urcu_bp_stress_perthread.tap])
 313 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_bp_uperf_global.tap], [chmod +x tests/regression/rcutorture_urcu_bp_uperf_global.tap])
 314 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_bp_uperf_percpu.tap], [chmod +x tests/regression/rcutorture_urcu_bp_uperf_percpu.tap])
 315 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_bp_uperf_perthread.tap], [chmod +x tests/regression/rcutorture_urcu_bp_uperf_perthread.tap])
 316 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_mb_perf_global.tap], [chmod +x tests/regression/rcutorture_urcu_mb_perf_global.tap])
 317 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_mb_perf_percpu.tap], [chmod +x tests/regression/rcutorture_urcu_mb_perf_percpu.tap])
 318 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_mb_perf_perthread.tap], [chmod +x tests/regression/rcutorture_urcu_mb_perf_perthread.tap])
 319 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_mb_rperf_global.tap], [chmod +x tests/regression/rcutorture_urcu_mb_rperf_global.tap])
 320 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_mb_rperf_percpu.tap], [chmod +x tests/regression/rcutorture_urcu_mb_rperf_percpu.tap])
 321 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_mb_rperf_perthread.tap], [chmod +x tests/regression/rcutorture_urcu_mb_rperf_perthread.tap])
 322 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_mb_stress_global.tap], [chmod +x tests/regression/rcutorture_urcu_mb_stress_global.tap])
 323 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_mb_stress_percpu.tap], [chmod +x tests/regression/rcutorture_urcu_mb_stress_percpu.tap])
 324 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_mb_stress_perthread.tap], [chmod +x tests/regression/rcutorture_urcu_mb_stress_perthread.tap])
 325 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_mb_uperf_global.tap], [chmod +x tests/regression/rcutorture_urcu_mb_uperf_global.tap])
 326 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_mb_uperf_percpu.tap], [chmod +x tests/regression/rcutorture_urcu_mb_uperf_percpu.tap])
 327 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_mb_uperf_perthread.tap], [chmod +x tests/regression/rcutorture_urcu_mb_uperf_perthread.tap])
 328 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_membarrier_perf_global.tap], [chmod +x tests/regression/rcutorture_urcu_membarrier_perf_global.tap])
 329 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_membarrier_perf_percpu.tap], [chmod +x tests/regression/rcutorture_urcu_membarrier_perf_percpu.tap])
 330 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_membarrier_perf_perthread.tap], [chmod +x tests/regression/rcutorture_urcu_membarrier_perf_perthread.tap])
 331 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_membarrier_rperf_global.tap], [chmod +x tests/regression/rcutorture_urcu_membarrier_rperf_global.tap])
 332 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_membarrier_rperf_percpu.tap], [chmod +x tests/regression/rcutorture_urcu_membarrier_rperf_percpu.tap])
 333 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_membarrier_rperf_perthread.tap], [chmod +x tests/regression/rcutorture_urcu_membarrier_rperf_perthread.tap])
 334 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_membarrier_stress_global.tap], [chmod +x tests/regression/rcutorture_urcu_membarrier_stress_global.tap])
 335 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_membarrier_stress_percpu.tap], [chmod +x tests/regression/rcutorture_urcu_membarrier_stress_percpu.tap])
 336 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_membarrier_stress_perthread.tap], [chmod +x tests/regression/rcutorture_urcu_membarrier_stress_perthread.tap])
 337 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_membarrier_uperf_global.tap], [chmod +x tests/regression/rcutorture_urcu_membarrier_uperf_global.tap])
 338 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_membarrier_uperf_percpu.tap], [chmod +x tests/regression/rcutorture_urcu_membarrier_uperf_percpu.tap])
 339 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_membarrier_uperf_perthread.tap], [chmod +x tests/regression/rcutorture_urcu_membarrier_uperf_perthread.tap])
 340 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_qsbr_perf_global.tap], [chmod +x tests/regression/rcutorture_urcu_qsbr_perf_global.tap])
 341 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_qsbr_perf_percpu.tap], [chmod +x tests/regression/rcutorture_urcu_qsbr_perf_percpu.tap])
 342 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_qsbr_perf_perthread.tap], [chmod +x tests/regression/rcutorture_urcu_qsbr_perf_perthread.tap])
 343 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_qsbr_rperf_global.tap], [chmod +x tests/regression/rcutorture_urcu_qsbr_rperf_global.tap])
 344 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_qsbr_rperf_percpu.tap], [chmod +x tests/regression/rcutorture_urcu_qsbr_rperf_percpu.tap])
 345 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_qsbr_rperf_perthread.tap], [chmod +x tests/regression/rcutorture_urcu_qsbr_rperf_perthread.tap])
 346 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_qsbr_stress_global.tap], [chmod +x tests/regression/rcutorture_urcu_qsbr_stress_global.tap])
 347 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_qsbr_stress_percpu.tap], [chmod +x tests/regression/rcutorture_urcu_qsbr_stress_percpu.tap])
 348 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_qsbr_stress_perthread.tap], [chmod +x tests/regression/rcutorture_urcu_qsbr_stress_perthread.tap])
 349 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_qsbr_uperf_global.tap], [chmod +x tests/regression/rcutorture_urcu_qsbr_uperf_global.tap])
 350 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_qsbr_uperf_percpu.tap], [chmod +x tests/regression/rcutorture_urcu_qsbr_uperf_percpu.tap])
 351 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_qsbr_uperf_perthread.tap], [chmod +x tests/regression/rcutorture_urcu_qsbr_uperf_perthread.tap])
 352 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_signal_perf_global.tap], [chmod +x tests/regression/rcutorture_urcu_signal_perf_global.tap])
 353 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_signal_perf_percpu.tap], [chmod +x tests/regression/rcutorture_urcu_signal_perf_percpu.tap])
 354 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_signal_perf_perthread.tap], [chmod +x tests/regression/rcutorture_urcu_signal_perf_perthread.tap])
 355 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_signal_rperf_global.tap], [chmod +x tests/regression/rcutorture_urcu_signal_rperf_global.tap])
 356 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_signal_rperf_percpu.tap], [chmod +x tests/regression/rcutorture_urcu_signal_rperf_percpu.tap])
 357 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_signal_rperf_perthread.tap], [chmod +x tests/regression/rcutorture_urcu_signal_rperf_perthread.tap])
 358 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_signal_stress_global.tap], [chmod +x tests/regression/rcutorture_urcu_signal_stress_global.tap])
 359 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_signal_stress_percpu.tap], [chmod +x tests/regression/rcutorture_urcu_signal_stress_percpu.tap])
 360 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_signal_stress_perthread.tap], [chmod +x tests/regression/rcutorture_urcu_signal_stress_perthread.tap])
 361 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_signal_uperf_global.tap], [chmod +x tests/regression/rcutorture_urcu_signal_uperf_global.tap])
 362 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_signal_uperf_percpu.tap], [chmod +x tests/regression/rcutorture_urcu_signal_uperf_percpu.tap])
 363 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_signal_uperf_perthread.tap], [chmod +x tests/regression/rcutorture_urcu_signal_uperf_perthread.tap])
 364
 365
 366 AC_OUTPUT
 367
 368 #
 369 # Mini-report on what will be built.
 370 #
 371
 372 PPRINT_INIT
 373 PPRINT_SET_INDENT(1)
 374 PPRINT_SET_TS(38)
 375
 376 AS_ECHO
 377 AS_ECHO("${PPRINT_COLOR_BLDBLU}Userspace-RCU $PACKAGE_VERSION${PPRINT_COLOR_RST}")
 378 AS_ECHO
 379
 380 PPRINT_SUBTITLE([Features])
 381
 382 PPRINT_PROP_STRING([Target architecture], $host_cpu)
 383
 384 # SMP support enabled/disabled
 385 AE_IS_FEATURE_ENABLED([smp-support]) && value=1 || value=0
 386 PPRINT_PROP_BOOL([SMP support], $value)
 387
 388 # TLS
 389 AE_IS_FEATURE_ENABLED([compiler-tls]) && value="compiler TLS" || value="pthread_getspecific()"
 390 PPRINT_PROP_STRING([Thread Local Storage (TLS)], [$value])
 391
 392 # clock_gettime() available
 393 test "x$ac_cv_search_function_clock_gettime" != "xno" && value=1 || value=0
 394 PPRINT_PROP_BOOL([clock_gettime()], $value)
 395
 396 # Require membarrier
 397 AE_IS_FEATURE_ENABLED([sys-membarrier-fallback]) && value=0 || value=1
 398 PPRINT_PROP_BOOL([Require membarrier], $value)
 399
 400 # RCU debug enabled/disabled
 401 AE_IS_FEATURE_ENABLED([rcu-debug]) && value=1 || value=0
 402 PPRINT_PROP_BOOL([Internal debugging], $value)
 403
 404 # rculfhash iterator debug enabled/disabled
 405 AE_IS_FEATURE_ENABLED([cds-lfht-iter-debug]) && value=1 || value=0
 406 PPRINT_PROP_BOOL([Lock-free HT iterator debugging], $value)
 407
 408 PPRINT_PROP_BOOL([Multi-flavor support], 1)
 409
 410 report_bindir="`eval eval echo $bindir`"
 411 report_libdir="`eval eval echo $libdir`"
 412
 413 # Print the bindir and libdir this 'make install' will install into.
 414 AS_ECHO
 415 PPRINT_SUBTITLE([Install directories])
 416 PPRINT_PROP_STRING([Binaries], [$report_bindir])
 417 PPRINT_PROP_STRING([Libraries], [$report_libdir])
 418