Cleanup the JNI interface options in configure.ac

[lttng-ust.git] / configure.ac

diff --git a/configure.ac b/configure.ac
index d3cac78f9954b23a1af7353abd9197a8909ef5d5..454664f9c32811e80c7ea178029b338063a9b7b1 100644 (file)
--- a/configure.ac
+++ b/configure.ac
@@ -1,7 +1,7 @@
 #                                               -*- Autoconf -*-
 # Process this file with autoconf to produce a configure script.
 
-AC_INIT([lttng-ust], [1.9.0], [mathieu dot desnoyers at efficios dot com])
+AC_INIT([lttng-ust],[1.9.0],[mathieu dot desnoyers at efficios dot com])
 AC_CONFIG_AUX_DIR([config])
 AC_CANONICAL_TARGET
 AC_CANONICAL_HOST
@@ -27,8 +27,9 @@ AC_DEFINE_UNQUOTED([VERSION_PATCHLEVEL], $patchlevel_version, [UST patchlevel ve
 
 # Checks for programs.
 AC_PROG_CC
+AC_PROG_CXX
 AC_PROG_MAKE_SET
-AC_PROG_LIBTOOL
+LT_INIT
 
 ## Checks for libraries.
 AC_CHECK_LIB([dl], [dlopen])
@@ -63,6 +64,13 @@ AC_CHECK_FUNCS([gettimeofday munmap socket strerror strtol])
 
 CFLAGS="-Wall $CFLAGS"
 
+# Check for texinfo, required for building the documentation
+# TODO: make this (and building the documentation) optional
+AC_CHECK_PROG([TEXINFO], [makeinfo], [yes])
+AS_IF([test "x$TEXINFO" != "xyes"],[
+       AC_MSG_ERROR([Please install the 'texinfo' program and make sure 'makeinfo' is in the PATH.])
+])
+
 # URCU
 
 # urcu - check if we just find the headers it out of the box.
@@ -70,25 +78,21 @@ AC_CHECK_HEADERS([urcu-bp.h], [], [AC_MSG_ERROR([Cannot find [URCU] headers (urc
 This error can also occur when the liburcu package's configure script has not been run.])])
 
 AC_MSG_CHECKING([caa_likely()])
-AC_TRY_COMPILE(
-[
+AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 #include <urcu/compiler.h>
-],
-[
+]], [[
 void fct(void)
 {
        if (caa_likely(1)) {
        }
 }
-],
-[
+]])],[
        AC_MSG_RESULT([yes])
-],
-[
+],[
        AC_MSG_RESULT([no])
        AC_MSG_ERROR([Please upgrade your version of liburcu to 0.6.6 or better])
-]
-)
+
+])
 
 # urcu - check that URCU lib is available to compilation
 AC_CHECK_LIB([urcu-bp], [synchronize_rcu_bp], [], [AC_MSG_ERROR([Cannot find liburcu-bp lib. Use [LDFLAGS]=-Ldir to specify its location.])])
@@ -145,57 +149,57 @@ AC_MSG_RESULT($LIBFORMAT)
 
 if test "x$host_cpu" = "xarm" ; then
 AC_MSG_CHECKING([checking for armv5])
-AC_TRY_COMPILE(
-[
-],
-[
+AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
+]], [[
 #ifndef __ARM_ARCH_5TEJ__
 #error "no arm5 here"
 #endif
-],
-[
+]])],[
        AC_MSG_RESULT([yes])
        NO_UNALIGNED_ACCESS=1
-]
-,
-[
+
+],[
        AC_MSG_RESULT([no])
-]
-)
+
+])
 fi
 if test x$NO_UNALIGNED_ACCESS = x ; then
 AC_DEFINE([HAVE_EFFICIENT_UNALIGNED_ACCESS], [1])
 fi
 
 # Set compile flags to java include files if given
-AC_ARG_WITH(java_jdk, [  --with-java-jdk=DIR     use java jdk from DIR. Ex : $JAVA_HOME.], JAVA_SDK=$withval,)
-if test $JAVA_SDK; then
-        if test -d $JAVA_SDK; then
-                AC_MSG_RESULT([using java include in $JAVA_SDK])
-                SUBDIRS=`find $JAVA_SDK/include -type d`
+AC_ARG_WITH([java-jdk],
+       [AS_HELP_STRING([--with-java-jdk=DIR],[use the Java JDK in DIR. Ex : $JAVA_HOME.])],
+       [JAVA_JDK=$withval],
+       [JAVA_JDK=""]
+)
+AS_IF([test $JAVA_JDK],[
+       AS_IF([test -d $JAVA_JDK],[
+                AC_MSG_RESULT([using Java includes in $JAVA_SDK])
+                SUBDIRS=`find $JAVA_JDK/include -type d`
                CFLAGS+=" "
                 CFLAGS+=`for x in $SUBDIRS; do echo -n "-I$x "; done`
                CFLAGS+=" "
-        else
-                AC_MSG_ERROR(Unable to find java include file in $JAVA_JDK)
-        fi
-fi
+        ],[
+                AC_MSG_ERROR(Unable to find Java include files in $JAVA_JDK)
+        ])
+])
 
 # Check for JNI header files if requested
-AC_ARG_WITH(jni-interface, [  --with-jni-interface    build JNI interface between C and java. Need java include files.
-                         [[default=no]]])
-
-if test -z "$with_jni_interface"; then
-        with_jni_interface=${with_jni_interface_default-no}
-fi
+AC_ARG_WITH([jni-interface],
+       [AS_HELP_STRING([--with-jni-interface],[build JNI interface between C and Java. Needs Java include files [default=no]])],
+       [jni_interface=$withval],
+       [jni_interface=no]
+)
 
-if test "$with_jni_interface" = "yes"; then
-        AC_CHECK_HEADERS([jni.h],,AC_MSG_ERROR([
-missing jni.h
-Make sure Sun Java or OpenJDK or GCJ is installed and that this header file exists in the system path.
-Use --with-java-jdk=DIR flag to point to your java include files or desactivate the JNI interface.]))
-fi
-AM_CONDITIONAL(BUILD_JNI_INTERFACE, test "$with_jni_interface" = "yes")
+AS_IF([test "x$jni_interface" = "xyes"],[
+        AC_CHECK_HEADERS([jni.h],[],[
+        AC_MSG_ERROR([missing jni.h
+Make sure Sun Java, OpenJDK or GCJ is installed and that this header file exists in the system path.
+Use the --with-java-jdk=DIR flag to point to your Java include files, or disable the JNI interface.])
+       ])
+])
+AM_CONDITIONAL([BUILD_JNI_INTERFACE], [test "x$jni_interface" = "xyes"])
 
 #currently disabled.
        #liblttng-ust-malloc/Makefile
@@ -231,6 +235,7 @@ AC_CONFIG_FILES([
        liblttng-ust-java/Makefile
        tests/Makefile
        tests/hello/Makefile
+       tests/hello.cxx/Makefile
        tests/demo/Makefile
        tests/fork/Makefile
        tests/ust-basic-tracing/Makefile