configure.ac

   1 AC_PREREQ(2.59)
   2 AC_INIT([userspace-rcu],[0.12.0],[mathieu dot desnoyers at efficios dot com], [], [http://liburcu.org/])
   3
   4 # Following the numbering scheme proposed by libtool for the library version
   5 # http://www.gnu.org/software/libtool/manual/html_node/Updating-version-info.html
   6 AC_SUBST([URCU_LIBRARY_VERSION], [7:0:1])
   7
   8 AC_CONFIG_HEADERS([include/config.h include/urcu/config.h])
   9 AC_CONFIG_AUX_DIR([config])
  10 AC_CONFIG_MACRO_DIR([m4])
  11
  12 AC_CANONICAL_TARGET
  13 AC_CANONICAL_HOST
  14
  15 AM_INIT_AUTOMAKE([1.12 foreign dist-bzip2 no-dist-gzip nostdinc])
  16 AM_MAINTAINER_MODE([enable])
  17
  18 # Enable silent rules if available (Introduced in AM 1.11)
  19 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  20
  21 AC_REQUIRE_AUX_FILE([tap-driver.sh])
  22
  23 AH_TEMPLATE([CONFIG_RCU_SMP], [Enable SMP support. With SMP support enabled, uniprocessors are also supported. With SMP support disabled, UP systems work fine, but the behavior of SMP systems is undefined.])
  24 AH_TEMPLATE([CONFIG_RCU_HAVE_FENCE], [Defined when on a system that has memory fence instructions.])
  25 AH_TEMPLATE([CONFIG_RCU_HAVE_FUTEX], [Defined when on a system with futex support.])
  26 AH_TEMPLATE([CONFIG_RCU_COMPAT_ARCH], [Compatibility mode for i386 which lacks cmpxchg instruction.])
  27 AH_TEMPLATE([CONFIG_RCU_ARM_HAVE_DMB], [Use the dmb instruction if available for use on ARM.])
  28 AH_TEMPLATE([CONFIG_RCU_TLS], [TLS provided by the compiler.])
  29 AH_TEMPLATE([CONFIG_RCU_HAVE_CLOCK_GETTIME], [clock_gettime() is detected.])
  30 AH_TEMPLATE([CONFIG_RCU_FORCE_SYS_MEMBARRIER], [Require the operating system to support the membarrier system call for default and bulletproof flavors.])
  31 AH_TEMPLATE([CONFIG_RCU_DEBUG], [Enable internal debugging self-checks. Introduce performance penalty.])
  32 AH_TEMPLATE([CONFIG_CDS_LFHT_ITER_DEBUG], [Enable extra debugging checks for lock-free hash table iterator traversal. Alters the rculfhash ABI. Make sure to compile both library and application with matching configuration.])
  33
  34 # Allow requiring the operating system to support the membarrier system
  35 # call. Applies to default and bulletproof flavors.
  36 AC_ARG_ENABLE([sys-membarrier-fallback],
  37         AS_HELP_STRING([--disable-sys-membarrier-fallback], [Abort if sys-membarrier is needed but not available rather than using a fallback.]),
  38         [def_sys_membarrier_fallback=$enableval],
  39         [def_sys_membarrier_fallback="yes"])
  40 AS_IF([test "x$def_sys_membarrier_fallback" != "xyes"], [AC_DEFINE([CONFIG_RCU_FORCE_SYS_MEMBARRIER], [1])])
  41
  42 # Allow overriding storage used for TLS variables.
  43 AC_ARG_ENABLE([compiler-tls],
  44         AS_HELP_STRING([--disable-compiler-tls], [Use pthread_getspecific() to emulate Thread Local Storage (TLS) variables.]),
  45         [def_compiler_tls=$enableval],
  46         [def_compiler_tls="yes"])
  47
  48 # Checks for C compiler
  49 AC_USE_SYSTEM_EXTENSIONS
  50 AC_PROG_CC
  51 AC_PROG_CC_STDC
  52
  53 AS_IF([test "x$def_compiler_tls" = "xyes"], AC_DEFINE([CONFIG_RCU_TLS], [1]), [:])
  54
  55 # Checks for programs.
  56 AC_PROG_AWK
  57 AC_PROG_MAKE_SET
  58 AC_CHECK_PROGS(NPROC, [nproc gnproc])
  59 AC_CHECK_PROGS(GETCONF, [getconf])
  60 AS_IF([test "x$NPROC" != "x"],
  61         [NPROC_CMD=$NPROC],
  62         [AS_IF([test "x$GETCONF" != "x"],
  63                 [NPROC_CMD="$GETCONF _NPROCESSORS_ONLN"],
  64                 [NPROC_CMD="echo 1"]
  65         )]
  66 )
  67 AC_SUBST([NPROC_CMD], [$NPROC_CMD])
  68
  69 LT_INIT
  70
  71 # Checks for typedefs, structures, and compiler characteristics.
  72 AC_C_INLINE
  73 AC_TYPE_PID_T
  74 AC_TYPE_SIZE_T
  75 AC_TYPE_SSIZE_T
  76 AC_TYPE_UINT16_T
  77 AC_TYPE_INT32_T
  78 AC_TYPE_UINT32_T
  79 AC_TYPE_UINT64_T
  80 AC_TYPE_UINT8_T
  81
  82 AX_C___ATTRIBUTE__
  83 AS_IF([test "x$ax_cv___attribute__" = "xyes"],
  84         [:],
  85         [AC_MSG_ERROR([The compiler does not support __attribute__ extensions])])
  86
  87 AX_PTHREAD(,[AC_MSG_ERROR([Could not configure pthreads support])])
  88
  89 AM_CFLAGS="$AM_CFLAGS $PTHREAD_CFLAGS"
  90
  91 # Checks for library functions.
  92 AC_FUNC_MMAP
  93 AC_FUNC_FORK
  94 AC_CHECK_FUNCS([ \
  95         atexit \
  96         getcpuid \
  97         gettid \
  98         gettimeofday \
  99         memeset \
 100         memset \
 101         munmap \
 102         rand_r \
 103         sched_getcpu \
 104         strerror \
 105         strtoul \
 106         sysconf \
 107 ])
 108
 109 # AC_FUNC_MALLOC causes problems when cross-compiling.
 110 #AC_FUNC_MALLOC
 111
 112 # Check for headers
 113 AC_HEADER_STDBOOL
 114 AC_CHECK_HEADERS([ \
 115         limits.h \
 116         stddef.h \
 117         sys/param.h \
 118         sys/time.h \
 119 ])
 120
 121 # Find arch type
 122 AS_CASE([$host_cpu],
 123         [k1om], [ARCHTYPE="x86"],
 124         [i386], [ARCHTYPE="x86" && SUBARCHTYPE="x86compat"],
 125         [i486], [ARCHTYPE="x86"],
 126         [i586], [ARCHTYPE="x86"],
 127         [i686], [ARCHTYPE="x86"],
 128         [amd64], [ARCHTYPE="x86"],
 129         [x86_64], [ARCHTYPE="x86"],
 130         [powerpc], [ARCHTYPE="ppc"],
 131         [ppc64], [ARCHTYPE="ppc"],
 132         [powerpc64], [ARCHTYPE="ppc"],
 133         [powerpc64le], [ARCHTYPE="ppc"],
 134         [ppc], [ARCHTYPE="ppc"],
 135         [s390], [ARCHTYPE="s390"],
 136         [s390x], [ARCHTYPE="s390"],
 137         [sparc], [ARCHTYPE="sparc64"],
 138         [sparc64], [ARCHTYPE="sparc64"],
 139         [alpha*], [ARCHTYPE="alpha"],
 140         [ia64], [ARCHTYPE="ia64"],
 141         [arm*], [ARCHTYPE="arm"],
 142         [aarch64*], [ARCHTYPE="aarch64"],
 143         [mips*], [ARCHTYPE="mips"],
 144         [nios2*], [ARCHTYPE="nios2"],
 145         [tile*], [ARCHTYPE="tile"],
 146         [hppa*], [ARCHTYPE="hppa"],
 147         [m68k], [ARCHTYPE="m68k"],
 148         [riscv*], [ARCHTYPE="riscv"],
 149         [ARCHTYPE="unknown"]
 150 )
 151
 152 AS_CASE([$host],[*-cygwin*],
 153         [AM_CONDITIONAL(USE_CYGWIN, true)],
 154         [AM_CONDITIONAL(USE_CYGWIN, false)]
 155 )
 156
 157 AC_SUBST(ARCHTYPE)
 158 AC_SUBST(SUBARCHTYPE)
 159
 160 UATOMICSRC=include/urcu/uatomic/$ARCHTYPE.h
 161 ARCHSRC=include/urcu/arch/$ARCHTYPE.h
 162
 163 AS_IF([test "x$SUBARCHTYPE" = xx86compat],[
 164         AC_DEFINE([CONFIG_RCU_COMPAT_ARCH], [1])
 165 ])
 166
 167 AS_IF([test "$host_cpu" = "armv7l"],[
 168         AM_CFLAGS="$AM_CFLAGS -mcpu=cortex-a9 -mtune=cortex-a9 -O1"
 169 ])
 170
 171 # ARM-specific checks
 172 AS_IF([test "x$ARCHTYPE" = "xarm"],[
 173         AC_MSG_CHECKING([for dmb instruction])
 174         AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 175                                 int main()
 176                                 {
 177                                         asm volatile("dmb":::"memory");
 178                                         return 0;
 179                                 }
 180                 ]])
 181         ],[
 182                 AC_MSG_RESULT([yes])
 183                 AC_DEFINE([CONFIG_RCU_ARM_HAVE_DMB], [1])
 184         ],[
 185                 AC_MSG_RESULT([no])
 186         ])
 187 ])
 188
 189 # Tile-specific checks
 190 AS_IF([echo "$host_cpu" | grep "^tile"],[
 191         AC_MSG_CHECKING([for Tile architecture type])
 192         AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 193                                 #ifndef __tilegx__
 194                                 #error
 195                                 #endif
 196                 ]])
 197         ],[
 198                 AC_MSG_RESULT([ok])
 199         ],[
 200                 AC_MSG_FAILURE([URCU has only been tested on the TileGx architecture. For other Tile* architectures, please run the tests first and report the results to the maintainer so that proper support can be added.])
 201         ])
 202 ])
 203
 204 # x86-specific checks
 205 AS_IF([test "x$ARCHTYPE" = "xx86"],[
 206         AC_MSG_CHECKING([if architecture really supports the mfence instruction])
 207         #For now, using lock; addl compatibility mode even for i686, because the
 208         #Pentium III is seen as a i686, but lacks mfence instruction.
 209         #Only using fence for x86_64.
 210         #
 211         #k1om is the name for the Intel MIC family (Xeon Phi). It is an x86_64
 212         #variant but lacks fence instructions.
 213         AS_IF([test "x$host_cpu" != "xi386" -a "x$host_cpu" != "xi486" -a "x$host_cpu" != "xi586" -a "x$host_cpu" != "xi686" -a "x$host_vendor" != "xk1om" -a "x$host_cpu" != "xk1om"],[
 214                 AC_MSG_RESULT([yes])
 215                 AC_DEFINE([CONFIG_RCU_HAVE_FENCE], [1])
 216                 config_rcu_have_fence=yes
 217         ],[
 218                 AC_MSG_RESULT([no])
 219                 config_rcu_have_fence=no
 220         ])
 221 ])
 222
 223 # Check if sys_futex() is available
 224 AC_MSG_CHECKING([for sys_futex()])
 225 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 226                 #include <sys/syscall.h>
 227                 #ifndef __NR_futex
 228                 #error "futexes not available"
 229                 #endif
 230         ]])
 231 ],[
 232         AC_MSG_RESULT([yes])
 233         AC_DEFINE([CONFIG_RCU_HAVE_FUTEX], [1])
 234         compat_futex_test=0
 235 ],[
 236         AC_MSG_RESULT([no])
 237         compat_futex_test=1
 238 ])
 239
 240 # Search for clock_gettime
 241 AC_SEARCH_LIBS([clock_gettime], [rt], [
 242         AC_DEFINE([CONFIG_RCU_HAVE_CLOCK_GETTIME], [1])
 243         config_rcu_have_clock_gettime=yes
 244 ], [])
 245
 246 AM_CONDITIONAL([COMPAT_FUTEX], [test "x$compat_futex_test" = "x1"])
 247 AM_CONDITIONAL([COMPAT_ARCH], [test "x$SUBARCHTYPE" = "xx86compat"])
 248 AM_CONDITIONAL([NO_SHARED], [test "x$enable_shared" = "xno"])
 249
 250 # smp-support configure option
 251 AC_ARG_ENABLE([smp-support],
 252         AS_HELP_STRING([--disable-smp-support], [Disable SMP support. Warning: only use this on uniprocessor systems. [default=enabled]]),
 253         [def_smp_support=$enableval],
 254         [def_smp_support="yes"])
 255 AS_IF([test "x$def_smp_support" = "xyes"], [AC_DEFINE([CONFIG_RCU_SMP], [1])])
 256
 257 # RCU debugging option
 258 AC_ARG_ENABLE([rcu-debug],
 259       AS_HELP_STRING([--enable-rcu-debug], [Enable internal debugging
 260                       self-checks. Introduce performance penalty.]))
 261 AS_IF([test "x$enable_rcu_debug" = "xyes"], [
 262        AC_DEFINE([CONFIG_RCU_DEBUG], [1])
 263 ])
 264
 265 # rculfhash iterator debugging
 266 AC_ARG_ENABLE([cds-lfht-iter-debug],
 267       AS_HELP_STRING([--enable-cds-lfht-iter-debug], [Enable extra debugging checks for lock-free hash table iterator traversal. Alters the rculfhash ABI. Make sure to compile both library and application with matching configuration.]))
 268 AS_IF([test "x$enable_cds_lfht_iter_debug" = "xyes"], [
 269        AC_DEFINE([CONFIG_CDS_LFHT_ITER_DEBUG], [1])
 270 ])
 271
 272 # From the sched_setaffinity(2)'s man page:
 273 # ~~~~
 274 # The CPU affinity system calls were introduced in Linux kernel 2.5.8.
 275 # The library interfaces were introduced in glibc 2.3.  Initially, the
 276 # glibc interfaces included a cpusetsize argument.  In glibc 2.3.3,
 277 # the cpuset size argument was removed, but this argument was
 278 # restored in glibc 2.3.4.
 279 # ~~~~
 280
 281 # In addition to that, some vendors ported the system call to 2.4
 282 # kernels.
 283
 284 # Furthermore, when the function first appeared, the MASK argument was
 285 # an unsigned long pointer, while later it was made into a cpu_set_t
 286 # pointer.  Systems that have the cpu_set_t version also should have
 287 # the CPU_ZERO, CPU_SET, etc. macros.
 288
 289 # All this mess means we have to cater for at least 3 different
 290 # sched_setaffinity prototypes:
 291
 292 # ~~~~
 293 #  int sched_setaffinity (pid_t pid, unsigned int len, unsigned long *mask);
 294 #  int sched_setaffinity (pid_t __pid, size_t __cpusetsize, const cpu_set_t *__cpuset);
 295 #  int sched_setaffinity (pid_t __pid, const cpu_set_t *__mask);
 296 # ~~~~
 297
 298 AC_CHECK_TYPES([cpu_set_t],
 299         [have_cpu_set_t="yes"],
 300         [have_cpu_set_t="no"],
 301         [#include <sched.h>])
 302
 303 # Confirm that we have CPU_ZERO, and it actually works.
 304 AC_MSG_CHECKING([whether CPU_ZERO works])
 305 AH_TEMPLATE([HAVE_CPU_ZERO], [Defined to 1 if we have CPU_ZERO and it works])
 306 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 307                 #include <sched.h>
 308                 int main()
 309                 {
 310                         cpu_set_t foo; CPU_ZERO(&foo);
 311                         return 0;
 312                 }
 313         ]])
 314 ],[
 315         AC_DEFINE(HAVE_CPU_ZERO, 1)
 316         AC_MSG_RESULT([yes])
 317 ],[
 318         AC_MSG_RESULT([no])
 319 ])
 320
 321 # Confirm that we have CPU_SET, and it actually works.
 322 AC_MSG_CHECKING([whether CPU_SET works])
 323 AH_TEMPLATE([HAVE_CPU_SET], [Defined to 1 if we have CPU_SET and it works])
 324 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 325                 #include <sched.h>
 326                 int main()
 327                 {
 328                         cpu_set_t foo; CPU_SET(0, &foo);
 329                         return 0;
 330                 }
 331         ]])
 332 ],[
 333         AC_DEFINE(HAVE_CPU_SET, 1)
 334         AC_MSG_RESULT([yes])
 335 ],[
 336         AC_MSG_RESULT([no])
 337 ])
 338
 339 # First check if the function is available at all.
 340 AC_CHECK_FUNCS([sched_setaffinity],[
 341         # Okay, we have it.  Check if also have cpu_set_t.  If we don't,
 342         # then we have the first version using unsigned long, and no
 343         # CPU_ZERO, etc. macros.  If we do have cpu_set_t, we may have the
 344         # version with 2 or 3 arguments.  In that case, CPU_ZERO, etc.,
 345         # should also be present, but we confirm nonetheless.
 346
 347         AS_IF([test "x$have_cpu_set_t" = "xyes"], [
 348                 # We do have it.
 349                 # Check how many arguments does sched_setaffinity take.
 350                 # Should be 3 or 2.
 351                 AC_MSG_CHECKING([how many arguments sched_setaffinity takes])
 352                 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 353                                 #include <sched.h>
 354                                 int main()
 355                                 {
 356                                         cpu_set_t foo;
 357                                         sched_setaffinity(0, sizeof (foo), &foo);
 358                                         return 0;
 359                                 }
 360                         ]])
 361                 ],
 362                 [sched_set_affinity_args=3],
 363                 [sched_set_affinity_args=2])
 364                 AC_DEFINE_UNQUOTED(SCHED_SETAFFINITY_ARGS,
 365                         $sched_set_affinity_args,
 366                         [Defined to sched_setaffinity's number of arguments.])
 367                 AC_MSG_RESULT([$sched_set_affinity_args])
 368         ],[
 369                 # No cpu_set_t, always 3 args.
 370                 AC_DEFINE(SCHED_SETAFFINITY_ARGS, 3)
 371         ])
 372 ])
 373
 374 AM_CPPFLAGS="-include config.h"
 375 AC_SUBST(AM_CPPFLAGS)
 376
 377 AM_CFLAGS="-Wall -Wextra -Wno-unused-parameter $AM_CFLAGS"
 378 AC_SUBST(AM_CFLAGS)
 379
 380 AC_CONFIG_LINKS([
 381         include/urcu/arch.h:$ARCHSRC
 382         include/urcu/uatomic.h:$UATOMICSRC
 383 ])
 384 AC_CONFIG_FILES([
 385         Makefile
 386         doc/Makefile
 387         doc/examples/Makefile
 388         include/Makefile
 389         src/Makefile
 390         tests/Makefile
 391         tests/common/Makefile
 392         tests/unit/Makefile
 393         tests/benchmark/Makefile
 394         tests/regression/Makefile
 395         tests/utils/Makefile
 396         src/liburcu.pc
 397         src/liburcu-bp.pc
 398         src/liburcu-cds.pc
 399         src/liburcu-qsbr.pc
 400         src/liburcu-mb.pc
 401         src/liburcu-signal.pc
 402 ])
 403
 404 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_bp_perf_global.tap], [chmod +x tests/regression/rcutorture_urcu_bp_perf_global.tap])
 405 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_bp_perf_percpu.tap], [chmod +x tests/regression/rcutorture_urcu_bp_perf_percpu.tap])
 406 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_bp_perf_perthread.tap], [chmod +x tests/regression/rcutorture_urcu_bp_perf_perthread.tap])
 407 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_bp_rperf_global.tap], [chmod +x tests/regression/rcutorture_urcu_bp_rperf_global.tap])
 408 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_bp_rperf_percpu.tap], [chmod +x tests/regression/rcutorture_urcu_bp_rperf_percpu.tap])
 409 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_bp_rperf_perthread.tap], [chmod +x tests/regression/rcutorture_urcu_bp_rperf_perthread.tap])
 410 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_bp_stress_global.tap], [chmod +x tests/regression/rcutorture_urcu_bp_stress_global.tap])
 411 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_bp_stress_percpu.tap], [chmod +x tests/regression/rcutorture_urcu_bp_stress_percpu.tap])
 412 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_bp_stress_perthread.tap], [chmod +x tests/regression/rcutorture_urcu_bp_stress_perthread.tap])
 413 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_bp_uperf_global.tap], [chmod +x tests/regression/rcutorture_urcu_bp_uperf_global.tap])
 414 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_bp_uperf_percpu.tap], [chmod +x tests/regression/rcutorture_urcu_bp_uperf_percpu.tap])
 415 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_bp_uperf_perthread.tap], [chmod +x tests/regression/rcutorture_urcu_bp_uperf_perthread.tap])
 416 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_mb_perf_global.tap], [chmod +x tests/regression/rcutorture_urcu_mb_perf_global.tap])
 417 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_mb_perf_percpu.tap], [chmod +x tests/regression/rcutorture_urcu_mb_perf_percpu.tap])
 418 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_mb_perf_perthread.tap], [chmod +x tests/regression/rcutorture_urcu_mb_perf_perthread.tap])
 419 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_mb_rperf_global.tap], [chmod +x tests/regression/rcutorture_urcu_mb_rperf_global.tap])
 420 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_mb_rperf_percpu.tap], [chmod +x tests/regression/rcutorture_urcu_mb_rperf_percpu.tap])
 421 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_mb_rperf_perthread.tap], [chmod +x tests/regression/rcutorture_urcu_mb_rperf_perthread.tap])
 422 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_mb_stress_global.tap], [chmod +x tests/regression/rcutorture_urcu_mb_stress_global.tap])
 423 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_mb_stress_percpu.tap], [chmod +x tests/regression/rcutorture_urcu_mb_stress_percpu.tap])
 424 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_mb_stress_perthread.tap], [chmod +x tests/regression/rcutorture_urcu_mb_stress_perthread.tap])
 425 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_mb_uperf_global.tap], [chmod +x tests/regression/rcutorture_urcu_mb_uperf_global.tap])
 426 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_mb_uperf_percpu.tap], [chmod +x tests/regression/rcutorture_urcu_mb_uperf_percpu.tap])
 427 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_mb_uperf_perthread.tap], [chmod +x tests/regression/rcutorture_urcu_mb_uperf_perthread.tap])
 428 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_membarrier_perf_global.tap], [chmod +x tests/regression/rcutorture_urcu_membarrier_perf_global.tap])
 429 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_membarrier_perf_percpu.tap], [chmod +x tests/regression/rcutorture_urcu_membarrier_perf_percpu.tap])
 430 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_membarrier_perf_perthread.tap], [chmod +x tests/regression/rcutorture_urcu_membarrier_perf_perthread.tap])
 431 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_membarrier_rperf_global.tap], [chmod +x tests/regression/rcutorture_urcu_membarrier_rperf_global.tap])
 432 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_membarrier_rperf_percpu.tap], [chmod +x tests/regression/rcutorture_urcu_membarrier_rperf_percpu.tap])
 433 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_membarrier_rperf_perthread.tap], [chmod +x tests/regression/rcutorture_urcu_membarrier_rperf_perthread.tap])
 434 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_membarrier_stress_global.tap], [chmod +x tests/regression/rcutorture_urcu_membarrier_stress_global.tap])
 435 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_membarrier_stress_percpu.tap], [chmod +x tests/regression/rcutorture_urcu_membarrier_stress_percpu.tap])
 436 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_membarrier_stress_perthread.tap], [chmod +x tests/regression/rcutorture_urcu_membarrier_stress_perthread.tap])
 437 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_membarrier_uperf_global.tap], [chmod +x tests/regression/rcutorture_urcu_membarrier_uperf_global.tap])
 438 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_membarrier_uperf_percpu.tap], [chmod +x tests/regression/rcutorture_urcu_membarrier_uperf_percpu.tap])
 439 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_membarrier_uperf_perthread.tap], [chmod +x tests/regression/rcutorture_urcu_membarrier_uperf_perthread.tap])
 440 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_qsbr_perf_global.tap], [chmod +x tests/regression/rcutorture_urcu_qsbr_perf_global.tap])
 441 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_qsbr_perf_percpu.tap], [chmod +x tests/regression/rcutorture_urcu_qsbr_perf_percpu.tap])
 442 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_qsbr_perf_perthread.tap], [chmod +x tests/regression/rcutorture_urcu_qsbr_perf_perthread.tap])
 443 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_qsbr_rperf_global.tap], [chmod +x tests/regression/rcutorture_urcu_qsbr_rperf_global.tap])
 444 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_qsbr_rperf_percpu.tap], [chmod +x tests/regression/rcutorture_urcu_qsbr_rperf_percpu.tap])
 445 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_qsbr_rperf_perthread.tap], [chmod +x tests/regression/rcutorture_urcu_qsbr_rperf_perthread.tap])
 446 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_qsbr_stress_global.tap], [chmod +x tests/regression/rcutorture_urcu_qsbr_stress_global.tap])
 447 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_qsbr_stress_percpu.tap], [chmod +x tests/regression/rcutorture_urcu_qsbr_stress_percpu.tap])
 448 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_qsbr_stress_perthread.tap], [chmod +x tests/regression/rcutorture_urcu_qsbr_stress_perthread.tap])
 449 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_qsbr_uperf_global.tap], [chmod +x tests/regression/rcutorture_urcu_qsbr_uperf_global.tap])
 450 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_qsbr_uperf_percpu.tap], [chmod +x tests/regression/rcutorture_urcu_qsbr_uperf_percpu.tap])
 451 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_qsbr_uperf_perthread.tap], [chmod +x tests/regression/rcutorture_urcu_qsbr_uperf_perthread.tap])
 452 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_signal_perf_global.tap], [chmod +x tests/regression/rcutorture_urcu_signal_perf_global.tap])
 453 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_signal_perf_percpu.tap], [chmod +x tests/regression/rcutorture_urcu_signal_perf_percpu.tap])
 454 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_signal_perf_perthread.tap], [chmod +x tests/regression/rcutorture_urcu_signal_perf_perthread.tap])
 455 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_signal_rperf_global.tap], [chmod +x tests/regression/rcutorture_urcu_signal_rperf_global.tap])
 456 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_signal_rperf_percpu.tap], [chmod +x tests/regression/rcutorture_urcu_signal_rperf_percpu.tap])
 457 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_signal_rperf_perthread.tap], [chmod +x tests/regression/rcutorture_urcu_signal_rperf_perthread.tap])
 458 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_signal_stress_global.tap], [chmod +x tests/regression/rcutorture_urcu_signal_stress_global.tap])
 459 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_signal_stress_percpu.tap], [chmod +x tests/regression/rcutorture_urcu_signal_stress_percpu.tap])
 460 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_signal_stress_perthread.tap], [chmod +x tests/regression/rcutorture_urcu_signal_stress_perthread.tap])
 461 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_signal_uperf_global.tap], [chmod +x tests/regression/rcutorture_urcu_signal_uperf_global.tap])
 462 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_signal_uperf_percpu.tap], [chmod +x tests/regression/rcutorture_urcu_signal_uperf_percpu.tap])
 463 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_signal_uperf_perthread.tap], [chmod +x tests/regression/rcutorture_urcu_signal_uperf_perthread.tap])
 464
 465
 466 AC_OUTPUT
 467
 468 #
 469 # Mini-report on what will be built.
 470 #
 471
 472 PPRINT_INIT
 473 PPRINT_SET_INDENT(1)
 474 PPRINT_SET_TS(38)
 475
 476 AS_ECHO
 477 AS_ECHO("${PPRINT_COLOR_BLDBLU}Userspace-RCU $PACKAGE_VERSION${PPRINT_COLOR_RST}")
 478 AS_ECHO
 479
 480 PPRINT_SUBTITLE([Features])
 481
 482 PPRINT_PROP_STRING([Target architecture], $host_cpu)
 483
 484 # SMP support enabled/disabled
 485 test "x$def_smp_support" = "xyes" && value=1 || value=0
 486 PPRINT_PROP_BOOL([SMP support], $value)
 487
 488 # Memory fence support available
 489 test "x$config_rcu_have_fence" = "xyes" && value=1 || value=0
 490 PPRINT_PROP_BOOL([Memory fence instructions], $value)
 491
 492 # Futex support available
 493 test "x$compat_futex_test" = "x0" && value=1 || value=0
 494 PPRINT_PROP_BOOL([Futex support], $value)
 495
 496 # TLS
 497 test "x$def_compiler_tls" = "xyes" && value="compiler TLS" || value="pthread_getspecific()"
 498 PPRINT_PROP_STRING([Thread Local Storage (TLS)], [$value])
 499
 500 # clock_gettime() available
 501 test "x$config_rcu_have_clock_gettime" = "xyes" && value=1 || value=0
 502 PPRINT_PROP_BOOL([clock_gettime()], $value)
 503
 504 # Require membarrier
 505 test "x$def_sys_membarrier_fallback" != "xyes" && value=1 || value=0
 506 PPRINT_PROP_BOOL([Require membarrier], $value)
 507
 508 # RCU debug enabled/disabled
 509 test "x$enable_rcu_debug" = "xyes" && value=1 || value=0
 510 PPRINT_PROP_BOOL([Internal debugging], $value)
 511
 512 # rculfhash iterator debug enabled/disabled
 513 test "x$enable_cds_lfht_iter_debug" = "xyes" && value=1 || value=0
 514 PPRINT_PROP_BOOL([Lock-free hash table iterator debugging], $value)
 515
 516 PPRINT_PROP_BOOL([Multi-flavor support], 1)
 517
 518 report_bindir="`eval eval echo $bindir`"
 519 report_libdir="`eval eval echo $libdir`"
 520
 521 # Print the bindir and libdir this `make install' will install into.
 522 AS_ECHO
 523 PPRINT_SUBTITLE([Install directories])
 524 PPRINT_PROP_STRING([Binaries], [$report_bindir])
 525 PPRINT_PROP_STRING([Libraries], [$report_libdir])
 526