configure.ac

   1 #                                               -*- Autoconf -*-
   2 # Process this file with autoconf to produce a configure script.
   3
   4
   5 AC_INIT([userspace-rcu], [0.6.3], [mathieu dot desnoyers at efficios dot com])
   6
   7 # Following the numbering scheme proposed by libtool for the library version
   8 # http://www.gnu.org/software/libtool/manual/html_node/Updating-version-info.html
   9 AC_SUBST([URCU_LIBRARY_VERSION], [1:0:0])
  10
  11 AC_CONFIG_AUX_DIR([config])
  12 AC_CANONICAL_TARGET
  13 AC_CANONICAL_HOST
  14 AM_INIT_AUTOMAKE([foreign dist-bzip2 no-dist-gzip])
  15 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  16
  17 AC_CONFIG_SRCDIR([urcu.h])
  18 AM_PROG_MKDIR_P
  19
  20 AC_CONFIG_HEADERS([config.h urcu/config.h])
  21
  22 #for tests
  23 AM_PATH_GLIB_2_0(2.22.0, ,AC_MSG_ERROR([glib is required in order to compile BabelTrace - download it from ftp://ftp.gtk.org/pub/gtk]) , gmodule)
  24
  25 # Keep at the end to do not pollute installed header.
  26 AH_TEMPLATE([CONFIG_RCU_SMP], [Enable SMP support. With SMP support enabled, uniprocessors are also supported. With SMP support disabled, UP systems work fine, but the behavior of SMP systems is undefined.])
  27 AH_TEMPLATE([CONFIG_RCU_HAVE_FENCE], [Defined when on a system that has memory fence instructions.])
  28 AH_TEMPLATE([CONFIG_RCU_HAVE_FUTEX], [Defined when on a system with futex support.])
  29 AH_TEMPLATE([CONFIG_RCU_COMPAT_ARCH], [Compatibility mode for i386 which lacks
  30 cmpxchg instruction.])
  31 AH_TEMPLATE([CONFIG_RCU_ARM_HAVE_DMB], [Use the dmb instruction is available for use on ARM.])
  32
  33 # Checks for programs.
  34 AC_PROG_CC
  35 AC_PROG_MAKE_SET
  36 AC_PROG_LIBTOOL
  37
  38 # Checks for typedefs, structures, and compiler characteristics.
  39 AC_C_INLINE
  40 AC_TYPE_PID_T
  41 AC_TYPE_SIZE_T
  42
  43 # Checks for library functions.
  44 AC_FUNC_MALLOC
  45 AC_FUNC_MMAP
  46 AC_CHECK_FUNCS([bzero gettimeofday munmap sched_getcpu strtoul sysconf])
  47
  48 # Find arch type
  49 case $host_cpu in
  50         i386) ARCHTYPE="x86"; SUBARCHTYPE="x86compat" ;;
  51         i486) ARCHTYPE="x86";;
  52         i586) ARCHTYPE="x86";;
  53         i686) ARCHTYPE="x86";;
  54         x86_64) ARCHTYPE="x86";;
  55         powerpc) ARCHTYPE="ppc" ;;
  56         ppc64) ARCHTYPE="ppc" ;;
  57         powerpc64) ARCHTYPE="ppc" ;;
  58         ppc) ARCHTYPE="ppc" ;;
  59         s390) ARCHTYPE="s390" ;;
  60         s390x) ARCHTYPE="s390" ;;
  61         sparc64) ARCHTYPE="sparc64" ;;
  62         alpha*) ARCHTYPE="alpha" ;;
  63         ia64) ARCHTYPE="gcc" ;;
  64         arm*) ARCHTYPE="arm" ;;
  65         *) ARCHTYPE="unknown";;
  66 esac
  67
  68 if test "x$ARCHTYPE" = "xarm" ; then
  69 AC_MSG_CHECKING([checking for dmb instruction])
  70 AC_TRY_COMPILE(
  71 [
  72 ],
  73 [
  74 asm volatile("dmb":::"memory");
  75 ],
  76 [
  77         AC_MSG_RESULT([yes])
  78         AC_DEFINE([CONFIG_RCU_ARM_HAVE_DMB], [1])
  79 ]
  80 ,
  81 [
  82         AC_MSG_RESULT([no])
  83 ]
  84 )
  85 fi
  86
  87 UATOMICSRC=urcu/uatomic/$ARCHTYPE.h
  88 ARCHSRC=urcu/arch/$ARCHTYPE.h
  89 if test "x$ARCHTYPE" != xx86 -a "x$ARCHTYPE" != xppc; then
  90         APISRC=tests/api_gcc.h
  91 else
  92         APISRC=tests/api_$ARCHTYPE.h
  93 fi
  94 if test "$ARCHTYPE" == "armv7l"; then
  95         CFLAGS="-mcpu=cortex-a9 -mtune=cortex-a9 -O"
  96 fi
  97
  98 AC_SUBST(ARCHTYPE)
  99 AC_SUBST(SUBARCHTYPE)
 100
 101 [
 102 #if test "x$ARCHTYPE" = "xx86" -a "x$host_cpu" != "xi386" -a "x$host_cpu" != "xi486" -a "x$host_cpu" != "xi586"; then
 103 #For now, using lock; addl compatibility mode even for i686, because the
 104 #Pentium III is seen as a i686, but lacks mfence instruction.
 105 #Only using fence for x86_64.
 106 if test "x$ARCHTYPE" = "xx86" -a "x$host_cpu" != "xi386" -a "x$host_cpu" != "xi486" -a "x$host_cpu" != "xi586" -a "x$host_cpu" != "xi686"; then
 107 ]
 108         AC_DEFINE([CONFIG_RCU_HAVE_FENCE], [1])
 109 [
 110 fi
 111 ]
 112
 113 AC_MSG_CHECKING([sys_futex()])
 114 AC_TRY_COMPILE(
 115 [
 116 #include <sys/syscall.h>
 117 ],
 118 [
 119 #ifndef __NR_futex
 120 #error "futexes not available"
 121 #endif
 122 ],
 123 [
 124         AC_MSG_RESULT([yes])
 125         AC_DEFINE([CONFIG_RCU_HAVE_FUTEX], [1])
 126         compat_futex_test=0
 127 ]
 128 ,
 129 [
 130         AC_MSG_RESULT([no])
 131         compat_futex_test=1
 132 ]
 133 )
 134
 135 AM_CONDITIONAL([COMPAT_FUTEX], [ test "x$compat_futex_test" = "x1" ])
 136
 137 AM_CONDITIONAL([COMPAT_ARCH], [test "x$SUBARCHTYPE" = xx86compat ])
 138
 139 [
 140 if test "x$SUBARCHTYPE" = xx86compat; then
 141 ]
 142         AC_DEFINE([CONFIG_RCU_COMPAT_ARCH], [1])
 143 [
 144 fi
 145 ]
 146
 147 AC_ARG_ENABLE([smp-support], [  --disable-smp-support   Disable SMP support. Warning: only use this
 148                           on uniprocessor systems. [[default=enabled]]], [def_smp_support=$enableval], [def_smp_support="yes"])
 149
 150 [
 151 if test "$def_smp_support" = "no"; then
 152         echo "SMP support disabled."
 153 else
 154 ]
 155         AC_DEFINE([CONFIG_RCU_SMP], [1])
 156 [
 157         echo "SMP support enabled."
 158 fi
 159 ]
 160
 161 # From the sched_setaffinity(2)'s man page:
 162 # ~~~~
 163 # The CPU affinity system calls were introduced in Linux kernel 2.5.8.
 164 # The library interfaces were introduced in glibc 2.3.  Initially, the
 165 # glibc interfaces included a cpusetsize argument.  In glibc 2.3.3,
 166 # the cpuset size argument was removed, but this argument was
 167 # restored in glibc 2.3.4.
 168 # ~~~~
 169
 170 # In addition to that, some vendors ported the system call to 2.4
 171 # kernels.
 172
 173 # Furthermore, when the function first appeared, the MASK argument was
 174 # an unsigned long pointer, while later it was made into a cpu_set_t
 175 # pointer.  Systems that have the cpu_set_t version also should have
 176 # the CPU_ZERO, CPU_SET, etc. macros.
 177
 178 # All this mess means we have to cater for at least 3 different
 179 # sched_setaffinity prototypes:
 180
 181 # ~~~~
 182 #  int sched_setaffinity (pid_t pid, unsigned int len, unsigned long *mask);
 183 #  int sched_setaffinity (pid_t __pid, size_t __cpusetsize, const cpu_set_t *__cpuset);
 184 #  int sched_setaffinity (pid_t __pid, const cpu_set_t *__mask);
 185 # ~~~~
 186
 187 dnl Since we define _GNU_SOURCE in the sources, must do so too in the
 188 dnl autoconf tests, as defining _GNU_SOURCE or not exposes
 189 dnl sched_setaffinity bits differently.
 190 saved_CFLAGS=$CFLAGS
 191 CFLAGS="$CFLAGS -D_GNU_SOURCE"
 192
 193 # First check if the function is available at all.
 194 AC_CHECK_FUNCS(
 195   [sched_setaffinity],
 196   [ # Okay, we have it.  Check if also have cpu_set_t.  If we don't,
 197     # then we have the first version using unsigned long, and no
 198     # CPU_ZERO, etc. macros.  If we do have cpu_set_t, we may have the
 199     # version with 2 or 3 arguments.  In that case, CPU_ZERO, etc.,
 200     # should also be present, but we confirm nonetheless.
 201
 202     AC_CHECK_TYPES(
 203       [cpu_set_t],
 204       [ # We do have it.  Confirm that we have CPU_ZERO, and it actually works.
 205         AC_MSG_CHECKING([whether CPU_ZERO works])
 206         AH_TEMPLATE([HAVE_CPU_ZERO],
 207                     [Define to 1 if we have CPU_ZERO and if it works])
 208         AC_COMPILE_IFELSE(
 209           [AC_LANG_PROGRAM(
 210             [#define _GNU_SOURCE
 211             #include <sched.h>],
 212             [cpu_set_t foo; CPU_ZERO (&foo);])
 213           ],
 214           [ # Works!
 215             AC_DEFINE(HAVE_CPU_ZERO, 1)
 216             AC_MSG_RESULT([yes])
 217           ],
 218           [AC_MSG_RESULT([no])]
 219         )
 220
 221         # Check how many arguments does sched_setaffinity take.
 222         # Should be 3 or 2.
 223         AC_MSG_CHECKING([how many arguments sched_setaffinity takes])
 224         AC_COMPILE_IFELSE(
 225           [AC_LANG_PROGRAM(
 226             [#include <sched.h>],
 227             [cpu_set_t foo; sched_setaffinity (0, sizeof (foo), &foo);])
 228           ],
 229           [sched_set_affinity_args=3],
 230           [sched_set_affinity_args=2])
 231         AC_DEFINE_UNQUOTED(SCHED_SETAFFINITY_ARGS, $sched_set_affinity_args,
 232          [Define to sched_setaffinity's number of arguments.])
 233         AC_MSG_RESULT([$sched_set_affinity_args])
 234       ],
 235       [ # No cpu_set_t, always 3 args.
 236         AC_DEFINE(SCHED_SETAFFINITY_ARGS, 3) ],
 237       [#include <sched.h>]
 238     )
 239   ]
 240 )
 241
 242 CFLAGS=$saved_CFLAGS
 243
 244 AC_CONFIG_LINKS([
 245         urcu/arch.h:$ARCHSRC
 246         urcu/uatomic.h:$UATOMICSRC
 247         tests/api.h:$APISRC
 248 ])
 249 AC_CONFIG_FILES([
 250         Makefile
 251         tests/Makefile
 252         liburcu-cds.pc
 253         liburcu.pc
 254         liburcu-bp.pc
 255         liburcu-qsbr.pc
 256         liburcu-mb.pc
 257         liburcu-signal.pc
 258 ])
 259 AC_OUTPUT