configure.ac

   1 #                                               -*- Autoconf -*-
   2 # Process this file with autoconf to produce a configure script.
   3
   4
   5 AC_INIT([userspace-rcu],[0.7.13],[mathieu dot desnoyers at efficios dot com])
   6
   7 # Following the numbering scheme proposed by libtool for the library version
   8 # http://www.gnu.org/software/libtool/manual/html_node/Updating-version-info.html
   9 AC_SUBST([URCU_LIBRARY_VERSION], [1:0:0])
  10
  11 AC_CONFIG_AUX_DIR([config])
  12 AC_CONFIG_MACRO_DIR([config])
  13 AC_CANONICAL_TARGET
  14 AC_CANONICAL_HOST
  15 AM_INIT_AUTOMAKE([foreign dist-bzip2 no-dist-gzip])
  16 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  17
  18 m4_include([config/ax_tls.m4])
  19
  20 AC_CONFIG_SRCDIR([urcu.h])
  21
  22 AC_CONFIG_HEADERS([config.h urcu/config.h])
  23
  24 AH_TEMPLATE([CONFIG_RCU_SMP], [Enable SMP support. With SMP support enabled, uniprocessors are also supported. With SMP support disabled, UP systems work fine, but the behavior of SMP systems is undefined.])
  25 AH_TEMPLATE([CONFIG_RCU_HAVE_FENCE], [Defined when on a system that has memory fence instructions.])
  26 AH_TEMPLATE([CONFIG_RCU_HAVE_FUTEX], [Defined when on a system with futex support.])
  27 AH_TEMPLATE([CONFIG_RCU_COMPAT_ARCH], [Compatibility mode for i386 which lacks cmpxchg instruction.])
  28 AH_TEMPLATE([CONFIG_RCU_ARM_HAVE_DMB], [Use the dmb instruction if available for use on ARM.])
  29 AH_TEMPLATE([CONFIG_RCU_TLS], [TLS provided by the compiler.])
  30
  31 # Allow overriding storage used for TLS variables.
  32 AC_ARG_ENABLE([compiler-tls],
  33         AS_HELP_STRING([--disable-compiler-tls], [Use pthread_getspecific() to emulate Thread Local Storage (TLS) variables.]),
  34         [def_compiler_tls=$enableval],
  35         [def_compiler_tls="yes"])
  36
  37 # If not overridden, use ax_tls.m4 to check if TLS is available.
  38 AS_IF([test "x$def_compiler_tls" = "xyes"],
  39         [AX_TLS([def_tls_detect=$ac_cv_tls], [:])],
  40         [:])
  41
  42 AS_IF([test "x$def_tls_detect" = "x"],
  43         [:],
  44         [AC_DEFINE_UNQUOTED([CONFIG_RCU_TLS], $def_tls_detect)])
  45
  46 # Checks for programs.
  47 AC_PROG_CC
  48 AC_PROG_MAKE_SET
  49 LT_INIT
  50
  51 # Checks for typedefs, structures, and compiler characteristics.
  52 AC_C_INLINE
  53 AC_TYPE_PID_T
  54 AC_TYPE_SIZE_T
  55
  56 # Checks for library functions.
  57 AC_FUNC_MALLOC
  58 AC_FUNC_MMAP
  59 AC_CHECK_FUNCS([bzero gettimeofday munmap sched_getcpu strtoul sysconf])
  60
  61 # Find arch type
  62 AS_CASE([$host_cpu],
  63         [i386], [ARCHTYPE="x86" && SUBARCHTYPE="x86compat"],
  64         [i486], [ARCHTYPE="x86"],
  65         [i586], [ARCHTYPE="x86"],
  66         [i686], [ARCHTYPE="x86"],
  67         [amd64], [ARCHTYPE="x86"],
  68         [x86_64], [ARCHTYPE="x86"],
  69         [powerpc], [ARCHTYPE="ppc"],
  70         [ppc64], [ARCHTYPE="ppc"],
  71         [powerpc64], [ARCHTYPE="ppc"],
  72         [ppc], [ARCHTYPE="ppc"],
  73         [s390], [ARCHTYPE="s390"],
  74         [s390x], [ARCHTYPE="s390"],
  75         [sparc], [ARCHTYPE="sparc64"],
  76         [sparc64], [ARCHTYPE="sparc64"],
  77         [alpha*], [ARCHTYPE="alpha"],
  78         [ia64], [ARCHTYPE="gcc"],
  79         [arm*], [ARCHTYPE="arm"],
  80         [mips*], [ARCHTYPE="mips"],
  81         [ARCHTYPE="unknown"]
  82 )
  83
  84 AC_SUBST(ARCHTYPE)
  85 AC_SUBST(SUBARCHTYPE)
  86
  87 UATOMICSRC=urcu/uatomic/$ARCHTYPE.h
  88 ARCHSRC=urcu/arch/$ARCHTYPE.h
  89
  90 AS_IF([test "x$SUBARCHTYPE" = xx86compat],[
  91         AC_DEFINE([CONFIG_RCU_COMPAT_ARCH], [1])
  92 ])
  93
  94 AS_IF([test "$host_cpu" = "armv7l"],[
  95         CFLAGS="$CFLAGS -mcpu=cortex-a9 -mtune=cortex-a9 -O1"
  96 ])
  97
  98 # ARM-specific checks
  99 AS_IF([test "x$ARCHTYPE" = "xarm"],[
 100         AC_MSG_CHECKING([for dmb instruction])
 101         AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 102                                 int main()
 103                                 {
 104                                         asm volatile("dmb":::"memory");
 105                                         return 0;
 106                                 }
 107                 ]])
 108         ],[
 109                 AC_MSG_RESULT([yes])
 110                 AC_DEFINE([CONFIG_RCU_ARM_HAVE_DMB], [1])
 111         ],[
 112                 AC_MSG_RESULT([no])
 113         ])
 114 ])
 115
 116 # x86-specific checks
 117 AS_IF([test "x$ARCHTYPE" = "xx86"],[
 118         AC_MSG_CHECKING([if architecture really supports the mfence instruction])
 119         #For now, using lock; addl compatibility mode even for i686, because the
 120         #Pentium III is seen as a i686, but lacks mfence instruction.
 121         #Only using fence for x86_64.
 122         AS_IF([test "x$host_cpu" != "xi386" -a "x$host_cpu" != "xi486" -a "x$host_cpu" != "xi586" -a "x$host_cpu" != "xi686"],[
 123                 AC_MSG_RESULT([yes])
 124                 AC_DEFINE([CONFIG_RCU_HAVE_FENCE], [1])
 125         ],[
 126                 AC_MSG_RESULT([no])
 127         ])
 128 ])
 129
 130 # Check if sys_futex() is available
 131 AC_MSG_CHECKING([for sys_futex()])
 132 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 133                 #include <sys/syscall.h>
 134                 #ifndef __NR_futex
 135                 #error "futexes not available"
 136                 #endif
 137         ]])
 138 ],[
 139         AC_MSG_RESULT([yes])
 140         AC_DEFINE([CONFIG_RCU_HAVE_FUTEX], [1])
 141         compat_futex_test=0
 142 ],[
 143         AC_MSG_RESULT([no])
 144         compat_futex_test=1
 145 ])
 146
 147 AM_CONDITIONAL([COMPAT_FUTEX], [test "x$compat_futex_test" = "x1"])
 148 AM_CONDITIONAL([COMPAT_ARCH], [test "x$SUBARCHTYPE" = "xx86compat"])
 149
 150 # smp-support configure option
 151 AC_ARG_ENABLE([smp-support],
 152         AS_HELP_STRING([--disable-smp-support], [Disable SMP support. Warning: only use this on uniprocessor systems. [default=enabled]]),
 153         [def_smp_support=$enableval],
 154         [def_smp_support="yes"])
 155 AS_IF([test "x$def_smp_support" = "xyes"], [AC_DEFINE([CONFIG_RCU_SMP], [1])])
 156
 157
 158 # From the sched_setaffinity(2)'s man page:
 159 # ~~~~
 160 # The CPU affinity system calls were introduced in Linux kernel 2.5.8.
 161 # The library interfaces were introduced in glibc 2.3.  Initially, the
 162 # glibc interfaces included a cpusetsize argument.  In glibc 2.3.3,
 163 # the cpuset size argument was removed, but this argument was
 164 # restored in glibc 2.3.4.
 165 # ~~~~
 166
 167 # In addition to that, some vendors ported the system call to 2.4
 168 # kernels.
 169
 170 # Furthermore, when the function first appeared, the MASK argument was
 171 # an unsigned long pointer, while later it was made into a cpu_set_t
 172 # pointer.  Systems that have the cpu_set_t version also should have
 173 # the CPU_ZERO, CPU_SET, etc. macros.
 174
 175 # All this mess means we have to cater for at least 3 different
 176 # sched_setaffinity prototypes:
 177
 178 # ~~~~
 179 #  int sched_setaffinity (pid_t pid, unsigned int len, unsigned long *mask);
 180 #  int sched_setaffinity (pid_t __pid, size_t __cpusetsize, const cpu_set_t *__cpuset);
 181 #  int sched_setaffinity (pid_t __pid, const cpu_set_t *__mask);
 182 # ~~~~
 183
 184 # Since we define _GNU_SOURCE in the sources, must do so too in the
 185 # autoconf tests, as defining _GNU_SOURCE or not exposes
 186 # sched_setaffinity bits differently.
 187 saved_CFLAGS=$CFLAGS
 188 CFLAGS="$CFLAGS -D_GNU_SOURCE"
 189
 190 AC_CHECK_TYPES([cpu_set_t],
 191         [have_cpu_set_t="yes"],
 192         [have_cpu_set_t="no"],
 193         [#include <sched.h>])
 194
 195 # Confirm that we have CPU_ZERO, and it actually works.
 196 AC_MSG_CHECKING([whether CPU_ZERO works])
 197 AH_TEMPLATE([HAVE_CPU_ZERO], [Defined to 1 if we have CPU_ZERO and it works])
 198 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 199                 #define _GNU_SOURCE
 200                 #include <sched.h>
 201                 int main()
 202                 {
 203                         cpu_set_t foo; CPU_ZERO(&foo);
 204                         return 0;
 205                 }
 206         ]])
 207 ],[
 208         AC_DEFINE(HAVE_CPU_ZERO, 1)
 209         AC_MSG_RESULT([yes])
 210 ],[
 211         AC_MSG_RESULT([no])
 212 ])
 213
 214 # Confirm that we have CPU_SET, and it actually works.
 215 AC_MSG_CHECKING([whether CPU_SET works])
 216 AH_TEMPLATE([HAVE_CPU_SET], [Defined to 1 if we have CPU_SET and it works])
 217 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 218                 #define _GNU_SOURCE
 219                 #include <sched.h>
 220                 int main()
 221                 {
 222                         cpu_set_t foo, mask; CPU_SET(0, &foo);
 223                         return 0;
 224                 }
 225         ]])
 226 ],[
 227         AC_DEFINE(HAVE_CPU_SET, 1)
 228         AC_MSG_RESULT([yes])
 229 ],[
 230         AC_MSG_RESULT([no])
 231 ])
 232
 233 # First check if the function is available at all.
 234 AC_CHECK_FUNCS([sched_setaffinity],[
 235         # Okay, we have it.  Check if also have cpu_set_t.  If we don't,
 236         # then we have the first version using unsigned long, and no
 237         # CPU_ZERO, etc. macros.  If we do have cpu_set_t, we may have the
 238         # version with 2 or 3 arguments.  In that case, CPU_ZERO, etc.,
 239         # should also be present, but we confirm nonetheless.
 240
 241         AS_IF([test "x$have_cpu_set_t" = "xyes"], [
 242                 # We do have it.
 243                 # Check how many arguments does sched_setaffinity take.
 244                 # Should be 3 or 2.
 245                 AC_MSG_CHECKING([how many arguments sched_setaffinity takes])
 246                 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 247                                 #include <sched.h>
 248                                 int main()
 249                                 {
 250                                         cpu_set_t foo;
 251                                         sched_setaffinity(0, sizeof (foo), &foo);
 252                                         return 0;
 253                                 }
 254                         ]])
 255                 ],
 256                 [sched_set_affinity_args=3],
 257                 [sched_set_affinity_args=2])
 258                 AC_DEFINE_UNQUOTED(SCHED_SETAFFINITY_ARGS,
 259                         $sched_set_affinity_args,
 260                         [Defined to sched_setaffinity's number of arguments.])
 261                 AC_MSG_RESULT([$sched_set_affinity_args])
 262         ],[
 263                 # No cpu_set_t, always 3 args.
 264                 AC_DEFINE(SCHED_SETAFFINITY_ARGS, 3)
 265         ])
 266 ])
 267
 268 CFLAGS=$saved_CFLAGS
 269
 270 AC_CONFIG_LINKS([
 271         urcu/arch.h:$ARCHSRC
 272         urcu/uatomic.h:$UATOMICSRC
 273 ])
 274 AC_CONFIG_FILES([
 275         Makefile
 276         doc/Makefile
 277         tests/Makefile
 278         liburcu.pc
 279         liburcu-bp.pc
 280         liburcu-cds.pc
 281         liburcu-qsbr.pc
 282         liburcu-mb.pc
 283         liburcu-signal.pc
 284 ])
 285 AC_OUTPUT
 286
 287 # Report on selected configure options
 288 AS_IF([test "x$def_smp_support" = "xyes"],[
 289         AS_ECHO("SMP support enabled.")
 290 ],[
 291         AS_ECHO("SMP support disabled.")
 292 ])
 293
 294 AS_IF([test "x$def_tls_detect" = "x"],[
 295         AS_ECHO("Thread Local Storage (TLS): pthread_getspecific().")
 296 ],[
 297         AS_ECHO("Thread Local Storage (TLS): $def_tls_detect.")
 298 ])