configure.ac

   1 AC_PREREQ(2.59)
   2 AC_INIT([userspace-rcu],[0.12.0],[mathieu dot desnoyers at efficios dot com], [], [http://liburcu.org/])
   3
   4 # Following the numbering scheme proposed by libtool for the library version
   5 # http://www.gnu.org/software/libtool/manual/html_node/Updating-version-info.html
   6 AC_SUBST([URCU_LIBRARY_VERSION], [7:0:1])
   7
   8 AC_CONFIG_HEADERS([include/config.h include/urcu/config.h])
   9 AC_CONFIG_AUX_DIR([config])
  10 AC_CONFIG_MACRO_DIR([m4])
  11
  12 AC_CANONICAL_TARGET
  13 AC_CANONICAL_HOST
  14
  15 AM_INIT_AUTOMAKE([1.12 foreign dist-bzip2 no-dist-gzip nostdinc])
  16 AM_MAINTAINER_MODE([enable])
  17
  18 # Enable silent rules if available (Introduced in AM 1.11)
  19 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  20
  21 AC_REQUIRE_AUX_FILE([tap-driver.sh])
  22
  23 AH_TEMPLATE([CONFIG_RCU_SMP], [Enable SMP support. With SMP support enabled, uniprocessors are also supported. With SMP support disabled, UP systems work fine, but the behavior of SMP systems is undefined.])
  24 AH_TEMPLATE([CONFIG_RCU_HAVE_FUTEX], [Defined when on a system with futex support.])
  25 AH_TEMPLATE([CONFIG_RCU_ARM_HAVE_DMB], [Use the dmb instruction if available for use on ARM.])
  26 AH_TEMPLATE([CONFIG_RCU_TLS], [TLS provided by the compiler.])
  27 AH_TEMPLATE([CONFIG_RCU_HAVE_CLOCK_GETTIME], [clock_gettime() is detected.])
  28 AH_TEMPLATE([CONFIG_RCU_FORCE_SYS_MEMBARRIER], [Require the operating system to support the membarrier system call for default and bulletproof flavors.])
  29 AH_TEMPLATE([CONFIG_RCU_DEBUG], [Enable internal debugging self-checks. Introduces a performance penalty.])
  30 AH_TEMPLATE([CONFIG_CDS_LFHT_ITER_DEBUG], [Enable extra debugging checks for lock-free hash table iterator traversal. Alters the rculfhash ABI. Make sure to compile both library and application with matching configuration.])
  31
  32 # Allow requiring the operating system to support the membarrier system
  33 # call. Applies to default and bulletproof flavors.
  34 AC_ARG_ENABLE([sys-membarrier-fallback],
  35         AS_HELP_STRING([--disable-sys-membarrier-fallback], [Abort if sys-membarrier is needed but not available rather than using a fallback.]),
  36         [def_sys_membarrier_fallback=$enableval],
  37         [def_sys_membarrier_fallback="yes"])
  38 AS_IF([test "x$def_sys_membarrier_fallback" != "xyes"], [AC_DEFINE([CONFIG_RCU_FORCE_SYS_MEMBARRIER], [1])])
  39
  40 # Allow overriding storage used for TLS variables.
  41 AC_ARG_ENABLE([compiler-tls],
  42         AS_HELP_STRING([--disable-compiler-tls], [Use pthread_getspecific() to emulate Thread Local Storage (TLS) variables.]),
  43         [def_compiler_tls=$enableval],
  44         [def_compiler_tls="yes"])
  45
  46 # Checks for C compiler
  47 AC_USE_SYSTEM_EXTENSIONS
  48 AC_PROG_CC
  49 AC_PROG_CC_STDC
  50
  51 AS_IF([test "x$def_compiler_tls" = "xyes"], AC_DEFINE([CONFIG_RCU_TLS], [1]), [:])
  52
  53 # Checks for programs.
  54 AC_PROG_AWK
  55 AC_PROG_MAKE_SET
  56 AC_CHECK_PROGS(NPROC, [nproc gnproc])
  57 AC_CHECK_PROGS(GETCONF, [getconf])
  58 AS_IF([test "x$NPROC" != "x"],
  59         [NPROC_CMD=$NPROC],
  60         [AS_IF([test "x$GETCONF" != "x"],
  61                 [NPROC_CMD="$GETCONF _NPROCESSORS_ONLN"],
  62                 [NPROC_CMD="echo 1"]
  63         )]
  64 )
  65 AC_SUBST([NPROC_CMD], [$NPROC_CMD])
  66
  67 LT_INIT
  68
  69 # Checks for typedefs, structures, and compiler characteristics.
  70 AC_C_INLINE
  71 AC_TYPE_PID_T
  72 AC_TYPE_SIZE_T
  73 AC_TYPE_SSIZE_T
  74 AC_TYPE_UINT16_T
  75 AC_TYPE_INT32_T
  76 AC_TYPE_UINT32_T
  77 AC_TYPE_UINT64_T
  78 AC_TYPE_UINT8_T
  79
  80 AX_C___ATTRIBUTE__
  81 AS_IF([test "x$ax_cv___attribute__" = "xyes"],
  82         [:],
  83         [AC_MSG_ERROR([The compiler does not support __attribute__ extensions])])
  84
  85 AX_PTHREAD(,[AC_MSG_ERROR([Could not configure pthreads support])])
  86
  87 AM_CFLAGS="$AM_CFLAGS $PTHREAD_CFLAGS"
  88
  89 # Checks for library functions.
  90 AC_FUNC_MMAP
  91 AC_FUNC_FORK
  92 AC_CHECK_FUNCS([ \
  93         atexit \
  94         getcpuid \
  95         gettid \
  96         gettimeofday \
  97         memeset \
  98         memset \
  99         munmap \
 100         rand_r \
 101         sched_getcpu \
 102         strerror \
 103         strtoul \
 104         sysconf \
 105 ])
 106
 107 # AC_FUNC_MALLOC causes problems when cross-compiling.
 108 #AC_FUNC_MALLOC
 109
 110 # Check for headers
 111 AC_HEADER_STDBOOL
 112 AC_CHECK_HEADERS([ \
 113         limits.h \
 114         stddef.h \
 115         sys/param.h \
 116         sys/time.h \
 117 ])
 118
 119 AS_CASE([$host],[*-cygwin*],
 120         [AM_CONDITIONAL(USE_CYGWIN, true)],
 121         [AM_CONDITIONAL(USE_CYGWIN, false)]
 122 )
 123
 124 AS_IF([test "$host_cpu" = "armv7l"],[
 125         AM_CFLAGS="$AM_CFLAGS -mcpu=cortex-a9 -mtune=cortex-a9 -O1"
 126 ])
 127
 128 # ARM-specific checks
 129 AS_CASE([$host_cpu], [arm*], [
 130         AC_MSG_CHECKING([for dmb instruction])
 131         AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 132                                 int main()
 133                                 {
 134                                         asm volatile("dmb":::"memory");
 135                                         return 0;
 136                                 }
 137                 ]])
 138         ],[
 139                 AC_MSG_RESULT([yes])
 140                 AC_DEFINE([CONFIG_RCU_ARM_HAVE_DMB], [1])
 141         ],[
 142                 AC_MSG_RESULT([no])
 143         ])
 144 ])
 145
 146 # Check if sys_futex() is available
 147 AC_MSG_CHECKING([for sys_futex()])
 148 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 149                 #include <sys/syscall.h>
 150                 #ifndef __NR_futex
 151                 #error "futexes not available"
 152                 #endif
 153         ]])
 154 ],[
 155         AC_MSG_RESULT([yes])
 156         AC_DEFINE([CONFIG_RCU_HAVE_FUTEX], [1])
 157         compat_futex_test=0
 158 ],[
 159         AC_MSG_RESULT([no])
 160         compat_futex_test=1
 161 ])
 162
 163 # Search for clock_gettime
 164 AC_SEARCH_LIBS([clock_gettime], [rt], [
 165         AC_DEFINE([CONFIG_RCU_HAVE_CLOCK_GETTIME], [1])
 166         config_rcu_have_clock_gettime=yes
 167 ], [])
 168
 169 AM_CONDITIONAL([COMPAT_FUTEX], [test "x$compat_futex_test" = "x1"])
 170 AM_CONDITIONAL([NO_SHARED], [test "x$enable_shared" = "xno"])
 171
 172 # smp-support configure option
 173 AC_ARG_ENABLE([smp-support],
 174         AS_HELP_STRING([--disable-smp-support], [Disable SMP support. Warning: only use this on uniprocessor systems. [default=enabled]]),
 175         [def_smp_support=$enableval],
 176         [def_smp_support="yes"])
 177 AS_IF([test "x$def_smp_support" = "xyes"], [AC_DEFINE([CONFIG_RCU_SMP], [1])])
 178
 179 # RCU debugging option
 180 AC_ARG_ENABLE([rcu-debug],
 181       AS_HELP_STRING([--enable-rcu-debug], [Enable internal debugging
 182                       self-checks. Introduces a performance penalty.]))
 183 AS_IF([test "x$enable_rcu_debug" = "xyes"], [
 184        AC_DEFINE([CONFIG_RCU_DEBUG], [1])
 185 ])
 186
 187 # rculfhash iterator debugging
 188 AC_ARG_ENABLE([cds-lfht-iter-debug],
 189       AS_HELP_STRING([--enable-cds-lfht-iter-debug], [Enable extra debugging checks for lock-free hash table iterator traversal. Alters the rculfhash ABI. Make sure to compile both library and application with matching configuration.]))
 190 AS_IF([test "x$enable_cds_lfht_iter_debug" = "xyes"], [
 191        AC_DEFINE([CONFIG_CDS_LFHT_ITER_DEBUG], [1])
 192 ])
 193
 194 # From the sched_setaffinity(2)'s man page:
 195 # ~~~~
 196 # The CPU affinity system calls were introduced in Linux kernel 2.5.8.
 197 # The library interfaces were introduced in glibc 2.3.  Initially, the
 198 # glibc interfaces included a cpusetsize argument.  In glibc 2.3.3,
 199 # the cpuset size argument was removed, but this argument was
 200 # restored in glibc 2.3.4.
 201 # ~~~~
 202
 203 # In addition to that, some vendors ported the system call to 2.4
 204 # kernels.
 205
 206 # Furthermore, when the function first appeared, the MASK argument was
 207 # an unsigned long pointer, while later it was made into a cpu_set_t
 208 # pointer.  Systems that have the cpu_set_t version also should have
 209 # the CPU_ZERO, CPU_SET, etc. macros.
 210
 211 # All this mess means we have to cater for at least 3 different
 212 # sched_setaffinity prototypes:
 213
 214 # ~~~~
 215 #  int sched_setaffinity (pid_t pid, unsigned int len, unsigned long *mask);
 216 #  int sched_setaffinity (pid_t __pid, size_t __cpusetsize, const cpu_set_t *__cpuset);
 217 #  int sched_setaffinity (pid_t __pid, const cpu_set_t *__mask);
 218 # ~~~~
 219
 220 AC_CHECK_TYPES([cpu_set_t],
 221         [have_cpu_set_t="yes"],
 222         [have_cpu_set_t="no"],
 223         [#include <sched.h>])
 224
 225 # Confirm that we have CPU_ZERO, and it actually works.
 226 AC_MSG_CHECKING([whether CPU_ZERO works])
 227 AH_TEMPLATE([HAVE_CPU_ZERO], [Defined to 1 if we have CPU_ZERO and it works])
 228 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 229                 #include <sched.h>
 230                 int main()
 231                 {
 232                         cpu_set_t foo; CPU_ZERO(&foo);
 233                         return 0;
 234                 }
 235         ]])
 236 ],[
 237         AC_DEFINE(HAVE_CPU_ZERO, 1)
 238         AC_MSG_RESULT([yes])
 239 ],[
 240         AC_MSG_RESULT([no])
 241 ])
 242
 243 # Confirm that we have CPU_SET, and it actually works.
 244 AC_MSG_CHECKING([whether CPU_SET works])
 245 AH_TEMPLATE([HAVE_CPU_SET], [Defined to 1 if we have CPU_SET and it works])
 246 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 247                 #include <sched.h>
 248                 int main()
 249                 {
 250                         cpu_set_t foo; CPU_SET(0, &foo);
 251                         return 0;
 252                 }
 253         ]])
 254 ],[
 255         AC_DEFINE(HAVE_CPU_SET, 1)
 256         AC_MSG_RESULT([yes])
 257 ],[
 258         AC_MSG_RESULT([no])
 259 ])
 260
 261 # First check if the function is available at all.
 262 AC_CHECK_FUNCS([sched_setaffinity],[
 263         # Okay, we have it.  Check if also have cpu_set_t.  If we don't,
 264         # then we have the first version using unsigned long, and no
 265         # CPU_ZERO, etc. macros.  If we do have cpu_set_t, we may have the
 266         # version with 2 or 3 arguments.  In that case, CPU_ZERO, etc.,
 267         # should also be present, but we confirm nonetheless.
 268
 269         AS_IF([test "x$have_cpu_set_t" = "xyes"], [
 270                 # We do have it.
 271                 # Check how many arguments does sched_setaffinity take.
 272                 # Should be 3 or 2.
 273                 AC_MSG_CHECKING([how many arguments sched_setaffinity takes])
 274                 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 275                                 #include <sched.h>
 276                                 int main()
 277                                 {
 278                                         cpu_set_t foo;
 279                                         sched_setaffinity(0, sizeof (foo), &foo);
 280                                         return 0;
 281                                 }
 282                         ]])
 283                 ],
 284                 [sched_set_affinity_args=3],
 285                 [sched_set_affinity_args=2])
 286                 AC_DEFINE_UNQUOTED(SCHED_SETAFFINITY_ARGS,
 287                         $sched_set_affinity_args,
 288                         [Defined to sched_setaffinity's number of arguments.])
 289                 AC_MSG_RESULT([$sched_set_affinity_args])
 290         ],[
 291                 # No cpu_set_t, always 3 args.
 292                 AC_DEFINE(SCHED_SETAFFINITY_ARGS, 3)
 293         ])
 294 ])
 295
 296 AM_CPPFLAGS="-include config.h"
 297 AC_SUBST(AM_CPPFLAGS)
 298
 299 AM_CFLAGS="-Wall -Wextra -Wno-unused-parameter $AM_CFLAGS"
 300 AC_SUBST(AM_CFLAGS)
 301
 302 AC_CONFIG_FILES([
 303         Makefile
 304         doc/Makefile
 305         doc/examples/Makefile
 306         include/Makefile
 307         src/Makefile
 308         tests/Makefile
 309         tests/common/Makefile
 310         tests/unit/Makefile
 311         tests/benchmark/Makefile
 312         tests/regression/Makefile
 313         tests/utils/Makefile
 314         src/liburcu.pc
 315         src/liburcu-bp.pc
 316         src/liburcu-cds.pc
 317         src/liburcu-qsbr.pc
 318         src/liburcu-mb.pc
 319         src/liburcu-signal.pc
 320 ])
 321
 322 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_bp_perf_global.tap], [chmod +x tests/regression/rcutorture_urcu_bp_perf_global.tap])
 323 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_bp_perf_percpu.tap], [chmod +x tests/regression/rcutorture_urcu_bp_perf_percpu.tap])
 324 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_bp_perf_perthread.tap], [chmod +x tests/regression/rcutorture_urcu_bp_perf_perthread.tap])
 325 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_bp_rperf_global.tap], [chmod +x tests/regression/rcutorture_urcu_bp_rperf_global.tap])
 326 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_bp_rperf_percpu.tap], [chmod +x tests/regression/rcutorture_urcu_bp_rperf_percpu.tap])
 327 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_bp_rperf_perthread.tap], [chmod +x tests/regression/rcutorture_urcu_bp_rperf_perthread.tap])
 328 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_bp_stress_global.tap], [chmod +x tests/regression/rcutorture_urcu_bp_stress_global.tap])
 329 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_bp_stress_percpu.tap], [chmod +x tests/regression/rcutorture_urcu_bp_stress_percpu.tap])
 330 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_bp_stress_perthread.tap], [chmod +x tests/regression/rcutorture_urcu_bp_stress_perthread.tap])
 331 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_bp_uperf_global.tap], [chmod +x tests/regression/rcutorture_urcu_bp_uperf_global.tap])
 332 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_bp_uperf_percpu.tap], [chmod +x tests/regression/rcutorture_urcu_bp_uperf_percpu.tap])
 333 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_bp_uperf_perthread.tap], [chmod +x tests/regression/rcutorture_urcu_bp_uperf_perthread.tap])
 334 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_mb_perf_global.tap], [chmod +x tests/regression/rcutorture_urcu_mb_perf_global.tap])
 335 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_mb_perf_percpu.tap], [chmod +x tests/regression/rcutorture_urcu_mb_perf_percpu.tap])
 336 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_mb_perf_perthread.tap], [chmod +x tests/regression/rcutorture_urcu_mb_perf_perthread.tap])
 337 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_mb_rperf_global.tap], [chmod +x tests/regression/rcutorture_urcu_mb_rperf_global.tap])
 338 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_mb_rperf_percpu.tap], [chmod +x tests/regression/rcutorture_urcu_mb_rperf_percpu.tap])
 339 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_mb_rperf_perthread.tap], [chmod +x tests/regression/rcutorture_urcu_mb_rperf_perthread.tap])
 340 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_mb_stress_global.tap], [chmod +x tests/regression/rcutorture_urcu_mb_stress_global.tap])
 341 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_mb_stress_percpu.tap], [chmod +x tests/regression/rcutorture_urcu_mb_stress_percpu.tap])
 342 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_mb_stress_perthread.tap], [chmod +x tests/regression/rcutorture_urcu_mb_stress_perthread.tap])
 343 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_mb_uperf_global.tap], [chmod +x tests/regression/rcutorture_urcu_mb_uperf_global.tap])
 344 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_mb_uperf_percpu.tap], [chmod +x tests/regression/rcutorture_urcu_mb_uperf_percpu.tap])
 345 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_mb_uperf_perthread.tap], [chmod +x tests/regression/rcutorture_urcu_mb_uperf_perthread.tap])
 346 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_membarrier_perf_global.tap], [chmod +x tests/regression/rcutorture_urcu_membarrier_perf_global.tap])
 347 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_membarrier_perf_percpu.tap], [chmod +x tests/regression/rcutorture_urcu_membarrier_perf_percpu.tap])
 348 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_membarrier_perf_perthread.tap], [chmod +x tests/regression/rcutorture_urcu_membarrier_perf_perthread.tap])
 349 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_membarrier_rperf_global.tap], [chmod +x tests/regression/rcutorture_urcu_membarrier_rperf_global.tap])
 350 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_membarrier_rperf_percpu.tap], [chmod +x tests/regression/rcutorture_urcu_membarrier_rperf_percpu.tap])
 351 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_membarrier_rperf_perthread.tap], [chmod +x tests/regression/rcutorture_urcu_membarrier_rperf_perthread.tap])
 352 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_membarrier_stress_global.tap], [chmod +x tests/regression/rcutorture_urcu_membarrier_stress_global.tap])
 353 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_membarrier_stress_percpu.tap], [chmod +x tests/regression/rcutorture_urcu_membarrier_stress_percpu.tap])
 354 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_membarrier_stress_perthread.tap], [chmod +x tests/regression/rcutorture_urcu_membarrier_stress_perthread.tap])
 355 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_membarrier_uperf_global.tap], [chmod +x tests/regression/rcutorture_urcu_membarrier_uperf_global.tap])
 356 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_membarrier_uperf_percpu.tap], [chmod +x tests/regression/rcutorture_urcu_membarrier_uperf_percpu.tap])
 357 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_membarrier_uperf_perthread.tap], [chmod +x tests/regression/rcutorture_urcu_membarrier_uperf_perthread.tap])
 358 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_qsbr_perf_global.tap], [chmod +x tests/regression/rcutorture_urcu_qsbr_perf_global.tap])
 359 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_qsbr_perf_percpu.tap], [chmod +x tests/regression/rcutorture_urcu_qsbr_perf_percpu.tap])
 360 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_qsbr_perf_perthread.tap], [chmod +x tests/regression/rcutorture_urcu_qsbr_perf_perthread.tap])
 361 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_qsbr_rperf_global.tap], [chmod +x tests/regression/rcutorture_urcu_qsbr_rperf_global.tap])
 362 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_qsbr_rperf_percpu.tap], [chmod +x tests/regression/rcutorture_urcu_qsbr_rperf_percpu.tap])
 363 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_qsbr_rperf_perthread.tap], [chmod +x tests/regression/rcutorture_urcu_qsbr_rperf_perthread.tap])
 364 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_qsbr_stress_global.tap], [chmod +x tests/regression/rcutorture_urcu_qsbr_stress_global.tap])
 365 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_qsbr_stress_percpu.tap], [chmod +x tests/regression/rcutorture_urcu_qsbr_stress_percpu.tap])
 366 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_qsbr_stress_perthread.tap], [chmod +x tests/regression/rcutorture_urcu_qsbr_stress_perthread.tap])
 367 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_qsbr_uperf_global.tap], [chmod +x tests/regression/rcutorture_urcu_qsbr_uperf_global.tap])
 368 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_qsbr_uperf_percpu.tap], [chmod +x tests/regression/rcutorture_urcu_qsbr_uperf_percpu.tap])
 369 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_qsbr_uperf_perthread.tap], [chmod +x tests/regression/rcutorture_urcu_qsbr_uperf_perthread.tap])
 370 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_signal_perf_global.tap], [chmod +x tests/regression/rcutorture_urcu_signal_perf_global.tap])
 371 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_signal_perf_percpu.tap], [chmod +x tests/regression/rcutorture_urcu_signal_perf_percpu.tap])
 372 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_signal_perf_perthread.tap], [chmod +x tests/regression/rcutorture_urcu_signal_perf_perthread.tap])
 373 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_signal_rperf_global.tap], [chmod +x tests/regression/rcutorture_urcu_signal_rperf_global.tap])
 374 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_signal_rperf_percpu.tap], [chmod +x tests/regression/rcutorture_urcu_signal_rperf_percpu.tap])
 375 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_signal_rperf_perthread.tap], [chmod +x tests/regression/rcutorture_urcu_signal_rperf_perthread.tap])
 376 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_signal_stress_global.tap], [chmod +x tests/regression/rcutorture_urcu_signal_stress_global.tap])
 377 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_signal_stress_percpu.tap], [chmod +x tests/regression/rcutorture_urcu_signal_stress_percpu.tap])
 378 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_signal_stress_perthread.tap], [chmod +x tests/regression/rcutorture_urcu_signal_stress_perthread.tap])
 379 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_signal_uperf_global.tap], [chmod +x tests/regression/rcutorture_urcu_signal_uperf_global.tap])
 380 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_signal_uperf_percpu.tap], [chmod +x tests/regression/rcutorture_urcu_signal_uperf_percpu.tap])
 381 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_signal_uperf_perthread.tap], [chmod +x tests/regression/rcutorture_urcu_signal_uperf_perthread.tap])
 382
 383
 384 AC_OUTPUT
 385
 386 #
 387 # Mini-report on what will be built.
 388 #
 389
 390 PPRINT_INIT
 391 PPRINT_SET_INDENT(1)
 392 PPRINT_SET_TS(38)
 393
 394 AS_ECHO
 395 AS_ECHO("${PPRINT_COLOR_BLDBLU}Userspace-RCU $PACKAGE_VERSION${PPRINT_COLOR_RST}")
 396 AS_ECHO
 397
 398 PPRINT_SUBTITLE([Features])
 399
 400 PPRINT_PROP_STRING([Target architecture], $host_cpu)
 401
 402 # SMP support enabled/disabled
 403 test "x$def_smp_support" = "xyes" && value=1 || value=0
 404 PPRINT_PROP_BOOL([SMP support], $value)
 405
 406 # Futex support available
 407 test "x$compat_futex_test" = "x0" && value=1 || value=0
 408 PPRINT_PROP_BOOL([Futex support], $value)
 409
 410 # TLS
 411 test "x$def_compiler_tls" = "xyes" && value="compiler TLS" || value="pthread_getspecific()"
 412 PPRINT_PROP_STRING([Thread Local Storage (TLS)], [$value])
 413
 414 # clock_gettime() available
 415 test "x$config_rcu_have_clock_gettime" = "xyes" && value=1 || value=0
 416 PPRINT_PROP_BOOL([clock_gettime()], $value)
 417
 418 # Require membarrier
 419 test "x$def_sys_membarrier_fallback" != "xyes" && value=1 || value=0
 420 PPRINT_PROP_BOOL([Require membarrier], $value)
 421
 422 # RCU debug enabled/disabled
 423 test "x$enable_rcu_debug" = "xyes" && value=1 || value=0
 424 PPRINT_PROP_BOOL([Internal debugging], $value)
 425
 426 # rculfhash iterator debug enabled/disabled
 427 test "x$enable_cds_lfht_iter_debug" = "xyes" && value=1 || value=0
 428 PPRINT_PROP_BOOL([Lock-free hash table iterator debugging], $value)
 429
 430 PPRINT_PROP_BOOL([Multi-flavor support], 1)
 431
 432 report_bindir="`eval eval echo $bindir`"
 433 report_libdir="`eval eval echo $libdir`"
 434
 435 # Print the bindir and libdir this `make install' will install into.
 436 AS_ECHO
 437 PPRINT_SUBTITLE([Install directories])
 438 PPRINT_PROP_STRING([Binaries], [$report_bindir])
 439 PPRINT_PROP_STRING([Libraries], [$report_libdir])
 440