configure.ac

   1 AC_PREREQ([2.64])
   2 AC_INIT([lttng-tools],[2.5.5],[jeremie.galarneau@efficios.com],[],[https://lttng.org])
   3 AC_CONFIG_AUX_DIR([config])
   4 AC_CANONICAL_TARGET
   5 AC_CANONICAL_HOST
   6 AC_CONFIG_MACRO_DIR([config])
   7 AM_INIT_AUTOMAKE([foreign dist-bzip2 no-dist-gzip])
   8 AM_MAINTAINER_MODE([enable])
   9 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  10
  11 # Compute minor/major/patchlevel version numbers
  12 AC_PROG_SED
  13 major_version=$(echo AC_PACKAGE_VERSION | sed 's/^\([[0-9]]\)*\.[[0-9]]*\.[[0-9]]*.*$/\1/')
  14 minor_version=$(echo AC_PACKAGE_VERSION | sed 's/^[[0-9]]*\.\([[0-9]]*\)\.[[0-9]]*.*$/\1/')
  15 patchlevel_version=$(echo AC_PACKAGE_VERSION | sed 's/^[[0-9]]*\.[[0-9]]*\.\([[0-9]]*\).*$/\1/')
  16 AC_SUBST([MAJOR_VERSION], [$major_version])
  17 AC_SUBST([MINOR_VERSION], [$minor_version])
  18 AC_SUBST([PATCHLEVEL_VERSION], [$patchlevel_version])
  19 AC_DEFINE_UNQUOTED([VERSION_MAJOR], $major_version, [LTTng-Tools major version number])
  20 AC_DEFINE_UNQUOTED([VERSION_MINOR], $minor_version, [LTTng-Tools minor version number])
  21 AC_DEFINE_UNQUOTED([VERSION_PATCHLEVEL], $patchlevel_version, [LTTng-Tools patchlevel version number])
  22
  23 version_name="Fumisterie"
  24 version_description="The Fumisterie is a beer whose style is at the confluence of English and German ales. On the palate, it is full-bodied, malty and slightly caramelized. The organic hemp seeds incorporated during the brewing gives it a unique and original taste. The hop flavour comes through delicately in the after taste."
  25
  26 AC_DEFINE_UNQUOTED([VERSION_NAME], ["$version_name"], "")
  27 AC_DEFINE_UNQUOTED([VERSION_DESCRIPTION], ["$version_description"], "")
  28
  29 AC_CONFIG_HEADERS([include/config.h])
  30
  31 AC_PROG_GREP
  32 # libtool link_all_deplibs fixup. See http://bugs.lttng.org/issues/321.
  33 AC_ARG_ENABLE(libtool-linkdep-fixup,
  34         AS_HELP_STRING([--disable-libtool-linkdep-fixup],
  35                         [disable the libtool fixup for linking all dependent libraries (link_all_deplibs)]),
  36         libtool_fixup=$enableval,
  37         libtool_fixup=yes)
  38
  39 AS_IF([test "x$libtool_fixup" = "xyes"],
  40             [
  41             libtool_m4="$srcdir/config/libtool.m4"
  42             libtool_flag_pattern=".*link_all_deplibs\s*,\s*\$1\s*)"
  43             AC_MSG_CHECKING([for occurence(s) of link_all_deplibs = no in $libtool_m4])
  44             libtool_flag_pattern_count=$(grep -c "$libtool_flag_pattern\s*=\s*no" $libtool_m4)
  45             AS_IF([test $libtool_flag_pattern_count -ne 0],
  46             [
  47                   AC_MSG_RESULT([$libtool_flag_pattern_count])
  48                   AC_MSG_WARN([the detected libtool will not link all dependencies, forcing link_all_deplibs = unknown])
  49                   sed -i "s/\($libtool_flag_pattern\)\s*=\s*no/\1=unknown/g" $libtool_m4
  50                   ],
  51                   [
  52                   AC_MSG_RESULT([none])
  53                   ])
  54             ])
  55
  56 AM_CONDITIONAL([NO_SHARED], [test x$enable_shared = xno])
  57
  58 AC_CHECK_HEADERS([ \
  59         sys/types.h unistd.h fcntl.h string.h pthread.h limits.h \
  60         signal.h stdlib.h sys/un.h sys/socket.h stdlib.h stdio.h \
  61         getopt.h sys/ipc.h sys/shm.h popt.h grp.h \
  62 ])
  63
  64 # Babeltrace viewer check
  65 AC_ARG_WITH([babeltrace-bin],
  66         AS_HELP_STRING([--with-babeltrace-bin],
  67         [Location of the babeltrace viewer executable (including the filename)]),
  68         [BABELTRACE_BIN="$withval"],
  69         [BABELTRACE_BIN=''])
  70 AC_SUBST([BABELTRACE_BIN])
  71
  72 # lttv-gui
  73 AC_ARG_WITH([lttv-gui-bin],
  74         AS_HELP_STRING([--with-lttv-gui-bin],
  75    [Location of the lttv GUI viewer executable (including the filename)]),
  76    [LTTV_GUI_BIN="$withval"],
  77    [LTTV_GUI_BIN=''])
  78 AC_SUBST([LTTV_GUI_BIN])
  79
  80 AC_ARG_WITH([consumerd32-bin],
  81         AS_HELP_STRING([--with-consumerd32-bin],
  82         [Location of the 32-bit consumerd executable (including the filename)]),
  83         [CONSUMERD32_BIN="$withval"],
  84         [CONSUMERD32_BIN=''])
  85 AC_SUBST([CONSUMERD32_BIN])
  86
  87 AC_ARG_WITH([consumerd64-bin],
  88         AS_HELP_STRING([--with-consumerd64-bin],
  89         [Location of the 64-bit consumerd executable (including the filename)]),
  90         [CONSUMERD64_BIN="$withval"],
  91         [CONSUMERD64_BIN=''])
  92 AC_SUBST([CONSUMERD64_BIN])
  93
  94 AC_ARG_WITH([consumerd32-libdir],
  95         AS_HELP_STRING([--with-consumerd32-libdir],
  96         [Directory containing the 32-bit consumerd libraries]),
  97         [CONSUMERD32_LIBDIR="$withval"],
  98         [CONSUMERD32_LIBDIR=''])
  99 AC_SUBST([CONSUMERD32_LIBDIR])
 100
 101 AC_ARG_WITH([consumerd64-libdir],
 102         AS_HELP_STRING([--with-consumerd64-libdir],
 103         [Directory containing the 64-bit consumerd libraries]),
 104         [CONSUMERD64_LIBDIR="$withval"],
 105         [CONSUMERD64_LIBDIR=''])
 106 AC_SUBST([CONSUMERD64_LIBDIR])
 107
 108 AC_ARG_WITH([sessiond-bin],
 109         AS_HELP_STRING([--with-sessiond-bin],
 110         [Location of the sessiond executable (including the filename)]),
 111         [SESSIOND_BIN="$withval"],
 112         [SESSIOND_BIN=''])
 113 AC_SUBST([SESSIOND_BIN])
 114
 115 AC_ARG_WITH([lttng-system-rundir],
 116         AS_HELP_STRING([--with-lttng-system-rundir],
 117         [Location of the system directory where the system-wide lttng-sessiond runtime files are kept. The default is "/var/run/lttng".]),
 118         [LTTNG_SYSTEM_RUNDIR="$withval"],
 119         [LTTNG_SYSTEM_RUNDIR="/var/run/lttng"])
 120 AC_SUBST([LTTNG_SYSTEM_RUNDIR])
 121
 122 AC_DEFINE_UNQUOTED([CONFIG_CONSUMERD32_BIN], "$CONSUMERD32_BIN", [Location of the 32-bit consumerd executable.])
 123 AC_DEFINE_UNQUOTED([CONFIG_CONSUMERD64_BIN], "$CONSUMERD64_BIN", [Location of the 64-bit consumerd executable])
 124 AC_DEFINE_UNQUOTED([CONFIG_CONSUMERD32_LIBDIR], "$CONSUMERD32_LIBDIR", [Search for consumerd 32-bit libraries in this location.])
 125 AC_DEFINE_UNQUOTED([CONFIG_CONSUMERD64_LIBDIR], "$CONSUMERD64_LIBDIR", [Search for consumerd 64-bit libraries in this location.])
 126 AC_DEFINE_UNQUOTED([CONFIG_BABELTRACE_BIN], "$BABELTRACE_BIN", [Location of the babeltrace viewer executable.])
 127 AC_DEFINE_UNQUOTED([CONFIG_LTTV_GUI_BIN], "$LTTV_GUI_BIN", [Location of the lttv GUI viewer executable.])
 128 AC_DEFINE_UNQUOTED([CONFIG_SESSIOND_BIN], "$SESSIOND_BIN", [Location of the sessiond executable.])
 129 AC_DEFINE_UNQUOTED([CONFIG_LTTNG_SYSTEM_RUNDIR], ["$LTTNG_SYSTEM_RUNDIR"], [LTTng system runtime directory])
 130
 131 if test "x$prefix" = "xNONE"; then
 132         prefix=$ac_default_prefix
 133 fi
 134 CONFDIR=`eval echo $sysconfdir`
 135 AC_SUBST(CONFDIR)
 136 AC_DEFINE_UNQUOTED([CONFIG_LTTNG_SYSTEM_CONFIGDIR],"$CONFDIR", [LTTng system configuration directory.])
 137
 138 AC_DEFINE_DIR([CONFIG_LTTNG_SYSTEM_DATADIR],[datadir], [LTTng system data directory.])
 139
 140 #
 141 # Check for pthread
 142 AC_CHECK_LIB([pthread], [pthread_create], [],
 143         [AC_MSG_ERROR([Cannot find libpthread. Use [LDFLAGS]=-Ldir to specify its location.])]
 144 )
 145
 146 # Check libpopt
 147 AC_CHECK_LIB([popt], [poptGetContext], [],
 148         [AC_MSG_ERROR([Cannot find libpopt. Use [LDFLAGS]=-Ldir to specify its location.])]
 149 )
 150
 151 AM_PATH_XML2(2.7.6, true, AC_MSG_ERROR(No supported version of libxml2 found.))
 152
 153 # Check for libuuid
 154 AC_CHECK_LIB([uuid], [uuid_generate],
 155 [
 156         AC_DEFINE_UNQUOTED([LTTNG_HAVE_LIBUUID], 1, [Has libuuid support.])
 157         have_libuuid=yes
 158 ],
 159 [
 160         # libuuid not found, check for uuid_create in libc.
 161         AC_CHECK_LIB([c], [uuid_create],
 162         [
 163                 AC_DEFINE_UNQUOTED([LTTNG_HAVE_LIBC_UUID], 1, [Has libc uuid support.])
 164                 have_libc_uuid=yes
 165         ],
 166         [
 167                 AC_MSG_ERROR([Cannot find libuuid uuid_generate nor libc uuid_create. Use [LDFLAGS]=-Ldir to specify their location.])
 168         ])
 169 ]
 170 )
 171 AM_CONDITIONAL([LTTNG_BUILD_WITH_LIBUUID], [test "x$have_libuuid" = "xyes"])
 172 AM_CONDITIONAL([LTTNG_BUILD_WITH_LIBC_UUID], [test "x$have_libc_uuid" = "xyes"])
 173
 174 # URCU library version needed or newer
 175 liburcu_version=">= 0.7.2"
 176
 177 # Check liburcu needed function calls
 178 AC_CHECK_DECL([cds_list_add], [],
 179         [AC_MSG_ERROR([liburcu $liburcu_version or newer is needed])], [[#include <urcu/list.h>]]
 180 )
 181 AC_CHECK_DECL([cds_wfq_init], [],
 182         [AC_MSG_ERROR([liburcu $liburcu_version or newer is needed])], [[#include <urcu/wfqueue.h>]]
 183 )
 184 AC_CHECK_DECL([cds_wfq_dequeue_blocking], [],
 185     [AC_MSG_ERROR([liburcu $liburcu_version or newer is needed])], [[#include <urcu/wfqueue.h>]]
 186 )
 187 AC_CHECK_DECL([futex_async], [],
 188         [AC_MSG_ERROR([liburcu $liburcu_version or newer is needed])], [[#include <urcu/futex.h>]]
 189 )
 190 AC_CHECK_DECL([rcu_thread_offline], [],
 191         [AC_MSG_ERROR([liburcu $liburcu_version or newer is needed])], [[#include <urcu.h>]]
 192 )
 193 AC_CHECK_DECL([rcu_thread_online], [],
 194         [AC_MSG_ERROR([liburcu $liburcu_version or newer is needed])], [[#include <urcu.h>]]
 195 )
 196 AC_CHECK_DECL([caa_likely], [],
 197         [AC_MSG_ERROR([liburcu $liburcu_version or newer is needed])], [[#include <urcu.h>]]
 198 )
 199 #Function added in urcu 0.7.0
 200 AC_CHECK_DECL([cmm_smp_mb__before_uatomic_or], [],
 201         [AC_MSG_ERROR([liburcu $liburcu_version or newer is needed])], [[#include <urcu.h>]]
 202 )
 203
 204 AC_ARG_WITH(lttng-ust-prefix,
 205   AS_HELP_STRING([--with-lttng-ust-prefix=PATH],
 206                  [Specify the installation prefix of the lttng-ust library.
 207                   Headers must be in PATH/include; libraries in PATH/lib.]),
 208                   [
 209                     CPPFLAGS="$CPPFLAGS -I${withval}/include"
 210                     LDFLAGS="$LDFLAGS -L${withval}/lib64 -L${withval}/lib"
 211                   ])
 212
 213 # Check liblttng-ust-ctl library
 214 AC_ARG_ENABLE(lttng-ust,
 215         AS_HELP_STRING([--disable-lttng-ust],[build without LTTng-UST (Userspace Tracing) support]),
 216         lttng_ust_support=$enableval, lttng_ust_support=yes)
 217
 218 AS_IF([test "x$lttng_ust_support" = "xyes"], [
 219         AC_CHECK_LIB([lttng-ust-ctl], [ustctl_recv_channel_from_consumer],
 220                 [
 221                         AC_DEFINE([HAVE_LIBLTTNG_UST_CTL], [1], [has LTTng-UST control support])
 222                         lttng_ust_ctl_found=yes
 223                 ],
 224                 [AC_MSG_ERROR([Cannot find LTTng-UST >= 2.2.x. Use --with-lttng-ust-prefix=PREFIX to specify its location, or specify --disable-lttng-ust to build lttng-tools without LTTng-UST support.])],
 225                 [-lurcu-common -lurcu-bp -lurcu-cds -lrt]
 226         )
 227 ])
 228 AM_CONDITIONAL([HAVE_LIBLTTNG_UST_CTL], [test "x$lttng_ust_ctl_found" = xyes])
 229 AC_CHECK_FUNCS([sched_getcpu sysconf sync_file_range])
 230
 231 # check for dlopen
 232 AC_CHECK_LIB([dl], [dlopen],
 233 [
 234         have_libdl=yes
 235 ],
 236 [
 237         #libdl not found, check for dlopen in libc.
 238         AC_CHECK_LIB([c], [dlopen],
 239         [
 240                 have_libc_dl=yes
 241         ],
 242         [
 243                 AC_MSG_ERROR([Cannot find dlopen in libdl nor libc. Use [LDFLAGS]=-Ldir to specify their location.])
 244         ])
 245 ])
 246 AM_CONDITIONAL([LTTNG_TOOLS_BUILD_WITH_LIBDL], [test "x$have_libdl" = "xyes"])
 247 AM_CONDITIONAL([LTTNG_TOOLS_BUILD_WITH_LIBC_DL], [test "x$have_libc_dl" = "xyes"])
 248
 249 # Check for fmemopen
 250 AC_CHECK_LIB([c], [fmemopen],
 251 [
 252         AC_DEFINE_UNQUOTED([LTTNG_HAVE_FMEMOPEN], 1, [Has fmemopen support.])
 253 ]
 254 )
 255
 256 # Check for open_memstream
 257 AC_CHECK_LIB([c], [open_memstream],
 258 [
 259         AC_DEFINE_UNQUOTED([LTTNG_HAVE_OPEN_MEMSTREAM], 1, [Has open_memstream support.])
 260 ]
 261 )
 262
 263 # For Python
 264 # SWIG version needed or newer:
 265 swig_version=2.0.0
 266
 267 AC_ARG_ENABLE([python-bindings],
 268               [AC_HELP_STRING([--enable-python-bindings],
 269                               [compile Python bindings])],
 270               [enable_python=yes], [enable_python=no])
 271
 272 AM_CONDITIONAL([USE_PYTHON], [test "x${enable_python:-yes}" = xyes])
 273
 274 if test "x${enable_python:-yes}" = xyes; then
 275   AX_PKG_SWIG($swig_version, [], [ AC_MSG_ERROR([SWIG $swig_version or newer is needed]) ])
 276   AM_PATH_PYTHON
 277
 278   AC_ARG_VAR([PYTHON_INCLUDE], [Include flags for python, bypassing python-config])
 279   AC_ARG_VAR([PYTHON_CONFIG], [Path to python-config])
 280   AS_IF([test -z "$PYTHON_INCLUDE"], [
 281     AS_IF([test -z "$PYTHON_CONFIG"], [
 282       AC_PATH_PROGS([PYTHON_CONFIG],
 283                     [python$PYTHON_VERSION-config python-config],
 284                     [no],
 285                     [`dirname $PYTHON`])
 286       AS_IF([test "$PYTHON_CONFIG" = no], [AC_MSG_ERROR([cannot find python-config for $PYTHON. Do you have python-dev installed?])])
 287     ])
 288     AC_MSG_CHECKING([python include flags])
 289     PYTHON_INCLUDE=`$PYTHON_CONFIG --includes`
 290     AC_MSG_RESULT([$PYTHON_INCLUDE])
 291   ])
 292
 293 else
 294     AC_MSG_NOTICE([You may configure with --enable-python-bindings ]dnl
 295 [if you want Python bindings.])
 296
 297 fi
 298
 299 # Epoll check. If not present, the build will fallback on poll() API
 300 AX_HAVE_EPOLL(
 301         [AX_CONFIG_FEATURE_ENABLE(epoll)],
 302         [AX_CONFIG_FEATURE_DISABLE(epoll)]
 303 )
 304 AX_CONFIG_FEATURE(
 305         [epoll], [This platform supports epoll(7)],
 306         [HAVE_EPOLL], [This platform supports epoll(7).],
 307         [enable_epoll="yes"], [enable_epoll="no"]
 308 )
 309 AM_CONDITIONAL([COMPAT_EPOLL], [ test "$enable_epoll" = "yes" ])
 310
 311 # Set compile flags to java include files if given. This is only used to
 312 # compile JUL tests.
 313 AC_ARG_WITH([java-jdk],
 314         [AS_HELP_STRING([--with-java-jdk=DIR],[use the Java JDK in DIR. Ex : $JAVA_HOME.])],
 315         [JAVA_JDK=$withval],
 316         [JAVA_JDK=""]
 317 )
 318 AM_CONDITIONAL([HAVE_JAVA_JDK], [test $JAVA_JDK], [Java JDK path])
 319 AC_SUBST([JAVA_JDK])
 320
 321 AS_IF([test $JAVA_JDK],[
 322         AS_IF([test -d $JAVA_JDK],
 323                 [
 324                         AC_MSG_RESULT([using Java includes in $JAVA_SDK])
 325                         SUBDIRS=`find $JAVA_JDK/include -type d`
 326                         CPPFLAGS+=" "
 327                         CPPFLAGS+=`for x in $SUBDIRS; do echo -n "-I$x "; done`
 328                         CPPFLAGS+=" "
 329         ],[AC_MSG_ERROR(Unable to find Java include files in $JAVA_JDK)]
 330         )
 331 ])
 332
 333 # Check for the UST JUL jar file in the system. Hardcoded path is added here
 334 # since we have *no* idea where this could be installed. Note that this is only
 335 # used for JUL testing.
 336 AC_MSG_CHECKING(Java JUL UST jar file)
 337 java_jul_jar_path="/usr/local/lib/lttng/java/liblttng-ust-jul.jar"
 338 if test -f $java_jul_jar_path; then
 339         build_java_jul=yes
 340         AC_MSG_RESULT(found)
 341 else
 342         build_java_jul=no
 343         AC_MSG_RESULT(not found)
 344 fi
 345 AM_CONDITIONAL([BUILD_JAVA_JUL], [test "x$build_java_jul" = "xyes"])
 346 AC_SUBST([java_jul_jar_path])
 347
 348 AC_SYS_LARGEFILE
 349 AC_PROG_CC
 350 LT_INIT
 351 AC_PROG_YACC
 352 AC_PROG_LEX
 353
 354 if test ! -f "$srcdir/src/lib/lttng-ctl/filter/filter-parser.h"; then
 355         if test x"$YACC" != "xbison -y"; then
 356                 AC_MSG_ERROR([[bison not found and is required when building from git.
 357                 Please install bison]])
 358         fi
 359         AC_PATH_PROG([BISON],[bison])
 360         AX_PROG_BISON_VERSION([2.4], [],[
 361                 AC_MSG_ERROR([[Bison >= 2.4 is required when building from git]])
 362         ])
 363 fi
 364
 365 if test ! -f "$srcdir/src/lib/lttng-ctl/filter/filter-lexer.c"; then
 366         if test x"$LEX" != "xflex"; then
 367                 AC_MSG_ERROR([[flex not found and is required when building from git.
 368                 Please install flex]])
 369         fi
 370         AC_PATH_PROG([FLEX],[flex])
 371         AX_PROG_FLEX_VERSION([2.5.35], [],[
 372                 AC_MSG_ERROR([[Flex >= 2.5.35 is required when building from git]])
 373         ])
 374 fi
 375
 376 CFLAGS="-Wall $CFLAGS -g -fno-strict-aliasing"
 377
 378 DEFAULT_INCLUDES="-I\$(top_srcdir) -I\$(top_builddir) -I\$(top_builddir)/src -I\$(top_builddir)/include -include config.h"
 379
 380 lttngincludedir="${includedir}/lttng"
 381
 382 AC_SUBST(lttngincludedir)
 383 AC_SUBST(DEFAULT_INCLUDES)
 384
 385 lttnglibexecdir="${libdir}/lttng/libexec"
 386 AC_SUBST(lttnglibexecdir)
 387
 388 AC_CONFIG_FILES([
 389         Makefile
 390         doc/Makefile
 391         doc/man/Makefile
 392         include/Makefile
 393         extras/Makefile
 394         extras/bindings/Makefile
 395         extras/bindings/swig/Makefile
 396         extras/bindings/swig/python/Makefile
 397         extras/core-handler/Makefile
 398         src/Makefile
 399         src/common/Makefile
 400         src/common/kernel-ctl/Makefile
 401         src/common/kernel-consumer/Makefile
 402         src/common/ust-consumer/Makefile
 403         src/common/hashtable/Makefile
 404         src/common/sessiond-comm/Makefile
 405         src/common/compat/Makefile
 406         src/common/relayd/Makefile
 407         src/common/testpoint/Makefile
 408         src/common/index/Makefile
 409         src/common/health/Makefile
 410         src/common/config/Makefile
 411         src/lib/Makefile
 412         src/lib/lttng-ctl/Makefile
 413         src/lib/lttng-ctl/filter/Makefile
 414         src/lib/lttng-ctl/lttng-ctl.pc
 415         src/bin/Makefile
 416         src/bin/lttng-consumerd/Makefile
 417         src/bin/lttng-sessiond/Makefile
 418         src/bin/lttng-relayd/Makefile
 419         src/bin/lttng/Makefile
 420         tests/Makefile
 421         tests/regression/Makefile
 422         tests/regression/kernel/Makefile
 423         tests/regression/tools/Makefile
 424         tests/regression/tools/streaming/Makefile
 425         tests/regression/tools/filtering/Makefile
 426         tests/regression/tools/health/Makefile
 427         tests/regression/tools/tracefile-limits/Makefile
 428         tests/regression/tools/snapshots/Makefile
 429         tests/regression/tools/live/Makefile
 430         tests/regression/tools/exclusion/Makefile
 431         tests/regression/tools/save-load/Makefile
 432         tests/regression/ust/Makefile
 433         tests/regression/ust/nprocesses/Makefile
 434         tests/regression/ust/high-throughput/Makefile
 435         tests/regression/ust/low-throughput/Makefile
 436         tests/regression/ust/before-after/Makefile
 437         tests/regression/ust/buffers-pid/Makefile
 438         tests/regression/ust/periodical-metadata-flush/Makefile
 439         tests/regression/ust/multi-session/Makefile
 440         tests/regression/ust/overlap/Makefile
 441         tests/regression/ust/overlap/demo/Makefile
 442         tests/regression/ust/linking/Makefile
 443         tests/regression/ust/daemon/Makefile
 444         tests/regression/ust/exit-fast/Makefile
 445         tests/regression/ust/fork/Makefile
 446         tests/regression/ust/libc-wrapper/Makefile
 447         tests/regression/ust/java-jul/Makefile
 448         tests/stress/Makefile
 449         tests/unit/Makefile
 450         tests/unit/ini_config/Makefile
 451         tests/utils/Makefile
 452         tests/utils/tap/Makefile
 453         tests/utils/testapp/Makefile
 454         tests/utils/testapp/gen-ust-events/Makefile
 455         tests/utils/testapp/gen-ust-nevents/Makefile
 456         tests/utils/testapp/gen-ust-tracef/Makefile
 457 ])
 458
 459 AC_OUTPUT
 460
 461 #
 462 # Mini-report on what will be built
 463 #
 464 AS_ECHO()
 465
 466 AS_ECHO("Version name: $version_name")
 467 AS_ECHO("$version_description")
 468
 469 AS_ECHO()
 470
 471 # Target architecture we're building for
 472 target_arch=$host_cpu
 473 [
 474 for f in $CFLAGS; do
 475         if test $f = "-m32"; then
 476                         target_arch="32-bit"
 477         elif test $f = "-m64"; then
 478                         target_arch="64-bit"
 479         fi
 480 done
 481 ]
 482 AS_ECHO_N("Target architecture: ")
 483 AS_ECHO($target_arch)
 484
 485 # LTTng-UST enabled/disabled
 486 AS_ECHO_N("Lttng-UST support: ")
 487 AS_IF([test "x$lttng_ust_support" = "xyes"],[
 488         AS_ECHO("Enabled")
 489 ],[
 490         AS_ECHO("Disabled")
 491 ])
 492
 493 #Python binding enabled/disabled
 494 AS_ECHO_N("Python binding: ")
 495 AS_IF([test "x${enable_python:-yes}" = xyes], [
 496         AS_ECHO("Enabled")
 497 ],[
 498         AS_ECHO("Disabled")
 499 ])
 500
 501 # Do we build only the consumerd, or everything
 502 AS_IF([test "x$consumerd_only" = "xyes"],[
 503         AS_ECHO("Only the consumerd daemon will be built.")
 504 ],[
 505         AS_ECHO("All binaries will be built.")
 506 ])
 507
 508 # Print the bindir and libdir this `make install' will install into.
 509 AS_ECHO()
 510 AS_ECHO_N("Binaries will be installed in:  ")
 511 AS_ECHO("`eval eval echo $bindir`")
 512 AS_ECHO_N("Libraries will be installed in: ")
 513 AS_ECHO("`eval eval echo $libdir`")
 514
 515 # If we build the sessiond, print the paths it will use
 516 AS_IF([test "x$consumerd_only" = "xno"],[
 517         AS_ECHO()
 518         AS_ECHO_N("The lttng command will look for the lttng-sessiond executable at: ")
 519         AS_IF([test "$SESSIOND_BIN" = ""],[
 520                 AS_ECHO_N("`eval eval echo $bindir`")
 521                 AS_ECHO("/lttng-sessiond")
 522         ],[
 523                 AS_ECHO("$SESSIOND_BIN")
 524         ])
 525
 526         AS_ECHO()
 527         AS_ECHO("The sessiond daemon will look in the following directories: ")
 528         AS_ECHO_N("32-bit consumerd executable at: ")
 529         AS_IF([test "$CONSUMERD32_BIN" = ""],[
 530                 AS_ECHO_N("`eval eval echo $lttnglibexecdir`")
 531                 AS_ECHO("/lttng-consumerd")
 532         ],[
 533                 AS_ECHO("$CONSUMERD32_BIN")
 534         ])
 535
 536         AS_ECHO_N("32-bit consumer libraries in:   ")
 537         AS_IF([test "$CONSUMERD32_LIBDIR" = ""],[
 538                 AS_ECHO("`eval eval echo $libdir`")
 539         ],[
 540                 AS_ECHO("$CONSUMERD32_LIBDIR")
 541         ])
 542
 543         AS_ECHO_N("64-bit consumerd executable at: ")
 544         AS_IF([test "$CONSUMERD64_BIN" = ""],[
 545                 AS_ECHO_N("`eval eval echo $lttnglibexecdir`")
 546                 AS_ECHO("/lttng-consumerd")
 547         ],[
 548                 AS_ECHO("$CONSUMERD64_BIN")
 549         ])
 550
 551         AS_ECHO_N("64-bit consumer libraries in:   ")
 552         AS_IF([test "$CONSUMERD64_LIBDIR" = ""],[
 553                 AS_ECHO("`eval eval echo $libdir`")
 554         ],[
 555                 AS_ECHO("$CONSUMERD64_LIBDIR")
 556         ])
 557 ])
 558
 559 AS_ECHO()
 560