configure.ac

   1 dnl Version infos
   2 m4_define([V_MAJOR], [2])
   3 m4_define([V_MINOR], [10])
   4 m4_define([V_PATCH], [0])
   5 m4_define([V_EXTRA], [rc1])
   6 m4_define([V_NAME], [[KeKriek]])
   7 m4_define([V_DESC], [[From Brasserie Dunham, a sour mashed golden wheat ale fermented with local sour cherries from Tougas orchards. Fresh sweet cherry notes with some tartness, lively carbonation with a dry finish.]])
   8
   9 m4_define([V_STRING], [V_MAJOR.V_MINOR.V_PATCH])
  10 m4_ifdef([V_EXTRA], [m4_append([V_STRING], [-V_EXTRA])])
  11
  12 AC_PREREQ(2.59)
  13 AC_INIT([lttng-ust], V_STRING, [mathieu dot desnoyers at efficios dot com], [], [https://lttng.org])
  14
  15 dnl Substitute minor/major/patchlevel version numbers
  16 AC_SUBST([MAJOR_VERSION], [V_MAJOR])
  17 AC_SUBST([MINOR_VERSION], [V_MINOR])
  18 AC_SUBST([PATCHLEVEL_VERSION], [V_PATCH])
  19
  20 # Following the numbering scheme proposed by libtool for the library version
  21 # http://www.gnu.org/software/libtool/manual/html_node/Updating-version-info.html
  22 # This is the library version of liblttng-ust.
  23 AC_SUBST([LTTNG_UST_LIBRARY_VERSION], [0:0:0])
  24 # note: remember to update tracepoint.h dlopen() to match this version
  25 # number. TODO: eventually automate by exporting the major number.
  26
  27 # This is the library version of liblttng-ust-ctl, used internally by
  28 # liblttng-ust, lttng-sessiond, and lttng-consumerd.
  29 AC_SUBST([LTTNG_UST_CTL_LIBRARY_VERSION], [4:0:0])
  30
  31 AC_CONFIG_HEADERS([config.h include/lttng/ust-config.h])
  32 AC_CONFIG_AUX_DIR([config])
  33 AC_CONFIG_MACRO_DIR([m4])
  34 AC_CONFIG_SRCDIR([include/lttng/tracepoint.h])
  35
  36 AC_CANONICAL_TARGET
  37 AC_CANONICAL_HOST
  38
  39 AM_INIT_AUTOMAKE([1.9 foreign dist-bzip2 no-dist-gzip tar-ustar])
  40 AM_MAINTAINER_MODE([enable])
  41
  42 # Enable silent rules if available (Introduced in AM 1.11)
  43 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  44
  45 AC_REQUIRE_AUX_FILE([tap-driver.sh])
  46
  47 # Checks for C compiler
  48 AC_USE_SYSTEM_EXTENSIONS
  49 AC_SYS_LARGEFILE
  50 AC_PROG_CC
  51 AC_PROG_CC_STDC
  52 AC_PROG_CXX
  53 rw_PROG_CXX_WORKS
  54 AM_CONDITIONAL([CXX_WORKS], [test "x$rw_cv_prog_cxx_works" = "xyes"])
  55
  56 # Check if the compiler support weak symbols
  57 AX_SYS_WEAK_ALIAS
  58
  59 AS_IF([test "x${ax_cv_sys_weak_alias}" = "xno"], [
  60         AC_MSG_ERROR([Your platform doesn't support weak symbols.])
  61 ])
  62
  63 # Checks for programs.
  64 AC_PROG_SED
  65 AC_PROG_GREP
  66 AC_PROG_LN_S
  67 AC_PROG_MKDIR_P
  68 AC_PROG_MAKE_SET
  69 AC_CHECK_PROG([HAVE_CMAKE], [cmake], ["yes"])
  70 AM_CONDITIONAL([HAVE_CMAKE], [test "x$HAVE_CMAKE" = "xyes"])
  71
  72 # libtool link_all_deplibs fixup. See http://bugs.lttng.org/issues/321.
  73 AC_ARG_ENABLE([libtool-linkdep-fixup], [
  74 AS_HELP_STRING([--disable-libtool-linkdep-fixup], [disable the libtool fixup for linking all dependent libraries (link_all_deplibs)])
  75 ], [
  76         libtool_fixup=$enableval
  77 ], [
  78         libtool_fixup=yes
  79 ])
  80
  81 AS_IF([test "x$libtool_fixup" = "xyes"], [
  82         libtool_m4="$srcdir/m4/libtool.m4"
  83         libtool_flag_pattern=".*link_all_deplibs\s*,\s*\$1\s*)"
  84         AC_MSG_CHECKING([for occurence(s) of link_all_deplibs = no in $libtool_m4])
  85         libtool_flag_pattern_count=$(grep -c "$libtool_flag_pattern\s*=\s*no" $libtool_m4)
  86
  87         AS_IF([test $libtool_flag_pattern_count -ne 0], [
  88         AC_MSG_RESULT([$libtool_flag_pattern_count])
  89         AC_MSG_WARN([the detected libtool will not link all dependencies, forcing link_all_deplibs = unknown])
  90                 $SED -i "s/\($libtool_flag_pattern\)\s*=\s*no/\1=unknown/g" $libtool_m4
  91         ], [
  92                 AC_MSG_RESULT([none])
  93         ])
  94 ])
  95 LT_INIT([disable-static])
  96
  97 AC_MSG_CHECKING([whether shared libraries are enabled])
  98 AS_IF([test "x$enable_shared" = "xyes"], [
  99         AC_MSG_RESULT([yes])
 100 ], [
 101         AC_MSG_RESULT([no])
 102         AC_MSG_ERROR([LTTng-UST requires shared libraries to be enabled])
 103 ])
 104
 105 # Checks for typedefs, structures, and compiler characteristics.
 106 AC_C_INLINE
 107 AC_TYPE_INT8_T
 108 AC_TYPE_INT16_T
 109 AC_TYPE_INT32_T
 110 AC_TYPE_INT64_T
 111 AC_TYPE_MODE_T
 112 AC_TYPE_OFF_T
 113 AC_TYPE_PID_T
 114 AC_TYPE_SIZE_T
 115 AC_TYPE_SSIZE_T
 116 AC_TYPE_UID_T
 117 AC_TYPE_UINT8_T
 118 AC_TYPE_UINT16_T
 119 AC_TYPE_UINT32_T
 120 AC_TYPE_UINT64_T
 121 AC_CHECK_TYPES([ptrdiff_t])
 122
 123 AX_C___ATTRIBUTE__
 124 AS_IF([test "x$ax_cv___attribute__" = "xyes"],
 125         [:],
 126         [AC_MSG_ERROR([The compiler does not support __attribute__ extensions])])
 127
 128 # Checks for library functions.
 129 AC_FUNC_CHOWN
 130 AC_FUNC_FORK
 131 AC_FUNC_MMAP
 132 AC_FUNC_REALLOC
 133 AC_FUNC_STRERROR_R
 134 AC_FUNC_STRNLEN
 135 AC_CHECK_FUNCS([ \
 136         atexit \
 137         clock_gettime \
 138         ftruncate \
 139         getpagesize \
 140         gettimeofday \
 141         localeconv \
 142         memchr \
 143         memmove \
 144         memset \
 145         mkdir \
 146         munmap \
 147         realpath \
 148         sched_getcpu \
 149         socket \
 150         strchr \
 151         strdup \
 152         strerror \
 153         strtol \
 154         sysconf \
 155 ])
 156
 157 # AC_FUNC_MALLOC causes problems when cross-compiling.
 158 #AC_FUNC_MALLOC
 159
 160 # Checks for header files.
 161 AC_HEADER_STDBOOL
 162 AC_CHECK_HEADERS([ \
 163         arpa/inet.h \
 164         fcntl.h \
 165         float.h \
 166         limits.h \
 167         locale.h \
 168         stddef.h \
 169         sys/socket.h \
 170         sys/time.h \
 171         wchar.h \
 172 ])
 173
 174 # Set architecture specific options
 175 AS_CASE([$host_cpu],
 176         [i[[3456]]86], [],
 177         [x86_64], [],
 178         [amd64], [],
 179         [powerpc], [],
 180         [ppc64], [],
 181         [ppc64le], [],
 182         [powerpc64], [],
 183         [powerpc64le], [],
 184         [s390], [NO_UNALIGNED_ACCESS=1],
 185         [s390x], [NO_UNALIGNED_ACCESS=1],
 186         [arm*], [
 187                 NO_UNALIGNED_ACCESS=1
 188                 NO_NUMA=1
 189                 ],
 190         [aarch64*], [NO_UNALIGNED_ACCESS=1],
 191         [mips*], [NO_UNALIGNED_ACCESS=1],
 192         [tile*], [NO_UNALIGNED_ACCESS=1],
 193         [
 194                 UNSUPPORTED_ARCH=1
 195                 NO_UNALIGNED_ACCESS=1
 196         ])
 197
 198 # Configuration options, which will be installed in the config.h
 199 AH_TEMPLATE([LTTNG_UST_HAVE_EFFICIENT_UNALIGNED_ACCESS], [Use efficient unaligned access.])
 200 AH_TEMPLATE([LTTNG_UST_HAVE_SDT_INTEGRATION], [SystemTap integration via sdt.h])
 201 AH_TEMPLATE([LTTNG_UST_HAVE_PERF_EVENT], [Perf event integration via perf_event.h])
 202
 203 # Checks for libraries.
 204 AC_CHECK_LIB([dl], [dlopen], [
 205         have_libdl=yes
 206         libdl_name=dl
 207 ], [
 208         #libdl not found, check for dlopen in libc.
 209         AC_CHECK_LIB([c], [dlopen], [
 210                 have_libc_dl=yes
 211                 libdl_name=c
 212         ], [
 213                 AC_MSG_ERROR([Cannot find dlopen in libdl nor libc. Use [LDFLAGS]=-Ldir to specify their location.])
 214         ])
 215 ])
 216
 217 # Check if libdl has dlmopen support.
 218 AH_TEMPLATE([HAVE_DLMOPEN], ["Define to 1 if dlmopen is available."])
 219 AC_CHECK_LIB([$libdl_name], [dlmopen],
 220         [AC_DEFINE([HAVE_DLMOPEN], [1])]
 221 )
 222
 223 AM_CONDITIONAL([LTTNG_UST_BUILD_WITH_LIBDL], [test "x$have_libdl" = "xyes"])
 224 AM_CONDITIONAL([LTTNG_UST_BUILD_WITH_LIBC_DL], [test "x$have_libc_dl" = "xyes"])
 225
 226 AC_CHECK_LIB([pthread], [pthread_create])
 227 AC_CHECK_LIB([pthread], [pthread_setname_np],
 228         AC_DEFINE([HAVE_PTHREAD_SETNAME_NP], [1], [Define to 1 if pthread_setname_np is available.]),
 229         AC_CHECK_LIB([pthread], [pthread_set_name_np],
 230                 AC_DEFINE([HAVE_PTHREAD_SET_NAME_NP], [1], [Define to 1 if pthread_set_name_np is available.]),
 231                 AC_MSG_RESULT([pthread setname/set_name not found.])))
 232
 233 # Check for dlfcn.h
 234 AC_CHECK_HEADER([dlfcn.h])
 235 AS_IF([test "x${ac_cv_header_dlfcn_h}" = "xyes"], [
 236         AC_CHECK_DECLS([RTLD_DI_LINKMAP], [], [], [
 237                 #define _GNU_SOURCE /* Required on Linux to get GNU extensions */
 238                 #include <dlfcn.h>
 239         ])
 240 ], [
 241         ac_cv_have_decl_RTLD_DI_LINKMAP="no"
 242 ])
 243
 244 AM_CONDITIONAL([HAVE_DLINFO], [test "x${ac_cv_have_decl_RTLD_DI_LINKMAP}" = "xyes"])
 245
 246 # URCU
 247
 248 # urcu - check if we just find the headers it out of the box.
 249 AC_CHECK_HEADERS([urcu-bp.h], [], [AC_MSG_ERROR([Cannot find [URCU] headers (urcu-bp.h). Use [CPPFLAGS]=-Idir to specify their location.
 250 This error can also occur when the liburcu package's configure script has not been run.])])
 251
 252 # urcu-cds - check that URCU Concurrent Data Structure lib is available to compilation
 253 # Part of Userspace RCU library 0.7.2 or better.
 254 AC_CHECK_LIB([urcu-cds], [_cds_lfht_new], [], [AC_MSG_ERROR([Cannot find
 255 liburcu-cds lib, part of Userspace RCU 0.7 or better. Use [LDFLAGS]=-Ldir to specify its location.])])
 256
 257 AC_MSG_CHECKING([caa_likely()])
 258 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 259         #include <urcu/compiler.h>
 260         void fct(void)
 261         {
 262                 if (caa_likely(1)) {
 263                 }
 264         }
 265 ]])], [
 266         AC_MSG_RESULT([yes])
 267 ], [
 268         AC_MSG_RESULT([no])
 269         AC_MSG_ERROR([Please upgrade your version of liburcu to 0.6.6 or better])
 270 ])
 271
 272 # urcu - check that URCU lib is available to compilation
 273 AC_CHECK_LIB([urcu-bp], [synchronize_rcu_bp], [], [AC_MSG_ERROR([Cannot find liburcu-bp lib. Use [LDFLAGS]=-Ldir to specify its location.])])
 274
 275 # urcu - check that URCU lib is at least version 0.6
 276 AC_CHECK_LIB([urcu-bp], [call_rcu_bp], [], [AC_MSG_ERROR([liburcu 0.6 or newer is needed, please update your version or use [LDFLAGS]=-Ldir to specify the right location.])])
 277
 278 # numa.h integration
 279 AS_IF([test "x$NO_NUMA" = "x1"],[
 280       AS_IF([test "x$enable_numa" = "x" ], [enable_numa=no])
 281 ])
 282
 283 AC_ARG_ENABLE([numa], [
 284 AS_HELP_STRING([--disable-numa], [disable NUMA support])
 285 ], [
 286         enable_numa=$enableval
 287 ], [
 288         enable_numa=yes
 289 ])
 290
 291 AS_IF([test "x$enable_numa" = "xyes"], [
 292         # numa - check that numa lib is available
 293         AC_CHECK_LIB([numa], [numa_available], [],
 294 [AC_MSG_ERROR([libnuma is not available. Please either install it (e.g. libnuma-dev) or use [LDFLAGS]=-Ldir to specify the right location, or use --disable-numa configure argument to disable NUMA support.])])
 295         have_libnuma=yes
 296 ])
 297 AM_CONDITIONAL([HAVE_LIBNUMA], [test "x$have_libnuma" = "xyes"])
 298
 299 # optional linux/perf_event.h
 300 AC_CHECK_HEADERS([linux/perf_event.h], [have_perf_event=yes], [])
 301
 302 # Perf event counters are supported on all architectures supported by
 303 # perf, using the read system call as fallback.
 304 AM_CONDITIONAL([HAVE_PERF_EVENT], [test "x$have_perf_event" = "xyes"])
 305
 306 AS_IF([test "x$have_perf_event" = "xyes"], [
 307         AC_DEFINE([LTTNG_UST_HAVE_PERF_EVENT], [1])
 308 ])
 309
 310 AS_IF([test "x$NO_UNALIGNED_ACCESS" = "x"], [
 311         AC_DEFINE([LTTNG_UST_HAVE_EFFICIENT_UNALIGNED_ACCESS], [1])
 312 ])
 313
 314 # Check for JNI header files if requested
 315 AC_ARG_ENABLE([jni-interface], [
 316 AS_HELP_STRING([--enable-jni-interface], [build JNI interface between C and Java. Needs Java include files [default=no]])
 317 ], [
 318         jni_interface=$enableval
 319 ], [
 320         jni_interface=no
 321 ])
 322
 323 AM_CONDITIONAL([BUILD_JNI_INTERFACE], [test "x$jni_interface" = "xyes"])
 324
 325
 326 AC_ARG_ENABLE([java-agent-jul], [
 327 AS_HELP_STRING([--enable-java-agent-jul], [build the LTTng UST Java agent with JUL support [default=no]])
 328 ], [
 329         java_agent_jul=$enableval
 330 ], [
 331         java_agent_jul=no
 332 ])
 333
 334 AC_ARG_ENABLE([java-agent-log4j], [
 335 AS_HELP_STRING([--enable-java-agent-log4j], [build the LTTng UST Java agent with Log4j support [default=no]])
 336 ], [
 337         java_agent_log4j=$enableval
 338 ], [
 339         java_agent_log4j=no
 340 ])
 341
 342 AC_ARG_ENABLE([java-agent-all], [
 343 AS_HELP_STRING([--enable-java-agent-all], [build the LTTng UST Java agent with all supported backends [default=no]])
 344 ], [
 345         java_agent_jul=$enableval
 346         java_agent_log4j=$enableval
 347 ], [:])
 348
 349 AM_CONDITIONAL([BUILD_JAVA_AGENT], [test "x$java_agent_jul" = "xyes" || test "x$java_agent_log4j" = "xyes"])
 350 AM_CONDITIONAL([BUILD_JAVA_AGENT_WITH_JUL], [test "x$java_agent_jul" = "xyes"])
 351 AM_CONDITIONAL([BUILD_JAVA_AGENT_WITH_LOG4J], [test "x$java_agent_log4j" = "xyes"])
 352
 353 AS_IF([test "x$jni_interface" = "xyes" || test "x$java_agent_jul" = "xyes" || test "x$java_agent_log4j" = "xyes"], [
 354         AX_JAVA_OPTIONS
 355         AX_PROG_JAVAC
 356         AX_PROG_JAVA
 357         AX_PROG_JAR
 358
 359         AX_JNI_INCLUDE_DIR
 360         for JNI_INCLUDE_DIR in $JNI_INCLUDE_DIRS
 361         do
 362                 JNI_CPPFLAGS="$JNI_CPPFLAGS -I$JNI_INCLUDE_DIR"
 363         done
 364
 365         saved_CPPFLAGS="$CPPFLAGS"
 366         CPPFLAGS="$CPPFLAGS $JNI_CPPFLAGS"
 367         AX_PROG_JAVAH
 368         CPPFLAGS="$saved_CPPFLAGS"
 369 ])
 370
 371 AS_IF([test "x$java_agent_log4j" = "xyes"], [
 372         AX_CHECK_CLASSPATH
 373         AX_CHECK_CLASS([org.apache.log4j.Logger])
 374         AS_IF([test "x$ac_cv_class_org_apache_log4j_Logger" = "xno"], [
 375                 AC_MSG_ERROR([The UST Java agent support for log4j was requested but the Log4j classes were not found. Please specify the location of the Log4j jar via the Java CLASSPATH e.g: export CLASSPATH="/path/to/log4j.jar"])
 376         ])
 377 ])
 378
 379 # Option to build the python agent
 380 AC_ARG_ENABLE([python-agent], [
 381 AS_HELP_STRING([--enable-python-agent], [build the LTTng UST Python agent [default=no]])
 382 ], [
 383         python_agent=$enableval
 384 ], [:])
 385 AM_CONDITIONAL([BUILD_PYTHON_AGENT], [test "x$python_agent" = "xyes"])
 386 AS_IF([test "x$python_agent" = "xyes"], [
 387         AM_PATH_PYTHON([2.7])
 388 ])
 389
 390 # sdt.h integration
 391 AC_ARG_WITH([sdt], [
 392 AS_HELP_STRING([--with-sdt], [provide SystemTap integration via sdt.h [default=no]])
 393 ], [
 394         with_sdt=$withval
 395 ], [
 396         with_sdt="no"
 397 ])
 398
 399 AS_IF([test "x$with_sdt" = "xyes"], [
 400         AC_MSG_CHECKING([STAP_PROBEV()])
 401         AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 402                 #define SDT_USE_VARIADIC
 403                 #include <sys/sdt.h>
 404                 void fct(void)
 405                 {
 406                         STAP_PROBEV(provider,name,1,2,3,4,5,6,7,8,9,10);
 407                 }
 408         ]])], [
 409                 AC_MSG_RESULT([yes])
 410                 AC_DEFINE([LTTNG_UST_HAVE_SDT_INTEGRATION], [1])
 411         ], [
 412                 AC_MSG_RESULT([no])
 413                 AC_MSG_ERROR([The sdt.h integration was requested but the STAP_PROBEV define cannot be used. Make sure it is installed, and up to date, or use CPPFLAGS=-I/path/ to specify a non-standard path to sys/sdt.h])
 414         ])
 415 ])
 416
 417 AC_ARG_WITH([lttng-system-rundir], [
 418 AS_HELP_STRING([--with-lttng-system-rundir], [Location of the system directory where LTTng-UST expects the system-wide lttng-sessiond runtime files. The default is "/var/run/lttng".]),
 419 ], [
 420         lttng_system_rundir="$withval"
 421 ], [
 422         lttng_system_rundir="/var/run/lttng"
 423 ])
 424 AC_DEFINE_UNQUOTED([LTTNG_SYSTEM_RUNDIR], ["$lttng_system_rundir"],
 425                 [LTTng system runtime directory])
 426
 427 AC_CHECK_PROG([BUILD_GEN_TP_EXAMPLES], [python], ["yes"])
 428 AM_CONDITIONAL([BUILD_GEN_TP_EXAMPLES], [test "x$BUILD_GEN_TP_EXAMPLES" = "xyes"])
 429
 430 # Enable building examples
 431 AC_ARG_ENABLE(
 432         examples,
 433         AS_HELP_STRING(
 434                 [--disable-examples],
 435                 [Do not build and install examples]
 436         ),
 437         [enable_examples=$enableval],
 438         [enable_examples=yes]
 439 )
 440
 441 AM_CONDITIONAL([ENABLE_EXAMPLES], [test "x$enable_examples" != "xno"])
 442
 443 # Set $IN_GIT_REPO if we're in the Git repository; the `bootstrap` file
 444 # is not distributed in tarballs.
 445 AS_IF([test -f "$srcdir/bootstrap"], [in_git_repo=yes], [in_git_repo=no])
 446 AM_CONDITIONAL([IN_GIT_REPO], [test "x$in_git_repo" = "xyes"])
 447
 448 # Enable building man pages (user's intention).
 449 AC_ARG_ENABLE(
 450         man-pages,
 451         AS_HELP_STRING(
 452                 [--disable-man-pages],
 453                 [Do not build and install man pages (already built in a distributed tarball)]
 454         ),
 455         [man_pages_opt=$enableval],
 456         [man_pages_opt=yes]
 457 )
 458
 459 # Check for asciidoc and xmlto if we enabled building the man pages.
 460 have_asciidoc_xmlto=no
 461 warn_prebuilt_man_pages=no
 462
 463 AS_IF([test "x$man_pages_opt" = "xyes"], [
 464         AC_PATH_PROG([ASCIIDOC], [asciidoc], [no])
 465         AC_PATH_PROG([XMLTO], [xmlto], [no])
 466
 467         AS_IF([test "x$ASCIIDOC" = "xno" || test "x$XMLTO" = "xno"], [
 468                 AS_IF([test "x$in_git_repo" = "xyes"], [
 469                         # This is an error because we're in the Git repo, which
 470                         # means the man pages are not already generated for us,
 471                         # thus asciidoc/xmlto are required because we were asked
 472                         # to build the man pages.
 473                         AC_MSG_ERROR([
 474 Both asciidoc and xmlto are needed to build the LTTng-UST man pages. Use
 475 --disable-man-pages to disable building the man pages, in which case
 476 they will not be installed.
 477                         ])
 478                 ], [
 479                         # Only warn here: since we're in the tarball, the man
 480                         # pages should already be generated at this point, thus
 481                         # asciidoc/xmlto are not strictly required.
 482                         warn_prebuilt_man_pages=yes
 483                 ])
 484         ], [
 485                 have_asciidoc_xmlto=yes
 486         ])
 487 ])
 488
 489 # Export man page build condition: build the man pages if the user
 490 # asked for it, and if the tools are available.
 491 AM_CONDITIONAL([MAN_PAGES_OPT], [test "x$man_pages_opt" != "xno"])
 492 AM_CONDITIONAL([HAVE_ASCIIDOC_XMLTO], [test "x$have_asciidoc_xmlto" = "xyes"])
 493
 494 # Default values
 495 AC_DEFUN([_AC_DEFINE_AND_SUBST], [
 496         AC_DEFINE_UNQUOTED([CONFIG_$1], [$2], [$1])
 497         $1="$2"
 498         AC_SUBST([$1])
 499 ])
 500
 501 _AC_DEFINE_AND_SUBST([LTTNG_UST_DEFAULT_CONSTRUCTOR_TIMEOUT_MS], [3000])
 502
 503 AM_CFLAGS="-Wall"
 504 AC_SUBST(AM_CFLAGS)
 505 AC_SUBST(JNI_CPPFLAGS)
 506
 507 AC_CONFIG_FILES([
 508         Makefile
 509         doc/Makefile
 510         doc/examples/Makefile
 511         doc/man/Makefile
 512         include/Makefile
 513         include/lttng/ust-version.h
 514         snprintf/Makefile
 515         libringbuffer/Makefile
 516         liblttng-ust-comm/Makefile
 517         liblttng-ust/Makefile
 518         liblttng-ust-ctl/Makefile
 519         liblttng-ust-fork/Makefile
 520         liblttng-ust-dl/Makefile
 521         liblttng-ust-fd/Makefile
 522         liblttng-ust-java/Makefile
 523         liblttng-ust-java-agent/Makefile
 524         liblttng-ust-java-agent/java/Makefile
 525         liblttng-ust-java-agent/java/lttng-ust-agent-all/Makefile
 526         liblttng-ust-java-agent/java/lttng-ust-agent-common/Makefile
 527         liblttng-ust-java-agent/java/lttng-ust-agent-jul/Makefile
 528         liblttng-ust-java-agent/java/lttng-ust-agent-log4j/Makefile
 529         liblttng-ust-java-agent/jni/Makefile
 530         liblttng-ust-java-agent/jni/common/Makefile
 531         liblttng-ust-java-agent/jni/jul/Makefile
 532         liblttng-ust-java-agent/jni/log4j/Makefile
 533         liblttng-ust-libc-wrapper/Makefile
 534         liblttng-ust-cyg-profile/Makefile
 535         liblttng-ust-python-agent/Makefile
 536         python-lttngust/Makefile
 537         python-lttngust/setup.py
 538         python-lttngust/lttngust/__init__.py
 539         tools/Makefile
 540         tests/Makefile
 541         tests/ctf-types/Makefile
 542         tests/hello/Makefile
 543         tests/hello.cxx/Makefile
 544         tests/same_line_tracepoint/Makefile
 545         tests/snprintf/Makefile
 546         tests/ust-elf/Makefile
 547         tests/benchmark/Makefile
 548         tests/utils/Makefile
 549         tests/test-app-ctx/Makefile
 550         tests/gcc-weak-hidden/Makefile
 551         lttng-ust.pc
 552 ])
 553
 554 # Create link for python agent for the VPATH guru.
 555 AC_CONFIG_LINKS([
 556         python-lttngust/lttngust/agent.py:python-lttngust/lttngust/agent.py
 557         python-lttngust/lttngust/cmd.py:python-lttngust/lttngust/cmd.py
 558         python-lttngust/lttngust/debug.py:python-lttngust/lttngust/debug.py
 559         python-lttngust/lttngust/loghandler.py:python-lttngust/lttngust/loghandler.py
 560 ])
 561
 562 AC_OUTPUT
 563
 564
 565 #
 566 # Mini-report on what will be built.
 567 #
 568
 569 PPRINT_INIT
 570 PPRINT_SET_INDENT(1)
 571 PPRINT_SET_TS(38)
 572
 573 AS_ECHO
 574 AS_ECHO("${PPRINT_COLOR_BLDBLU}LTTng-ust $PACKAGE_VERSION \"V_NAME\"$PPRINT_COLOR_RST")
 575 AS_ECHO
 576
 577 AS_ECHO("V_DESC")
 578
 579 AS_ECHO
 580 PPRINT_SUBTITLE([System])
 581
 582 PPRINT_PROP_STRING([Target architecture], $host_cpu)
 583
 584 test "x$NO_UNALIGNED_ACCESS" != "x1" && value=1 || value=0
 585 PPRINT_PROP_BOOL([Efficient unaligned memory access], $value)
 586
 587 AS_IF([test "x$UNSUPPORTED_ARCH" = "x1"],[
 588        PPRINT_WARN([Your architecture ($host_cpu) is unsupported, using safe default of no unaligned access.])
 589 ])
 590
 591 AS_ECHO
 592 PPRINT_SUBTITLE([Features])
 593 PPRINT_SET_INDENT(1)
 594
 595 test "x$with_sdt" = "xyes" && value=1 || value=0
 596 PPRINT_PROP_BOOL_CUSTOM([sdt.h integration], $value, [use --with-sdt])
 597
 598 test "x$java_agent_jul" = xyes && value=1 || value=0
 599 PPRINT_PROP_BOOL_CUSTOM([Java agent (JUL support)], $value, [use --enable-java-agent-jul])
 600
 601 test "x$java_agent_log4j" = xyes && value=1 || value=0
 602 PPRINT_PROP_BOOL_CUSTOM([Java agent (Log4j support)], $value, [use --enable-java-agent-log4j])
 603
 604 test "x$jni_interface" = xyes && value=1 || value=0
 605 PPRINT_PROP_BOOL_CUSTOM([JNI interface (JNI)], $value, [use --enable-jni-interface])
 606
 607 test "x$python_agent" = xyes && value=1 || value=0
 608 PPRINT_PROP_BOOL_CUSTOM([Python agent], $value, [use --enable-python-agent])
 609
 610 test "x$enable_numa" = xyes && value=1 || value=0
 611 PPRINT_PROP_BOOL([NUMA], $value)
 612
 613 AS_ECHO
 614 PPRINT_SET_INDENT(0)
 615
 616 test "x$enable_examples" = xyes && value=1 || value=0
 617 PPRINT_PROP_BOOL([Build and install examples], $value, $PPRINT_COLOR_SUBTITLE)
 618
 619 # man pages build enabled/disabled
 620 m4_pushdef([build_man_pages_msg], [Build and install man pages])
 621
 622 AS_IF([test "x$man_pages_opt" != "xno"], [
 623         AS_IF([test "x$in_git_repo" = "xyes"], [
 624                 PPRINT_PROP_BOOL([build_man_pages_msg], 1, $PPRINT_COLOR_SUBTITLE)
 625         ], [
 626                 AS_IF([test "x$have_asciidoc_xmlto" = "xyes"], [
 627                         PPRINT_PROP_BOOL([build_man_pages_msg], 1, $PPRINT_COLOR_SUBTITLE)
 628                 ], [
 629                         PPRINT_PROP_STRING([build_man_pages_msg],
 630                                 [${PPRINT_COLOR_BLDGRN}yes (already built)],
 631                                 $PPRINT_COLOR_SUBTITLE)
 632                 ])
 633         ])
 634 ], [
 635         PPRINT_PROP_BOOL([build_man_pages_msg], 0, $PPRINT_COLOR_SUBTITLE)
 636 ])
 637
 638 m4_popdef([build_man_pages_msg])
 639
 640 PPRINT_SET_INDENT(1)
 641
 642 report_bindir="`eval eval echo $bindir`"
 643 report_libdir="`eval eval echo $libdir`"
 644
 645 # Print the bindir and libdir this `make install' will install into.
 646 AS_ECHO
 647 PPRINT_SUBTITLE([Install directories])
 648 PPRINT_PROP_STRING([Binaries], [$report_bindir])
 649 PPRINT_PROP_STRING([Libraries], [$report_libdir])
 650
 651 AS_ECHO
 652 PPRINT_SUBTITLE([System directories])
 653
 654 PPRINT_PROP_STRING([lttng-sessiond rundir], [$lttng_system_rundir])
 655
 656 PPRINT_SET_INDENT(0)
 657
 658 AS_IF([test "x$warn_prebuilt_man_pages" = "xyes" ], [
 659         AS_ECHO
 660         PPRINT_WARN([Both asciidoc and xmlto are needed to build the LTTng-UST man pages.
 661
 662 Note that the man pages are already built in this distribution tarball,
 663 therefore asciidoc and xmlto are only needed if you intend to modify
 664 their sources.
 665
 666 Use --disable-man-pages to completely disable building and installing
 667 the man pages.])
 668 ])